libstdc++-v3/aclocal.m4

   1 # generated automatically by aclocal 1.7.8 -*- Autoconf -*-
   2
   3 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 # Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  11 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  12 # PARTICULAR PURPOSE.
  13
  14
  15 dnl
  16 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
  17 dnl
  18 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
  19 dnl end of configure.  This lets tested variables be reassigned, and the
  20 dnl conditional will depend on the final state of the variable.  For a simple
  21 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
  22 dnl
  23 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  24 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  25   m4_divert_text([glibcxx_diversion],dnl
  26    AM_CONDITIONAL([$1],[$2])
  27   )dnl
  28 ])dnl
  29 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  30
  31
  32 dnl
  33 dnl Check to see what architecture and operating system we are compiling
  34 dnl for.  Also, if architecture- or OS-specific flags are required for
  35 dnl compilation, pick them up here.
  36 dnl
  37 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  38   . $glibcxx_srcdir/configure.host
  39   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  40   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  41 ])
  42
  43
  44 dnl
  45 dnl Initialize basic configure bits.
  46 dnl
  47 dnl Substs:
  48 dnl  multi_basedir
  49 dnl
  50 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  51   # Sets up multi_basedir, which is srcdir/.. plus the usual
  52   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  53   AM_ENABLE_MULTILIB(, ..)
  54
  55   # The generated code is exactly the same, except that automake's looks in
  56   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  57   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  58   # know what they are or what the other differences might be (and they keep
  59   # changing anyhow).
  60   #
  61   # Looking in multi_basedir seems smarter, so actually execute that branch.
  62   if false; then
  63     # this is for automake
  64     AC_CONFIG_AUX_DIR(..)
  65   else
  66     # this is for autoconf
  67     AC_CONFIG_AUX_DIRS(${multi_basedir})
  68   fi
  69
  70   dnl XXX Turn this on.
  71   dnl AC_LANG_CPLUSPLUS
  72 ])
  73
  74
  75 dnl
  76 dnl Initialize the rest of the library configury.  At this point we have
  77 dnl variables like $host.
  78 dnl
  79 dnl Sets:
  80 dnl  gcc_version          (x.y.z format)
  81 dnl  SUBDIRS
  82 dnl Substs:
  83 dnl  glibcxx_builddir     (absolute path)
  84 dnl  glibcxx_srcdir       (absolute path)
  85 dnl  toplevel_srcdir      (absolute path)
  86 dnl  with_cross_host
  87 dnl  with_newlib
  88 dnl  with_target_subdir
  89 dnl plus
  90 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  91 dnl  - default settings for all AM_CONFITIONAL test variables
  92 dnl  - lots of tools, like CC and CXX
  93 dnl
  94 AC_DEFUN(GLIBCXX_CONFIGURE, [
  95   # Keep these sync'd with the list in Makefile.am.  The first provides an
  96   # expandable list at autoconf time; the second provides an expandable list
  97   # (i.e., shell variable) at configure time.
  98   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  99   SUBDIRS='glibcxx_SUBDIRS'
 100
 101   # These need to be absolute paths, yet at the same time need to
 102   # canonicalize only relative paths, because then amd will not unmount
 103   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
 104   glibcxx_builddir=`${PWDCMD-pwd}`
 105   case $srcdir in
 106     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
 107     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
 108   esac
 109   toplevel_srcdir=${glibcxx_srcdir}/..
 110   AC_SUBST(glibcxx_builddir)
 111   AC_SUBST(glibcxx_srcdir)
 112   AC_SUBST(toplevel_srcdir)
 113
 114   # We use these options to decide which functions to include.  They are
 115   # set from the top level.
 116   AC_ARG_WITH([target-subdir],
 117     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 118                    [configuring in a subdirectory]))
 119
 120   AC_ARG_WITH([cross-host],
 121     AC_HELP_STRING([--with-cross-host=HOST],
 122                    [configuring with a cross compiler]))
 123
 124   AC_ARG_WITH([newlib],
 125     AC_HELP_STRING([--with-newlib],
 126                    [assume newlib as a system C library]))
 127
 128   # We're almost certainly being configured before anything else which uses
 129   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 130   # we not cache the value of CXX that we "discover" here, because it's set
 131   # to something unique for us and libjava.  Other target libraries need to
 132   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 133   # process by sneakily renaming the cache variable.  This also lets us debug
 134   # the value of "our" CXX in postmortems.
 135   #
 136   # We must also force CXX to /not/ be a precious variable, otherwise the
 137   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 138   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 139   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 140   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 141   #
 142   # -fno-builtin must be present here so that a non-conflicting form of
 143   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 144
 145   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 146   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 147   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 148   save_CXXFLAGS="$CXXFLAGS"
 149   CXXFLAGS="$CXXFLAGS -fno-builtin"
 150   AC_PROG_CC
 151   AC_PROG_CXX
 152   CXXFLAGS="$save_CXXFLAGS"
 153   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 154   AC_SUBST(CFLAGS)
 155   AC_SUBST(CXXFLAGS)
 156
 157   # For directory versioning (e.g., headers) and other variables.
 158   AC_MSG_CHECKING([for GCC version number])
 159   gcc_version=`$CXX -dumpversion`
 160   AC_MSG_RESULT($gcc_version)
 161
 162   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 163   # available).  Uncomment the next line to force a particular method.
 164   AC_PROG_LN_S
 165   #LN_S='cp -p'
 166
 167   AC_CHECK_TOOL(AS, as)
 168   AC_CHECK_TOOL(AR, ar)
 169   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 170
 171   AM_MAINTAINER_MODE
 172
 173   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 174   # which are themselves conditionally expanded.
 175   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 176   ## other macros from doing the same.  This should be automated.)  -pme
 177   need_libmath=no
 178   enable_wchar_t=no
 179   #enable_libstdcxx_debug=no
 180   #enable_libstdcxx_pch=no
 181   #enable_cheaders=c
 182   #c_compatibility=no
 183   #enable_abi_check=no
 184   #enable_symvers=no
 185   #enable_hosted_libstdcxx=yes
 186
 187   # Find platform-specific directories containing configuration info.
 188   # Also possibly modify flags used elsewhere, as needed by the platform.
 189   GLIBCXX_CHECK_HOST
 190 ])
 191
 192
 193 m4_include([linkage.m4])
 194 m4_include([../config/no-executables.m4])
 195
 196
 197 dnl
 198 dnl Tests for newer compiler features, or features that are present in newer
 199 dnl compiler versions but not older compiler versions still in use, should
 200 dnl be placed here.
 201 dnl
 202 dnl Defines:
 203 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 204 dnl   new inlining code or the new system_header pragma will die on -Werror.
 205 dnl   Leave it out by default and use maint-mode to use it.
 206 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 207 dnl   compiler supports it and the user has not requested debug mode.
 208 dnl
 209 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 210   # All these tests are for C++; save the language and the compiler flags.
 211   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 212   # found in GLIBCXX_CONFIGURE.
 213   AC_LANG_SAVE
 214   AC_LANG_CPLUSPLUS
 215   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 216   ac_save_CXXFLAGS="$CXXFLAGS"
 217
 218   # Check for maintainer-mode bits.
 219   if test x"$USE_MAINTAINER_MODE" = xno; then
 220     WERROR=''
 221   else
 222     WERROR='-Werror'
 223   fi
 224
 225   # Check for -ffunction-sections -fdata-sections
 226   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 227   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 228   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 229   if test "$ac_test_CXXFLAGS" = set; then
 230     CXXFLAGS="$ac_save_CXXFLAGS"
 231   else
 232     # this is the suspicious part
 233     CXXFLAGS=''
 234   fi
 235   if test x"$ac_fdsections" = x"yes"; then
 236     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 237   fi
 238   AC_MSG_RESULT($ac_fdsections)
 239
 240   AC_LANG_RESTORE
 241   AC_SUBST(WERROR)
 242   AC_SUBST(SECTION_FLAGS)
 243 ])
 244
 245
 246 dnl
 247 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 248 dnl the native linker is in use, all variables will be defined to something
 249 dnl safe (like an empty string).
 250 dnl
 251 dnl Defines:
 252 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 253 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 254 dnl  LD (as a side effect of testing)
 255 dnl Sets:
 256 dnl  with_gnu_ld
 257 dnl  glibcxx_gnu_ld_version (possibly)
 258 dnl
 259 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 260 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 261 dnl
 262 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 263   # If we're not using GNU ld, then there's no point in even trying these
 264   # tests.  Check for that first.  We should have already tested for gld
 265   # by now (in libtool), but require it now just to be safe...
 266   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 267   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 268   AC_REQUIRE([AC_PROG_LD])
 269   AC_REQUIRE([AC_PROG_AWK])
 270
 271   # The name set by libtool depends on the version of libtool.  Shame on us
 272   # for depending on an impl detail, but c'est la vie.  Older versions used
 273   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 274   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 275   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 276   # set (hence we're using an older libtool), then set it.
 277   if test x${with_gnu_ld+set} != xset; then
 278     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 279       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 280       with_gnu_ld=no
 281     else
 282       with_gnu_ld=$ac_cv_prog_gnu_ld
 283     fi
 284   fi
 285
 286   # Start by getting the version number.  I think the libtool test already
 287   # does some of this, but throws away the result.
 288   changequote(,)
 289   ldver=`$LD --version 2>/dev/null | head -1 | \
 290          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 291   changequote([,])
 292   glibcxx_gnu_ld_version=`echo $ldver | \
 293          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 294
 295   # Set --gc-sections.
 296   if test "$with_gnu_ld" = "notbroken"; then
 297     # GNU ld it is!  Joy and bunny rabbits!
 298
 299     # All these tests are for C++; save the language and the compiler flags.
 300     # Need to do this so that g++ won't try to link in libstdc++
 301     ac_test_CFLAGS="${CFLAGS+set}"
 302     ac_save_CFLAGS="$CFLAGS"
 303     CFLAGS='-x c++  -Wl,--gc-sections'
 304
 305     # Check for -Wl,--gc-sections
 306     # XXX This test is broken at the moment, as symbols required for linking
 307     # are now in libsupc++ (not built yet).  In addition, this test has
 308     # cored on solaris in the past.  In addition, --gc-sections doesn't
 309     # really work at the moment (keeps on discarding used sections, first
 310     # .eh_frame and now some of the glibc sections for iconv).
 311     # Bzzzzt.  Thanks for playing, maybe next time.
 312     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 313     AC_TRY_RUN([
 314      int main(void)
 315      {
 316        try { throw 1; }
 317        catch (...) { };
 318        return 0;
 319      }
 320     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 321     if test "$ac_test_CFLAGS" = set; then
 322       CFLAGS="$ac_save_CFLAGS"
 323     else
 324       # this is the suspicious part
 325       CFLAGS=''
 326     fi
 327     if test "$ac_sectionLDflags" = "yes"; then
 328       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 329     fi
 330     AC_MSG_RESULT($ac_sectionLDflags)
 331   fi
 332
 333   # Set linker optimization flags.
 334   if test x"$with_gnu_ld" = x"yes"; then
 335     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 336   fi
 337
 338   AC_SUBST(SECTION_LDFLAGS)
 339   AC_SUBST(OPT_LDFLAGS)
 340 ])
 341
 342
 343 dnl
 344 dnl Check to see if this target can enable the wchar_t parts.
 345 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 346 dnl must have been previously checked.)  By default, wide characters are
 347 dnl disabled.
 348 dnl
 349 dnl Defines:
 350 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 351 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 352 dnl
 353 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 354   # Test wchar.h for mbstate_t, which is needed for char_traits and
 355   # others even if wchar_t support is not on.
 356   AC_MSG_CHECKING([for mbstate_t])
 357   AC_TRY_COMPILE([#include <wchar.h>],
 358   [mbstate_t teststate;],
 359   have_mbstate_t=yes, have_mbstate_t=no)
 360   AC_MSG_RESULT($have_mbstate_t)
 361   if test x"$have_mbstate_t" = xyes; then
 362     AC_DEFINE(HAVE_MBSTATE_T)
 363   fi
 364
 365   # Sanity check for existence of ISO C99 headers for extended encoding.
 366   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 367   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 368
 369   # Only continue checking if the ISO C99 headers exist and support is on.
 370   if test x"$ac_has_wchar_h" = xyes &&
 371      test x"$ac_has_wctype_h" = xyes &&
 372      test x"$enable_c_mbchar" != xno; then
 373
 374     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 375     # numeric_limits can instantiate type_traits<wchar_t>
 376     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 377     AC_TRY_COMPILE([#include <wchar.h>],
 378     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 379     has_wchar_minmax=yes, has_wchar_minmax=no)
 380     AC_MSG_RESULT($has_wchar_minmax)
 381
 382     # Test wchar.h for WEOF, which is what we use to determine whether
 383     # to specialize for char_traits<wchar_t> or not.
 384     AC_MSG_CHECKING([for WEOF])
 385     AC_TRY_COMPILE([
 386       #include <wchar.h>
 387       #include <stddef.h>],
 388     [wint_t i = WEOF;],
 389     has_weof=yes, has_weof=no)
 390     AC_MSG_RESULT($has_weof)
 391
 392     # Tests for wide character functions used in char_traits<wchar_t>.
 393     ac_wfuncs=yes
 394     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 395     [],[ac_wfuncs=no])
 396
 397     # Checks for names injected into std:: by the c_std headers.
 398     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 399     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 400     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 401     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 402     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 403     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 404     [],[ac_wfuncs=no])
 405
 406     # Checks for wide character functions that are not required
 407     # for basic wchar_t support.  Don't disable support if they are missing.
 408     # Injection of these is wrapped with guard macros.
 409     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 410
 411     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 412     if test x"$has_weof" = xyes &&
 413        test x"$has_wchar_minmax" = xyes &&
 414        test x"$ac_wfuncs" = xyes;
 415     then
 416       ac_isoC99_wchar_t=yes
 417     else
 418       ac_isoC99_wchar_t=no
 419     fi
 420     AC_MSG_RESULT($ac_isoC99_wchar_t)
 421
 422     # Use iconv for wchar_t to char conversions. As such, check for
 423     # X/Open Portability Guide, version 2 features (XPG2).
 424     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 425     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 426
 427     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 428     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 429     ac_save_LIBS="$LIBS"
 430     LIBS="$LIBS $libiconv"
 431
 432     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 433     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 434
 435     LIBS="$ac_save_LIBS"
 436
 437     AC_MSG_CHECKING([for XPG2 wchar_t support])
 438     if test x"$ac_has_iconv_h" = xyes &&
 439        test x"$ac_has_langinfo_h" = xyes &&
 440        test x"$ac_XPG2funcs" = xyes;
 441     then
 442       ac_XPG2_wchar_t=yes
 443     else
 444       ac_XPG2_wchar_t=no
 445     fi
 446     AC_MSG_RESULT($ac_XPG2_wchar_t)
 447
 448     # At the moment, only enable wchar_t specializations if all the
 449     # above support is present.
 450     if test x"$ac_isoC99_wchar_t" = xyes &&
 451        test x"$ac_XPG2_wchar_t" = xyes;
 452     then
 453       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 454       enable_wchar_t=yes
 455     fi
 456   fi
 457   AC_MSG_CHECKING([for enabled wchar_t specializations])
 458   AC_MSG_RESULT($enable_wchar_t)
 459 ])
 460
 461
 462 dnl
 463 dnl Check for headers for, and arguments to, the setrlimit() function.
 464 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 465 dnl
 466 dnl Defines:
 467 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 468 dnl  various HAVE_MEMLIMIT_* for individual limit names
 469 dnl
 470 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 471   AC_TRY_COMPILE(
 472     [#include <unistd.h>
 473      #include <sys/time.h>
 474      #include <sys/resource.h>
 475     ],
 476     [ int f = RLIMIT_$1 ; ],
 477     [glibcxx_mresult=1], [glibcxx_mresult=0])
 478   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 479                      [Only used in build directory testsuite_hooks.h.])
 480 ])
 481
 482 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 483   setrlimit_have_headers=yes
 484   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 485                    [],
 486                    [setrlimit_have_headers=no])
 487   # If don't have the headers, then we can't run the tests now, and we
 488   # won't be seeing any of these during testsuite compilation.
 489   if test $setrlimit_have_headers = yes; then
 490     # Can't do these in a loop, else the resulting syntax is wrong.
 491     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 492     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 493     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 494     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 495
 496     # Check for rlimit, setrlimit.
 497     AC_CACHE_VAL(ac_setrlimit, [
 498       AC_TRY_COMPILE(
 499         [#include <unistd.h>
 500          #include <sys/time.h>
 501          #include <sys/resource.h>
 502         ],
 503         [struct rlimit r;
 504          setrlimit(0, &r);],
 505         [ac_setrlimit=yes], [ac_setrlimit=no])
 506     ])
 507   fi
 508
 509   AC_MSG_CHECKING([for testsuite memory limit support])
 510   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 511     ac_mem_limits=yes
 512     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 513   else
 514     ac_mem_limits=no
 515   fi
 516   AC_MSG_RESULT($ac_mem_limits)
 517 ])
 518
 519
 520 dnl
 521 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 522 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 523 dnl
 524 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 525   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 526     AC_TRY_LINK(
 527       [#include <sys/stat.h>],
 528       [struct stat buffer;
 529        fstat(0, &buffer);
 530        S_ISREG(buffer.st_mode);],
 531       [glibcxx_cv_S_ISREG=yes],
 532       [glibcxx_cv_S_ISREG=no])
 533   ])
 534   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 535     AC_TRY_LINK(
 536       [#include <sys/stat.h>],
 537       [struct stat buffer;
 538        fstat(0, &buffer);
 539        S_IFREG & buffer.st_mode;],
 540       [glibcxx_cv_S_IFREG=yes],
 541       [glibcxx_cv_S_IFREG=no])
 542   ])
 543   if test $glibcxx_cv_S_ISREG = yes; then
 544     AC_DEFINE(HAVE_S_ISREG)
 545   elif test $glibcxx_cv_S_IFREG = yes; then
 546     AC_DEFINE(HAVE_S_IFREG)
 547   fi
 548 ])
 549
 550
 551 dnl
 552 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 553 dnl
 554 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 555   AC_CACHE_VAL(glibcxx_cv_POLL, [
 556     AC_TRY_LINK(
 557       [#include <poll.h>],
 558       [struct pollfd pfd[1];
 559        pfd[0].events = POLLIN;
 560        poll(pfd, 1, 0);],
 561       [glibcxx_cv_POLL=yes],
 562       [glibcxx_cv_POLL=no])
 563   ])
 564   if test $glibcxx_cv_POLL = yes; then
 565     AC_DEFINE(HAVE_POLL)
 566   fi
 567 ])
 568
 569
 570 dnl
 571 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 572 dnl
 573 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 574   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 575     AC_TRY_LINK(
 576       [#include <sys/uio.h>],
 577       [struct iovec iov[2];
 578        writev(0, iov, 0);],
 579       [glibcxx_cv_WRITEV=yes],
 580       [glibcxx_cv_WRITEV=no])
 581   ])
 582   if test $glibcxx_cv_WRITEV = yes; then
 583     AC_DEFINE(HAVE_WRITEV)
 584   fi
 585 ])
 586
 587
 588 dnl
 589 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 590 dnl
 591 AC_DEFUN(GLIBCXX_CHECK_INT64_T, [
 592   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 593     AC_TRY_COMPILE(
 594       [#include <stdint.h>],
 595       [int64_t var;],
 596       [glibcxx_cv_INT64_T=yes],
 597       [glibcxx_cv_INT64_T=no])
 598   ])
 599   if test $glibcxx_cv_INT64_T = yes; then
 600     AC_DEFINE(HAVE_INT64_T)
 601   fi
 602 ])
 603
 604
 605 dnl
 606 dnl Check whether LFS support is available.
 607 dnl
 608 AC_DEFUN(GLIBCXX_CHECK_LFS, [
 609   AC_CACHE_VAL(glibcxx_cv_LFS, [
 610     AC_TRY_LINK(
 611       [#include <unistd.h>],
 612       [fopen64("t", "w");
 613        lseek64(1, 0, SEEK_CUR);],
 614       [glibcxx_cv_LFS=yes],
 615       [glibcxx_cv_LFS=no])
 616   ])
 617   if test $glibcxx_cv_LFS = yes; then
 618     AC_DEFINE(_GLIBCXX_USE_LFS)
 619   fi
 620 ])
 621
 622
 623 dnl
 624 dnl Does any necessary configuration of the testsuite directory.  Generates
 625 dnl the testsuite_hooks.h header.
 626 dnl
 627 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 628 dnl
 629 dnl Sets:
 630 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 631 dnl Substs:
 632 dnl  baseline_dir
 633 dnl
 634 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 635   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 636     # Do checks for memory limit functions.
 637     GLIBCXX_CHECK_SETRLIMIT
 638
 639     # Look for setenv, so that extended locale tests can be performed.
 640     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 641
 642     if test $enable_symvers = no; then
 643       enable_abi_check=no
 644     else
 645       case "$host" in
 646         *-*-cygwin*)
 647           enable_abi_check=no ;;
 648         *)
 649           enable_abi_check=yes ;;
 650       esac
 651     fi
 652   else
 653     # Only build this as native, since automake does not understand
 654     # CXX_FOR_BUILD.
 655     enable_abi_check=no
 656   fi
 657
 658   # Export file names for ABI checking.
 659   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 660   AC_SUBST(baseline_dir)
 661
 662   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 663   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 664 ])
 665
 666
 667 dnl
 668 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 669 dnl
 670 dnl Substs:
 671 dnl  GLIBCXX_INCLUDES
 672 dnl  TOPLEVEL_INCLUDES
 673 dnl
 674 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 675   # Used for every C++ compile we perform.
 676   GLIBCXX_INCLUDES="\
 677 -I$glibcxx_builddir/include/$host_alias \
 678 -I$glibcxx_builddir/include \
 679 -I$glibcxx_srcdir/libsupc++"
 680
 681   # For Canadian crosses, pick this up too.
 682   if test $CANADIAN = yes; then
 683     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 684   fi
 685
 686   # Stuff in the actual top level.  Currently only used by libsupc++ to
 687   # get unwind* headers from the gcc dir.
 688   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 689   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 690
 691   # Now, export this to all the little Makefiles....
 692   AC_SUBST(GLIBCXX_INCLUDES)
 693   AC_SUBST(TOPLEVEL_INCLUDES)
 694 ])
 695
 696
 697 dnl
 698 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 699 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 700 dnl
 701 dnl Substs:
 702 dnl  OPTIMIZE_CXXFLAGS
 703 dnl  WARN_FLAGS
 704 dnl
 705 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 706   # Optimization flags that are probably a good idea for thrill-seekers. Just
 707   # uncomment the lines below and make, everything else is ready to go...
 708   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 709   OPTIMIZE_CXXFLAGS=
 710   AC_SUBST(OPTIMIZE_CXXFLAGS)
 711
 712   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 713   AC_SUBST(WARN_FLAGS)
 714 ])
 715
 716
 717 dnl
 718 dnl All installation directory information is determined here.
 719 dnl
 720 dnl Substs:
 721 dnl  gxx_install_dir
 722 dnl  glibcxx_prefixdir
 723 dnl  glibcxx_toolexecdir
 724 dnl  glibcxx_toolexeclibdir
 725 dnl
 726 dnl Assumes cross_compiling bits already done, and with_cross_host in
 727 dnl particular.
 728 dnl
 729 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 730   glibcxx_toolexecdir=no
 731   glibcxx_toolexeclibdir=no
 732   glibcxx_prefixdir=$prefix
 733
 734   AC_MSG_CHECKING([for gxx-include-dir])
 735   AC_ARG_WITH([gxx-include-dir],
 736     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 737                    [installation directory for include files]),
 738     [case "$withval" in
 739       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 740       no)  gxx_include_dir=no ;;
 741       *)   gxx_include_dir=$withval ;;
 742      esac],
 743     [gxx_include_dir=no])
 744   AC_MSG_RESULT($gxx_include_dir)
 745
 746   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 747   AC_ARG_ENABLE([version-specific-runtime-libs],
 748     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 749                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 750     [case "$enableval" in
 751       yes) version_specific_libs=yes ;;
 752       no)  version_specific_libs=no ;;
 753       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 754      esac],
 755     [version_specific_libs=no])
 756   AC_MSG_RESULT($version_specific_libs)
 757
 758   # Default case for install directory for include files.
 759   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 760     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 761   fi
 762
 763   # Version-specific runtime libs processing.
 764   if test $version_specific_libs = yes; then
 765     # Need the gcc compiler version to know where to install libraries
 766     # and header files if --enable-version-specific-runtime-libs option
 767     # is selected.
 768     if test x"$gxx_include_dir" = x"no"; then
 769       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 770     fi
 771     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 772     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 773   fi
 774
 775   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 776   # Install a library built with a cross compiler in tooldir, not libdir.
 777   if test x"$glibcxx_toolexecdir" = x"no"; then
 778     if test -n "$with_cross_host" &&
 779        test x"$with_cross_host" != x"no"; then
 780       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 781       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 782     else
 783       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 784       glibcxx_toolexeclibdir='${libdir}'
 785     fi
 786     multi_os_directory=`$CXX -print-multi-os-directory`
 787     case $multi_os_directory in
 788       .) ;; # Avoid trailing /.
 789       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 790     esac
 791   fi
 792
 793   AC_MSG_CHECKING([for install location])
 794   AC_MSG_RESULT($gxx_include_dir)
 795
 796   AC_SUBST(glibcxx_prefixdir)
 797   AC_SUBST(gxx_include_dir)
 798   AC_SUBST(glibcxx_toolexecdir)
 799   AC_SUBST(glibcxx_toolexeclibdir)
 800 ])
 801
 802
 803 dnl
 804 dnl GLIBCXX_ENABLE
 805 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 806 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 807 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 808 dnl
 809 dnl See docs/html/17_intro/configury.html#enable for documentation.
 810 dnl
 811 m4_define([GLIBCXX_ENABLE],[dnl
 812 m4_define([_g_switch],[--enable-$1])dnl
 813 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 814  AC_ARG_ENABLE($1,_g_help,
 815   m4_bmatch([$5],
 816    [^permit ],
 817      [[
 818       case "$enableval" in
 819        m4_bpatsubst([$5],[permit ])) ;;
 820        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 821           dnl Idea for future:  generate a URL pointing to
 822           dnl "onlinedocs/configopts.html#whatever"
 823       esac
 824      ]],
 825    [^$],
 826      [[
 827       case "$enableval" in
 828        yes|no) ;;
 829        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 830       esac
 831      ]],
 832    [[$5]]),
 833   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 834 m4_undefine([_g_switch])dnl
 835 m4_undefine([_g_help])dnl
 836 ])
 837
 838
 839 dnl
 840 dnl Check for ISO/IEC 9899:1999 "C99" support.
 841 dnl
 842 dnl --enable-c99 defines _GLIBCXX_USE_C99
 843 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 844 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 845 dnl       Where DEFAULT is either `yes' or `no'.
 846 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 847 dnl
 848 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 849   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 850
 851   AC_LANG_SAVE
 852   AC_LANG_CPLUSPLUS
 853
 854   # Check for the existence of <math.h> functions used if C99 is enabled.
 855   ac_c99_math=yes;
 856   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 857   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 858   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 859   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 860   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 861   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 862   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 863   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 864   AC_TRY_COMPILE([#include <math.h>],
 865                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 866   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 867   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 868   AC_TRY_COMPILE([#include <math.h>],
 869                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 870   AC_TRY_COMPILE([#include <math.h>],
 871                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 872   AC_MSG_RESULT($ac_c99_math)
 873
 874   # Check for the existence in <stdio.h> of vscanf, et. al.
 875   ac_c99_stdio=yes;
 876   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 877   AC_TRY_COMPILE([#include <stdio.h>],
 878                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 879   AC_TRY_COMPILE([#include <stdio.h>
 880                   #include <stdarg.h>
 881                   void foo(char* fmt, ...)
 882                   {va_list args; va_start(args, fmt);
 883                   vfscanf(stderr, "%i", args);}],
 884                   [],, [ac_c99_stdio=no])
 885   AC_TRY_COMPILE([#include <stdio.h>
 886                   #include <stdarg.h>
 887                   void foo(char* fmt, ...)
 888                   {va_list args; va_start(args, fmt);
 889                   vscanf("%i", args);}],
 890                   [],, [ac_c99_stdio=no])
 891   AC_TRY_COMPILE([#include <stdio.h>
 892                   #include <stdarg.h>
 893                   void foo(char* fmt, ...)
 894                   {va_list args; va_start(args, fmt);
 895                   vsnprintf(fmt, 0, "%i", args);}],
 896                   [],, [ac_c99_stdio=no])
 897   AC_TRY_COMPILE([#include <stdio.h>
 898                   #include <stdarg.h>
 899                   void foo(char* fmt, ...)
 900                   {va_list args; va_start(args, fmt);
 901                   vsscanf(fmt, "%i", args);}],
 902                   [],, [ac_c99_stdio=no])
 903   AC_MSG_RESULT($ac_c99_stdio)
 904
 905   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 906   ac_c99_stdlib=yes;
 907   AC_MSG_CHECKING([for lldiv_t declaration])
 908   AC_CACHE_VAL(ac_c99_lldiv_t, [
 909   AC_TRY_COMPILE([#include <stdlib.h>],
 910                    [ lldiv_t mydivt;],
 911                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 912   ])
 913   AC_MSG_RESULT($ac_c99_lldiv_t)
 914
 915   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 916   AC_TRY_COMPILE([#include <stdlib.h>],
 917                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 918   AC_TRY_COMPILE([#include <stdlib.h>],
 919                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 920   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 921   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 922   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 923   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 924   if test x"$ac_c99_lldiv_t" = x"no"; then
 925     ac_c99_stdlib=no;
 926   fi;
 927   AC_MSG_RESULT($ac_c99_stdlib)
 928
 929   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 930   # XXX the wchar.h checks should be rolled into the general C99 bits.
 931   ac_c99_wchar=yes;
 932   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 933   AC_TRY_COMPILE([#include <wchar.h>],
 934                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 935   AC_TRY_COMPILE([#include <wchar.h>],
 936                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 937   AC_TRY_COMPILE([#include <wchar.h>],
 938                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 939   AC_MSG_RESULT($ac_c99_wchar)
 940
 941   AC_MSG_CHECKING([for enabled ISO C99 support])
 942   if test x"$ac_c99_math" = x"no" ||
 943      test x"$ac_c99_stdio" = x"no" ||
 944      test x"$ac_c99_stdlib" = x"no" ||
 945      test x"$ac_c99_wchar" = x"no"; then
 946     enable_c99=no;
 947   fi;
 948   AC_MSG_RESULT($enable_c99)
 949
 950   # Option parsed, now set things appropriately
 951   if test x"$enable_c99" = x"yes"; then
 952     AC_DEFINE(_GLIBCXX_USE_C99)
 953   fi
 954
 955   AC_LANG_RESTORE
 956 ])
 957
 958
 959 dnl
 960 dnl Check for what type of C headers to use.
 961 dnl
 962 dnl --enable-cheaders= [does stuff].
 963 dnl --disable-cheaders [does not do anything, really].
 964 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 965 dnl       Where DEFAULT is either `c' or `c_std'.
 966 dnl
 967 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 968   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 969     [construct "C" headers for g++], [permit c|c_std])
 970   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 971
 972   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 973
 974   AC_SUBST(C_INCLUDE_DIR)
 975   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 976   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 977   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 978 ])
 979
 980
 981 dnl
 982 dnl Check for which locale library to use.  The choice is mapped to
 983 dnl a subdirectory of config/locale.
 984 dnl
 985 dnl Default is generic.
 986 dnl
 987 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 988   AC_MSG_CHECKING([for C locale to use])
 989   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 990     [use MODEL for target locale package],
 991     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 992
 993   # If they didn't use this option switch, or if they specified --enable
 994   # with no specific model, we'll have to look for one.  If they
 995   # specified --disable (???), do likewise.
 996   if test $enable_clocale = no || test $enable_clocale = yes; then
 997      enable_clocale=auto
 998   fi
 999
1000   # Either a known package, or "auto"
1001   enable_clocale_flag=$enable_clocale
1002
1003   # Probe for locale support if no specific model is specified.
1004   # Default to "generic".
1005   if test $enable_clocale_flag = auto; then
1006     case x${target_os} in
1007       xlinux* | xgnu*)
1008         AC_EGREP_CPP([_GLIBCXX_ok], [
1009         #include <features.h>
1010         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1011           _GLIBCXX_ok
1012         #endif
1013         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1014
1015         # Test for bugs early in glibc-2.2.x series
1016           if test x$enable_clocale_flag = xgnu; then
1017           AC_TRY_RUN([
1018           #define _GNU_SOURCE 1
1019           #include <locale.h>
1020           #include <string.h>
1021           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1022           extern __typeof(newlocale) __newlocale;
1023           extern __typeof(duplocale) __duplocale;
1024           extern __typeof(strcoll_l) __strcoll_l;
1025           #endif
1026           int main()
1027           {
1028               const char __one[] = "Äuglein Augmen";
1029               const char __two[] = "Äuglein";
1030               int i;
1031               int j;
1032               __locale_t        loc;
1033                __locale_t        loc_dup;
1034               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1035               loc_dup = __duplocale(loc);
1036               i = __strcoll_l(__one, __two, loc);
1037               j = __strcoll_l(__one, __two, loc_dup);
1038               return 0;
1039           }
1040           ],
1041           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1042           [enable_clocale_flag=generic])
1043           fi
1044
1045         # ... at some point put __strxfrm_l tests in as well.
1046         ;;
1047       *)
1048         enable_clocale_flag=generic
1049         ;;
1050     esac
1051   fi
1052
1053   # Deal with gettext issues.  Default to not using it (=no) until we detect
1054   # support for it later.  Let the user turn it off via --e/d, but let that
1055   # default to on for easier handling.
1056   USE_NLS=no
1057   AC_ARG_ENABLE(nls,
1058     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1059     [],
1060     [enable_nls=yes])
1061
1062   # Set configure bits for specified locale package
1063   case ${enable_clocale_flag} in
1064     generic)
1065       AC_MSG_RESULT(generic)
1066
1067       CLOCALE_H=config/locale/generic/c_locale.h
1068       CLOCALE_CC=config/locale/generic/c_locale.cc
1069       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1070       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1071       CCOLLATE_CC=config/locale/generic/collate_members.cc
1072       CCTYPE_CC=config/locale/generic/ctype_members.cc
1073       CMESSAGES_H=config/locale/generic/messages_members.h
1074       CMESSAGES_CC=config/locale/generic/messages_members.cc
1075       CMONEY_CC=config/locale/generic/monetary_members.cc
1076       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1077       CTIME_H=config/locale/generic/time_members.h
1078       CTIME_CC=config/locale/generic/time_members.cc
1079       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1080       ;;
1081     gnu)
1082       AC_MSG_RESULT(gnu)
1083
1084       # Declare intention to use gettext, and add support for specific
1085       # languages.
1086       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1087       ALL_LINGUAS="de fr"
1088
1089       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1090       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1091       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1092         USE_NLS=yes
1093       fi
1094       # Export the build objects.
1095       for ling in $ALL_LINGUAS; do \
1096         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1097         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1098       done
1099       AC_SUBST(glibcxx_MOFILES)
1100       AC_SUBST(glibcxx_POFILES)
1101
1102       CLOCALE_H=config/locale/gnu/c_locale.h
1103       CLOCALE_CC=config/locale/gnu/c_locale.cc
1104       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1105       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1106       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1107       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1108       CMESSAGES_H=config/locale/gnu/messages_members.h
1109       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1110       CMONEY_CC=config/locale/gnu/monetary_members.cc
1111       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1112       CTIME_H=config/locale/gnu/time_members.h
1113       CTIME_CC=config/locale/gnu/time_members.cc
1114       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1115       ;;
1116     ieee_1003.1-2001)
1117       AC_MSG_RESULT(IEEE 1003.1)
1118
1119       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1120       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1121       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1122       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1123       CCOLLATE_CC=config/locale/generic/collate_members.cc
1124       CCTYPE_CC=config/locale/generic/ctype_members.cc
1125       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1126       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1127       CMONEY_CC=config/locale/generic/monetary_members.cc
1128       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1129       CTIME_H=config/locale/generic/time_members.h
1130       CTIME_CC=config/locale/generic/time_members.cc
1131       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1132       ;;
1133   esac
1134
1135   # This is where the testsuite looks for locale catalogs, using the
1136   # -DLOCALEDIR define during testsuite compilation.
1137   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1138   AC_SUBST(glibcxx_localedir)
1139
1140   # A standalone libintl (e.g., GNU libintl) may be in use.
1141   if test $USE_NLS = yes; then
1142     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1143     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1144   fi
1145   if test $USE_NLS = yes; then
1146     AC_DEFINE(_GLIBCXX_USE_NLS)
1147   fi
1148
1149   AC_SUBST(USE_NLS)
1150   AC_SUBST(CLOCALE_H)
1151   AC_SUBST(CCODECVT_H)
1152   AC_SUBST(CMESSAGES_H)
1153   AC_SUBST(CCODECVT_CC)
1154   AC_SUBST(CCOLLATE_CC)
1155   AC_SUBST(CCTYPE_CC)
1156   AC_SUBST(CMESSAGES_CC)
1157   AC_SUBST(CMONEY_CC)
1158   AC_SUBST(CNUMERIC_CC)
1159   AC_SUBST(CTIME_H)
1160   AC_SUBST(CTIME_CC)
1161   AC_SUBST(CLOCALE_CC)
1162   AC_SUBST(CLOCALE_INTERNAL_H)
1163 ])
1164
1165
1166 dnl
1167 dnl Check for whether the Boost-derived checks should be turned on.
1168 dnl
1169 dnl --enable-concept-checks turns them on.
1170 dnl --disable-concept-checks leaves them off.
1171 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1172 dnl       Where DEFAULT is either `yes' or `no'.
1173 dnl
1174 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1175   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1176   if test $enable_concept_checks = yes; then
1177     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1178   fi
1179 ])
1180
1181
1182 dnl
1183 dnl Check for which I/O library to use:  stdio, or something specific.
1184 dnl
1185 dnl Default is stdio.
1186 dnl
1187 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1188   AC_MSG_CHECKING([for underlying I/O to use])
1189   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1190     [use target-specific I/O package], [permit stdio])
1191
1192   # Now that libio has been removed, you can have any color you want as long
1193   # as it's black.  This is one big no-op until other packages are added, but
1194   # showing the framework never hurts.
1195   case ${enable_cstdio} in
1196     stdio)
1197       CSTDIO_H=config/io/c_io_stdio.h
1198       BASIC_FILE_H=config/io/basic_file_stdio.h
1199       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1200       AC_MSG_RESULT(stdio)
1201       ;;
1202   esac
1203
1204   AC_SUBST(CSTDIO_H)
1205   AC_SUBST(BASIC_FILE_H)
1206   AC_SUBST(BASIC_FILE_CC)
1207 ])
1208
1209
1210 dnl
1211 dnl Check for "unusual" flags to pass to the compiler while building.
1212 dnl
1213 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1214 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1215 dnl --disable-cxx-flags passes nothing.
1216 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1217 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1218 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1219 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1220 dnl       If "default flags" is an empty string, the effect is the same
1221 dnl       as --disable or --enable=no.
1222 dnl
1223 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1224   AC_MSG_CHECKING([for extra compiler flags for building])
1225   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1226     [pass compiler FLAGS when building library],
1227     [case "x$enable_cxx_flags" in
1228       xno | x)   enable_cxx_flags= ;;
1229       x-*)       ;;
1230       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1231      esac])
1232
1233   # Run through flags (either default or command-line) and set anything
1234   # extra (e.g., #defines) that must accompany particular g++ options.
1235   if test -n "$enable_cxx_flags"; then
1236     for f in $enable_cxx_flags; do
1237       case "$f" in
1238         -fhonor-std)  ;;
1239         -*)  ;;
1240         *)   # and we're trying to pass /what/ exactly?
1241              AC_MSG_ERROR([compiler flags start with a -]) ;;
1242       esac
1243     done
1244   fi
1245
1246   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1247   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1248   AC_SUBST(EXTRA_CXX_FLAGS)
1249 ])
1250
1251
1252 dnl
1253 dnl Check for wide character support.  Has the same effect as the option
1254 dnl in gcc's configure, but in a form that autoconf can mess with.
1255 dnl
1256 dnl --enable-c-mbchar requests all the wchar_t stuff.
1257 dnl --disable-c-mbchar doesn't.
1258 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1259 dnl       Where DEFAULT is either `yes' or `no'.
1260 dnl
1261 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1262   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1263   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1264 ])
1265
1266
1267 dnl
1268 dnl Check to see if debugging libraries are to be built.
1269 dnl
1270 dnl --enable-libstdcxx-debug
1271 dnl builds a separate set of debugging libraries in addition to the
1272 dnl normal (shared, static) libstdc++ binaries.
1273 dnl
1274 dnl --disable-libstdcxx-debug
1275 dnl builds only one (non-debug) version of libstdc++.
1276 dnl
1277 dnl --enable-libstdcxx-debug-flags=FLAGS
1278 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1279 dnl
1280 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1281 dnl       Where DEFAULT is either `yes' or `no'.
1282 dnl
1283 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1284   AC_MSG_CHECKING([for additional debug build])
1285   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1286   AC_MSG_RESULT($enable_libstdcxx_debug)
1287   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1288 ])
1289
1290
1291 dnl
1292 dnl Check for explicit debug flags.
1293 dnl
1294 dnl --enable-libstdcxx-debug-flags='-O1'
1295 dnl is a general method for passing flags to be used when
1296 dnl building debug libraries with --enable-debug.
1297 dnl
1298 dnl --disable-libstdcxx-debug-flags does nothing.
1299 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1300 dnl       If "default flags" is an empty string, the effect is the same
1301 dnl       as --disable or --enable=no.
1302 dnl
1303 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1304   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1305     [pass compiler FLAGS when building debug library],
1306     [case "x$enable_libstdcxx_debug_flags" in
1307       xno | x)    enable_libstdcxx_debug_flags= ;;
1308       x-*)        ;;
1309       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1310      esac])
1311
1312   # Option parsed, now set things appropriately
1313   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1314   AC_SUBST(DEBUG_FLAGS)
1315
1316   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1317 ])
1318
1319
1320 dnl
1321 dnl Check if the user only wants a freestanding library implementation.
1322 dnl
1323 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1324 dnl installing only the headers required by [17.4.1.3] and the language
1325 dnl support library.  More than that will be built (to keep the Makefiles
1326 dnl conveniently clean), but not installed.
1327 dnl
1328 dnl Sets:
1329 dnl  is_hosted  (yes/no)
1330 dnl
1331 dnl Defines:
1332 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1333 dnl
1334 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1335   AC_ARG_ENABLE([hosted-libstdcxx],
1336     AC_HELP_STRING([--disable-hosted-libstdcxx],
1337                    [only build freestanding C++ runtime support]),,
1338     [enable_hosted_libstdcxx=yes])
1339   if test "$enable_hosted_libstdcxx" = no; then
1340     AC_MSG_NOTICE([Only freestanding libraries will be built])
1341     is_hosted=no
1342     hosted_define=0
1343     enable_abi_check=no
1344     enable_libstdcxx_pch=no
1345   else
1346     is_hosted=yes
1347     hosted_define=1
1348   fi
1349   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1350   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1351     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1352 ])
1353
1354
1355 dnl
1356 dnl Check for libunwind exception handling support.  If enabled, then
1357 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1358 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1359 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1360 dnl on libunwind as well as libgcc.
1361 dnl
1362 dnl --enable-libunwind-exceptions forces the use of libunwind.
1363 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1364 dnl
1365 dnl Substs:
1366 dnl  LIBUNWIND_FLAG
1367 dnl
1368 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1369   AC_MSG_CHECKING([for use of libunwind])
1370   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1371     [force use of libunwind for exceptions])
1372   AC_MSG_RESULT($use_libunwind_exceptions)
1373   if test $enable_libunwind_exceptions = yes; then
1374     LIBUNWIND_FLAG="-lunwind"
1375   else
1376     LIBUNWIND_FLAG=""
1377   fi
1378   AC_SUBST(LIBUNWIND_FLAG)
1379 ])
1380
1381
1382 dnl
1383 dnl Check for template specializations for the 'long long' type extension.
1384 dnl The result determines only whether 'long long' I/O is enabled; things
1385 dnl like numeric_limits<> specializations are always available.
1386 dnl
1387 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1388 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1389 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1390 dnl       Where DEFAULT is either `yes' or `no'.
1391 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1392 dnl
1393 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1394   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1395
1396   AC_LANG_SAVE
1397   AC_LANG_CPLUSPLUS
1398
1399   AC_MSG_CHECKING([for enabled long long I/O support])
1400   # iostreams require strtoll, strtoull to compile
1401   AC_TRY_COMPILE([#include <stdlib.h>],
1402                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1403   AC_TRY_COMPILE([#include <stdlib.h>],
1404                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1405
1406   # Option parsed, now set things appropriately
1407   if test $enable_long_long = yes; then
1408     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1409   fi
1410   AC_MSG_RESULT($enable_long_long)
1411
1412   AC_LANG_RESTORE
1413 ])
1414
1415
1416 dnl
1417 dnl Check to see if building and using a C++ precompiled header can be done.
1418 dnl
1419 dnl --enable-libstdcxx-pch=yes
1420 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1421 dnl may work, after some light-hearted attempts to puzzle out compiler
1422 dnl support, flip bits on in include/Makefile.am
1423 dnl
1424 dnl --disable-libstdcxx-pch
1425 dnl turns off attempts to use or build stdc++.h.gch.
1426 dnl
1427 dnl Substs:
1428 dnl  glibcxx_PCHFLAGS
1429 dnl
1430 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1431   AC_MSG_CHECKING([for enabled PCH])
1432   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1433   AC_MSG_RESULT([$enable_libstdcxx_pch])
1434
1435   if test $enable_libstdcxx_pch = yes; then
1436     AC_CACHE_CHECK([for compiler with PCH support],
1437       [glibcxx_cv_prog_CXX_pch],
1438       [ac_save_CXXFLAGS="$CXXFLAGS"
1439        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1440        AC_LANG_SAVE
1441        AC_LANG_CPLUSPLUS
1442        echo '#include <math.h>' > conftest.h
1443        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1444                           -o conftest.h.gch 1>&5 2>&1 &&
1445                 echo '#error "pch failed"' > conftest.h &&
1446           echo '#include "conftest.h"' > conftest.cc &&
1447                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1448        then
1449          glibcxx_cv_prog_CXX_pch=yes
1450        else
1451          glibcxx_cv_prog_CXX_pch=no
1452        fi
1453        rm -f conftest*
1454        CXXFLAGS=$ac_save_CXXFLAGS
1455        AC_LANG_RESTORE
1456       ])
1457     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1458   fi
1459
1460   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1461   if test $enable_libstdcxx_pch = yes; then
1462     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1463   else
1464     glibcxx_PCHFLAGS=""
1465   fi
1466   AC_SUBST(glibcxx_PCHFLAGS)
1467 ])
1468
1469
1470 dnl
1471 dnl Check for exception handling support.  If an explicit enable/disable
1472 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1473 dnl target may or may not support call frame exceptions.
1474 dnl
1475 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1476 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1477 dnl Neither one forces an attempt at detection.
1478 dnl
1479 dnl Defines:
1480 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1481 dnl
1482 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1483   AC_MSG_CHECKING([for exception model to use])
1484   AC_LANG_SAVE
1485   AC_LANG_CPLUSPLUS
1486   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1487     [force use of builtin_setjmp for exceptions],
1488     [permit yes|no|auto])
1489
1490   if test $enable_sjlj_exceptions = auto; then
1491     # Botheration.  Now we've got to detect the exception model.  Link tests
1492     # against libgcc.a are problematic since we've not been given proper -L
1493     # bits for single-tree newlib and libgloss.
1494     #
1495     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1496     cat > conftest.$ac_ext << EOF
1497 [#]line __oline__ "configure"
1498 struct S { ~S(); };
1499 void bar();
1500 void foo()
1501 {
1502   S s;
1503   bar();
1504 }
1505 EOF
1506     old_CXXFLAGS="$CXXFLAGS"
1507     CXXFLAGS=-S
1508     if AC_TRY_EVAL(ac_compile); then
1509       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1510         enable_sjlj_exceptions=yes
1511       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1512         enable_sjlj_exceptions=no
1513       fi
1514     fi
1515     CXXFLAGS="$old_CXXFLAGS"
1516     rm -f conftest*
1517   fi
1518
1519   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1520   # to two different models.
1521   case $enable_sjlj_exceptions in
1522     yes)
1523       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1524         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1525       ac_exception_model_name=sjlj
1526       ;;
1527     no)
1528       ac_exception_model_name="call frame"
1529       ;;
1530     *)
1531       AC_MSG_ERROR([unable to detect exception model])
1532       ;;
1533   esac
1534  AC_LANG_RESTORE
1535  AC_MSG_RESULT($ac_exception_model_name)
1536 ])
1537
1538
1539 dnl
1540 dnl Add version tags to symbols in shared library (or not), additionally
1541 dnl marking other symbols as private/local (or not).
1542 dnl
1543 dnl --enable-symvers=style adds a version script to the linker call when
1544 dnl       creating the shared library.  The choice of version script is
1545 dnl       controlled by 'style'.
1546 dnl --disable-symvers does not.
1547 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1548 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1549 dnl       choose a default style based on linker characteristics.  Passing
1550 dnl       'no' disables versioning.
1551 dnl
1552 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1553
1554 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1555   [enables symbol versioning of the shared library],
1556   [permit yes|no|gnu])
1557
1558 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1559 # don't know enough about $LD to do tricks...
1560 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1561 # FIXME  The following test is too strict, in theory.
1562 if test $enable_shared = no ||
1563         test "x$LD" = x ||
1564         test x$glibcxx_gnu_ld_version = x; then
1565   enable_symvers=no
1566 fi
1567
1568 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1569 if test $enable_symvers != no; then
1570   AC_MSG_CHECKING([for shared libgcc])
1571   ac_save_CFLAGS="$CFLAGS"
1572   CFLAGS=' -lgcc_s'
1573   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1574   CFLAGS="$ac_save_CFLAGS"
1575   AC_MSG_RESULT($glibcxx_shared_libgcc)
1576 fi
1577
1578 # For GNU ld, we need at least this version.  The format is described in
1579 # GLIBCXX_CHECK_LINKER_FEATURES above.
1580 glibcxx_min_gnu_ld_version=21400
1581 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1582
1583 # Check to see if unspecified "yes" value can win, given results above.
1584 # Change "yes" into either "no" or a style name.
1585 if test $enable_symvers = yes; then
1586   if test $with_gnu_ld = yes &&
1587      test $glibcxx_shared_libgcc = yes;
1588   then
1589     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1590       enable_symvers=gnu
1591     else
1592       # The right tools, the right setup, but too old.  Fallbacks?
1593       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1594       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1595       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1596       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1597       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1598         # Globbing fix is present, proper block support is not.
1599         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1600         dnl enable_symvers=???
1601         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1602         enable_symvers=no
1603       else
1604         # 2.11 or older.
1605         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1606         enable_symvers=no
1607       fi
1608     fi
1609   else
1610     # just fail for now
1611     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1612     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1613     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1614     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1615     enable_symvers=no
1616   fi
1617 fi
1618
1619 # Everything parsed; figure out what file to use.
1620 case $enable_symvers in
1621   no)
1622     SYMVER_MAP=config/linker-map.dummy
1623     ;;
1624   gnu)
1625     SYMVER_MAP=config/linker-map.gnu
1626     AC_DEFINE(_GLIBCXX_SYMVER)
1627     ;;
1628 esac
1629
1630 AC_SUBST(SYMVER_MAP)
1631 AC_SUBST(port_specific_symbol_files)
1632 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1633 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1634 ])
1635
1636
1637 dnl
1638 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1639 dnl We must stage the required headers so that they will be installed
1640 dnl with the library (unlike libgcc, the STL implementation is provided
1641 dnl solely within headers).  Since we must not inject random user-space
1642 dnl macro names into user-provided C++ code, we first stage into <file>-in
1643 dnl and process to <file> with an output command.  The reason for a two-
1644 dnl stage process here is to correctly handle $srcdir!=$objdir without
1645 dnl having to write complex code (the sed commands to clean the macro
1646 dnl namespace are complex and fragile enough as it is).  We must also
1647 dnl add a relative path so that -I- is supported properly.
1648 dnl
1649 dnl Substs:
1650 dnl  glibcxx_thread_h
1651 dnl
1652 dnl Defines:
1653 dnl  HAVE_GTHR_DEFAULT
1654 dnl  _GLIBCXX_SUPPORTS_WEAK
1655 dnl
1656 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1657   AC_MSG_CHECKING([for thread model used by GCC])
1658   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1659   AC_MSG_RESULT([$target_thread_file])
1660
1661   if test $target_thread_file != single; then
1662     AC_DEFINE(HAVE_GTHR_DEFAULT)
1663     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1664   fi
1665
1666   glibcxx_thread_h=gthr-$target_thread_file.h
1667   AC_SUBST(glibcxx_thread_h)
1668 ])
1669
1670
1671 # Check whether LC_MESSAGES is available in <locale.h>.
1672 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1673 #
1674 # This file file be copied and used freely without restrictions.  It can
1675 # be used in projects which are not available under the GNU Public License
1676 # but which still want to provide support for the GNU gettext functionality.
1677 # Please note that the actual code is *not* freely available.
1678
1679 # serial 1
1680 AC_DEFUN(AC_LC_MESSAGES, [
1681   AC_CHECK_HEADER(locale.h, [
1682     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1683       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1684        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1685     if test $ac_cv_val_LC_MESSAGES = yes; then
1686       AC_DEFINE(HAVE_LC_MESSAGES)
1687     fi
1688   ])
1689 ])
1690
1691
1692 sinclude([../libtool.m4])
1693 dnl The lines below arrange for aclocal not to bring an installed
1694 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1695 dnl add a definition of LIBTOOL to Makefile.in.
1696 ifelse(,,,[AC_SUBST(LIBTOOL)
1697 AC_DEFUN([AM_PROG_LIBTOOL])
1698 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1699 AC_DEFUN([AC_PROG_LD])
1700 ])
1701
1702 dnl vim:et:ts=2:sw=2
1703
1704 # AM_CONDITIONAL                                              -*- Autoconf -*-
1705
1706 # Copyright 1997, 2000, 2001 Free Software Foundation, Inc.
1707
1708 # This program is free software; you can redistribute it and/or modify
1709 # it under the terms of the GNU General Public License as published by
1710 # the Free Software Foundation; either version 2, or (at your option)
1711 # any later version.
1712
1713 # This program is distributed in the hope that it will be useful,
1714 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1715 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1716 # GNU General Public License for more details.
1717
1718 # You should have received a copy of the GNU General Public License
1719 # along with this program; if not, write to the Free Software
1720 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1721 # 02111-1307, USA.
1722
1723 # serial 5
1724
1725 AC_PREREQ(2.52)
1726
1727 # AM_CONDITIONAL(NAME, SHELL-CONDITION)
1728 # -------------------------------------
1729 # Define a conditional.
1730 AC_DEFUN([AM_CONDITIONAL],
1731 [ifelse([$1], [TRUE],  [AC_FATAL([$0: invalid condition: $1])],
1732         [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
1733 AC_SUBST([$1_TRUE])
1734 AC_SUBST([$1_FALSE])
1735 if $2; then
1736   $1_TRUE=
1737   $1_FALSE='#'
1738 else
1739   $1_TRUE='#'
1740   $1_FALSE=
1741 fi
1742 AC_CONFIG_COMMANDS_PRE(
1743 [if test -z "${$1_TRUE}" && test -z "${$1_FALSE}"; then
1744   AC_MSG_ERROR([conditional "$1" was never defined.
1745 Usually this means the macro was only invoked conditionally.])
1746 fi])])
1747
1748 # Copyright 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
1749
1750 # This program is free software; you can redistribute it and/or modify
1751 # it under the terms of the GNU General Public License as published by
1752 # the Free Software Foundation; either version 2, or (at your option)
1753 # any later version.
1754
1755 # This program is distributed in the hope that it will be useful,
1756 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1757 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1758 # GNU General Public License for more details.
1759
1760 # You should have received a copy of the GNU General Public License
1761 # along with this program; if not, write to the Free Software
1762 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1763 # 02111-1307, USA.
1764
1765 # serial 3
1766
1767 # AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
1768 # ---------------------------------------------------
1769 # Add --enable-multilib to configure.
1770 AC_DEFUN([AM_ENABLE_MULTILIB],
1771 [# Default to --enable-multilib
1772 AC_ARG_ENABLE(multilib,
1773 [  --enable-multilib         build many library versions (default)],
1774 [case "$enableval" in
1775   yes) multilib=yes ;;
1776   no)  multilib=no ;;
1777   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
1778  esac],
1779               [multilib=yes])
1780
1781 # We may get other options which we leave undocumented:
1782 # --with-target-subdir, --with-multisrctop, --with-multisubdir
1783 # See config-ml.in if you want the gory details.
1784
1785 if test "$srcdir" = "."; then
1786   if test "$with_target_subdir" != "."; then
1787     multi_basedir="$srcdir/$with_multisrctop../$2"
1788   else
1789     multi_basedir="$srcdir/$with_multisrctop$2"
1790   fi
1791 else
1792   multi_basedir="$srcdir/$2"
1793 fi
1794 AC_SUBST(multi_basedir)
1795
1796 AC_OUTPUT_COMMANDS([
1797 # Only add multilib support code if we just rebuilt the top-level
1798 # Makefile.
1799 case " $CONFIG_FILES " in
1800  *" ]m4_default([$1],Makefile)[ "*)
1801    ac_file=]m4_default([$1],Makefile)[ . ${multi_basedir}/config-ml.in
1802    ;;
1803 esac],
1804                    [
1805 srcdir="$srcdir"
1806 host="$host"
1807 target="$target"
1808 with_multisubdir="$with_multisubdir"
1809 with_multisrctop="$with_multisrctop"
1810 with_target_subdir="$with_target_subdir"
1811 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1812 multi_basedir="$multi_basedir"
1813 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1814 CC="$CC"])])dnl
1815
1816 # Add --enable-maintainer-mode option to configure.
1817 # From Jim Meyering
1818
1819 # Copyright 1996, 1998, 2000, 2001, 2002  Free Software Foundation, Inc.
1820
1821 # This program is free software; you can redistribute it and/or modify
1822 # it under the terms of the GNU General Public License as published by
1823 # the Free Software Foundation; either version 2, or (at your option)
1824 # any later version.
1825
1826 # This program is distributed in the hope that it will be useful,
1827 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1828 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1829 # GNU General Public License for more details.
1830
1831 # You should have received a copy of the GNU General Public License
1832 # along with this program; if not, write to the Free Software
1833 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1834 # 02111-1307, USA.
1835
1836 # serial 2
1837
1838 AC_DEFUN([AM_MAINTAINER_MODE],
1839 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1840   dnl maintainer-mode is disabled by default
1841   AC_ARG_ENABLE(maintainer-mode,
1842 [  --enable-maintainer-mode enable make rules and dependencies not useful
1843                           (and sometimes confusing) to the casual installer],
1844       USE_MAINTAINER_MODE=$enableval,
1845       USE_MAINTAINER_MODE=no)
1846   AC_MSG_RESULT([$USE_MAINTAINER_MODE])
1847   AM_CONDITIONAL(MAINTAINER_MODE, [test $USE_MAINTAINER_MODE = yes])
1848   MAINT=$MAINTAINER_MODE_TRUE
1849   AC_SUBST(MAINT)dnl
1850 ]
1851 )
1852
1853 AU_DEFUN([jm_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
1854
1855 # Do all the work for Automake.                            -*- Autoconf -*-
1856
1857 # This macro actually does too much some checks are only needed if
1858 # your package does certain things.  But this isn't really a big deal.
1859
1860 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
1861 # Free Software Foundation, Inc.
1862
1863 # This program is free software; you can redistribute it and/or modify
1864 # it under the terms of the GNU General Public License as published by
1865 # the Free Software Foundation; either version 2, or (at your option)
1866 # any later version.
1867
1868 # This program is distributed in the hope that it will be useful,
1869 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1870 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1871 # GNU General Public License for more details.
1872
1873 # You should have received a copy of the GNU General Public License
1874 # along with this program; if not, write to the Free Software
1875 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1876 # 02111-1307, USA.
1877
1878 # serial 10
1879
1880 AC_PREREQ([2.54])
1881
1882 # Autoconf 2.50 wants to disallow AM_ names.  We explicitly allow
1883 # the ones we care about.
1884 m4_pattern_allow([^AM_[A-Z]+FLAGS$])dnl
1885
1886 # AM_INIT_AUTOMAKE(PACKAGE, VERSION, [NO-DEFINE])
1887 # AM_INIT_AUTOMAKE([OPTIONS])
1888 # -----------------------------------------------
1889 # The call with PACKAGE and VERSION arguments is the old style
1890 # call (pre autoconf-2.50), which is being phased out.  PACKAGE
1891 # and VERSION should now be passed to AC_INIT and removed from
1892 # the call to AM_INIT_AUTOMAKE.
1893 # We support both call styles for the transition.  After
1894 # the next Automake release, Autoconf can make the AC_INIT
1895 # arguments mandatory, and then we can depend on a new Autoconf
1896 # release and drop the old call support.
1897 AC_DEFUN([AM_INIT_AUTOMAKE],
1898 [AC_REQUIRE([AM_SET_CURRENT_AUTOMAKE_VERSION])dnl
1899  AC_REQUIRE([AC_PROG_INSTALL])dnl
1900 # test to see if srcdir already configured
1901 if test "`cd $srcdir && pwd`" != "`pwd`" &&
1902    test -f $srcdir/config.status; then
1903   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
1904 fi
1905
1906 # test whether we have cygpath
1907 if test -z "$CYGPATH_W"; then
1908   if (cygpath --version) >/dev/null 2>/dev/null; then
1909     CYGPATH_W='cygpath -w'
1910   else
1911     CYGPATH_W=echo
1912   fi
1913 fi
1914 AC_SUBST([CYGPATH_W])
1915
1916 # Define the identity of the package.
1917 dnl Distinguish between old-style and new-style calls.
1918 m4_ifval([$2],
1919 [m4_ifval([$3], [_AM_SET_OPTION([no-define])])dnl
1920  AC_SUBST([PACKAGE], [$1])dnl
1921  AC_SUBST([VERSION], [$2])],
1922 [_AM_SET_OPTIONS([$1])dnl
1923  AC_SUBST([PACKAGE], ['AC_PACKAGE_TARNAME'])dnl
1924  AC_SUBST([VERSION], ['AC_PACKAGE_VERSION'])])dnl
1925
1926 _AM_IF_OPTION([no-define],,
1927 [AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
1928  AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package])])dnl
1929
1930 # Some tools Automake needs.
1931 AC_REQUIRE([AM_SANITY_CHECK])dnl
1932 AC_REQUIRE([AC_ARG_PROGRAM])dnl
1933 AM_MISSING_PROG(ACLOCAL, aclocal-${am__api_version})
1934 AM_MISSING_PROG(AUTOCONF, autoconf)
1935 AM_MISSING_PROG(AUTOMAKE, automake-${am__api_version})
1936 AM_MISSING_PROG(AUTOHEADER, autoheader)
1937 AM_MISSING_PROG(MAKEINFO, makeinfo)
1938 AM_MISSING_PROG(AMTAR, tar)
1939 AM_PROG_INSTALL_SH
1940 AM_PROG_INSTALL_STRIP
1941 # We need awk for the "check" target.  The system "awk" is bad on
1942 # some platforms.
1943 AC_REQUIRE([AC_PROG_AWK])dnl
1944 AC_REQUIRE([AC_PROG_MAKE_SET])dnl
1945 AC_REQUIRE([AM_SET_LEADING_DOT])dnl
1946
1947 _AM_IF_OPTION([no-dependencies],,
1948 [AC_PROVIDE_IFELSE([AC_PROG_CC],
1949                   [_AM_DEPENDENCIES(CC)],
1950                   [define([AC_PROG_CC],
1951                           defn([AC_PROG_CC])[_AM_DEPENDENCIES(CC)])])dnl
1952 AC_PROVIDE_IFELSE([AC_PROG_CXX],
1953                   [_AM_DEPENDENCIES(CXX)],
1954                   [define([AC_PROG_CXX],
1955                           defn([AC_PROG_CXX])[_AM_DEPENDENCIES(CXX)])])dnl
1956 ])
1957 ])
1958
1959
1960 # When config.status generates a header, we must update the stamp-h file.
1961 # This file resides in the same directory as the config header
1962 # that is generated.  The stamp files are numbered to have different names.
1963
1964 # Autoconf calls _AC_AM_CONFIG_HEADER_HOOK (when defined) in the
1965 # loop where config.status creates the headers, so we can generate
1966 # our stamp files there.
1967 AC_DEFUN([_AC_AM_CONFIG_HEADER_HOOK],
1968 [# Compute $1's index in $config_headers.
1969 _am_stamp_count=1
1970 for _am_header in $config_headers :; do
1971   case $_am_header in
1972     $1 | $1:* )
1973       break ;;
1974     * )
1975       _am_stamp_count=`expr $_am_stamp_count + 1` ;;
1976   esac
1977 done
1978 echo "timestamp for $1" >`AS_DIRNAME([$1])`/stamp-h[]$_am_stamp_count])
1979
1980 # Copyright 2002  Free Software Foundation, Inc.
1981
1982 # This program is free software; you can redistribute it and/or modify
1983 # it under the terms of the GNU General Public License as published by
1984 # the Free Software Foundation; either version 2, or (at your option)
1985 # any later version.
1986
1987 # This program is distributed in the hope that it will be useful,
1988 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1989 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1990 # GNU General Public License for more details.
1991
1992 # You should have received a copy of the GNU General Public License
1993 # along with this program; if not, write to the Free Software
1994 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1995
1996 # AM_AUTOMAKE_VERSION(VERSION)
1997 # ----------------------------
1998 # Automake X.Y traces this macro to ensure aclocal.m4 has been
1999 # generated from the m4 files accompanying Automake X.Y.
2000 AC_DEFUN([AM_AUTOMAKE_VERSION],[am__api_version="1.7"])
2001
2002 # AM_SET_CURRENT_AUTOMAKE_VERSION
2003 # -------------------------------
2004 # Call AM_AUTOMAKE_VERSION so it can be traced.
2005 # This function is AC_REQUIREd by AC_INIT_AUTOMAKE.
2006 AC_DEFUN([AM_SET_CURRENT_AUTOMAKE_VERSION],
2007          [AM_AUTOMAKE_VERSION([1.7.8])])
2008
2009 # Helper functions for option handling.                    -*- Autoconf -*-
2010
2011 # Copyright 2001, 2002  Free Software Foundation, Inc.
2012
2013 # This program is free software; you can redistribute it and/or modify
2014 # it under the terms of the GNU General Public License as published by
2015 # the Free Software Foundation; either version 2, or (at your option)
2016 # any later version.
2017
2018 # This program is distributed in the hope that it will be useful,
2019 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2020 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2021 # GNU General Public License for more details.
2022
2023 # You should have received a copy of the GNU General Public License
2024 # along with this program; if not, write to the Free Software
2025 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2026 # 02111-1307, USA.
2027
2028 # serial 2
2029
2030 # _AM_MANGLE_OPTION(NAME)
2031 # -----------------------
2032 AC_DEFUN([_AM_MANGLE_OPTION],
2033 [[_AM_OPTION_]m4_bpatsubst($1, [[^a-zA-Z0-9_]], [_])])
2034
2035 # _AM_SET_OPTION(NAME)
2036 # ------------------------------
2037 # Set option NAME.  Presently that only means defining a flag for this option.
2038 AC_DEFUN([_AM_SET_OPTION],
2039 [m4_define(_AM_MANGLE_OPTION([$1]), 1)])
2040
2041 # _AM_SET_OPTIONS(OPTIONS)
2042 # ----------------------------------
2043 # OPTIONS is a space-separated list of Automake options.
2044 AC_DEFUN([_AM_SET_OPTIONS],
2045 [AC_FOREACH([_AM_Option], [$1], [_AM_SET_OPTION(_AM_Option)])])
2046
2047 # _AM_IF_OPTION(OPTION, IF-SET, [IF-NOT-SET])
2048 # -------------------------------------------
2049 # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
2050 AC_DEFUN([_AM_IF_OPTION],
2051 [m4_ifset(_AM_MANGLE_OPTION([$1]), [$2], [$3])])
2052
2053 #
2054 # Check to make sure that the build environment is sane.
2055 #
2056
2057 # Copyright 1996, 1997, 2000, 2001 Free Software Foundation, Inc.
2058
2059 # This program is free software; you can redistribute it and/or modify
2060 # it under the terms of the GNU General Public License as published by
2061 # the Free Software Foundation; either version 2, or (at your option)
2062 # any later version.
2063
2064 # This program is distributed in the hope that it will be useful,
2065 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2066 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2067 # GNU General Public License for more details.
2068
2069 # You should have received a copy of the GNU General Public License
2070 # along with this program; if not, write to the Free Software
2071 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2072 # 02111-1307, USA.
2073
2074 # serial 3
2075
2076 # AM_SANITY_CHECK
2077 # ---------------
2078 AC_DEFUN([AM_SANITY_CHECK],
2079 [AC_MSG_CHECKING([whether build environment is sane])
2080 # Just in case
2081 sleep 1
2082 echo timestamp > conftest.file
2083 # Do `set' in a subshell so we don't clobber the current shell's
2084 # arguments.  Must try -L first in case configure is actually a
2085 # symlink; some systems play weird games with the mod time of symlinks
2086 # (eg FreeBSD returns the mod time of the symlink's containing
2087 # directory).
2088 if (
2089    set X `ls -Lt $srcdir/configure conftest.file 2> /dev/null`
2090    if test "$[*]" = "X"; then
2091       # -L didn't work.
2092       set X `ls -t $srcdir/configure conftest.file`
2093    fi
2094    rm -f conftest.file
2095    if test "$[*]" != "X $srcdir/configure conftest.file" \
2096       && test "$[*]" != "X conftest.file $srcdir/configure"; then
2097
2098       # If neither matched, then we have a broken ls.  This can happen
2099       # if, for instance, CONFIG_SHELL is bash and it inherits a
2100       # broken ls alias from the environment.  This has actually
2101       # happened.  Such a system could not be considered "sane".
2102       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
2103 alias in your environment])
2104    fi
2105
2106    test "$[2]" = conftest.file
2107    )
2108 then
2109    # Ok.
2110    :
2111 else
2112    AC_MSG_ERROR([newly created file is older than distributed files!
2113 Check your system clock])
2114 fi
2115 AC_MSG_RESULT(yes)])
2116
2117 #  -*- Autoconf -*-
2118
2119
2120 # Copyright 1997, 1999, 2000, 2001 Free Software Foundation, Inc.
2121
2122 # This program is free software; you can redistribute it and/or modify
2123 # it under the terms of the GNU General Public License as published by
2124 # the Free Software Foundation; either version 2, or (at your option)
2125 # any later version.
2126
2127 # This program is distributed in the hope that it will be useful,
2128 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2129 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2130 # GNU General Public License for more details.
2131
2132 # You should have received a copy of the GNU General Public License
2133 # along with this program; if not, write to the Free Software
2134 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2135 # 02111-1307, USA.
2136
2137 # serial 3
2138
2139 # AM_MISSING_PROG(NAME, PROGRAM)
2140 # ------------------------------
2141 AC_DEFUN([AM_MISSING_PROG],
2142 [AC_REQUIRE([AM_MISSING_HAS_RUN])
2143 $1=${$1-"${am_missing_run}$2"}
2144 AC_SUBST($1)])
2145
2146
2147 # AM_MISSING_HAS_RUN
2148 # ------------------
2149 # Define MISSING if not defined so far and test if it supports --run.
2150 # If it does, set am_missing_run to use it, otherwise, to nothing.
2151 AC_DEFUN([AM_MISSING_HAS_RUN],
2152 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
2153 test x"${MISSING+set}" = xset || MISSING="\${SHELL} $am_aux_dir/missing"
2154 # Use eval to expand $SHELL
2155 if eval "$MISSING --run true"; then
2156   am_missing_run="$MISSING --run "
2157 else
2158   am_missing_run=
2159   AC_MSG_WARN([`missing' script is too old or missing])
2160 fi
2161 ])
2162
2163 # AM_AUX_DIR_EXPAND
2164
2165 # Copyright 2001 Free Software Foundation, Inc.
2166
2167 # This program is free software; you can redistribute it and/or modify
2168 # it under the terms of the GNU General Public License as published by
2169 # the Free Software Foundation; either version 2, or (at your option)
2170 # any later version.
2171
2172 # This program is distributed in the hope that it will be useful,
2173 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2174 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2175 # GNU General Public License for more details.
2176
2177 # You should have received a copy of the GNU General Public License
2178 # along with this program; if not, write to the Free Software
2179 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2180 # 02111-1307, USA.
2181
2182 # For projects using AC_CONFIG_AUX_DIR([foo]), Autoconf sets
2183 # $ac_aux_dir to `$srcdir/foo'.  In other projects, it is set to
2184 # `$srcdir', `$srcdir/..', or `$srcdir/../..'.
2185 #
2186 # Of course, Automake must honor this variable whenever it calls a
2187 # tool from the auxiliary directory.  The problem is that $srcdir (and
2188 # therefore $ac_aux_dir as well) can be either absolute or relative,
2189 # depending on how configure is run.  This is pretty annoying, since
2190 # it makes $ac_aux_dir quite unusable in subdirectories: in the top
2191 # source directory, any form will work fine, but in subdirectories a
2192 # relative path needs to be adjusted first.
2193 #
2194 # $ac_aux_dir/missing
2195 #    fails when called from a subdirectory if $ac_aux_dir is relative
2196 # $top_srcdir/$ac_aux_dir/missing
2197 #    fails if $ac_aux_dir is absolute,
2198 #    fails when called from a subdirectory in a VPATH build with
2199 #          a relative $ac_aux_dir
2200 #
2201 # The reason of the latter failure is that $top_srcdir and $ac_aux_dir
2202 # are both prefixed by $srcdir.  In an in-source build this is usually
2203 # harmless because $srcdir is `.', but things will broke when you
2204 # start a VPATH build or use an absolute $srcdir.
2205 #
2206 # So we could use something similar to $top_srcdir/$ac_aux_dir/missing,
2207 # iff we strip the leading $srcdir from $ac_aux_dir.  That would be:
2208 #   am_aux_dir='\$(top_srcdir)/'`expr "$ac_aux_dir" : "$srcdir//*\(.*\)"`
2209 # and then we would define $MISSING as
2210 #   MISSING="\${SHELL} $am_aux_dir/missing"
2211 # This will work as long as MISSING is not called from configure, because
2212 # unfortunately $(top_srcdir) has no meaning in configure.
2213 # However there are other variables, like CC, which are often used in
2214 # configure, and could therefore not use this "fixed" $ac_aux_dir.
2215 #
2216 # Another solution, used here, is to always expand $ac_aux_dir to an
2217 # absolute PATH.  The drawback is that using absolute paths prevent a
2218 # configured tree to be moved without reconfiguration.
2219
2220 # Rely on autoconf to set up CDPATH properly.
2221 AC_PREREQ([2.50])
2222
2223 AC_DEFUN([AM_AUX_DIR_EXPAND], [
2224 # expand $ac_aux_dir to an absolute path
2225 am_aux_dir=`cd $ac_aux_dir && pwd`
2226 ])
2227
2228 # AM_PROG_INSTALL_SH
2229 # ------------------
2230 # Define $install_sh.
2231
2232 # Copyright 2001 Free Software Foundation, Inc.
2233
2234 # This program is free software; you can redistribute it and/or modify
2235 # it under the terms of the GNU General Public License as published by
2236 # the Free Software Foundation; either version 2, or (at your option)
2237 # any later version.
2238
2239 # This program is distributed in the hope that it will be useful,
2240 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2241 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2242 # GNU General Public License for more details.
2243
2244 # You should have received a copy of the GNU General Public License
2245 # along with this program; if not, write to the Free Software
2246 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2247 # 02111-1307, USA.
2248
2249 AC_DEFUN([AM_PROG_INSTALL_SH],
2250 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
2251 install_sh=${install_sh-"$am_aux_dir/install-sh"}
2252 AC_SUBST(install_sh)])
2253
2254 # AM_PROG_INSTALL_STRIP
2255
2256 # Copyright 2001 Free Software Foundation, Inc.
2257
2258 # This program is free software; you can redistribute it and/or modify
2259 # it under the terms of the GNU General Public License as published by
2260 # the Free Software Foundation; either version 2, or (at your option)
2261 # any later version.
2262
2263 # This program is distributed in the hope that it will be useful,
2264 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2265 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2266 # GNU General Public License for more details.
2267
2268 # You should have received a copy of the GNU General Public License
2269 # along with this program; if not, write to the Free Software
2270 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2271 # 02111-1307, USA.
2272
2273 # One issue with vendor `install' (even GNU) is that you can't
2274 # specify the program used to strip binaries.  This is especially
2275 # annoying in cross-compiling environments, where the build's strip
2276 # is unlikely to handle the host's binaries.
2277 # Fortunately install-sh will honor a STRIPPROG variable, so we
2278 # always use install-sh in `make install-strip', and initialize
2279 # STRIPPROG with the value of the STRIP variable (set by the user).
2280 AC_DEFUN([AM_PROG_INSTALL_STRIP],
2281 [AC_REQUIRE([AM_PROG_INSTALL_SH])dnl
2282 # Installed binaries are usually stripped using `strip' when the user
2283 # run `make install-strip'.  However `strip' might not be the right
2284 # tool to use in cross-compilation environments, therefore Automake
2285 # will honor the `STRIP' environment variable to overrule this program.
2286 dnl Don't test for $cross_compiling = yes, because it might be `maybe'.
2287 if test "$cross_compiling" != no; then
2288   AC_CHECK_TOOL([STRIP], [strip], :)
2289 fi
2290 INSTALL_STRIP_PROGRAM="\${SHELL} \$(install_sh) -c -s"
2291 AC_SUBST([INSTALL_STRIP_PROGRAM])])
2292
2293 #                                                          -*- Autoconf -*-
2294 # Copyright (C) 2003  Free Software Foundation, Inc.
2295
2296 # This program is free software; you can redistribute it and/or modify
2297 # it under the terms of the GNU General Public License as published by
2298 # the Free Software Foundation; either version 2, or (at your option)
2299 # any later version.
2300
2301 # This program is distributed in the hope that it will be useful,
2302 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2303 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2304 # GNU General Public License for more details.
2305
2306 # You should have received a copy of the GNU General Public License
2307 # along with this program; if not, write to the Free Software
2308 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2309 # 02111-1307, USA.
2310
2311 # serial 1
2312
2313 # Check whether the underlying file-system supports filenames
2314 # with a leading dot.  For instance MS-DOS doesn't.
2315 AC_DEFUN([AM_SET_LEADING_DOT],
2316 [rm -rf .tst 2>/dev/null
2317 mkdir .tst 2>/dev/null
2318 if test -d .tst; then
2319   am__leading_dot=.
2320 else
2321   am__leading_dot=_
2322 fi
2323 rmdir .tst 2>/dev/null
2324 AC_SUBST([am__leading_dot])])
2325
2326 # serial 5                                              -*- Autoconf -*-
2327
2328 # Copyright (C) 1999, 2000, 2001, 2002, 2003  Free Software Foundation, Inc.
2329
2330 # This program is free software; you can redistribute it and/or modify
2331 # it under the terms of the GNU General Public License as published by
2332 # the Free Software Foundation; either version 2, or (at your option)
2333 # any later version.
2334
2335 # This program is distributed in the hope that it will be useful,
2336 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2337 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2338 # GNU General Public License for more details.
2339
2340 # You should have received a copy of the GNU General Public License
2341 # along with this program; if not, write to the Free Software
2342 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2343 # 02111-1307, USA.
2344
2345
2346 # There are a few dirty hacks below to avoid letting `AC_PROG_CC' be
2347 # written in clear, in which case automake, when reading aclocal.m4,
2348 # will think it sees a *use*, and therefore will trigger all it's
2349 # C support machinery.  Also note that it means that autoscan, seeing
2350 # CC etc. in the Makefile, will ask for an AC_PROG_CC use...
2351
2352
2353
2354 # _AM_DEPENDENCIES(NAME)
2355 # ----------------------
2356 # See how the compiler implements dependency checking.
2357 # NAME is "CC", "CXX", "GCJ", or "OBJC".
2358 # We try a few techniques and use that to set a single cache variable.
2359 #
2360 # We don't AC_REQUIRE the corresponding AC_PROG_CC since the latter was
2361 # modified to invoke _AM_DEPENDENCIES(CC); we would have a circular
2362 # dependency, and given that the user is not expected to run this macro,
2363 # just rely on AC_PROG_CC.
2364 AC_DEFUN([_AM_DEPENDENCIES],
2365 [AC_REQUIRE([AM_SET_DEPDIR])dnl
2366 AC_REQUIRE([AM_OUTPUT_DEPENDENCY_COMMANDS])dnl
2367 AC_REQUIRE([AM_MAKE_INCLUDE])dnl
2368 AC_REQUIRE([AM_DEP_TRACK])dnl
2369
2370 ifelse([$1], CC,   [depcc="$CC"   am_compiler_list=],
2371        [$1], CXX,  [depcc="$CXX"  am_compiler_list=],
2372        [$1], OBJC, [depcc="$OBJC" am_compiler_list='gcc3 gcc'],
2373        [$1], GCJ,  [depcc="$GCJ"  am_compiler_list='gcc3 gcc'],
2374                    [depcc="$$1"   am_compiler_list=])
2375
2376 AC_CACHE_CHECK([dependency style of $depcc],
2377                [am_cv_$1_dependencies_compiler_type],
2378 [if test -z "$AMDEP_TRUE" && test -f "$am_depcomp"; then
2379   # We make a subdir and do the tests there.  Otherwise we can end up
2380   # making bogus files that we don't know about and never remove.  For
2381   # instance it was reported that on HP-UX the gcc test will end up
2382   # making a dummy file named `D' -- because `-MD' means `put the output
2383   # in D'.
2384   mkdir conftest.dir
2385   # Copy depcomp to subdir because otherwise we won't find it if we're
2386   # using a relative directory.
2387   cp "$am_depcomp" conftest.dir
2388   cd conftest.dir
2389   # We will build objects and dependencies in a subdirectory because
2390   # it helps to detect inapplicable dependency modes.  For instance
2391   # both Tru64's cc and ICC support -MD to output dependencies as a
2392   # side effect of compilation, but ICC will put the dependencies in
2393   # the current directory while Tru64 will put them in the object
2394   # directory.
2395   mkdir sub
2396
2397   am_cv_$1_dependencies_compiler_type=none
2398   if test "$am_compiler_list" = ""; then
2399      am_compiler_list=`sed -n ['s/^#*\([a-zA-Z0-9]*\))$/\1/p'] < ./depcomp`
2400   fi
2401   for depmode in $am_compiler_list; do
2402     # Setup a source with many dependencies, because some compilers
2403     # like to wrap large dependency lists on column 80 (with \), and
2404     # we should not choose a depcomp mode which is confused by this.
2405     #
2406     # We need to recreate these files for each test, as the compiler may
2407     # overwrite some of them when testing with obscure command lines.
2408     # This happens at least with the AIX C compiler.
2409     : > sub/conftest.c
2410     for i in 1 2 3 4 5 6; do
2411       echo '#include "conftst'$i'.h"' >> sub/conftest.c
2412       : > sub/conftst$i.h
2413     done
2414     echo "${am__include} ${am__quote}sub/conftest.Po${am__quote}" > confmf
2415
2416     case $depmode in
2417     nosideeffect)
2418       # after this tag, mechanisms are not by side-effect, so they'll
2419       # only be used when explicitly requested
2420       if test "x$enable_dependency_tracking" = xyes; then
2421         continue
2422       else
2423         break
2424       fi
2425       ;;
2426     none) break ;;
2427     esac
2428     # We check with `-c' and `-o' for the sake of the "dashmstdout"
2429     # mode.  It turns out that the SunPro C++ compiler does not properly
2430     # handle `-M -o', and we need to detect this.
2431     if depmode=$depmode \
2432        source=sub/conftest.c object=sub/conftest.${OBJEXT-o} \
2433        depfile=sub/conftest.Po tmpdepfile=sub/conftest.TPo \
2434        $SHELL ./depcomp $depcc -c -o sub/conftest.${OBJEXT-o} sub/conftest.c \
2435          >/dev/null 2>conftest.err &&
2436        grep sub/conftst6.h sub/conftest.Po > /dev/null 2>&1 &&
2437        grep sub/conftest.${OBJEXT-o} sub/conftest.Po > /dev/null 2>&1 &&
2438        ${MAKE-make} -s -f confmf > /dev/null 2>&1; then
2439       # icc doesn't choke on unknown options, it will just issue warnings
2440       # (even with -Werror).  So we grep stderr for any message
2441       # that says an option was ignored.
2442       if grep 'ignoring option' conftest.err >/dev/null 2>&1; then :; else
2443         am_cv_$1_dependencies_compiler_type=$depmode
2444         break
2445       fi
2446     fi
2447   done
2448
2449   cd ..
2450   rm -rf conftest.dir
2451 else
2452   am_cv_$1_dependencies_compiler_type=none
2453 fi
2454 ])
2455 AC_SUBST([$1DEPMODE], [depmode=$am_cv_$1_dependencies_compiler_type])
2456 AM_CONDITIONAL([am__fastdep$1], [
2457   test "x$enable_dependency_tracking" != xno \
2458   && test "$am_cv_$1_dependencies_compiler_type" = gcc3])
2459 ])
2460
2461
2462 # AM_SET_DEPDIR
2463 # -------------
2464 # Choose a directory name for dependency files.
2465 # This macro is AC_REQUIREd in _AM_DEPENDENCIES
2466 AC_DEFUN([AM_SET_DEPDIR],
2467 [AC_REQUIRE([AM_SET_LEADING_DOT])dnl
2468 AC_SUBST([DEPDIR], ["${am__leading_dot}deps"])dnl
2469 ])
2470
2471
2472 # AM_DEP_TRACK
2473 # ------------
2474 AC_DEFUN([AM_DEP_TRACK],
2475 [AC_ARG_ENABLE(dependency-tracking,
2476 [  --disable-dependency-tracking Speeds up one-time builds
2477   --enable-dependency-tracking  Do not reject slow dependency extractors])
2478 if test "x$enable_dependency_tracking" != xno; then
2479   am_depcomp="$ac_aux_dir/depcomp"
2480   AMDEPBACKSLASH='\'
2481 fi
2482 AM_CONDITIONAL([AMDEP], [test "x$enable_dependency_tracking" != xno])
2483 AC_SUBST([AMDEPBACKSLASH])
2484 ])
2485
2486 # Generate code to set up dependency tracking.   -*- Autoconf -*-
2487
2488 # Copyright 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
2489
2490 # This program is free software; you can redistribute it and/or modify
2491 # it under the terms of the GNU General Public License as published by
2492 # the Free Software Foundation; either version 2, or (at your option)
2493 # any later version.
2494
2495 # This program is distributed in the hope that it will be useful,
2496 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2497 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2498 # GNU General Public License for more details.
2499
2500 # You should have received a copy of the GNU General Public License
2501 # along with this program; if not, write to the Free Software
2502 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2503 # 02111-1307, USA.
2504
2505 #serial 2
2506
2507 # _AM_OUTPUT_DEPENDENCY_COMMANDS
2508 # ------------------------------
2509 AC_DEFUN([_AM_OUTPUT_DEPENDENCY_COMMANDS],
2510 [for mf in $CONFIG_FILES; do
2511   # Strip MF so we end up with the name of the file.
2512   mf=`echo "$mf" | sed -e 's/:.*$//'`
2513   # Check whether this is an Automake generated Makefile or not.
2514   # We used to match only the files named `Makefile.in', but
2515   # some people rename them; so instead we look at the file content.
2516   # Grep'ing the first line is not enough: some people post-process
2517   # each Makefile.in and add a new line on top of each file to say so.
2518   # So let's grep whole file.
2519   if grep '^#.*generated by automake' $mf > /dev/null 2>&1; then
2520     dirpart=`AS_DIRNAME("$mf")`
2521   else
2522     continue
2523   fi
2524   grep '^DEP_FILES *= *[[^ @%:@]]' < "$mf" > /dev/null || continue
2525   # Extract the definition of DEP_FILES from the Makefile without
2526   # running `make'.
2527   DEPDIR=`sed -n -e '/^DEPDIR = / s///p' < "$mf"`
2528   test -z "$DEPDIR" && continue
2529   # When using ansi2knr, U may be empty or an underscore; expand it
2530   U=`sed -n -e '/^U = / s///p' < "$mf"`
2531   test -d "$dirpart/$DEPDIR" || mkdir "$dirpart/$DEPDIR"
2532   # We invoke sed twice because it is the simplest approach to
2533   # changing $(DEPDIR) to its actual value in the expansion.
2534   for file in `sed -n -e '
2535     /^DEP_FILES = .*\\\\$/ {
2536       s/^DEP_FILES = //
2537       :loop
2538         s/\\\\$//
2539         p
2540         n
2541         /\\\\$/ b loop
2542       p
2543     }
2544     /^DEP_FILES = / s/^DEP_FILES = //p' < "$mf" | \
2545        sed -e 's/\$(DEPDIR)/'"$DEPDIR"'/g' -e 's/\$U/'"$U"'/g'`; do
2546     # Make sure the directory exists.
2547     test -f "$dirpart/$file" && continue
2548     fdir=`AS_DIRNAME(["$file"])`
2549     AS_MKDIR_P([$dirpart/$fdir])
2550     # echo "creating $dirpart/$file"
2551     echo '# dummy' > "$dirpart/$file"
2552   done
2553 done
2554 ])# _AM_OUTPUT_DEPENDENCY_COMMANDS
2555
2556
2557 # AM_OUTPUT_DEPENDENCY_COMMANDS
2558 # -----------------------------
2559 # This macro should only be invoked once -- use via AC_REQUIRE.
2560 #
2561 # This code is only required when automatic dependency tracking
2562 # is enabled.  FIXME.  This creates each `.P' file that we will
2563 # need in order to bootstrap the dependency handling code.
2564 AC_DEFUN([AM_OUTPUT_DEPENDENCY_COMMANDS],
2565 [AC_CONFIG_COMMANDS([depfiles],
2566      [test x"$AMDEP_TRUE" != x"" || _AM_OUTPUT_DEPENDENCY_COMMANDS],
2567      [AMDEP_TRUE="$AMDEP_TRUE" ac_aux_dir="$ac_aux_dir"])
2568 ])
2569
2570 # Check to see how 'make' treats includes.      -*- Autoconf -*-
2571
2572 # Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
2573
2574 # This program is free software; you can redistribute it and/or modify
2575 # it under the terms of the GNU General Public License as published by
2576 # the Free Software Foundation; either version 2, or (at your option)
2577 # any later version.
2578
2579 # This program is distributed in the hope that it will be useful,
2580 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2581 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2582 # GNU General Public License for more details.
2583
2584 # You should have received a copy of the GNU General Public License
2585 # along with this program; if not, write to the Free Software
2586 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2587 # 02111-1307, USA.
2588
2589 # serial 2
2590
2591 # AM_MAKE_INCLUDE()
2592 # -----------------
2593 # Check to see how make treats includes.
2594 AC_DEFUN([AM_MAKE_INCLUDE],
2595 [am_make=${MAKE-make}
2596 cat > confinc << 'END'
2597 am__doit:
2598         @echo done
2599 .PHONY: am__doit
2600 END
2601 # If we don't find an include directive, just comment out the code.
2602 AC_MSG_CHECKING([for style of include used by $am_make])
2603 am__include="#"
2604 am__quote=
2605 _am_result=none
2606 # First try GNU make style include.
2607 echo "include confinc" > confmf
2608 # We grep out `Entering directory' and `Leaving directory'
2609 # messages which can occur if `w' ends up in MAKEFLAGS.
2610 # In particular we don't look at `^make:' because GNU make might
2611 # be invoked under some other name (usually "gmake"), in which
2612 # case it prints its new name instead of `make'.
2613 if test "`$am_make -s -f confmf 2> /dev/null | grep -v 'ing directory'`" = "done"; then
2614    am__include=include
2615    am__quote=
2616    _am_result=GNU
2617 fi
2618 # Now try BSD make style include.
2619 if test "$am__include" = "#"; then
2620    echo '.include "confinc"' > confmf
2621    if test "`$am_make -s -f confmf 2> /dev/null`" = "done"; then
2622       am__include=.include
2623       am__quote="\""
2624       _am_result=BSD
2625    fi
2626 fi
2627 AC_SUBST([am__include])
2628 AC_SUBST([am__quote])
2629 AC_MSG_RESULT([$_am_result])
2630 rm -f confinc confmf
2631 ])
2632