libstdc++-v3/aclocal.m4

   1 dnl aclocal.m4 generated automatically by aclocal 1.4
   2
   3 dnl Copyright (C) 1994, 1995-8, 1999 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  10 dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  11 dnl PARTICULAR PURPOSE.
  12
  13 dnl
  14 dnl Initialize configure bits.
  15 dnl
  16 dnl GLIBCPP_CONFIGURE
  17 AC_DEFUN(GLIBCPP_CONFIGURE, [
  18   dnl Default to --enable-multilib
  19   AC_ARG_ENABLE(multilib,
  20   [  --enable-multilib       build hella library versions (default)],
  21   [case "${enableval}" in
  22     yes) multilib=yes ;;
  23     no)  multilib=no ;;
  24     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  25    esac], [multilib=yes])dnl
  26
  27   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  28   AC_SUBST(glibcpp_basedir)
  29
  30   AM_INIT_AUTOMAKE(libstdc++, 3.0.0)
  31
  32   # Never versions of autoconf add an underscore to these functions.
  33   # Prevent future problems ...
  34   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  35   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  36   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  37   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  38
  39 #  AC_PROG_CC
  40
  41 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  42 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  43 # are probably using a cross compiler, which will not be able to fully
  44 # link an executable.  This should really be fixed in autoconf
  45 # itself.
  46
  47 AC_DEFUN(LIB_AC_PROG_CC,
  48 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  49 dnl Fool anybody using AC_PROG_CC.
  50 AC_PROVIDE([AC_PROG_CC])
  51 AC_CHECK_PROG(CC, gcc, gcc)
  52 if test -z "$CC"; then
  53   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  54   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  55 fi
  56
  57 AC_PROG_CC_GNU
  58
  59 if test $ac_cv_prog_gcc = yes; then
  60   GCC=yes
  61 dnl Check whether -g works, even if CFLAGS is set, in case the package
  62 dnl plays around with CFLAGS (such as to build both debugging and
  63 dnl normal versions of a library), tasteless as that idea is.
  64   ac_test_CFLAGS="${CFLAGS+set}"
  65   ac_save_CFLAGS="$CFLAGS"
  66   CFLAGS=
  67   AC_PROG_CC_G
  68   if test "$ac_test_CFLAGS" = set; then
  69     CFLAGS="$ac_save_CFLAGS"
  70   elif test $ac_cv_prog_cc_g = yes; then
  71     CFLAGS="-g -O2"
  72   else
  73     CFLAGS="-O2"
  74   fi
  75 else
  76   GCC=
  77   test "${CFLAGS+set}" = set || CFLAGS="-g"
  78 fi
  79 ])
  80
  81 LIB_AC_PROG_CC
  82
  83 # Can't just call these here as g++ requires libstc++ to be built....
  84 #  AC_PROG_CXX
  85
  86 # Likewise for AC_PROG_CXX.
  87 AC_DEFUN(LIB_AC_PROG_CXX,
  88 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
  89 dnl Fool anybody using AC_PROG_CXX.
  90 AC_PROVIDE([AC_PROG_CXX])
  91 # Use glibcpp_CXX so that we do not cause CXX to be cached with the
  92 # flags that come in CXX while configuring libstdc++.  They're different
  93 # from those used for all other target libraries.  If CXX is set in
  94 # the environment, respect that here.
  95 glibcpp_CXX=$CXX
  96 AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
  97 AC_SUBST(glibcpp_CXX)
  98 CXX=$glibcpp_CXX
  99 test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 100
 101 AC_PROG_CXX_GNU
 102
 103 if test $ac_cv_prog_gxx = yes; then
 104   GXX=yes
 105 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 106 dnl plays around with CXXFLAGS (such as to build both debugging and
 107 dnl normal versions of a library), tasteless as that idea is.
 108   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 109   ac_save_CXXFLAGS="$CXXFLAGS"
 110   CXXFLAGS=
 111   AC_PROG_CXX_G
 112   if test "$ac_test_CXXFLAGS" = set; then
 113     CXXFLAGS="$ac_save_CXXFLAGS"
 114   elif test $ac_cv_prog_cxx_g = yes; then
 115     CXXFLAGS="-g -O2"
 116   else
 117     CXXFLAGS="-O2"
 118   fi
 119 else
 120   GXX=
 121   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 122 fi
 123 ])
 124
 125 LIB_AC_PROG_CXX
 126
 127   AC_CHECK_TOOL(AS, as)
 128   AC_CHECK_TOOL(AR, ar)
 129   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 130   AC_PROG_INSTALL
 131
 132   AM_MAINTAINER_MODE
 133
 134   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 135   # at least currently, we never actually build a program, so we never
 136   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 137   # fails, because we are probably configuring with a cross compiler
 138   # which cant create executables.  So we include AC_EXEEXT to keep
 139   # automake happy, but we dont execute it, since we dont care about
 140   # the result.
 141   if false; then
 142     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 143     # to nothing, so nothing would remain between `then' and `fi' if it
 144     # were not for the `:' below.
 145     :
 146     AC_EXEEXT
 147   fi
 148
 149   . [$]{glibcpp_basedir}/configure.host
 150
 151   case [$]{glibcpp_basedir} in
 152     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 153     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 154   esac
 155
 156   # This does for the target what configure.host does for the host.  In
 157   # addition to possibly modifying the same flags, it also sets up symlinks.
 158   GLIBCPP_CHECK_TARGET
 159 ])
 160
 161
 162 dnl
 163 dnl Check to see if g++ can compile this library, and if so, if any version-
 164 dnl specific precautions need to be taken.
 165 dnl
 166 dnl GLIBCPP_CHECK_COMPILER_VERSION
 167 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 168 if test ! -f stamp-sanity-compiler; then
 169   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 170   AC_LANG_SAVE
 171   AC_LANG_CPLUSPLUS
 172   AC_TRY_COMPILE(, [
 173   #if __GNUC__ < 3
 174     not_ok
 175   #endif
 176   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 177   AC_LANG_RESTORE
 178   AC_MSG_RESULT($gpp_satisfactory)
 179   touch stamp-sanity-compiler
 180 fi
 181 ])
 182
 183
 184 dnl
 185 dnl Tests for newer compiler features, or features that are present in newer
 186 dnl compiler versions but not older compiler versions still in use, should
 187 dnl be placed here.
 188 dnl
 189 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 190 dnl new inlining code or the new system_header pragma will die on -Werror.
 191 dnl Leave it out by default and use maint-mode to use it.
 192 dnl
 193 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 194 dnl compiler supports it and the user has not requested debug mode.
 195 dnl
 196 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 197 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 198   # All these tests are for C++; save the language and the compiler flags.
 199   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 200   # found in GLIBCPP_CONFIGURE.
 201   AC_LANG_SAVE
 202   AC_LANG_CPLUSPLUS
 203   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 204   ac_save_CXXFLAGS="$CXXFLAGS"
 205
 206   # Check for maintainer-mode bits.
 207   if test x"$USE_MAINTAINER_MODE" = xno; then
 208     WERROR=''
 209   else
 210     WERROR='-Werror'
 211   fi
 212
 213   # Check for -ffunction-sections -fdata-sections
 214   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 215   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 216   AC_TRY_COMPILE(, [int foo;
 217   ], [ac_fdsections=yes], [ac_fdsections=no])
 218   if test "$ac_test_CXXFLAGS" = set; then
 219     CXXFLAGS="$ac_save_CXXFLAGS"
 220   else
 221     # this is the suspicious part
 222     CXXFLAGS=''
 223   fi
 224   if test x"$ac_fdsections" = x"yes" &&
 225      test x"$enable_debug" = x"no"; then
 226     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 227   fi
 228   AC_MSG_RESULT($ac_fdsections)
 229
 230   AC_LANG_RESTORE
 231   AC_SUBST(WERROR)
 232   AC_SUBST(SECTION_FLAGS)
 233 ])
 234
 235
 236 dnl
 237 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 238 dnl the native linker is in use, all variables will be defined to something
 239 dnl safe (like an empty string).
 240 dnl
 241 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 242 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 243 dnl
 244 dnl GLIBCPP_CHECK_LINKER_FEATURES
 245 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 246   # If we're not using GNU ld, then there's no point in even trying these
 247   # tests.  Check for that first.  We should have already tested for gld
 248   # by now (in libtool), but require it now just to be safe...
 249   SECTION_LDFLAGS=''
 250   OPT_LDFLAGS=''
 251   AC_REQUIRE([AC_PROG_LD])
 252
 253   # Set --gc-sections.
 254   if test "$ac_cv_prog_gnu_ld" = "notbroken"; then
 255     # GNU ld it is!  Joy and bunny rabbits!
 256
 257     # All these tests are for C++; save the language and the compiler flags.
 258     # Need to do this so that g++ won't try to link in libstdc++
 259     ac_test_CFLAGS="${CFLAGS+set}"
 260     ac_save_CFLAGS="$CFLAGS"
 261     CFLAGS='-x c++  -Wl,--gc-sections'
 262
 263     # Check for -Wl,--gc-sections
 264     # XXX This test is broken at the moment, as symbols required for
 265     # linking are now in libsupc++ (not built yet.....). In addition,
 266     # this test has cored on solaris in the past. In addition,
 267     # --gc-sections doesn't really work at the moment (keeps on discarding
 268     # used sections, first .eh_frame and now some of the glibc sections for
 269     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 270     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 271     AC_TRY_RUN([
 272      int main(void)
 273      {
 274        try { throw 1; }
 275        catch (...) { };
 276        return 0;
 277      }
 278     ], [ac_sectionLDflags=yes],[ac_sectionLFflags=no], [ac_sectionLDflags=yes])
 279     if test "$ac_test_CFLAGS" = set; then
 280       CFLAGS="$ac_save_CFLAGS"
 281     else
 282       # this is the suspicious part
 283       CFLAGS=''
 284     fi
 285     if test "$ac_sectionLDflags" = "yes"; then
 286       SECTION_LDFLAGS='-Wl,--gc-sections'
 287     fi
 288     AC_MSG_RESULT($ac_sectionLDflags)
 289   fi
 290
 291   # Set linker optimization flags.
 292   if test x"$ac_cv_prog_gnu_ld" = x"yes" &&
 293      test x"$enable_debug" = x"no"; then
 294     OPT_LDFLAGS='-Wl,-O1'
 295   fi
 296
 297   AC_SUBST(SECTION_LDFLAGS)
 298   AC_SUBST(OPT_LDFLAGS)
 299 ])
 300
 301
 302 dnl
 303 dnl Check to see if the (math function) argument passed is
 304 dnl declared when using the c++ compiler
 305 dnl ASSUMES argument is a math function with ONE parameter
 306 dnl
 307 dnl GLIBCPP_CHECK_MATH_DECL_1
 308 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 309   AC_MSG_CHECKING([for $1 declaration])
 310   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 311     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 312       AC_LANG_SAVE
 313       AC_LANG_CPLUSPLUS
 314       AC_TRY_COMPILE([#include <math.h>
 315                       #ifdef HAVE_IEEEFP_H
 316                       #include <ieeefp.h>
 317                       #endif
 318                      ],
 319                      [ $1(0);],
 320                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 321       AC_LANG_RESTORE
 322     ])
 323   fi
 324   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 325 ])
 326
 327 dnl
 328 dnl Check to see if the (math function) argument passed is
 329 dnl 1) declared when using the c++ compiler
 330 dnl 2) has "C" linkage
 331 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 332 dnl
 333 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 334 dnl
 335 dnl argument 1 is name of function to check
 336 dnl
 337 dnl ASSUMES argument is a math function with ONE parameter
 338 dnl
 339 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 340 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 341   GLIBCPP_CHECK_MATH_DECL_1($1)
 342   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 343     AC_CHECK_FUNCS($1)
 344   else
 345     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 346     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 347       AC_CHECK_FUNCS(_$1)
 348     fi
 349   fi
 350 ])
 351
 352
 353 dnl
 354 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 355 dnl of functions at once.  It's an all-or-nothing check -- either
 356 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 357 dnl Doing it this way saves significant configure time.
 358 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 359   AC_MSG_CHECKING([for $1 functions])
 360   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 361     AC_LANG_SAVE
 362     AC_LANG_CPLUSPLUS
 363     AC_TRY_COMPILE([#include <math.h>],
 364                    [ `for x in $3; do echo "$x (0);"; done` ],
 365                    [glibcpp_cv_func_$2_use=yes],
 366                    [glibcpp_cv_func_$2_use=no])
 367     AC_LANG_RESTORE])
 368   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 369   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 370     AC_CHECK_FUNCS($3)
 371   fi
 372 ])
 373
 374 dnl
 375 dnl Check to see if the (math function) argument passed is
 376 dnl declared when using the c++ compiler
 377 dnl ASSUMES argument is a math function with TWO parameters
 378 dnl
 379 dnl GLIBCPP_CHECK_MATH_DECL_2
 380 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 381   AC_MSG_CHECKING([for $1 declaration])
 382   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 383     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 384       AC_LANG_SAVE
 385       AC_LANG_CPLUSPLUS
 386       AC_TRY_COMPILE([#include <math.h>],
 387                      [ $1(0, 0);],
 388                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 389       AC_LANG_RESTORE
 390     ])
 391   fi
 392   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 393 ])
 394
 395 dnl
 396 dnl Check to see if the (math function) argument passed is
 397 dnl 1) declared when using the c++ compiler
 398 dnl 2) has "C" linkage
 399 dnl
 400 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 401 dnl
 402 dnl argument 1 is name of function to check
 403 dnl
 404 dnl ASSUMES argument is a math function with TWO parameters
 405 dnl
 406 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 407 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 408   GLIBCPP_CHECK_MATH_DECL_2($1)
 409   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 410     AC_CHECK_FUNCS($1)
 411   else
 412     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 413     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 414       AC_CHECK_FUNCS(_$1)
 415     fi
 416   fi
 417 ])
 418
 419
 420 dnl
 421 dnl Check to see if the (math function) argument passed is
 422 dnl declared when using the c++ compiler
 423 dnl ASSUMES argument is a math function with THREE parameters
 424 dnl
 425 dnl GLIBCPP_CHECK_MATH_DECL_3
 426 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 427   AC_MSG_CHECKING([for $1 declaration])
 428   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 429     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 430       AC_LANG_SAVE
 431       AC_LANG_CPLUSPLUS
 432       AC_TRY_COMPILE([#include <math.h>],
 433                      [ $1(0, 0, 0);],
 434                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 435       AC_LANG_RESTORE
 436     ])
 437   fi
 438   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 439 ])
 440
 441 dnl
 442 dnl Check to see if the (math function) argument passed is
 443 dnl 1) declared when using the c++ compiler
 444 dnl 2) has "C" linkage
 445 dnl
 446 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 447 dnl
 448 dnl argument 1 is name of function to check
 449 dnl
 450 dnl ASSUMES argument is a math function with THREE parameters
 451 dnl
 452 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 453 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 454   GLIBCPP_CHECK_MATH_DECL_3($1)
 455   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 456     AC_CHECK_FUNCS($1)
 457   else
 458     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 459     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 460       AC_CHECK_FUNCS(_$1)
 461     fi
 462   fi
 463 ])
 464
 465
 466 dnl
 467 dnl Check to see if the (stdlib function) argument passed is
 468 dnl 1) declared when using the c++ compiler
 469 dnl 2) has "C" linkage
 470 dnl
 471 dnl argument 1 is name of function to check
 472 dnl
 473 dnl ASSUMES argument is a math function with TWO parameters
 474 dnl
 475 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 476 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 477   AC_MSG_CHECKING([for $1 declaration])
 478   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 479     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 480       AC_LANG_SAVE
 481       AC_LANG_CPLUSPLUS
 482       AC_TRY_COMPILE([#include <stdlib.h>],
 483                      [ $1(0, 0);],
 484                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 485       AC_LANG_RESTORE
 486     ])
 487   fi
 488   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 489   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 490     AC_CHECK_FUNCS($1)
 491   fi
 492 ])
 493
 494
 495 dnl
 496 dnl Because the builtins are picky picky picky about the arguments they take,
 497 dnl do an explict linkage tests here.
 498 dnl Check to see if the (math function) argument passed is
 499 dnl 1) declared when using the c++ compiler
 500 dnl 2) has "C" linkage
 501 dnl
 502 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 503 dnl
 504 dnl argument 1 is name of function to check
 505 dnl
 506 dnl ASSUMES argument is a math function with ONE parameter
 507 dnl
 508 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 509 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 510   AC_MSG_CHECKING([for $1 declaration])
 511   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 512     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 513       AC_LANG_SAVE
 514       AC_LANG_CPLUSPLUS
 515       AC_TRY_COMPILE([#include <math.h>],
 516                      [ $1(0);],
 517                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 518       AC_LANG_RESTORE
 519     ])
 520   fi
 521   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 522   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 523     AC_MSG_CHECKING([for $1 linkage])
 524     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 525       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 526         AC_TRY_LINK([#include <math.h>],
 527                     [ $1(0);],
 528                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 529       ])
 530     fi
 531     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 532     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 533       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 534       AC_DEFINE_UNQUOTED(${ac_tr_func})
 535     fi
 536   fi
 537 ])
 538
 539
 540 dnl
 541 dnl Check to see what builtin math functions are supported
 542 dnl
 543 dnl check for __builtin_abs
 544 dnl check for __builtin_fabsf
 545 dnl check for __builtin_fabs
 546 dnl check for __builtin_fabl
 547 dnl check for __builtin_labs
 548 dnl check for __builtin_sqrtf
 549 dnl check for __builtin_sqrtl
 550 dnl check for __builtin_fsqrt
 551 dnl check for __builtin_sinf
 552 dnl check for __builtin_sin
 553 dnl check for __builtin_sinl
 554 dnl check for __builtin_cosf
 555 dnl check for __builtin_cos
 556 dnl check for __builtin_cosl
 557 dnl
 558 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 559 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 560   dnl Test for builtin math functions.
 561   dnl These are made in gcc/c-common.c
 562   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 563   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 564   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 565   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 566   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 567
 568   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 569   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fsqrt)
 570   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 571
 572   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 573   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 574   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 575
 576   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 577   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 578   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 579
 580   dnl There is, without a doubt, a more elegant way to have these
 581   dnl names exported so that they won't be stripped out of acconfig.h by
 582   dnl autoheader. I leave this as an exercise to somebody less frustrated
 583   dnl than I.... please email the libstdc++ list if you can figure out a
 584   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 585   dnl AC_CHECK_FUNC for things to steal.)
 586   dummyvar=no
 587   if test x$dummyvar = x"yes"; then
 588     AC_DEFINE(HAVE___BUILTIN_ABS)
 589     AC_DEFINE(HAVE___BUILTIN_LABS)
 590     AC_DEFINE(HAVE___BUILTIN_COS)
 591     AC_DEFINE(HAVE___BUILTIN_COSF)
 592     AC_DEFINE(HAVE___BUILTIN_COSL)
 593     AC_DEFINE(HAVE___BUILTIN_FABS)
 594     AC_DEFINE(HAVE___BUILTIN_FABSF)
 595     AC_DEFINE(HAVE___BUILTIN_FABSL)
 596     AC_DEFINE(HAVE___BUILTIN_SIN)
 597     AC_DEFINE(HAVE___BUILTIN_SINF)
 598     AC_DEFINE(HAVE___BUILTIN_SINL)
 599     AC_DEFINE(HAVE___BUILTIN_FSQRT)
 600     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 601     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 602   fi
 603 ])
 604
 605
 606 dnl
 607 dnl Check to see what the underlying c library
 608 dnl These checks need to do two things:
 609 dnl 1) make sure the name is declared when using the c++ compiler
 610 dnl 2) make sure the name has "C" linkage
 611 dnl This might seem like overkill but experience has shown that it's not...
 612 dnl
 613 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 614 dnl Define HAVE_STRTOF if "strtof" is declared and links
 615 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 616 dnl
 617 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 618 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 619   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 620   ac_save_CXXFLAGS="$CXXFLAGS"
 621   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 622
 623   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 624   AC_CHECK_FUNCS(drand48)
 625
 626   CXXFLAGS="$ac_save_CXXFLAGS"
 627 ])
 628
 629
 630 dnl
 631 dnl Check to see what the underlying c library or math library is like.
 632 dnl These checks need to do two things:
 633 dnl 1) make sure the name is declared when using the c++ compiler
 634 dnl 2) make sure the name has "C" linkage
 635 dnl This might seem like overkill but experience has shown that it's not...
 636 dnl
 637 dnl Define HAVE_CARGF etc if "cargf" is found.
 638 dnl
 639 dnl GLIBCPP_CHECK_MATH_SUPPORT
 640 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 641   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 642   ac_save_CXXFLAGS="$CXXFLAGS"
 643   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 644
 645   dnl Check libm
 646   AC_CHECK_LIB(m, sin, libm="-lm")
 647   ac_save_LIBS="$LIBS"
 648   LIBS="$LIBS $libm"
 649
 650   dnl Check to see if certain C math functions exist.
 651   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 652   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 653   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 654   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 655   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 656   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 657   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 658
 659   dnl Check to see if basic C math functions have float versions.
 660   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 661                                           float_trig,
 662                                           acosf asinf atanf \
 663                                           cosf sinf tanf \
 664                                           coshf sinhf tanhf)
 665   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 666                                           float_round,
 667                                           ceilf floorf)
 668   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 669   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 670   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 671   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 672   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 673   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 674   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 675   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 676   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 677   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 678   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 679   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 680   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 681
 682   dnl Check to see if basic C math functions have long double versions.
 683   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 684                                           long_double_trig,
 685                                           acosl asinl atanl \
 686                                           cosl sinl tanl \
 687                                           coshl sinhl tanhl)
 688   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 689                                           long_double_round,
 690                                           ceill floorl)
 691   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 692   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 693   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 694   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 695   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 696   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 697   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 698   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 699   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 700   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 701   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 702   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 703   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 704   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 705   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 706   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 707
 708   dnl Some runtimes have these functions with a preceding underscore. Please
 709   dnl keep this sync'd with the one above. And if you add any new symbol,
 710   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 711   dnl Check to see if certain C math functions exist.
 712
 713   dnl Check to see if basic C math functions have float versions.
 714   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 715                                           _float_trig,
 716                                           _acosf _asinf _atanf \
 717                                           _cosf _sinf _tanf \
 718                                           _coshf _sinhf _tanhf)
 719   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 720                                           _float_round,
 721                                           _ceilf _floorf)
 722
 723   dnl Check to see if basic C math functions have long double versions.
 724   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 725                                           _long_double_trig,
 726                                           _acosl _asinl _atanl \
 727                                           _cosl _sinl _tanl \
 728                                           _coshl _sinhl _tanhl)
 729   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 730                                           _long_double_round,
 731                                           _ceill _floorl)
 732
 733   LIBS="$ac_save_LIBS"
 734   CXXFLAGS="$ac_save_CXXFLAGS"
 735 ])
 736
 737
 738 dnl
 739 dnl Check to see if there is native support for complex
 740 dnl
 741 dnl Don't compile bits in math/* if native support exits.
 742 dnl
 743 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "atan2l/copysignl" is found.
 744 dnl
 745 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 746 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 747   dnl Check for complex versions of math functions of platform.
 748   AC_CHECK_LIB(m, main)
 749   AC_REPLACE_MATHFUNCS(nan hypot hypotf atan2f expf copysignf)
 750
 751   dnl Compile the long double complex functions only if the function
 752   dnl provides the non-complex long double functions that are needed.
 753   dnl Currently this includes copysignl and atan2l, which should be
 754   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 755   USE_COMPLEX_LONG_DOUBLE=no
 756   if test x$ac_cv_func_atan2l = x"yes" &&
 757      test x$ac_cv_func_copysignl = x"yes"; then
 758     USE_COMPLEX_LONG_DOUBLE=yes
 759     AC_REPLACE_MATHFUNCS(hypotl signbitl)
 760   fi
 761
 762   AC_SUBST(USE_COMPLEX_LONG_DOUBLE)
 763 ])
 764
 765
 766 dnl Check to see what architecture and operating system we are compiling
 767 dnl for.  Also, if architecture- or OS-specific flags are required for
 768 dnl compilation, pick them up here.
 769 dnl
 770 dnl GLIBCPP_CHECK_TARGET
 771 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 772     . [$]{glibcpp_basedir}/configure.target
 773     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 774     AC_MSG_RESULT(OS config directory is $os_include_dir)
 775     AC_LINK_FILES($os_include_dir/bits/os_defines.h, include/bits/os_defines.h)
 776 ])
 777
 778
 779 dnl
 780 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 781 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 782 dnl must have been previously checked.)
 783 dnl
 784 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 785 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 786 dnl
 787 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 788 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 789
 790   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 791   dnl others even if wchar_t support is not on.
 792   AC_MSG_CHECKING([for mbstate_t])
 793   AC_TRY_COMPILE([#include <wchar.h>],
 794   [mbstate_t teststate;],
 795   have_mbstate_t=yes, have_mbstate_t=no)
 796   AC_MSG_RESULT($have_mbstate_t)
 797   if test x"$have_mbstate_t" = xyes; then
 798     AC_DEFINE(HAVE_MBSTATE_T)
 799   fi
 800
 801   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 802   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 803   AC_CHECK_HEADER(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 804
 805   dnl Only continue checking if the ISO C99 headers exist and support is on.
 806   if test x"$ac_has_wchar_h" = xyes &&
 807      test x"$ac_has_wctype_h" = xyes &&
 808      test x"$enable_c_mbchar" != xno; then
 809
 810     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 811     dnl numeric_limits can instantiate type_traits<wchar_t>
 812     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 813     AC_TRY_COMPILE([#include <wchar.h>],
 814     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 815     has_wchar_minmax=yes, has_wchar_minmax=no)
 816     AC_MSG_RESULT($has_wchar_minmax)
 817
 818     dnl Test wchar.h for WEOF, which is what we use to determine whether
 819     dnl to specialize for char_traits<wchar_t> or not.
 820     AC_MSG_CHECKING([for WEOF])
 821     AC_TRY_COMPILE([
 822       #include <wchar.h>
 823       #include <stddef.h>],
 824     [wint_t i = WEOF;],
 825     has_weof=yes, has_weof=no)
 826     AC_MSG_RESULT($has_weof)
 827
 828     dnl Tests for wide character functions used in char_traits<wchar_t>.
 829     ac_wfuncs=yes
 830     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 831     ac_wfuncs=no)
 832
 833     dnl Checks for names injected into std:: by the c_std headers.
 834     AC_CHECK_FUNCS(btowc wctob fgetwc fgetwc fgetws fputwc fputws fwide \
 835     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 836     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 837     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 838     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 839     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 840     ac_wfuncs=no)
 841
 842     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 843     if test x"$has_weof" = xyes &&
 844        test x"$has_wchar_minmax" = xyes &&
 845        test x"$ac_wfuncs" = xyes; then
 846       ac_isoC99_wchar_t=yes
 847     else
 848       ac_isoC99_wchar_t=no
 849     fi
 850     AC_MSG_RESULT($ac_isoC99_wchar_t)
 851
 852     dnl Use iconv for wchar_t to char conversions. As such, check for
 853     dnl X/Open Portability Guide, version 2 features (XPG2).
 854     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 855     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 856
 857     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 858     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 859     ac_save_LIBS="$LIBS"
 860     LIBS="$LIBS $libiconv"
 861
 862     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 863     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 864
 865     LIBS="$ac_save_LIBS"
 866
 867     AC_MSG_CHECKING([for XPG2 wchar_t support])
 868     if test x"$ac_has_iconv_h" = xyes &&
 869        test x"$ac_has_langinfo_h" = xyes &&
 870        test x"$ac_XPG2funcs" = xyes; then
 871       ac_XPG2_wchar_t=yes
 872     else
 873       ac_XPG2_wchar_t=no
 874     fi
 875     AC_MSG_RESULT($ac_XPG2_wchar_t)
 876
 877     dnl At the moment, only enable wchar_t specializations if all the
 878     dnl above support is present.
 879     AC_MSG_CHECKING([for enabled wchar_t specializations])
 880     if test x"$ac_isoC99_wchar_t" = xyes &&
 881        test x"$ac_XPG2_wchar_t" = xyes; then
 882       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
 883       AC_MSG_RESULT("yes")
 884     else
 885       AC_MSG_RESULT("no")
 886     fi
 887   else
 888     dnl Wide characters disabled by the user.
 889     AC_MSG_WARN([wchar_t support disabled.])
 890   fi
 891 ])
 892
 893
 894 dnl
 895 dnl Check for special debugging mode; not for production use.
 896 dnl
 897 dnl GLIBCPP_ENABLE_DEBUG
 898 dnl --enable-debug sets '-ggdb3 -O0'.
 899 dnl --disable-debug sets '-g' and whatever optimization options the
 900 dnl     compiler can handle.
 901 dnl  +  --enable-maintainer-mode automatically defaults this to on.
 902 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
 903 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
 904 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
 905 dnl       defaults to `no'.
 906 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
 907 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
 908 AC_ARG_ENABLE(debug,
 909 changequote(<<, >>)dnl
 910 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
 911 changequote([, ])dnl
 912 [case "${enableval}" in
 913  yes) enable_debug=yes ;;
 914  no)  enable_debug=no ;;
 915  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
 916  esac],
 917 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
 918
 919 dnl Option parsed, now set things appropriately
 920 case "${enable_debug}" in
 921     yes)
 922         DEBUG_FLAGS='-O0 -ggdb3'
 923         ;;
 924     no)
 925         DEBUG_FLAGS='-g'
 926         ;;
 927 esac
 928 AC_SUBST(DEBUG_FLAGS)
 929 ])
 930
 931
 932 dnl
 933 dnl Check for "unusual" flags to pass to the compiler while building.
 934 dnl
 935 dnl GLIBCPP_ENABLE_CXX_FLAGS
 936 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
 937 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
 938 dnl     Somehow this same set of flags must be passed when [re]building
 939 dnl     libgcc.
 940 dnl --disable-cxx-flags passes nothing.
 941 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
 942 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
 943 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
 944 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
 945 dnl       If "default flags" is an empty string (or "none"), the effect is
 946 dnl       the same as --disable or --enable=no.
 947 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
 948 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
 949 AC_ARG_ENABLE(cxx-flags,
 950 changequote(<<, >>)dnl
 951 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
 952                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
 953 changequote([, ])dnl
 954 [case "x$enableval" in
 955  xyes)
 956         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
 957  xno|x)
 958         enable_cxx_flags='' ;;
 959  *)
 960         enable_cxx_flags="$enableval" ;;
 961  esac],
 962 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
 963
 964 dnl Thinko on my part during design.  This kludge is the workaround.
 965 if test "$enable_cxx_flags" = "none"; then
 966   enable_cxx_flags='';
 967 fi
 968
 969 dnl Run through flags (either default or command-line) and set anything
 970 dnl extra (e.g., #defines) that must accompany particular g++ options.
 971 if test -n "$enable_cxx_flags"; then
 972     for f in $enable_cxx_flags; do
 973         case "$f" in
 974             -fhonor-std)  ;;
 975             -*)  ;;
 976             *)   # and we're trying to pass /what/ exactly?
 977                  AC_MSG_ERROR([compiler flags start with a -]) ;;
 978         esac
 979     done
 980 fi
 981 EXTRA_CXX_FLAGS="$enable_cxx_flags"
 982 AC_SUBST(EXTRA_CXX_FLAGS)
 983 ])
 984
 985
 986 dnl
 987 dnl Check for which locale library to use:  gnu or generic.
 988 dnl
 989 dnl GLIBCPP_ENABLE_CLOCALE
 990 dnl --enable-clocale=gnu sets config/c_locale_gnu.cc and friends
 991 dnl --enable-clocale=generic sets config/c_locale_generic.cc and friends
 992 dnl
 993 dnl default is generic
 994 dnl
 995 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
 996   AC_MSG_CHECKING([for clocale to use])
 997   AC_ARG_ENABLE(clocale,
 998   [  --enable-clocale        enable model for target locale package.
 999   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1000   ],
1001   if test x$enable_clocale = xno; then
1002      enable_clocale=generic
1003   fi,
1004      enable_clocale=generic)
1005
1006   enable_clocale_flag=$enable_clocale
1007
1008   dnl Check if a valid locale package
1009   case x${enable_clocale_flag} in
1010     xgnu)
1011       CLOCALE_H=config/c_locale_gnu.h
1012       CLOCALE_CC=config/c_locale_gnu.cc
1013       AC_MSG_RESULT(gnu)
1014       ;;
1015     xgeneric)
1016       CLOCALE_H=config/c_locale_generic.h
1017       CLOCALE_CC=config/c_locale_generic.cc
1018       AC_MSG_RESULT(generic)
1019       ;;
1020     *)
1021       echo "$enable_clocale is an unknown locale package" 1>&2
1022       exit 1
1023       ;;
1024   esac
1025
1026   AC_LINK_FILES($CLOCALE_H, include/bits/c++locale.h)
1027   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1028 ])
1029
1030
1031 dnl
1032 dnl Check for which I/O library to use:  libio, or something specific.
1033 dnl
1034 dnl GLIBCPP_ENABLE_CSTDIO
1035 dnl --enable-cstdio=libio sets config/c_io_libio.h and friends
1036 dnl
1037 dnl default is stdio
1038 dnl
1039 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1040   AC_MSG_CHECKING([for cstdio to use])
1041   AC_ARG_ENABLE(cstdio,
1042   [  --enable-cstdio         enable stdio for target io package.
1043   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1044   ],
1045   if test x$enable_cstdio = xno; then
1046      enable_cstdio=stdio
1047   fi,
1048      enable_cstdio=stdio)
1049
1050   enable_cstdio_flag=$enable_cstdio
1051
1052   dnl Check if a valid I/O package
1053   case x${enable_cstdio_flag} in
1054     xlibio)
1055       CSTDIO_H=config/c_io_libio.h
1056       BASIC_FILE_H=config/basic_file_libio.h
1057       BASIC_FILE_CC=config/basic_file_libio.cc
1058       AC_MSG_RESULT(libio)
1059
1060       # see if we are on a system with libio native (ie, linux)
1061       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1062
1063       # Need to check and see what version of glibc is being used. If
1064       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1065       # compile most of libio for linux systems.
1066       if test x$has_libio = x"yes"; then
1067         case "$target" in
1068           *-*-linux*)
1069               AC_MSG_CHECKING([for glibc version >= 2.2])
1070               AC_EGREP_CPP([ok], [
1071             #include <features.h>
1072               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1073                     ok
1074               #endif
1075               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1076               AC_MSG_RESULT($glibc_satisfactory)
1077             ;;
1078         esac
1079
1080         # XXX at the moment, admit defeat and force the recompilation
1081         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1082         glibc_satisfactory=no
1083
1084         if test x$glibc_satisfactory = x"yes"; then
1085            need_libio=no
1086            need_wlibio=no
1087         else
1088            need_libio=yes
1089            # bkoz XXX need to add checks to enable this
1090            # pme XXX here's a first pass at such a check
1091            if test x$enable_c_mbchar != xno; then
1092               need_wlibio=yes
1093            else
1094               need_wlibio=no
1095            fi
1096         fi
1097
1098       else
1099          # Using libio, but <libio.h> doesn't exist on the target system. . .
1100          need_libio=yes
1101          # bkoz XXX need to add checks to enable this
1102          # pme XXX here's a first pass at such a check
1103          if test x$enable_c_mbchar != xno; then
1104              need_wlibio=yes
1105          else
1106              need_wlibio=no
1107          fi
1108       fi
1109       ;;
1110     xstdio | x | xno | xnone | xyes)
1111       # default
1112       CSTDIO_H=config/c_io_stdio.h
1113       BASIC_FILE_H=config/basic_file_stdio.h
1114       BASIC_FILE_CC=config/basic_file_stdio.cc
1115       AC_MSG_RESULT(stdio)
1116
1117       # We're not using stdio.
1118       need_libio=no
1119       need_wlibio=no
1120       ;;
1121     *)
1122       echo "$enable_cstdio is an unknown io package" 1>&2
1123       exit 1
1124       ;;
1125   esac
1126   AC_LINK_FILES($CSTDIO_H, include/bits/c++io.h)
1127   AC_LINK_FILES($BASIC_FILE_H, include/bits/basic_file_model.h)
1128   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1129
1130   # 2000-08-04 bkoz hack
1131   CCODECVT_C=config/c_io_libio_codecvt.c
1132   AC_LINK_FILES($CCODECVT_C, libio/c_codecvt.c)
1133   # 2000-08-04 bkoz hack
1134
1135   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1136                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1137   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1138   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1139   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1140     libio_la=../libio/libio.la
1141   else
1142     libio_la=
1143   fi
1144   AC_SUBST(libio_la)
1145 ])
1146
1147
1148 dnl
1149 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1150 dnl We must stage the required headers so that they will be installed
1151 dnl with the library (unlike libgcc, the STL implementation is provided
1152 dnl solely within headers).  Since we must not inject random user-space
1153 dnl macro names into user-provided C++ code, we first stage into <file>-in
1154 dnl and process to <file> with an output command.  The reason for a two-
1155 dnl stage process here is to correctly handle $srcdir!=$objdir without
1156 dnl having to write complex code (the sed commands to clean the macro
1157 dnl namespace are complex and fragile enough as it is).  We must also
1158 dnl add a relative path so that -I- is supported properly.
1159 dnl
1160 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1161   AC_MSG_CHECKING([for thread model used by GCC])
1162   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1163   AC_MSG_RESULT([$target_thread_file])
1164
1165   AC_LINK_FILES($toprel/gcc/gthr.h, include/bits/gthr.h-in)
1166   AC_LINK_FILES($toprel/gcc/gthr-single.h,
1167                 include/bits/gthr-single.h-in)
1168   AC_LINK_FILES($toprel/gcc/gthr-$target_thread_file.h,
1169                 include/bits/gthr-default.h-in)
1170   if test $target_thread_file != single; then
1171     AC_DEFINE(HAVE_GTHR_DEFAULT)
1172     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1173   fi
1174   AC_OUTPUT_COMMANDS([d=include/bits
1175     rm -f $d/gthr.h $d/gthr-single.h $d/gthr-default.h
1176     sed '/^#/s/\([A-Z_][A-Z_]*\)/_GLIBCPP_\1/g' <$d/gthr.h-in \
1177       | sed 's,"gthr-,"bits/gthr-,' >$d/gthr.h
1178     sed 's/\(UNUSED\)/_GLIBCPP_\1/g' <$d/gthr-single.h-in \
1179       | sed 's/\(GCC[A-Z_]*_H\)/_GLIBCPP_\1/g' >$d/gthr-single.h
1180     sed 's/\(UNUSED\)/_GLIBCPP_\1/g' <$d/gthr-default.h-in \
1181       | sed 's/\(GCC[A-Z_]*_H\)/_GLIBCPP_\1/g' \
1182       | sed 's/\([A-Z_]*WEAK\)/_GLIBCPP_\1/g' >$d/gthr-default.h])
1183 ])
1184
1185
1186 dnl
1187 dnl Check for exception handling support.  If an explicit enable/disable
1188 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1189 dnl target may or may not support call frame exceptions.
1190 dnl
1191 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1192 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1193 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1194 dnl
1195 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1196 dnl
1197 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1198   AC_MSG_CHECKING([for exception model to use])
1199   AC_LANG_SAVE
1200   AC_LANG_CPLUSPLUS
1201   AC_ARG_ENABLE(sjlj-exceptions,
1202   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1203   [:],
1204   [dnl Botheration.  Now we've got to detect the exception model.
1205    dnl Link tests against libgcc.a are problematic since -- at least
1206    dnl as of this writing -- we've not been given proper -L bits for
1207    dnl single-tree newlib and libgloss.
1208    dnl
1209    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1210    dnl conftest files before we got a change to grep them first.
1211    cat > conftest.$ac_ext << EOF
1212 [#]line __oline__ "configure"
1213 struct S { ~S(); };
1214 void bar();
1215 void foo()
1216 {
1217   S s;
1218   bar();
1219 }
1220 EOF
1221    old_CXXFLAGS="$CXXFLAGS"
1222    CXXFLAGS=-S
1223    if AC_TRY_EVAL(ac_compile); then
1224      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1225        enable_sjlj_exceptions=yes
1226      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1227        enable_sjlj_exceptions=no
1228      fi
1229    fi
1230    CXXFLAGS="$old_CXXFLAGS"
1231    rm -f conftest*])
1232    if test x$enable_sjlj_exceptions = xyes; then
1233      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1234         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1235      ac_exception_model_name=sjlj
1236    elif test x$enable_sjlj_exceptions = xno; then
1237      ac_exception_model_name="call frame"
1238    else
1239      AC_MSG_ERROR([unable to detect exception model])
1240    fi
1241    AC_LANG_RESTORE
1242    AC_MSG_RESULT($ac_exception_model_name)
1243 ])
1244
1245
1246 dnl
1247 dnl Check for ISO/IEC 9899:1999 "C99" support.
1248 dnl
1249 dnl GLIBCPP_ENABLE_C99
1250 dnl --enable-c99 defines _GLIBCPP_USE_C99
1251 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1252 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1253 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1254 dnl       defaults to `no'.
1255 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1256 dnl
1257 dnl GLIBCPP_ENABLE_C99
1258 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1259   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1260
1261   AC_ARG_ENABLE(c99,
1262   changequote(<<, >>)dnl
1263   <<--enable-c99      turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1264   changequote([, ])dnl
1265   [case "$enableval" in
1266    yes) enable_c99=yes ;;
1267    no)  enable_c99=no ;;
1268    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1269    esac],
1270   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1271
1272   AC_LANG_SAVE
1273   AC_LANG_CPLUSPLUS
1274
1275   # Check for the existence of <math.h> functions used if C99 is enabled.
1276   ac_c99_math=yes;
1277   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1278   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1279   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1280   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1281   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1282   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1283   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1284   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1285   AC_TRY_COMPILE([#include <math.h>],
1286                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1287   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1288   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1289   AC_TRY_COMPILE([#include <math.h>],
1290                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1291   AC_TRY_COMPILE([#include <math.h>],
1292                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1293   AC_MSG_RESULT($ac_c99_math)
1294
1295   # Check for the existence in <stdio.h> of vscanf, et. al.
1296   ac_c99_stdio=yes;
1297   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1298   AC_TRY_COMPILE([#include <stdio.h>],
1299                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1300   AC_TRY_COMPILE([#include <stdio.h>
1301                   #include <stdarg.h>
1302                   void foo(char* fmt, ...)
1303                   {va_list args; va_start(args, fmt);
1304                   vfscanf(stderr, "%i", args);}],
1305                   [],, [ac_c99_stdio=no])
1306   AC_TRY_COMPILE([#include <stdio.h>
1307                   #include <stdarg.h>
1308                   void foo(char* fmt, ...)
1309                   {va_list args; va_start(args, fmt);
1310                   vscanf("%i", args);}],
1311                   [],, [ac_c99_stdio=no])
1312   AC_TRY_COMPILE([#include <stdio.h>
1313                   #include <stdarg.h>
1314                   void foo(char* fmt, ...)
1315                   {va_list args; va_start(args, fmt);
1316                   vsnprintf(fmt, 0, "%i", args);}],
1317                   [],, [ac_c99_stdio=no])
1318   AC_TRY_COMPILE([#include <stdio.h>
1319                   #include <stdarg.h>
1320                   void foo(char* fmt, ...)
1321                   {va_list args; va_start(args, fmt);
1322                   vsscanf(fmt, "%i", args);}],
1323                   [],, [ac_c99_stdio=no])
1324   AC_MSG_RESULT($ac_c99_stdio)
1325
1326   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1327   ac_c99_stdlib=yes;
1328   AC_MSG_CHECKING([for lldiv_t declaration])
1329   AC_CACHE_VAL(ac_c99_lldiv_t, [
1330   AC_TRY_COMPILE([#include <stdlib.h>],
1331                    [ lldiv_t mydivt;],
1332                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1333   ])
1334   AC_MSG_RESULT($ac_c99_lldiv_t)
1335
1336   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1337   AC_TRY_COMPILE([#include <stdlib.h>],
1338                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1339   AC_TRY_COMPILE([#include <stdlib.h>],
1340                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1341   AC_TRY_COMPILE([#include <stdlib.h>],
1342                  [char* tmp; strtoll("gnu", &tmp, 10);],, [ac_c99_stdlib=no])
1343   AC_TRY_COMPILE([#include <stdlib.h>],
1344                  [char* tmp; strtoull("gnu", &tmp, 10);],, [ac_c99_stdlib=no])
1345   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1346   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1347   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1348   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1349   if test x"$ac_c99_lldiv_t" = x"no"; then
1350     ac_c99_stdlib=no;
1351   fi;
1352   AC_MSG_RESULT($ac_c99_stdlib)
1353
1354   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1355   # XXX the wchar.h checks should be rolled into the general C99 bits.
1356   ac_c99_wchar=yes;
1357   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1358   AC_TRY_COMPILE([#include <wchar.h>],
1359                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1360   AC_TRY_COMPILE([#include <wchar.h>],
1361                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1362   AC_TRY_COMPILE([#include <wchar.h>],
1363                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1364   AC_MSG_RESULT($ac_c99_wchar)
1365
1366   AC_MSG_CHECKING([for enabled ISO C99 support])
1367   if test x"$ac_c99_math" = x"no" ||
1368      test x"$ac_c99_stdio" = x"no" ||
1369      test x"$ac_c99_stdlib" = x"no" ||
1370      test x"$ac_c99_wchar" = x"no"; then
1371     enable_c99=no;
1372   fi;
1373   AC_MSG_RESULT($enable_c99)
1374
1375   # Option parsed, now set things appropriately
1376   if test x"$enable_c99" = x"yes"; then
1377     AC_DEFINE(_GLIBCPP_USE_C99)
1378   fi
1379
1380   AC_LANG_RESTORE
1381 ])
1382
1383
1384 dnl
1385 dnl Check for template specializations for the 'long long' type extension.
1386 dnl NB: Must check for C99 support before calling _GLIBCPP_ENABLE_LONG_LONG
1387 dnl
1388 dnl GLIBCPP_ENABLE_LONG_LONG
1389 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1390 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1391 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1392 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1393 dnl       defaults to `no'.
1394 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1395 dnl
1396 dnl GLIBCPP_ENABLE_LONG_LONG
1397 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1398   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1399
1400   AC_ARG_ENABLE(long-long,
1401   changequote(<<, >>)dnl
1402   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1403   changequote([, ])dnl
1404   [case "$enableval" in
1405    yes) enable_long_long=yes ;;
1406    no)  enable_long_long=no ;;
1407    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1408    esac],
1409   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1410
1411   # iostreams require strtoll, strtoull to compile. If the
1412   # GLIBCPP_ENABLE_C99 tests found these, and if C99 support is enabled,
1413   # go ahead and allow long long to be used.
1414   if test x"$enable_c99" = x"no"; then
1415     enable_long_long=no;
1416   fi
1417
1418   # Option parsed, now set things appropriately
1419   AC_MSG_CHECKING([for enabled long long support])
1420   if test x"$enable_long_long" = xyes; then
1421     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1422   fi
1423   AC_MSG_RESULT($enable_long_long)
1424 ])
1425
1426
1427 dnl
1428 dnl Check for what kind of C headers to use.
1429 dnl
1430 dnl GLIBCPP_ENABLE_CHEADERS
1431 dnl --enable-cheaders= [does stuff].
1432 dnl --disable-cheaders [does not do anything, really].
1433 dnl  +  This will eventually need to be 'c_shadow' by default.
1434 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1435 dnl       Where DEFAULT is either `c' or `c_std' or 'c_shadow'.
1436 dnl       If ommitted, it defaults to `c_std'.
1437 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1438 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1439 AC_MSG_CHECKING([for c header strategy to use])
1440 AC_ARG_ENABLE(cheaders,
1441 changequote(<<, >>)dnl
1442 <<  --enable-cheaders       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1443 changequote([, ])
1444   [case "$enableval" in
1445    c)
1446         enable_cheaders=c
1447         ;;
1448    c_std)
1449         enable_cheaders=c_std
1450         ;;
1451    c_shadow)
1452         enable_cheaders=c_shadow
1453         ;;
1454    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1455         ;;
1456   esac],
1457   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1458   AC_MSG_RESULT($enable_cheaders)
1459
1460   dnl Option parsed, now set things appropriately
1461   case "$enable_cheaders" in
1462     c_shadow)
1463         CSHADOW_FLAGS="-fno-builtin"
1464         C_INCLUDE_DIR='${top_srcdir}/include/c_shadow'
1465         AC_DEFINE(_GLIBCPP_USE_SHADOW_HEADERS)
1466         ;;
1467     c_std)
1468         CSHADOW_FLAGS=""
1469         C_INCLUDE_DIR='${top_srcdir}/include/c_std'
1470         ;;
1471     c)
1472         CSHADOW_FLAGS=""
1473         C_INCLUDE_DIR='${top_srcdir}/include/c'
1474         ;;
1475   esac
1476
1477   AC_SUBST(CSHADOW_FLAGS)
1478   AC_SUBST(C_INCLUDE_DIR)
1479   AM_CONDITIONAL(GLIBCPP_USE_CSHADOW, test "$enable_cheaders" = c_shadow)
1480 ])
1481
1482
1483 dnl
1484 dnl Check for wide character support.  Has the same effect as the option
1485 dnl in gcc's configure, but in a form that autoconf can mess with.
1486 dnl
1487 dnl GLIBCPP_ENABLE_C_MBCHAR
1488 dnl --enable-c-mbchar requests all the wchar_t stuff.
1489 dnl --disable-c-mbchar doesn't.
1490 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1491 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1492 dnl       defaults to `no'.
1493 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1494 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1495 AC_ARG_ENABLE(c-mbchar,
1496 changequote(<<, >>)dnl
1497 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1498 changequote([, ])dnl
1499 [case "$enableval" in
1500  yes) enable_c_mbchar=yes ;;
1501  no)  enable_c_mbchar=no ;;
1502  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1503  esac],
1504 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1505 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1506 ])
1507
1508
1509 dnl
1510 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1511 dnl
1512 dnl GLIBCPP_INCLUDE_DIR
1513 dnl C_INCLUDE_DIR
1514 dnl TOPLEVEL_INCLUDES
1515 dnl LIBMATH_INCLUDES
1516 dnl LIBSUPCXX_INCLUDES
1517 dnl LIBIO_INCLUDES
1518 dnl CSHADOW_INCLUDES
1519 dnl
1520 dnl GLIBCPP_EXPORT_INCLUDE
1521 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1522   # Root level of the include sources.
1523   GLIBCPP_INCLUDE_DIR='$(top_srcdir)/include'
1524
1525   # Can either use include/c or include/c_std to grab "C" headers. This
1526   # variable is set to the include directory currently in use.
1527   # set with C_INCLUDE_DIR in GLIBCPP_ENABLE_CHEADERS
1528
1529   # Passed down for canadian crosses.
1530   if  test x"$CANADIAN" = xyes; then
1531     TOPLEVEL_INCLUDES='-I$(includedir)'
1532   fi
1533
1534   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1535
1536   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1537
1538   #if GLIBCPP_NEED_LIBIO
1539   LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1540   #else
1541   #LIBIO_INCLUDES='-I$(top_srcdir)/libio'
1542   #endif
1543
1544   #if GLIBCPP_USE_CSHADOW
1545   #  CSHADOW_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR) \
1546   #                   -I$(top_blddir)/cshadow'
1547   #else
1548   CSTD_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR)'
1549   #endif
1550
1551   # Now, export this to all the little Makefiles....
1552   AC_SUBST(GLIBCPP_INCLUDE_DIR)
1553   AC_SUBST(TOPLEVEL_INCLUDES)
1554   AC_SUBST(LIBMATH_INCLUDES)
1555   AC_SUBST(LIBSUPCXX_INCLUDES)
1556   AC_SUBST(LIBIO_INCLUDES)
1557   AC_SUBST(CSTD_INCLUDES)
1558 ])
1559
1560
1561 dnl
1562 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1563 dnl
1564 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1565   # Optimization flags that are probably a good idea for thrill-seekers. Just
1566   # uncomment the lines below and make, everything else is ready to go...
1567   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1568   OPTIMIZE_CXXFLAGS=
1569   AC_SUBST(OPTIMIZE_CXXFLAGS)
1570
1571   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1572   AC_SUBST(WARN_FLAGS)
1573 ])
1574
1575 dnl
1576 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1577 dnl  calculates gxx_install_dir
1578 dnl  exports glibcpp_toolexecdir
1579 dnl  exports glibcpp_toolexeclibdir
1580 dnl  exports glibcpp_builddir
1581 dnl  exports glibcpp_srcdir
1582 dnl  exports glibcpp_prefixdir
1583 dnl
1584 dnl Assumes cross_compiling bits already done, and with_cross_host in
1585 dnl particular
1586 dnl
1587 dnl GLIBCPP_EXPORT_INSTALL_INFO
1588 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1589
1590 glibcpp_toolexecdir=no
1591 glibcpp_toolexeclibdir=no
1592
1593 # Export build and source directories.
1594 # These need to be absolute paths, yet at the same time need to
1595 # canonicalize only relative paths, because then amd will not unmount
1596 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
1597 glibcpp_builddir=`pwd`
1598 case $srcdir in
1599 [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
1600 *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
1601 esac
1602 glibcpp_prefixdir=${prefix}
1603
1604 AC_MSG_CHECKING([for interface version number])
1605 libstdcxx_interface=$INTERFACE
1606 AC_MSG_RESULT($libstdcxx_interface)
1607
1608 # Process the option --with-gxx-include-dir=<path to include-files directory>
1609 AC_MSG_CHECKING([for --with-gxx-include-dir])
1610 AC_ARG_WITH(gxx-include-dir,
1611 [  --with-gxx-include-dir  the installation directory for include files],
1612 [case "${withval}" in
1613   yes)
1614     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1615     gxx_include_dir=no
1616     ;;
1617   no)
1618     gxx_include_dir=no
1619     ;;
1620   *)
1621     gxx_include_dir=${withval}
1622     ;;
1623 esac], [gxx_include_dir=no])
1624 AC_MSG_RESULT($gxx_include_dir)
1625
1626 # Process the option "--enable-version-specific-runtime-libs"
1627 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1628 AC_ARG_ENABLE(version-specific-runtime-libs,
1629 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1630 [  version_specific_libs=yes
1631 # Need the gcc compiler version to know where to install libraries
1632 # and header files if --enable-version-specific-runtime-libs option
1633 # is selected.
1634 changequote(,)dnl
1635 gcc_version_trigger=${srcdir}/../gcc/version.c
1636 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
1637 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1638 gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/g++
1639 glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1640 glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1641 changequote([,])dnl
1642 ],version_specific_libs=no)
1643 AC_MSG_RESULT($version_specific_libs)
1644
1645 # Default case for install directory for include files.
1646 if test x"$version_specific_libs" = x"no" \
1647    && test x"$gxx_include_dir" = x"no"; then
1648   gxx_include_dir='$(prefix)'/include/g++-${libstdcxx_interface}
1649 fi
1650
1651 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1652 # Install a library built with a cross compiler in tooldir, not libdir.
1653 if test x"$glibcpp_toolexecdir" = x"no"; then
1654   if test -n "$with_cross_host" &&
1655      test x"$with_cross_host" != x"no"; then
1656     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1657     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1658   else
1659     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1660     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1661   fi
1662 fi
1663
1664 AC_MSG_CHECKING([for install location])
1665 AC_MSG_RESULT($gxx_include_dir)
1666
1667 AC_SUBST(glibcpp_builddir)
1668 AC_SUBST(glibcpp_srcdir)
1669 AC_SUBST(glibcpp_prefixdir)
1670 AC_SUBST(gxx_include_dir)
1671 AC_SUBST(glibcpp_toolexecdir)
1672 AC_SUBST(glibcpp_toolexeclibdir)
1673 ])
1674
1675
1676 # Check whether LC_MESSAGES is available in <locale.h>.
1677 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1678 #
1679 # This file file be copied and used freely without restrictions.  It can
1680 # be used in projects which are not available under the GNU Public License
1681 # but which still want to provide support for the GNU gettext functionality.
1682 # Please note that the actual code is *not* freely available.
1683
1684 # serial 1
1685
1686 AC_DEFUN(AC_LC_MESSAGES, [
1687   AC_CHECK_HEADER(locale.h, [
1688     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1689       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1690        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1691     if test $ac_cv_val_LC_MESSAGES = yes; then
1692       AC_DEFINE(HAVE_LC_MESSAGES)
1693     fi
1694   ])
1695 ])
1696
1697
1698 # Check for functions in math library.
1699 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1700 #
1701 # This file can be copied and used freely without restrictions.  It can
1702 # be used in projects which are not available under the GNU Public License
1703 # but which still want to provide support for the GNU gettext functionality.
1704 # Please note that the actual code is *not* freely available.
1705
1706 # serial 1
1707
1708 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1709 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1710 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])
1711 AC_SUBST(LIBMATHOBJS)dnl
1712 ])
1713
1714
1715 # Check for string functions.
1716 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1717 #
1718 # This file can be copied and used freely without restrictions.  It can
1719 # be used in projects which are not available under the GNU Public License
1720 # but which still want to provide support for the GNU gettext functionality.
1721 # Please note that the actual code is *not* freely available.
1722
1723 # serial 1
1724
1725 dnl AC_REPLACE_STRINGFUNCS(FUNCTION...)
1726 AC_DEFUN(AC_REPLACE_STRINGFUNCS,
1727 [AC_CHECK_FUNCS([$1], , [LIBSTRINGOBJS="$LIBSTRINGOBJS ${ac_func}.lo"])
1728 AC_SUBST(LIBSTRINGOBJS)dnl
1729 ])
1730
1731
1732 dnl This macro searches for a GNU version of make.  If a match is found, the
1733 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1734 dnl set to "#". This is useful for  including a special features in a Makefile,
1735 dnl which cannot be handled by other versions of make.  The variable
1736 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1737 dnl the empty string otherwise.
1738 dnl
1739 dnl Here is an example of its use:
1740 dnl
1741 dnl Makefile.in might contain:
1742 dnl
1743 dnl     # A failsafe way of putting a dependency rule into a makefile
1744 dnl     $(DEPEND):
1745 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1746 dnl
1747 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1748 dnl     @ifGNUmake@ include $(DEPEND)
1749 dnl     @ifGNUmake@ endif
1750 dnl
1751 dnl Then configure.in would normally contain:
1752 dnl
1753 dnl     CHECK_GNU_MAKE()
1754 dnl     AC_OUTPUT(Makefile)
1755 dnl
1756 dnl Then perhaps to cause gnu make to override any other make, we could do
1757 dnl something like this (note that GNU make always looks for GNUmakefile first):
1758 dnl
1759 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1760 dnl             mv Makefile GNUmakefile
1761 dnl             echo .DEFAULT: > Makefile ;
1762 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1763 dnl     fi
1764 dnl
1765 dnl Then, if any (well almost any) other make is called, and GNU make also
1766 dnl exists, then the other make wraps the GNU make.
1767 dnl
1768 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1769 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1770 dnl
1771 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1772 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1773 dnl #### conditional's subshell (" --version" is not a command), using a
1774 dnl #### different option to grep(1).
1775 dnl #### -pme
1776 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1777 dnl #### ${MAKE:-make}).
1778 dnl #### -msokolov
1779 AC_DEFUN(
1780   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1781           _cv_gnu_make_command='' ;
1782 dnl Search all the common names for GNU make
1783           for a in "${MAKE-make}" make gmake gnumake ; do
1784                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1785                   then
1786                           _cv_gnu_make_command=$a ;
1787                           break;
1788                   fi
1789           done ;
1790   ) ;
1791 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1792 dnl string, '#' otherwise
1793   if test  "x$_cv_gnu_make_command" != "x"  ; then
1794           ifGNUmake='' ;
1795   else
1796           ifGNUmake='#' ;
1797   fi
1798   AC_SUBST(ifGNUmake)
1799 ])
1800
1801 sinclude(../libtool.m4)
1802 dnl The lines below arrange for aclocal not to bring an installed
1803 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1804 dnl add a definition of LIBTOOL to Makefile.in.
1805 ifelse(,,,[AC_SUBST(LIBTOOL)
1806 AC_DEFUN([AM_PROG_LIBTOOL])
1807 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1808 AC_DEFUN([AC_PROG_LD])
1809 ])
1810
1811
1812
1813 # Do all the work for Automake.  This macro actually does too much --
1814 # some checks are only needed if your package does certain things.
1815 # But this isn't really a big deal.
1816
1817 # serial 1
1818
1819 dnl Usage:
1820 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
1821
1822 AC_DEFUN(AM_INIT_AUTOMAKE,
1823 [AC_REQUIRE([AC_PROG_INSTALL])
1824 PACKAGE=[$1]
1825 AC_SUBST(PACKAGE)
1826 VERSION=[$2]
1827 AC_SUBST(VERSION)
1828 dnl test to see if srcdir already configured
1829 if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
1830   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
1831 fi
1832 ifelse([$3],,
1833 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
1834 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
1835 AC_REQUIRE([AM_SANITY_CHECK])
1836 AC_REQUIRE([AC_ARG_PROGRAM])
1837 dnl FIXME This is truly gross.
1838 missing_dir=`cd $ac_aux_dir && pwd`
1839 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
1840 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
1841 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
1842 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
1843 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
1844 AC_REQUIRE([AC_PROG_MAKE_SET])])
1845
1846 #
1847 # Check to make sure that the build environment is sane.
1848 #
1849
1850 AC_DEFUN(AM_SANITY_CHECK,
1851 [AC_MSG_CHECKING([whether build environment is sane])
1852 # Just in case
1853 sleep 1
1854 echo timestamp > conftestfile
1855 # Do `set' in a subshell so we don't clobber the current shell's
1856 # arguments.  Must try -L first in case configure is actually a
1857 # symlink; some systems play weird games with the mod time of symlinks
1858 # (eg FreeBSD returns the mod time of the symlink's containing
1859 # directory).
1860 if (
1861    set X `ls -Lt $srcdir/configure conftestfile 2> /dev/null`
1862    if test "[$]*" = "X"; then
1863       # -L didn't work.
1864       set X `ls -t $srcdir/configure conftestfile`
1865    fi
1866    if test "[$]*" != "X $srcdir/configure conftestfile" \
1867       && test "[$]*" != "X conftestfile $srcdir/configure"; then
1868
1869       # If neither matched, then we have a broken ls.  This can happen
1870       # if, for instance, CONFIG_SHELL is bash and it inherits a
1871       # broken ls alias from the environment.  This has actually
1872       # happened.  Such a system could not be considered "sane".
1873       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
1874 alias in your environment])
1875    fi
1876
1877    test "[$]2" = conftestfile
1878    )
1879 then
1880    # Ok.
1881    :
1882 else
1883    AC_MSG_ERROR([newly created file is older than distributed files!
1884 Check your system clock])
1885 fi
1886 rm -f conftest*
1887 AC_MSG_RESULT(yes)])
1888
1889 dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
1890 dnl The program must properly implement --version.
1891 AC_DEFUN(AM_MISSING_PROG,
1892 [AC_MSG_CHECKING(for working $2)
1893 # Run test in a subshell; some versions of sh will print an error if
1894 # an executable is not found, even if stderr is redirected.
1895 # Redirect stdin to placate older versions of autoconf.  Sigh.
1896 if ($2 --version) < /dev/null > /dev/null 2>&1; then
1897    $1=$2
1898    AC_MSG_RESULT(found)
1899 else
1900    $1="$3/missing $2"
1901    AC_MSG_RESULT(missing)
1902 fi
1903 AC_SUBST($1)])
1904
1905 # Add --enable-maintainer-mode option to configure.
1906 # From Jim Meyering
1907
1908 # serial 1
1909
1910 AC_DEFUN(AM_MAINTAINER_MODE,
1911 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1912   dnl maintainer-mode is disabled by default
1913   AC_ARG_ENABLE(maintainer-mode,
1914 [  --enable-maintainer-mode enable make rules and dependencies not useful
1915                           (and sometimes confusing) to the casual installer],
1916       USE_MAINTAINER_MODE=$enableval,
1917       USE_MAINTAINER_MODE=no)
1918   AC_MSG_RESULT($USE_MAINTAINER_MODE)
1919   AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
1920   MAINT=$MAINTAINER_MODE_TRUE
1921   AC_SUBST(MAINT)dnl
1922 ]
1923 )
1924
1925 # Define a conditional.
1926
1927 AC_DEFUN(AM_CONDITIONAL,
1928 [AC_SUBST($1_TRUE)
1929 AC_SUBST($1_FALSE)
1930 if $2; then
1931   $1_TRUE=
1932   $1_FALSE='#'
1933 else
1934   $1_TRUE='#'
1935   $1_FALSE=
1936 fi])
1937
1938 # Like AC_CONFIG_HEADER, but automatically create stamp file.
1939
1940 AC_DEFUN(AM_CONFIG_HEADER,
1941 [AC_PREREQ([2.12])
1942 AC_CONFIG_HEADER([$1])
1943 dnl When config.status generates a header, we must update the stamp-h file.
1944 dnl This file resides in the same directory as the config header
1945 dnl that is generated.  We must strip everything past the first ":",
1946 dnl and everything past the last "/".
1947 AC_OUTPUT_COMMANDS(changequote(<<,>>)dnl
1948 ifelse(patsubst(<<$1>>, <<[^ ]>>, <<>>), <<>>,
1949 <<test -z "<<$>>CONFIG_HEADERS" || echo timestamp > patsubst(<<$1>>, <<^\([^:]*/\)?.*>>, <<\1>>)stamp-h<<>>dnl>>,
1950 <<am_indx=1
1951 for am_file in <<$1>>; do
1952   case " <<$>>CONFIG_HEADERS " in
1953   *" <<$>>am_file "*<<)>>
1954     echo timestamp > `echo <<$>>am_file | sed -e 's%:.*%%' -e 's%[^/]*$%%'`stamp-h$am_indx
1955     ;;
1956   esac
1957   am_indx=`expr "<<$>>am_indx" + 1`
1958 done<<>>dnl>>)
1959 changequote([,]))])
1960