libstdc++-v3/aclocal.m4

   1 dnl aclocal.m4 generated automatically by aclocal 1.4
   2
   3 dnl Copyright (C) 1994, 1995-8, 1999 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  10 dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  11 dnl PARTICULAR PURPOSE.
  12
  13 dnl
  14 dnl Initialize configure bits.
  15 dnl
  16 dnl Define OPTLEVEL='-O2' if new inlining code present.
  17 dnl
  18 dnl GLIBCPP_CONFIGURE
  19 AC_DEFUN(GLIBCPP_CONFIGURE, [
  20   dnl Default to --enable-multilib
  21   AC_ARG_ENABLE(multilib,
  22   [  --enable-multilib       build hella library versions (default)],
  23   [case "${enableval}" in
  24     yes) multilib=yes ;;
  25     no)  multilib=no ;;
  26     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  27    esac], [multilib=yes])dnl
  28
  29   glibcpp_basedir=$auxdir/$1/libstdc++-v3
  30   AC_SUBST(glibcpp_basedir)
  31
  32   AM_INIT_AUTOMAKE(libstdc++, 2.91)
  33
  34   # Never versions of autoconf add an underscore to these functions.
  35   # Prevent future problems ...
  36   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  37   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  38   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  39   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  40
  41 #  AC_PROG_CC
  42
  43 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  44 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  45 # are probably using a cross compiler, which will not be able to fully
  46 # link an executable.  This should really be fixed in autoconf
  47 # itself.
  48
  49 AC_DEFUN(LIB_AC_PROG_CC,
  50 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  51 dnl Fool anybody using AC_PROG_CC.
  52 AC_PROVIDE([AC_PROG_CC])
  53 AC_CHECK_PROG(CC, gcc, gcc)
  54 if test -z "$CC"; then
  55   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  56   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  57 fi
  58
  59 AC_PROG_CC_GNU
  60
  61 if test $ac_cv_prog_gcc = yes; then
  62   GCC=yes
  63 dnl Check whether -g works, even if CFLAGS is set, in case the package
  64 dnl plays around with CFLAGS (such as to build both debugging and
  65 dnl normal versions of a library), tasteless as that idea is.
  66   ac_test_CFLAGS="${CFLAGS+set}"
  67   ac_save_CFLAGS="$CFLAGS"
  68   CFLAGS=
  69   AC_PROG_CC_G
  70   if test "$ac_test_CFLAGS" = set; then
  71     CFLAGS="$ac_save_CFLAGS"
  72   elif test $ac_cv_prog_cc_g = yes; then
  73     CFLAGS="-g -O2"
  74   else
  75     CFLAGS="-O2"
  76   fi
  77 else
  78   GCC=
  79   test "${CFLAGS+set}" = set || CFLAGS="-g"
  80 fi
  81 ])
  82
  83 LIB_AC_PROG_CC
  84
  85 # Can't just call these here as g++ requires libstc++ to be built....
  86 #  AC_PROG_CXX
  87
  88 # Likewise for AC_PROG_CXX.
  89 AC_DEFUN(LIB_AC_PROG_CXX,
  90 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
  91 dnl Fool anybody using AC_PROG_CXX.
  92 AC_PROVIDE([AC_PROG_CXX])
  93 # Use glibcpp_CXX so that we do not cause CXX to be cached with the
  94 # flags that come in CXX while configuring libstdc++.  They're different
  95 # from those used for all other target libraries.  If CXX is set in
  96 # the environment, respect that here.
  97 glibcpp_CXX=$CXX
  98 AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
  99 AC_SUBST(glibcpp_CXX)
 100 CXX=$glibcpp_CXX
 101 test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 102
 103 AC_PROG_CXX_GNU
 104
 105 if test $ac_cv_prog_gxx = yes; then
 106   GXX=yes
 107 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 108 dnl plays around with CXXFLAGS (such as to build both debugging and
 109 dnl normal versions of a library), tasteless as that idea is.
 110   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 111   ac_save_CXXFLAGS="$CXXFLAGS"
 112   CXXFLAGS=
 113   AC_PROG_CXX_G
 114   if test "$ac_test_CXXFLAGS" = set; then
 115     CXXFLAGS="$ac_save_CXXFLAGS"
 116   elif test $ac_cv_prog_cxx_g = yes; then
 117     CXXFLAGS="-g -O2"
 118   else
 119     CXXFLAGS="-O2"
 120   fi
 121 else
 122   GXX=
 123   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 124 fi
 125 ])
 126
 127 LIB_AC_PROG_CXX
 128
 129   AC_CHECK_TOOL(AS, as)
 130   AC_CHECK_TOOL(AR, ar)
 131   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 132   AC_CHECK_TOOL(glibcpp_expect, expect, expect-not-found-in-path-error)
 133   AC_CHECK_TOOL(glibcpp_runtest, runtest, runtest-not-found-in-path-error)
 134   AC_SUBST(glibcpp_expect)
 135   AC_SUBST(glibcpp_runtest)
 136   AC_PROG_INSTALL
 137
 138   AM_MAINTAINER_MODE
 139
 140   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 141   # at least currently, we never actually build a program, so we never
 142   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 143   # fails, because we are probably configuring with a cross compiler
 144   # which cant create executables.  So we include AC_EXEEXT to keep
 145   # automake happy, but we dont execute it, since we dont care about
 146   # the result.
 147   if false; then
 148     AC_EXEEXT
 149   fi
 150
 151   . [$]{glibcpp_basedir}/configure.host
 152
 153   case [$]{glibcpp_basedir} in
 154     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 155     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 156   esac
 157
 158   # This does for the target what configure.host does for the host.  In
 159   # addition to possibly modifying the same flags, it also sets up symlinks.
 160   GLIBCPP_CHECK_TARGET
 161 ])
 162
 163
 164 dnl
 165 dnl Check to see if g++ can compile this library, and if so, if any version-
 166 dnl specific precautions need to be taken.
 167 dnl
 168 dnl GLIBCPP_CHECK_COMPILER_VERSION
 169 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 170 if test ! -f stamp-sanity-compiler; then
 171   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 172   AC_LANG_SAVE
 173   AC_LANG_CPLUSPLUS
 174   AC_EGREP_CPP(ok, [
 175   #if __GNUC__ >= 3
 176     ok
 177   #endif
 178   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 179   AC_LANG_RESTORE
 180   AC_MSG_RESULT($gpp_satisfactory)
 181   touch stamp-sanity-compiler
 182 fi
 183 ])
 184
 185
 186 dnl
 187 dnl Test for newer compiler features, or features that are present in newer
 188 dnl compiler version but not older compiler versions should be placed
 189 dnl here.
 190 dnl
 191 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 192 dnl new inlining code or the new system_header pragma will die on -Werror.
 193 dnl Leave it out by default and use maint-mode to use it.
 194 dnl
 195 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 196 dnl compiler supports it and the user has not requested debug mode.
 197 dnl
 198 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 199 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 200   # All these tests are for C++; save the language and the compiler flags.
 201   # The CXXFLAGS thing is suspicious, but based on similar bits
 202   # found in GLIBCPP_CONFIGURE.
 203   AC_LANG_SAVE
 204   AC_LANG_CPLUSPLUS
 205   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 206   ac_save_CXXFLAGS="$CXXFLAGS"
 207
 208   # Check for maintainer-mode bits.
 209   if test x"$USE_MAINTAINER_MODE" = xno; then
 210     WERROR=''
 211   else
 212     WERROR='-Werror'
 213   fi
 214
 215   # Check for -ffunction-sections -fdata-sections
 216   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 217   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 218   AC_TRY_COMPILE(, [int foo;
 219   ], [ac_fdsections=yes], [ac_fdsections=no])
 220   if test "$ac_test_CXXFLAGS" = set; then
 221     CXXFLAGS="$ac_save_CXXFLAGS"
 222   else
 223     # this is the suspicious part
 224     CXXFLAGS=''
 225   fi
 226   if test x"$ac_fdsections" = x"yes" && test x"$enable_debug" = x"no"; then
 227     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 228   fi
 229   AC_MSG_RESULT($ac_fdsections)
 230
 231   AC_LANG_RESTORE
 232   AC_SUBST(WERROR)
 233   AC_SUBST(SECTION_FLAGS)
 234 ])
 235
 236
 237 dnl
 238 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 239 dnl the native linker is in use, all variables will be defined to something
 240 dnl safe (like an empty string).
 241 dnl
 242 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 243 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 244 dnl
 245 dnl GLIBCPP_CHECK_LINKER_FEATURES
 246 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 247   # If we're not using GNU ld, then there's no point in even trying these
 248   # tests.  Check for that first.  We should have already tested for gld
 249   # by now (in libtool), but require it now just to be safe...
 250   SECTION_LDFLAGS=''
 251   OPT_LDFLAGS=''
 252   AC_REQUIRE([AC_PROG_LD])
 253
 254   # Set --gc-sections.
 255   if test "$ac_cv_prog_gnu_ld" = "notbroken"; then
 256     # GNU ld it is!  Joy and bunny rabbits!
 257
 258     # All these tests are for C++; save the language and the compiler flags.
 259     # Need to do this so that g++ won't try to link in libstdc++
 260     ac_test_CFLAGS="${CFLAGS+set}"
 261     ac_save_CFLAGS="$CFLAGS"
 262     CFLAGS='-x c++  -Wl,--gc-sections'
 263
 264     # Check for -Wl,--gc-sections
 265     # XXX This test is broken at the moment, as symbols required for
 266     # linking are now in libsupc++ (not built yet.....). In addition,
 267     # this test has cored on solaris in the past. In addition,
 268     # --gc-sections doesn't really work at the moment (keeps on discarding
 269     # used sections, first .eh_frame and now some of the glibc sections for
 270     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 271     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 272     AC_TRY_RUN([
 273      int main(void)
 274      {
 275        try { throw 1; }
 276        catch (...) { };
 277        return 0;
 278      }
 279     ], [ac_sectionLDflags=yes],[ac_sectionLFflags=no], [ac_sectionLDflags=yes])
 280     if test "$ac_test_CFLAGS" = set; then
 281       CFLAGS="$ac_save_CFLAGS"
 282     else
 283       # this is the suspicious part
 284       CFLAGS=''
 285     fi
 286     if test "$ac_sectionLDflags" = "yes"; then
 287       SECTION_LDFLAGS='-Wl,--gc-sections'
 288     fi
 289     AC_MSG_RESULT($ac_sectionLDflags)
 290   fi
 291
 292   # Set linker optimization flags.
 293   if test x"$ac_cv_prog_gnu_ld" = x"yes" && test x"$enable_debug" = x"no"; then
 294     OPT_LDFLAGS='-Wl,-O1'
 295   fi
 296
 297   AC_SUBST(SECTION_LDFLAGS)
 298   AC_SUBST(OPT_LDFLAGS)
 299 ])
 300
 301
 302 dnl
 303 dnl Check to see if the (math function) argument passed is
 304 dnl declared when using the c++ compiler
 305 dnl ASSUMES argument is a math function with ONE parameter
 306 dnl
 307 dnl GLIBCPP_CHECK_MATH_DECL_1
 308 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 309   AC_MSG_CHECKING([for $1 declaration])
 310   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 311     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 312       AC_LANG_SAVE
 313       AC_LANG_CPLUSPLUS
 314       AC_TRY_COMPILE([#include <math.h>
 315                       #ifdef HAVE_IEEEFP_H
 316                       #include <ieeefp.h>
 317                       #endif
 318                      ],
 319                      [ $1(0);],
 320                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 321       AC_LANG_RESTORE
 322     ])
 323   fi
 324   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 325 ])
 326
 327 dnl
 328 dnl Check to see if the (math function) argument passed is
 329 dnl 1) declared when using the c++ compiler
 330 dnl 2) has "C" linkage
 331 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 332 dnl
 333 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 334 dnl
 335 dnl argument 1 is name of function to check
 336 dnl
 337 dnl ASSUMES argument is a math function with ONE parameter
 338 dnl
 339 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 340 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 341   GLIBCPP_CHECK_MATH_DECL_1($1)
 342   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 343     AC_CHECK_FUNCS($1)
 344   else
 345     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 346     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 347       AC_CHECK_FUNCS(_$1)
 348     fi
 349   fi
 350 ])
 351
 352
 353 dnl
 354 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 355 dnl of functions at once.  It's an all-or-nothing check -- either
 356 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 357 dnl Doing it this way saves significant configure time.
 358 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 359   AC_MSG_CHECKING([for $1 functions])
 360   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 361     AC_LANG_SAVE
 362     AC_LANG_CPLUSPLUS
 363     AC_TRY_COMPILE([#include <math.h>],
 364                    [ `for x in $3; do echo "$x (0);"; done` ],
 365                    [glibcpp_cv_func_$2_use=yes],
 366                    [glibcpp_cv_func_$2_use=no])
 367     AC_LANG_RESTORE])
 368   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 369   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 370     AC_CHECK_FUNCS($3)
 371   fi
 372 ])
 373
 374 dnl
 375 dnl Check to see if the (math function) argument passed is
 376 dnl declared when using the c++ compiler
 377 dnl ASSUMES argument is a math function with ONE parameter
 378 dnl
 379 dnl GLIBCPP_CHECK_MATH_DECL_2
 380 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 381   AC_MSG_CHECKING([for $1 declaration])
 382   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 383     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 384       AC_LANG_SAVE
 385       AC_LANG_CPLUSPLUS
 386       AC_TRY_COMPILE([#include <math.h>],
 387                      [ $1(0, 0);],
 388                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 389       AC_LANG_RESTORE
 390     ])
 391   fi
 392   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 393 ])
 394
 395 dnl
 396 dnl Check to see if the (math function) argument passed is
 397 dnl 1) declared when using the c++ compiler
 398 dnl 2) has "C" linkage
 399 dnl
 400 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 401 dnl
 402 dnl argument 1 is name of function to check
 403 dnl
 404 dnl ASSUMES argument is a math function with TWO parameters
 405 dnl
 406 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 407 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 408   GLIBCPP_CHECK_MATH_DECL_2($1)
 409   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 410     AC_CHECK_FUNCS($1)
 411   else
 412     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 413     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 414       AC_CHECK_FUNCS(_$1)
 415     fi
 416   fi
 417 ])
 418
 419
 420 dnl
 421 dnl Check to see if the (math function) argument passed is
 422 dnl declared when using the c++ compiler
 423 dnl ASSUMES argument is a math function with ONE parameter
 424 dnl
 425 dnl GLIBCPP_CHECK_MATH_DECL_3
 426 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 427   AC_MSG_CHECKING([for $1 declaration])
 428   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 429     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 430       AC_LANG_SAVE
 431       AC_LANG_CPLUSPLUS
 432       AC_TRY_COMPILE([#include <math.h>],
 433                      [ $1(0, 0, 0);],
 434                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 435       AC_LANG_RESTORE
 436     ])
 437   fi
 438   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 439 ])
 440
 441 dnl
 442 dnl Check to see if the (math function) argument passed is
 443 dnl 1) declared when using the c++ compiler
 444 dnl 2) has "C" linkage
 445 dnl
 446 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 447 dnl
 448 dnl argument 1 is name of function to check
 449 dnl
 450 dnl ASSUMES argument is a math function with THREE parameters
 451 dnl
 452 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 453 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 454   GLIBCPP_CHECK_MATH_DECL_3($1)
 455   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 456     AC_CHECK_FUNCS($1)
 457   else
 458     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 459     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 460       AC_CHECK_FUNCS(_$1)
 461     fi
 462   fi
 463 ])
 464
 465
 466 dnl
 467 dnl Check to see if the (stdlib function) argument passed is
 468 dnl 1) declared when using the c++ compiler
 469 dnl 2) has "C" linkage
 470 dnl
 471 dnl argument 1 is name of function to check
 472 dnl
 473 dnl ASSUMES argument is a math function with TWO parameters
 474 dnl
 475 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 476 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 477   AC_MSG_CHECKING([for $1 declaration])
 478   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 479     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 480       AC_LANG_SAVE
 481       AC_LANG_CPLUSPLUS
 482       AC_TRY_COMPILE([#include <stdlib.h>],
 483                      [ $1(0, 0);],
 484                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 485       AC_LANG_RESTORE
 486     ])
 487   fi
 488   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 489   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 490     AC_CHECK_FUNCS($1)
 491   fi
 492 ])
 493
 494
 495 dnl
 496 dnl Because the builtins are picky picky picky about the arguments they take,
 497 dnl do an explict linkage tests here.
 498 dnl Check to see if the (math function) argument passed is
 499 dnl 1) declared when using the c++ compiler
 500 dnl 2) has "C" linkage
 501 dnl
 502 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 503 dnl
 504 dnl argument 1 is name of function to check
 505 dnl
 506 dnl ASSUMES argument is a math function with ONE parameter
 507 dnl
 508 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 509 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 510   AC_MSG_CHECKING([for $1 declaration])
 511   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 512     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 513       AC_LANG_SAVE
 514       AC_LANG_CPLUSPLUS
 515       AC_TRY_COMPILE([#include <math.h>],
 516                      [ $1(0);],
 517                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 518       AC_LANG_RESTORE
 519     ])
 520   fi
 521   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 522   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 523     AC_MSG_CHECKING([for $1 linkage])
 524     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 525       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 526         AC_TRY_LINK([#include <math.h>],
 527                     [ $1(0);],
 528                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 529       ])
 530     fi
 531     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 532     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 533       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 534       AC_DEFINE_UNQUOTED(${ac_tr_func})
 535     fi
 536   fi
 537 ])
 538
 539
 540 dnl
 541 dnl Check to see what builtin math functions are supported
 542 dnl
 543 dnl check for __builtin_abs
 544 dnl check for __builtin_fabsf
 545 dnl check for __builtin_fabs
 546 dnl check for __builtin_fabl
 547 dnl check for __builtin_labs
 548 dnl check for __builtin_sqrtf
 549 dnl check for __builtin_sqrtl
 550 dnl check for __builtin_fsqrt
 551 dnl check for __builtin_sinf
 552 dnl check for __builtin_sin
 553 dnl check for __builtin_sinl
 554 dnl check for __builtin_cosf
 555 dnl check for __builtin_cos
 556 dnl check for __builtin_cosl
 557 dnl
 558 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 559 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 560   dnl Test for builtin math functions.
 561   dnl These are made in gcc/c-common.c
 562   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 563   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 564   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 565   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 566   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 567
 568   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 569   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fsqrt)
 570   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 571
 572   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 573   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 574   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 575
 576   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 577   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 578   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 579
 580   dnl There is, without a doubt, a more elegant way to have these
 581   dnl names exported so that they won't be stripped out of acconfig.h by
 582   dnl autoheader. I leave this as an exercise to somebody less frustrated
 583   dnl than I.... please email the libstdc++ list if you can figure out a
 584   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 585   dnl AC_CHECK_FUNC for things to steal.)
 586   dummyvar=no
 587   if test x$dummyvar = x"yes"; then
 588     AC_DEFINE(HAVE___BUILTIN_ABS)
 589     AC_DEFINE(HAVE___BUILTIN_LABS)
 590     AC_DEFINE(HAVE___BUILTIN_COS)
 591     AC_DEFINE(HAVE___BUILTIN_COSF)
 592     AC_DEFINE(HAVE___BUILTIN_COSL)
 593     AC_DEFINE(HAVE___BUILTIN_FABS)
 594     AC_DEFINE(HAVE___BUILTIN_FABSF)
 595     AC_DEFINE(HAVE___BUILTIN_FABSL)
 596     AC_DEFINE(HAVE___BUILTIN_SIN)
 597     AC_DEFINE(HAVE___BUILTIN_SINF)
 598     AC_DEFINE(HAVE___BUILTIN_SINL)
 599     AC_DEFINE(HAVE___BUILTIN_FSQRT)
 600     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 601     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 602   fi
 603 ])
 604
 605
 606 dnl
 607 dnl Check to see what the underlying c library
 608 dnl These checks need to do two things:
 609 dnl 1) make sure the name is declared when using the c++ compiler
 610 dnl 2) make sure the name has "C" linkage
 611 dnl This might seem like overkill but experience has shown that it's not...
 612 dnl
 613 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 614 dnl Define HAVE_STRTOF if "strtof" is declared and links
 615 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 616 dnl
 617 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 618 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 619   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 620   ac_save_CXXFLAGS="$CXXFLAGS"
 621   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 622
 623   AC_CHECK_FUNCS(strtof)
 624   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 625   AC_CHECK_FUNCS(drand48)
 626
 627   CXXFLAGS="$ac_save_CXXFLAGS"
 628 ])
 629
 630
 631 dnl
 632 dnl Check to see what the underlying c library or math library is like.
 633 dnl These checks need to do two things:
 634 dnl 1) make sure the name is declared when using the c++ compiler
 635 dnl 2) make sure the name has "C" linkage
 636 dnl This might seem like overkill but experience has shown that it's not...
 637 dnl
 638 dnl Define HAVE_CARGF etc if "cargf" is found.
 639 dnl
 640 dnl GLIBCPP_CHECK_MATH_SUPPORT
 641 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 642   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 643   ac_save_CXXFLAGS="$CXXFLAGS"
 644   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 645
 646   dnl Check libm
 647   AC_CHECK_LIB(m, sin, libm="-lm")
 648   ac_save_LIBS="$LIBS"
 649   LIBS="$LIBS $libm"
 650
 651   dnl Check to see if certain C math functions exist.
 652   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 653   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 654   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 655   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 656   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 657   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 658   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 659
 660   dnl Check to see if basic C math functions have float versions.
 661   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 662                                           float_trig,
 663                                           acosf asinf atanf \
 664                                           cosf sinf tanf \
 665                                           coshf sinhf tanhf)
 666   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 667                                           float_round,
 668                                           ceilf floorf)
 669   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 670   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 671   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 672   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 673   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 674   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 675   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 676   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 677   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 678   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 679   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 680   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 681   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 682
 683   dnl Check to see if basic C math functions have long double versions.
 684   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 685                                           long_double_trig,
 686                                           acosl asinl atanl \
 687                                           cosl sinl tanl \
 688                                           coshl sinhl tanhl)
 689   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 690                                           long_double_round,
 691                                           ceill floorl)
 692   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 693   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 694   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 695   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 696   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 697   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 698   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 699   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 700   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 701   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 702   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 703   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 704   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 705   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 706   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 707   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 708
 709   dnl Some runtimes have these functions with a preceding underscore. Please
 710   dnl keep this sync'd with the one above. And if you add any new symbol,
 711   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 712   dnl Check to see if certain C math functions exist.
 713
 714   dnl Check to see if basic C math functions have float versions.
 715   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 716                                           _float_trig,
 717                                           _acosf _asinf _atanf \
 718                                           _cosf _sinf _tanf \
 719                                           _coshf _sinhf _tanhf)
 720   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 721                                           _float_round,
 722                                           _ceilf _floorf)
 723
 724   dnl Check to see if basic C math functions have long double versions.
 725   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 726                                           _long_double_trig,
 727                                           _acosl _asinl _atanl \
 728                                           _cosl _sinl _tanl \
 729                                           _coshl _sinhl _tanhl)
 730   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 731                                           _long_double_round,
 732                                           _ceill _floorl)
 733
 734   LIBS="$ac_save_LIBS"
 735   CXXFLAGS="$ac_save_CXXFLAGS"
 736 ])
 737
 738
 739 dnl
 740 dnl Check to see if there is native support for complex
 741 dnl
 742 dnl Don't compile bits in math/* if native support exits.
 743 dnl
 744 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "atan2l/copysignl" is found.
 745 dnl
 746 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 747 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 748   dnl Check for complex versions of math functions of platform.
 749   AC_CHECK_LIB(m, main)
 750   AC_REPLACE_MATHFUNCS(nan hypot hypotf atan2f expf copysignf)
 751
 752   dnl Compile the long double complex functions only if the function
 753   dnl provides the non-complex long double functions that are needed.
 754   dnl Currently this includes copysignl and atan2l, which should be
 755   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 756   USE_COMPLEX_LONG_DOUBLE=no
 757   if test x$ac_cv_func_atan2l = x"yes" \
 758      && test x$ac_cv_func_copysignl = x"yes"; then
 759     USE_COMPLEX_LONG_DOUBLE=yes
 760     AC_REPLACE_MATHFUNCS(hypotl signbitl)
 761   fi
 762
 763   AC_SUBST(USE_COMPLEX_LONG_DOUBLE)
 764 ])
 765
 766
 767 dnl Check to see what architecture and operating system we are compiling
 768 dnl for.  Also, if architecture- or OS-specific flags are required for
 769 dnl compilation, pick them up here.
 770 dnl
 771 dnl GLIBCPP_CHECK_TARGET
 772 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 773     . [$]{glibcpp_basedir}/configure.target
 774     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 775     AC_MSG_RESULT(OS config directory is $os_include_dir)
 776     AC_LINK_FILES($os_include_dir/bits/os_defines.h, include/bits/os_defines.h)
 777 ])
 778
 779
 780 dnl
 781 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 782 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 783 dnl must have been previously checked.)
 784 dnl
 785 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 786 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 787 dnl
 788 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 789 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 790
 791   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 792   dnl others even if wchar_t support is not on.
 793   AC_MSG_CHECKING([for mbstate_t])
 794   AC_TRY_COMPILE([#include <wchar.h>],
 795   [mbstate_t teststate;],
 796   have_mbstate_t=yes, have_mbstate_t=no)
 797   AC_MSG_RESULT($have_mbstate_t)
 798   if test x"$have_mbstate_t" = xyes; then
 799     AC_DEFINE(HAVE_MBSTATE_T)
 800   fi
 801
 802   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 803   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 804   AC_CHECK_HEADER(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 805
 806   dnl Only continue checking if the ISO C99 headers exist and support is on.
 807   if test x"$ac_has_wchar_h" = xyes && test x"$ac_has_wctype_h" = xyes \
 808      && test x"$enable_c_mbchar" != xno; then
 809
 810     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 811     dnl numeric_limits can instantiate type_traits<wchar_t>
 812     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 813     AC_TRY_COMPILE([#include <wchar.h>],
 814     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 815     has_wchar_minmax=yes, has_wchar_minmax=no)
 816     AC_MSG_RESULT($has_wchar_minmax)
 817
 818     dnl Test wchar.h for WEOF, which is what we use to determine whether
 819     dnl to specialize for char_traits<wchar_t> or not.
 820     AC_MSG_CHECKING([for WEOF])
 821     AC_TRY_COMPILE([
 822       #include <wchar.h>
 823       #include <stddef.h>],
 824     [wint_t i = WEOF;],
 825     has_weof=yes, has_weof=no)
 826     AC_MSG_RESULT($has_weof)
 827
 828     dnl Tests for wide character functions used in char_traits<wchar_t>.
 829     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset \
 830     wcsrtombs mbsrtowcs, ac_wfuncs=yes, ac_wfuncs=no)
 831
 832     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 833     if test x"$has_weof" = xyes && test x"$has_wchar_minmax" = xyes \
 834        && test x"$ac_wfuncs" = xyes; then
 835       ac_isoC99_wchar_t=yes
 836     else
 837       ac_isoC99_wchar_t=no
 838     fi
 839     AC_MSG_RESULT($ac_isoC99_wchar_t)
 840
 841     dnl Use iconv for wchar_t to char conversions. As such, check for
 842     dnl X/Open Portability Guide, version 2 features (XPG2).
 843     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 844     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 845
 846     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 847     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 848     ac_save_LIBS="$LIBS"
 849     LIBS="$LIBS $libiconv"
 850
 851     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 852     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 853
 854     LIBS="$ac_save_LIBS"
 855
 856     AC_MSG_CHECKING([for XPG2 wchar_t support])
 857     if test x"$ac_has_iconv_h" = xyes && test x"$ac_has_langinfo_h" = xyes \
 858        && test x"$ac_XPG2funcs" = xyes; then
 859       ac_XPG2_wchar_t=yes
 860     else
 861       ac_XPG2_wchar_t=no
 862     fi
 863     AC_MSG_RESULT($ac_XPG2_wchar_t)
 864
 865     dnl At the moment, only enable wchar_t specializations if all the
 866     dnl above support is present.
 867     AC_MSG_CHECKING([for enabled wchar_t specializations])
 868     if test x"$ac_isoC99_wchar_t" = xyes \
 869        && test x"$ac_XPG2_wchar_t" = xyes; then
 870       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
 871       AC_MSG_RESULT("yes")
 872     else
 873       AC_MSG_RESULT("no")
 874     fi
 875   else
 876     dnl Wide characters disabled by the user.
 877     AC_MSG_WARN([wchar_t support disabled.])
 878   fi
 879 ])
 880
 881
 882 dnl
 883 dnl Check to see if this version of GNU C++ is afflicted by bugs in
 884 dnl __complex__ float support.
 885 dnl
 886 dnl Define _GLIBCPP_BUGGY_FLOAT_COMPLEX if buggy.
 887 dnl
 888 dnl Check to see if this version of GNU C++ is afflicted by bugs in
 889 dnl __complex__ support.Check for buggy __complex__ that will cause ICE in
 890 dnl gcc-2.95.x when using the library, unless we define the default copy
 891 dnl ctor in the specializations of complex<>.
 892 dnl
 893 dnl Define _GLIBCPP_BUGGY_COMPLEX if buggy.
 894 dnl GLIBCPP_CHECK_COMPLEX_MATH_COMPILER_SUPPORT
 895 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_COMPILER_SUPPORT, [
 896   AC_REQUIRE([AC_PROG_CXX])
 897
 898   AC_MSG_CHECKING([for GNU C++ __complex__ support])
 899   AC_CACHE_VAL(glibcpp_cv_complex, [
 900     AC_LANG_SAVE
 901     AC_LANG_CPLUSPLUS
 902     AC_TRY_COMPILE([struct dcomplex { __complex__ double x; }; \
 903                     dcomplex f(const dcomplex& x) { return dcomplex(x); }], \
 904                     [ dcomplex x; f(x); ],
 905       glibcpp_cv_complex=ok,
 906       glibcpp_cv_complex=buggy
 907     )
 908     AC_LANG_RESTORE
 909   ])
 910   AC_MSG_RESULT($glibcpp_cv_complex)
 911   if test $glibcpp_cv_complex = buggy; then
 912     AC_DEFINE(_GLIBCPP_BUGGY_COMPLEX)
 913   fi
 914
 915   AC_MSG_CHECKING([for GNU C++ __complex__ float support])
 916   AC_CACHE_VAL(glibcpp_cv_float_complex, [
 917     AC_LANG_SAVE
 918     AC_LANG_CPLUSPLUS
 919     rm -f conftest.h
 920     cat > conftest.h <<EOB
 921       //
 922       // Check for buggy __complex__ that causes ICE in most versions of egcs
 923       // and gcc-2.95.x on certain platforms (eg., x86-win32).
 924       //
 925       // See http://gcc.gnu.org/ml/gcc-bugs/1999-07n/msg00845.html for
 926       // more info on the bug itself.
 927       //
 928       struct
 929       float_complex
 930       {
 931        __complex__ float m_value;
 932        float_complex (float = 0.0f, float = 0.0f);
 933        float_complex (__complex__ float val) : m_value (val) {}
 934        float_complex foo (const float_complex &val)
 935          { return float_complex (~val.m_value); }
 936       };
 937 EOB
 938     AC_TRY_COMPILE([#include "conftest.h"], ,
 939       glibcpp_cv_float_complex=ok,
 940       glibcpp_cv_float_complex=buggy
 941     )
 942     AC_LANG_RESTORE
 943   ])
 944   AC_MSG_RESULT($glibcpp_cv_float_complex)
 945   if test $glibcpp_cv_float_complex = buggy; then
 946     AC_DEFINE(_GLIBCPP_BUGGY_FLOAT_COMPLEX)
 947   fi
 948 ])
 949
 950
 951 dnl
 952 dnl Check for special debugging mode; not for production use.
 953 dnl
 954 dnl GLIBCPP_ENABLE_DEBUG
 955 dnl --enable-debug sets '-ggdb3 -O0'.
 956 dnl --disable-debug sets '-g' and whatever optimization options the
 957 dnl     compiler can handle.
 958 dnl  +  --enable-maintainer-mode automatically defaults this to on.
 959 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
 960 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
 961 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
 962 dnl       defaults to `no'.
 963 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
 964 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
 965 AC_ARG_ENABLE(debug,
 966 changequote(<<, >>)dnl
 967 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
 968 changequote([, ])dnl
 969 [case "${enableval}" in
 970  yes) enable_debug=yes ;;
 971  no)  enable_debug=no ;;
 972  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
 973  esac],
 974 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
 975
 976 dnl Option parsed, now set things appropriately
 977 case "${enable_debug}" in
 978     yes)
 979         DEBUG_FLAGS='-O0 -ggdb3'
 980         ;;
 981     no)
 982         DEBUG_FLAGS='-g'
 983         ;;
 984 esac
 985 AC_SUBST(DEBUG_FLAGS)
 986 ])
 987
 988
 989 dnl
 990 dnl Check for "unusual" flags to pass to the compiler while building.
 991 dnl
 992 dnl GLIBCPP_ENABLE_CXX_FLAGS
 993 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
 994 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
 995 dnl     Somehow this same set of flags must be passed when [re]building
 996 dnl     libgcc.
 997 dnl --disable-cxx-flags passes nothing.
 998 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
 999 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1000 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1001 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
1002 dnl       If "default flags" is an empty string (or "none"), the effect is
1003 dnl       the same as --disable or --enable=no.
1004 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1005 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1006 AC_ARG_ENABLE(cxx-flags,
1007 changequote(<<, >>)dnl
1008 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1009                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1010 changequote([, ])dnl
1011 [case "x$enableval" in
1012  xyes)
1013         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1014  xno|x)
1015         enable_cxx_flags='' ;;
1016  *)
1017         enable_cxx_flags="$enableval" ;;
1018  esac],
1019 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1020
1021 dnl Thinko on my part during design.  This kludge is the workaround.
1022 if test "$enable_cxx_flags" = "none"; then
1023   enable_cxx_flags='';
1024 fi
1025
1026 dnl Run through flags (either default or command-line) and set anything
1027 dnl extra (e.g., #defines) that must accompany particular g++ options.
1028 if test -n "$enable_cxx_flags"; then
1029     for f in $enable_cxx_flags; do
1030         case "$f" in
1031             -fhonor-std)  ;;
1032             -*)  ;;
1033             *)   # and we're trying to pass /what/ exactly?
1034                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1035         esac
1036     done
1037 fi
1038 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1039 AC_SUBST(EXTRA_CXX_FLAGS)
1040 ])
1041
1042
1043 dnl
1044 dnl Check for which locale library to use:  gnu or generic.
1045 dnl
1046 dnl GLIBCPP_ENABLE_CLOCALE
1047 dnl --enable-clocale=gnu sets config/c_locale_gnu.cc and friends
1048 dnl --enable-clocale=generic sets config/c_locale_generic.cc and friends
1049 dnl
1050 dnl default is generic
1051 dnl
1052 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1053   AC_MSG_CHECKING([for clocale to use])
1054   AC_ARG_ENABLE(clocale,
1055   [  --enable-clocale       enable model for target locale package.
1056      --enable-clocale=MODEL use MODEL target-speific locale package. [default=generic]
1057   ],
1058   if test x$enable_clocale = xno; then
1059      enable_clocale=generic
1060   fi,
1061      enable_clocale=generic)
1062
1063   enable_clocale_flag=$enable_clocale
1064
1065   dnl Check if a valid locale package
1066   case x${enable_clocale_flag} in
1067     xgnu)
1068       CLOCALE_H=config/c_locale_gnu.h
1069       CLOCALE_CC=config/c_locale_gnu.cc
1070       AC_MSG_RESULT(gnu)
1071       ;;
1072     xgeneric)
1073       CLOCALE_H=config/c_locale_generic.h
1074       CLOCALE_CC=config/c_locale_generic.cc
1075       AC_MSG_RESULT(generic)
1076       ;;
1077     *)
1078       echo "$enable_clocale is an unknown locale package" 1>&2
1079       exit 1
1080       ;;
1081   esac
1082
1083   AC_LINK_FILES($CLOCALE_H, include/bits/c++locale.h)
1084   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1085 ])
1086
1087
1088 dnl
1089 dnl Check for which I/O library to use:  libio, or something specific.
1090 dnl
1091 dnl GLIBCPP_ENABLE_CSTDIO
1092 dnl --enable-cstdio=libio sets config/c_io_libio.h and friends
1093 dnl
1094 dnl default is stdio
1095 dnl
1096 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1097   AC_MSG_CHECKING([for cstdio to use])
1098   AC_ARG_ENABLE(cstdio,
1099   [  --enable-cstdio        enable stdio for target io package.
1100      --enable-cstdio=LIB    use LIB target-speific io package. [default=stdio]
1101   ],
1102   if test x$enable_cstdio = xno; then
1103      enable_cstdio=stdio
1104   fi,
1105      enable_cstdio=stdio)
1106
1107   enable_cstdio_flag=$enable_cstdio
1108
1109   dnl Check if a valid I/O package
1110   case x${enable_cstdio_flag} in
1111     xlibio)
1112       CSTDIO_H=config/c_io_libio.h
1113       BASIC_FILE_H=config/basic_file_libio.h
1114       BASIC_FILE_CC=config/basic_file_libio.cc
1115       AC_MSG_RESULT(libio)
1116
1117       # see if we are on a system with libio native (ie, linux)
1118       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1119
1120       # Need to check and see what version of glibc is being used. If
1121       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1122       # compile most of libio for linux systems.
1123       if test x$has_libio = x"yes"; then
1124         case "$target" in
1125           *-*-linux*)
1126               AC_MSG_CHECKING([for glibc version >= 2.2])
1127               AC_EGREP_CPP([ok], [
1128             #include <features.h>
1129               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1130                     ok
1131               #endif
1132               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1133               AC_MSG_RESULT($glibc_satisfactory)
1134             ;;
1135         esac
1136
1137         # XXX at the moment, admit defeat and force the recompilation
1138         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1139         glibc_satisfactory=no
1140
1141         if test x$glibc_satisfactory = x"yes"; then
1142            need_libio=no
1143            need_wlibio=no
1144         else
1145            need_libio=yes
1146            # bkoz XXX need to add checks to enable this
1147            # pme XXX here's a first pass at such a check
1148            if test x$enable_c_mbchar != xno; then
1149               need_wlibio=yes
1150            else
1151               need_wlibio=no
1152            fi
1153         fi
1154
1155       else
1156          # Using libio, but <libio.h> doesn't exist on the target system. . .
1157          need_libio=yes
1158          # bkoz XXX need to add checks to enable this
1159          # pme XXX here's a first pass at such a check
1160          if test x$enable_c_mbchar != xno; then
1161              need_wlibio=yes
1162          else
1163              need_wlibio=no
1164          fi
1165       fi
1166       ;;
1167     xstdio | x | xno | xnone | xyes)
1168       # default
1169       CSTDIO_H=config/c_io_stdio.h
1170       BASIC_FILE_H=config/basic_file_stdio.h
1171       BASIC_FILE_CC=config/basic_file_stdio.cc
1172       AC_MSG_RESULT(stdio)
1173
1174       # We're not using stdio.
1175       need_libio=no
1176       need_wlibio=no
1177       ;;
1178     *)
1179       echo "$enable_cstdio is an unknown io package" 1>&2
1180       exit 1
1181       ;;
1182   esac
1183   AC_LINK_FILES($CSTDIO_H, include/bits/c++io.h)
1184   AC_LINK_FILES($BASIC_FILE_H, include/bits/basic_file_model.h)
1185   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1186
1187   # 2000-08-04 bkoz hack
1188   CCODECVT_C=config/c_io_libio_codecvt.c
1189   AC_LINK_FILES($CCODECVT_C, libio/c_codecvt.c)
1190   # 2000-08-04 bkoz hack
1191
1192   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1193                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1194   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1195   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1196   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1197     libio_la=../libio/libio.la
1198   else
1199     libio_la=
1200   fi
1201   AC_SUBST(libio_la)
1202 ])
1203
1204
1205 dnl
1206 dnl Check for which threading library to use.
1207 dnl
1208 dnl GLIBCPP_ENABLE_THREADS
1209 dnl --enable-threads=posix sets config/threads-posix.h et. al.
1210 dnl
1211 dnl Default is no threads, which also disables _IO_MTSAFE_IO in
1212 dnl libio.  Any actual thread package will enable it.
1213 dnl
1214 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1215   dnl Note this comes from the gcc/config.in and libjava/config.in
1216   dnl Efforts should be made to keep this in sync.
1217   AC_MSG_CHECKING([for threads package to use])
1218   AC_ARG_ENABLE(threads,
1219   [  --enable-threads       enable thread usage for target GCC.
1220      --enable-threads=LIB   use LIB thread package for target GCC. [default=no]
1221   ],
1222   if test x$enable_threads = xno; then
1223     enable_threads=''
1224   fi,
1225     enable_threads='')
1226
1227   enable_threads_flag=$enable_threads
1228
1229   dnl Check if a valid thread package
1230   case x${enable_threads_flag} in
1231         x | xno | xnone)
1232                 # No threads
1233                 target_thread_file='single'
1234                 ;;
1235         xyes)
1236                 # default
1237                 target_thread_file='posix'
1238                 ;;
1239         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
1240         xsolaris | xwin32 | xdce | xvxworks)
1241                 target_thread_file=$enable_threads_flag
1242                 ;;
1243         *)
1244                 echo "$enable_threads is an unknown thread package" 1>&2
1245                 exit 1
1246                 ;;
1247   esac
1248
1249   dnl Check for thread package actually supported in libstdc++
1250   THREADH=
1251   case "$target_thread_file" in
1252     no | none | single)
1253       THREADH=threads-no.h
1254       ;;
1255     posix | pthreads)
1256       THREADH=threads-posix.h
1257       ;;
1258     decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
1259       AC_MSG_ERROR(thread package $THREADS not yet supported)
1260       ;;
1261     *)
1262       AC_MSG_ERROR($THREADS is an unsupported/unknown thread package)
1263       ;;
1264   esac
1265   AC_MSG_RESULT($THREADH)
1266
1267   AC_LINK_FILES(config/$THREADH, include/bits/c++threads.h)
1268   if test $THREADH != threads-no.h; then
1269     AC_DEFINE(_GLIBCPP_USE_THREADS)
1270   fi
1271 ])
1272
1273
1274 dnl
1275 dnl Check for exception handling support.  If an explicit enable/disable
1276 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1277 dnl target may or may not support call frame exceptions.
1278 dnl
1279 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1280 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1281 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1282 dnl
1283 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1284 dnl
1285 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1286   AC_MSG_CHECKING([for exception model to use])
1287   AC_LANG_SAVE
1288   AC_LANG_CPLUSPLUS
1289   AC_ARG_ENABLE(sjlj-exceptions,
1290   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1291   [:],
1292   [dnl Botheration.  Now we've got to detect the exception model.
1293    dnl Link tests against libgcc.a are problematic since -- at least
1294    dnl as of this writing -- we've not been given proper -L bits for
1295    dnl single-tree newlib and libgloss.
1296    dnl
1297    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1298    dnl conftest files before we got a change to grep them first.
1299    cat > conftest.$ac_ext << EOF
1300 [#]line __oline__ "configure"
1301 struct S { ~S(); };
1302 void bar();
1303 void foo()
1304 {
1305   S s;
1306   bar();
1307 }
1308 EOF
1309    old_CXXFLAGS="$CXXFLAGS"
1310    CXXFLAGS=-S
1311    if AC_TRY_EVAL(ac_compile); then
1312      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1313        enable_sjlj_exceptions=yes
1314      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1315        enable_sjlj_exceptions=no
1316      fi
1317    fi
1318    CXXFLAGS="$old_CXXFLAGS"
1319    rm -f conftest*])
1320    if test x$enable_sjlj_exceptions = xyes; then
1321      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1322         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1323      ac_exception_model_name=sjlj
1324    elif test x$enable_sjlj_exceptions = xno; then
1325      ac_exception_model_name="call frame"
1326    else
1327      AC_MSG_ERROR([unable to detect exception model])
1328    fi
1329    AC_LANG_RESTORE
1330    AC_MSG_RESULT($ac_exception_model_name)
1331 ])
1332
1333
1334 dnl
1335 dnl Check for ISO/IEC 9899:1999 "C99" support.
1336 dnl
1337 dnl GLIBCPP_ENABLE_C99
1338 dnl --enable-c99 defines _GLIBCPP_USE_C99
1339 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1340 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1341 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1342 dnl       defaults to `no'.
1343 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1344 dnl
1345 dnl GLIBCPP_ENABLE_C99
1346 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1347   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1348
1349   AC_ARG_ENABLE(c99,
1350   changequote(<<, >>)dnl
1351   <<--enable-c99      turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1352   changequote([, ])dnl
1353   [case "$enableval" in
1354    yes) enable_c99=yes ;;
1355    no)  enable_c99=no ;;
1356    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1357    esac],
1358   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1359
1360   AC_LANG_SAVE
1361   AC_LANG_CPLUSPLUS
1362
1363   # Check for the existence of <math.h> functions used if C99 is enabled.
1364   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1365   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1366   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1367   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1368   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1369   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1370   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1371   AC_TRY_COMPILE([#include <math.h>],
1372                  [isgreaterequal(0.0,0.0);], , [ac_c99_math=no])
1373   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1374   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1375   AC_TRY_COMPILE([#include <math.h>],
1376                  [islessgreater(0.0,0.0);], , [ac_c99_math=no])
1377   AC_TRY_COMPILE([#include <math.h>],
1378                  [isunordered(0.0,0.0);], , [ac_c99_math=no])
1379
1380   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1381   AC_CHECK_FUNC(strtoll,,ac_c99_stdlib=no)
1382   AC_CHECK_FUNC(strtoull,,ac_c99_stdlib=no)
1383   AC_CHECK_FUNC(llabs,,ac_c99_stdlib=no)
1384   AC_CHECK_FUNC(lldiv,,ac_c99_stdlib=no)
1385   AC_CHECK_FUNC(atoll,,ac_c99_stdlib=no)
1386
1387   AC_MSG_CHECKING([for lldiv_t declaration])
1388   AC_CACHE_VAL(ac_c99_lldiv_t, [
1389   AC_TRY_COMPILE([#include <stdlib.h>],
1390                    [ lldiv_t mydivt;],
1391                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1392   ])
1393   AC_MSG_RESULT($ac_c99_lldiv_t)
1394   if test x"$ac_c99_lldiv_t" = x"no"; then
1395     ac_c99_stdlib=no;
1396   fi;
1397
1398   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1399   AC_CHECK_FUNC(wcstold,,ac_c99_wchar=no)
1400   AC_CHECK_FUNC(wcstoll,,ac_c99_wchar=no)
1401   AC_CHECK_FUNC(wcstoull,,ac_c99_wchar=no)
1402
1403   AC_MSG_CHECKING([for enabled ISO C99 support])
1404   if test x"$ac_c99_math" = x"no" || test x"$ac_c99_wchar" = x"no" \
1405         || test x"$ac_c99_stdlib" = x"no"; then
1406     enable_c99=no;
1407   fi;
1408   AC_MSG_RESULT($enable_c99)
1409
1410   # Option parsed, now set things appropriately
1411   if test x"$enable_c99" = x"yes"; then
1412     AC_DEFINE(_GLIBCPP_USE_C99)
1413   fi
1414
1415   AC_LANG_RESTORE
1416 ])
1417
1418
1419 dnl
1420 dnl Check for template specializations for the 'long long' type extension.
1421 dnl NB: Must check for C99 support before calling _GLIBCPP_ENABLE_LONG_LONG
1422 dnl
1423 dnl GLIBCPP_ENABLE_LONG_LONG
1424 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1425 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1426 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1427 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1428 dnl       defaults to `no'.
1429 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1430 dnl
1431 dnl GLIBCPP_ENABLE_LONG_LONG
1432 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1433   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1434
1435   AC_ARG_ENABLE(long-long,
1436   changequote(<<, >>)dnl
1437   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1438   changequote([, ])dnl
1439   [case "$enableval" in
1440    yes) enable_long_long=yes ;;
1441    no)  enable_long_long=no ;;
1442    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1443    esac],
1444   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1445
1446   # iostreams require strtoll, strtoull to compile. If the
1447   # GLIBCPP_ENABLE_C99 tests found these, and if C99 support is enabled,
1448   # go ahead and allow long long to be used.
1449   if test x"$enable_c99" = x"no"; then
1450     enable_long_long=no;
1451   fi
1452
1453   # Option parsed, now set things appropriately
1454   AC_MSG_CHECKING([for enabled long long support])
1455   if test x"$enable_long_long" = xyes; then
1456     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1457   fi
1458   AC_MSG_RESULT($enable_long_long)
1459 ])
1460
1461
1462 dnl
1463 dnl Check for what kind of C headers to use.
1464 dnl
1465 dnl GLIBCPP_ENABLE_CHEADERS
1466 dnl --enable-cheaders= [does stuff].
1467 dnl --disable-cheaders [does not do anything, really].
1468 dnl  +  This will eventually need to be 'c_shadow' by default.
1469 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1470 dnl       Where DEFAULT is either `c' or `c_std' or 'c_shadow'.
1471 dnl       If ommitted, it defaults to `c_std'.
1472 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1473 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1474 AC_MSG_CHECKING([for c header strategy to use])
1475 AC_ARG_ENABLE(cheaders,
1476 changequote(<<, >>)dnl
1477 <<  --enable-cheaders construct "C" header files for
1478                            g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1479 changequote([, ])
1480   [case "$enableval" in
1481    c)
1482         enable_cheaders=c
1483         ;;
1484    c_std)
1485         enable_cheaders=c_std
1486         ;;
1487    c_shadow)
1488         enable_cheaders=c_shadow
1489         ;;
1490    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1491         ;;
1492   esac],
1493   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1494   AC_MSG_RESULT($enable_cheaders)
1495
1496   dnl Option parsed, now set things appropriately
1497   case "$enable_cheaders" in
1498     c_shadow)
1499         CSHADOW_FLAGS="-fno-builtin"
1500         C_INCLUDE_DIR='${top_srcdir}/include/c_shadow'
1501         AC_DEFINE(_GLIBCPP_USE_SHADOW_HEADERS)
1502         ;;
1503     c_std)
1504         CSHADOW_FLAGS=""
1505         C_INCLUDE_DIR='${top_srcdir}/include/c_std'
1506         ;;
1507     c)
1508         CSHADOW_FLAGS=""
1509         C_INCLUDE_DIR='${top_srcdir}/include/c'
1510         ;;
1511   esac
1512
1513   AC_SUBST(CSHADOW_FLAGS)
1514   AC_SUBST(C_INCLUDE_DIR)
1515   AM_CONDITIONAL(GLIBCPP_USE_CSHADOW, test "$enable_cheaders" = c_shadow)
1516 ])
1517
1518
1519 dnl
1520 dnl Check for wide character support.  Has the same effect as the option
1521 dnl in gcc's configure, but in a form that autoconf can mess with.
1522 dnl
1523 dnl GLIBCPP_ENABLE_C_MBCHAR
1524 dnl --enable-c-mbchar requests all the wchar_t stuff.
1525 dnl --disable-c-mbchar doesn't.
1526 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1527 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1528 dnl       defaults to `no'.
1529 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1530 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1531 AC_ARG_ENABLE(c-mbchar,
1532 changequote(<<, >>)dnl
1533 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1534 changequote([, ])dnl
1535 [case "$enableval" in
1536  yes) enable_c_mbchar=yes ;;
1537  no)  enable_c_mbchar=no ;;
1538  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1539  esac],
1540 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1541 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1542 ])
1543
1544
1545 dnl
1546 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1547 dnl
1548 dnl GLIBCPP_INCLUDE_DIR
1549 dnl C_INCLUDE_DIR
1550 dnl TOPLEVEL_INCLUDES
1551 dnl LIBMATH_INCLUDES
1552 dnl LIBSUPCXX_INCLUDES
1553 dnl LIBIO_INCLUDES
1554 dnl CSHADOW_INCLUDES
1555 dnl
1556 dnl GLIBCPP_EXPORT_INCLUDE
1557 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1558   # Root level of the include sources.
1559   GLIBCPP_INCLUDE_DIR='$(top_srcdir)/include'
1560
1561   # Can either use include/c or include/c_std to grab "C" headers. This
1562   # variable is set to the include directory currently in use.
1563   # set with C_INCLUDE_DIR in GLIBCPP_ENABLE_CHEADERS
1564
1565   # Passed down for canadian crosses.
1566   if  test x"$CANADIAN" = xyes; then
1567     TOPLEVEL_INCLUDES='-I$(includedir)'
1568   fi
1569
1570   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1571
1572   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1573
1574   #if GLIBCPP_NEED_LIBIO
1575   LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1576   #else
1577   #LIBIO_INCLUDES='-I$(top_srcdir)/libio'
1578   #endif
1579
1580   #if GLIBCPP_USE_CSHADOW
1581   #  CSHADOW_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR) \
1582   #                   -I$(top_blddir)/cshadow'
1583   #else
1584   CSTD_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR)'
1585   #endif
1586
1587   # Now, export this to all the little Makefiles....
1588   AC_SUBST(GLIBCPP_INCLUDE_DIR)
1589   AC_SUBST(TOPLEVEL_INCLUDES)
1590   AC_SUBST(LIBMATH_INCLUDES)
1591   AC_SUBST(LIBSUPCXX_INCLUDES)
1592   AC_SUBST(LIBIO_INCLUDES)
1593   AC_SUBST(CSTD_INCLUDES)
1594 ])
1595
1596
1597 dnl
1598 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1599 dnl
1600 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1601   # Optimization flags that are probably a good idea for thrill-seekers. Just
1602   # uncomment the lines below and make, everything else is ready to go...
1603   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1604   OPTIMIZE_CXXFLAGS=
1605   AC_SUBST(OPTIMIZE_CXXFLAGS)
1606
1607   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1608   AC_SUBST(WARN_FLAGS)
1609 ])
1610
1611 dnl
1612 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1613 dnl  calculates gxx_install_dir
1614 dnl  exports glibcpp_toolexecdir
1615 dnl  exports glibcpp_toolexeclibdir
1616 dnl
1617 dnl Assumes cross_compiling bits already done, and with_cross_host in
1618 dnl particular
1619 dnl
1620 dnl GLIBCPP_EXPORT_INSTALL_INFO
1621 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1622
1623 glibcpp_toolexecdir=no
1624 glibcpp_toolexeclibdir=no
1625
1626 AC_MSG_CHECKING([for interface version number])
1627 libstdcxx_interface=$INTERFACE
1628 AC_MSG_RESULT($libstdcxx_interface)
1629
1630 # Process the option --with-gxx-include-dir=<path to include-files directory>
1631 AC_MSG_CHECKING([for --with-gxx-include-dir])
1632 AC_ARG_WITH(gxx-include-dir,
1633 [ --with-gxx-include-dir  the installation directory for include files],
1634 [case "${withval}" in
1635   yes)
1636     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1637     gxx_include_dir=no
1638     ;;
1639   no)
1640     gxx_include_dir=no
1641     ;;
1642   *)
1643     gxx_include_dir=${withval}
1644     ;;
1645 esac], [gxx_include_dir=no])
1646 AC_MSG_RESULT($gxx_include_dir)
1647
1648 # Process the option "--enable-version-specific-runtime-libs"
1649 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1650 AC_ARG_ENABLE(version-specific-runtime-libs,
1651 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1652 [  version_specific_libs=yes
1653 # Need the gcc compiler version to know where to install libraries
1654 # and header files if --enable-version-specific-runtime-libs option
1655 # is selected.
1656 changequote(,)dnl
1657 gcc_version_trigger=${srcdir}/../gcc/version.c
1658 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
1659 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1660 gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/g++
1661 glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1662 glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}
1663 changequote([,])dnl
1664 ],version_specific_libs=no)
1665 AC_MSG_RESULT($version_specific_libs)
1666
1667 # Default case for install directory for include files.
1668 if test x"$version_specific_libs" = x"no" \
1669    && test x"$gxx_include_dir" = x"no"; then
1670   gxx_include_dir='$(prefix)'/include/g++-${libstdcxx_interface}
1671 fi
1672
1673 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1674 # Install a library built with a cross compiler in tooldir, not libdir.
1675 if test x"$glibcpp_toolexecdir" = x"no"; then
1676   if test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
1677     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1678     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1679   else
1680     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1681     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1682   fi
1683 fi
1684
1685 AC_MSG_CHECKING([for install location])
1686 AC_MSG_RESULT($gxx_include_dir)
1687
1688 AC_SUBST(gxx_include_dir)
1689 AC_SUBST(glibcpp_toolexecdir)
1690 AC_SUBST(glibcpp_toolexeclibdir)
1691 ])
1692
1693
1694 # Check whether LC_MESSAGES is available in <locale.h>.
1695 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1696 #
1697 # This file file be copied and used freely without restrictions.  It can
1698 # be used in projects which are not available under the GNU Public License
1699 # but which still want to provide support for the GNU gettext functionality.
1700 # Please note that the actual code is *not* freely available.
1701
1702 # serial 1
1703
1704 AC_DEFUN(AC_LC_MESSAGES, [
1705   AC_CHECK_HEADER(locale.h, [
1706     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1707       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1708        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1709     if test $ac_cv_val_LC_MESSAGES = yes; then
1710       AC_DEFINE(HAVE_LC_MESSAGES)
1711     fi
1712   ])
1713 ])
1714
1715
1716 # Check for functions in math library.
1717 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1718 #
1719 # This file can be copied and used freely without restrictions.  It can
1720 # be used in projects which are not available under the GNU Public License
1721 # but which still want to provide support for the GNU gettext functionality.
1722 # Please note that the actual code is *not* freely available.
1723
1724 # serial 1
1725
1726 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1727 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1728 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])
1729 AC_SUBST(LIBMATHOBJS)dnl
1730 ])
1731
1732
1733 # Check for string functions.
1734 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1735 #
1736 # This file can be copied and used freely without restrictions.  It can
1737 # be used in projects which are not available under the GNU Public License
1738 # but which still want to provide support for the GNU gettext functionality.
1739 # Please note that the actual code is *not* freely available.
1740
1741 # serial 1
1742
1743 dnl AC_REPLACE_STRINGFUNCS(FUNCTION...)
1744 AC_DEFUN(AC_REPLACE_STRINGFUNCS,
1745 [AC_CHECK_FUNCS([$1], , [LIBSTRINGOBJS="$LIBSTRINGOBJS ${ac_func}.lo"])
1746 AC_SUBST(LIBSTRINGOBJS)dnl
1747 ])
1748
1749
1750 dnl This macro searches for a GNU version of make.  If a match is found, the
1751 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1752 dnl set to "#". This is useful for  including a special features in a Makefile,
1753 dnl which cannot be handled by other versions of make.  The variable
1754 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1755 dnl the empty string otherwise.
1756 dnl
1757 dnl Here is an example of its use:
1758 dnl
1759 dnl Makefile.in might contain:
1760 dnl
1761 dnl     # A failsafe way of putting a dependency rule into a makefile
1762 dnl     $(DEPEND):
1763 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1764 dnl
1765 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1766 dnl     @ifGNUmake@ include $(DEPEND)
1767 dnl     @ifGNUmake@ endif
1768 dnl
1769 dnl Then configure.in would normally contain:
1770 dnl
1771 dnl     CHECK_GNU_MAKE()
1772 dnl     AC_OUTPUT(Makefile)
1773 dnl
1774 dnl Then perhaps to cause gnu make to override any other make, we could do
1775 dnl something like this (note that GNU make always looks for GNUmakefile first):
1776 dnl
1777 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1778 dnl             mv Makefile GNUmakefile
1779 dnl             echo .DEFAULT: > Makefile ;
1780 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1781 dnl     fi
1782 dnl
1783 dnl Then, if any (well almost any) other make is called, and GNU make also
1784 dnl exists, then the other make wraps the GNU make.
1785 dnl
1786 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1787 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1788 dnl
1789 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1790 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1791 dnl #### conditional's subshell (" --version" is not a command), using a
1792 dnl #### different option to grep(1).
1793 dnl #### -pme
1794 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1795 dnl #### ${MAKE:-make}).
1796 dnl #### -msokolov
1797 AC_DEFUN(
1798   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1799           _cv_gnu_make_command='' ;
1800 dnl Search all the common names for GNU make
1801           for a in "${MAKE-make}" make gmake gnumake ; do
1802                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1803                   then
1804                           _cv_gnu_make_command=$a ;
1805                           break;
1806                   fi
1807           done ;
1808   ) ;
1809 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1810 dnl string, '#' otherwise
1811   if test  "x$_cv_gnu_make_command" != "x"  ; then
1812           ifGNUmake='' ;
1813   else
1814           ifGNUmake='#' ;
1815   fi
1816   AC_SUBST(ifGNUmake)
1817 ])
1818
1819 sinclude(../libtool.m4)
1820 dnl The lines below arrange for aclocal not to bring an installed
1821 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1822 dnl add a definition of LIBTOOL to Makefile.in.
1823 ifelse(,,,[AC_SUBST(LIBTOOL)
1824 AC_DEFUN([AM_PROG_LIBTOOL])
1825 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1826 AC_DEFUN([AC_PROG_LD])
1827 ])
1828
1829
1830
1831 # Do all the work for Automake.  This macro actually does too much --
1832 # some checks are only needed if your package does certain things.
1833 # But this isn't really a big deal.
1834
1835 # serial 1
1836
1837 dnl Usage:
1838 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
1839
1840 AC_DEFUN(AM_INIT_AUTOMAKE,
1841 [AC_REQUIRE([AC_PROG_INSTALL])
1842 PACKAGE=[$1]
1843 AC_SUBST(PACKAGE)
1844 VERSION=[$2]
1845 AC_SUBST(VERSION)
1846 dnl test to see if srcdir already configured
1847 if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
1848   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
1849 fi
1850 ifelse([$3],,
1851 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
1852 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
1853 AC_REQUIRE([AM_SANITY_CHECK])
1854 AC_REQUIRE([AC_ARG_PROGRAM])
1855 dnl FIXME This is truly gross.
1856 missing_dir=`cd $ac_aux_dir && pwd`
1857 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
1858 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
1859 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
1860 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
1861 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
1862 AC_REQUIRE([AC_PROG_MAKE_SET])])
1863
1864 #
1865 # Check to make sure that the build environment is sane.
1866 #
1867
1868 AC_DEFUN(AM_SANITY_CHECK,
1869 [AC_MSG_CHECKING([whether build environment is sane])
1870 # Just in case
1871 sleep 1
1872 echo timestamp > conftestfile
1873 # Do `set' in a subshell so we don't clobber the current shell's
1874 # arguments.  Must try -L first in case configure is actually a
1875 # symlink; some systems play weird games with the mod time of symlinks
1876 # (eg FreeBSD returns the mod time of the symlink's containing
1877 # directory).
1878 if (
1879    set X `ls -Lt $srcdir/configure conftestfile 2> /dev/null`
1880    if test "[$]*" = "X"; then
1881       # -L didn't work.
1882       set X `ls -t $srcdir/configure conftestfile`
1883    fi
1884    if test "[$]*" != "X $srcdir/configure conftestfile" \
1885       && test "[$]*" != "X conftestfile $srcdir/configure"; then
1886
1887       # If neither matched, then we have a broken ls.  This can happen
1888       # if, for instance, CONFIG_SHELL is bash and it inherits a
1889       # broken ls alias from the environment.  This has actually
1890       # happened.  Such a system could not be considered "sane".
1891       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
1892 alias in your environment])
1893    fi
1894
1895    test "[$]2" = conftestfile
1896    )
1897 then
1898    # Ok.
1899    :
1900 else
1901    AC_MSG_ERROR([newly created file is older than distributed files!
1902 Check your system clock])
1903 fi
1904 rm -f conftest*
1905 AC_MSG_RESULT(yes)])
1906
1907 dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
1908 dnl The program must properly implement --version.
1909 AC_DEFUN(AM_MISSING_PROG,
1910 [AC_MSG_CHECKING(for working $2)
1911 # Run test in a subshell; some versions of sh will print an error if
1912 # an executable is not found, even if stderr is redirected.
1913 # Redirect stdin to placate older versions of autoconf.  Sigh.
1914 if ($2 --version) < /dev/null > /dev/null 2>&1; then
1915    $1=$2
1916    AC_MSG_RESULT(found)
1917 else
1918    $1="$3/missing $2"
1919    AC_MSG_RESULT(missing)
1920 fi
1921 AC_SUBST($1)])
1922
1923 # Add --enable-maintainer-mode option to configure.
1924 # From Jim Meyering
1925
1926 # serial 1
1927
1928 AC_DEFUN(AM_MAINTAINER_MODE,
1929 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1930   dnl maintainer-mode is disabled by default
1931   AC_ARG_ENABLE(maintainer-mode,
1932 [  --enable-maintainer-mode enable make rules and dependencies not useful
1933                           (and sometimes confusing) to the casual installer],
1934       USE_MAINTAINER_MODE=$enableval,
1935       USE_MAINTAINER_MODE=no)
1936   AC_MSG_RESULT($USE_MAINTAINER_MODE)
1937   AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
1938   MAINT=$MAINTAINER_MODE_TRUE
1939   AC_SUBST(MAINT)dnl
1940 ]
1941 )
1942
1943 # Define a conditional.
1944
1945 AC_DEFUN(AM_CONDITIONAL,
1946 [AC_SUBST($1_TRUE)
1947 AC_SUBST($1_FALSE)
1948 if $2; then
1949   $1_TRUE=
1950   $1_FALSE='#'
1951 else
1952   $1_TRUE='#'
1953   $1_FALSE=
1954 fi])
1955
1956 # Like AC_CONFIG_HEADER, but automatically create stamp file.
1957
1958 AC_DEFUN(AM_CONFIG_HEADER,
1959 [AC_PREREQ([2.12])
1960 AC_CONFIG_HEADER([$1])
1961 dnl When config.status generates a header, we must update the stamp-h file.
1962 dnl This file resides in the same directory as the config header
1963 dnl that is generated.  We must strip everything past the first ":",
1964 dnl and everything past the last "/".
1965 AC_OUTPUT_COMMANDS(changequote(<<,>>)dnl
1966 ifelse(patsubst(<<$1>>, <<[^ ]>>, <<>>), <<>>,
1967 <<test -z "<<$>>CONFIG_HEADERS" || echo timestamp > patsubst(<<$1>>, <<^\([^:]*/\)?.*>>, <<\1>>)stamp-h<<>>dnl>>,
1968 <<am_indx=1
1969 for am_file in <<$1>>; do
1970   case " <<$>>CONFIG_HEADERS " in
1971   *" <<$>>am_file "*<<)>>
1972     echo timestamp > `echo <<$>>am_file | sed -e 's%:.*%%' -e 's%[^/]*$%%'`stamp-h$am_indx
1973     ;;
1974   esac
1975   am_indx=`expr "<<$>>am_indx" + 1`
1976 done<<>>dnl>>)
1977 changequote([,]))])
1978