libstdc++-v3/aclocal.m4

   1 # generated automatically by aclocal 1.7.9 -*- Autoconf -*-
   2
   3 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 # Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  11 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  12 # PARTICULAR PURPOSE.
  13
  14
  15 dnl
  16 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
  17 dnl
  18 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
  19 dnl end of configure.  This lets tested variables be reassigned, and the
  20 dnl conditional will depend on the final state of the variable.  For a simple
  21 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
  22 dnl
  23 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  24 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  25   m4_divert_text([glibcxx_diversion],dnl
  26    AM_CONDITIONAL([$1],[$2])
  27   )dnl
  28 ])dnl
  29 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  30
  31
  32 dnl
  33 dnl Check to see what architecture and operating system we are compiling
  34 dnl for.  Also, if architecture- or OS-specific flags are required for
  35 dnl compilation, pick them up here.
  36 dnl
  37 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  38   . $glibcxx_srcdir/configure.host
  39   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  40   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  41 ])
  42
  43
  44 dnl
  45 dnl Initialize basic configure bits.
  46 dnl
  47 dnl Substs:
  48 dnl  multi_basedir
  49 dnl
  50 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  51   # Sets up multi_basedir, which is srcdir/.. plus the usual
  52   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  53   AM_ENABLE_MULTILIB(, ..)
  54
  55   # The generated code is exactly the same, except that automake's looks in
  56   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  57   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  58   # know what they are or what the other differences might be (and they keep
  59   # changing anyhow).
  60   #
  61   # Looking in multi_basedir seems smarter, so actually execute that branch.
  62   if false; then
  63     # this is for automake
  64     AC_CONFIG_AUX_DIR(..)
  65   else
  66     # this is for autoconf
  67     AC_CONFIG_AUX_DIRS(${multi_basedir})
  68   fi
  69
  70   dnl XXX Turn this on.
  71   dnl AC_LANG_CPLUSPLUS
  72 ])
  73
  74
  75 dnl
  76 dnl Initialize the rest of the library configury.  At this point we have
  77 dnl variables like $host.
  78 dnl
  79 dnl Sets:
  80 dnl  gcc_version          (x.y.z format)
  81 dnl  SUBDIRS
  82 dnl Substs:
  83 dnl  glibcxx_builddir     (absolute path)
  84 dnl  glibcxx_srcdir       (absolute path)
  85 dnl  toplevel_srcdir      (absolute path)
  86 dnl  with_cross_host
  87 dnl  with_newlib
  88 dnl  with_target_subdir
  89 dnl plus
  90 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  91 dnl  - default settings for all AM_CONFITIONAL test variables
  92 dnl  - lots of tools, like CC and CXX
  93 dnl
  94 AC_DEFUN(GLIBCXX_CONFIGURE, [
  95   # Keep these sync'd with the list in Makefile.am.  The first provides an
  96   # expandable list at autoconf time; the second provides an expandable list
  97   # (i.e., shell variable) at configure time.
  98   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  99   SUBDIRS='glibcxx_SUBDIRS'
 100
 101   # These need to be absolute paths, yet at the same time need to
 102   # canonicalize only relative paths, because then amd will not unmount
 103   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
 104   glibcxx_builddir=`${PWDCMD-pwd}`
 105   case $srcdir in
 106     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
 107     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
 108   esac
 109   toplevel_srcdir=${glibcxx_srcdir}/..
 110   AC_SUBST(glibcxx_builddir)
 111   AC_SUBST(glibcxx_srcdir)
 112   AC_SUBST(toplevel_srcdir)
 113
 114   # We use these options to decide which functions to include.  They are
 115   # set from the top level.
 116   AC_ARG_WITH([target-subdir],
 117     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 118                    [configuring in a subdirectory]))
 119
 120   AC_ARG_WITH([cross-host],
 121     AC_HELP_STRING([--with-cross-host=HOST],
 122                    [configuring with a cross compiler]))
 123
 124   AC_ARG_WITH([newlib],
 125     AC_HELP_STRING([--with-newlib],
 126                    [assume newlib as a system C library]))
 127
 128   # We're almost certainly being configured before anything else which uses
 129   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 130   # we not cache the value of CXX that we "discover" here, because it's set
 131   # to something unique for us and libjava.  Other target libraries need to
 132   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 133   # process by sneakily renaming the cache variable.  This also lets us debug
 134   # the value of "our" CXX in postmortems.
 135   #
 136   # We must also force CXX to /not/ be a precious variable, otherwise the
 137   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 138   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 139   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 140   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 141   #
 142   # -fno-builtin must be present here so that a non-conflicting form of
 143   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 144
 145   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 146   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 147   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 148   save_CXXFLAGS="$CXXFLAGS"
 149   CXXFLAGS="$CXXFLAGS -fno-builtin"
 150   AC_PROG_CC
 151   AC_PROG_CXX
 152   CXXFLAGS="$save_CXXFLAGS"
 153   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 154   AC_SUBST(CFLAGS)
 155   AC_SUBST(CXXFLAGS)
 156
 157   # For directory versioning (e.g., headers) and other variables.
 158   AC_MSG_CHECKING([for GCC version number])
 159   gcc_version=`$CXX -dumpversion`
 160   AC_MSG_RESULT($gcc_version)
 161
 162   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 163   # available).  Uncomment the next line to force a particular method.
 164   AC_PROG_LN_S
 165   #LN_S='cp -p'
 166
 167   AC_CHECK_TOOL(AS, as)
 168   AC_CHECK_TOOL(AR, ar)
 169   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 170
 171   AM_MAINTAINER_MODE
 172
 173   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 174   # which are themselves conditionally expanded.
 175   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 176   ## other macros from doing the same.  This should be automated.)  -pme
 177   need_libmath=no
 178   enable_wchar_t=no
 179   #enable_libstdcxx_debug=no
 180   #enable_libstdcxx_pch=no
 181   #enable_cheaders=c
 182   #c_compatibility=no
 183   #enable_abi_check=no
 184   #enable_symvers=no
 185   #enable_hosted_libstdcxx=yes
 186
 187   # Find platform-specific directories containing configuration info.
 188   # Also possibly modify flags used elsewhere, as needed by the platform.
 189   GLIBCXX_CHECK_HOST
 190 ])
 191
 192
 193 m4_include([linkage.m4])
 194 m4_include([../config/no-executables.m4])
 195
 196
 197 dnl
 198 dnl Tests for newer compiler features, or features that are present in newer
 199 dnl compiler versions but not older compiler versions still in use, should
 200 dnl be placed here.
 201 dnl
 202 dnl Defines:
 203 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 204 dnl   new inlining code or the new system_header pragma will die on -Werror.
 205 dnl   Leave it out by default and use maint-mode to use it.
 206 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 207 dnl   compiler supports it and the user has not requested debug mode.
 208 dnl
 209 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 210   # All these tests are for C++; save the language and the compiler flags.
 211   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 212   # found in GLIBCXX_CONFIGURE.
 213   AC_LANG_SAVE
 214   AC_LANG_CPLUSPLUS
 215   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 216   ac_save_CXXFLAGS="$CXXFLAGS"
 217
 218   # Check for maintainer-mode bits.
 219   if test x"$USE_MAINTAINER_MODE" = xno; then
 220     WERROR=''
 221   else
 222     WERROR='-Werror'
 223   fi
 224
 225   # Check for -ffunction-sections -fdata-sections
 226   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 227   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 228   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 229   if test "$ac_test_CXXFLAGS" = set; then
 230     CXXFLAGS="$ac_save_CXXFLAGS"
 231   else
 232     # this is the suspicious part
 233     CXXFLAGS=''
 234   fi
 235   if test x"$ac_fdsections" = x"yes"; then
 236     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 237   fi
 238   AC_MSG_RESULT($ac_fdsections)
 239
 240   AC_LANG_RESTORE
 241   AC_SUBST(WERROR)
 242   AC_SUBST(SECTION_FLAGS)
 243 ])
 244
 245
 246 dnl
 247 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 248 dnl the native linker is in use, all variables will be defined to something
 249 dnl safe (like an empty string).
 250 dnl
 251 dnl Defines:
 252 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 253 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 254 dnl  LD (as a side effect of testing)
 255 dnl Sets:
 256 dnl  with_gnu_ld
 257 dnl  glibcxx_gnu_ld_version (possibly)
 258 dnl
 259 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 260 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 261 dnl
 262 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 263   # If we're not using GNU ld, then there's no point in even trying these
 264   # tests.  Check for that first.  We should have already tested for gld
 265   # by now (in libtool), but require it now just to be safe...
 266   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 267   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 268   AC_REQUIRE([AC_PROG_LD])
 269   AC_REQUIRE([AC_PROG_AWK])
 270
 271   # The name set by libtool depends on the version of libtool.  Shame on us
 272   # for depending on an impl detail, but c'est la vie.  Older versions used
 273   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 274   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 275   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 276   # set (hence we're using an older libtool), then set it.
 277   if test x${with_gnu_ld+set} != xset; then
 278     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 279       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 280       with_gnu_ld=no
 281     else
 282       with_gnu_ld=$ac_cv_prog_gnu_ld
 283     fi
 284   fi
 285
 286   # Start by getting the version number.  I think the libtool test already
 287   # does some of this, but throws away the result.
 288   changequote(,)
 289   ldver=`$LD --version 2>/dev/null | head -1 | \
 290          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 291   changequote([,])
 292   glibcxx_gnu_ld_version=`echo $ldver | \
 293          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 294
 295   # Set --gc-sections.
 296   if test "$with_gnu_ld" = "notbroken"; then
 297     # GNU ld it is!  Joy and bunny rabbits!
 298
 299     # All these tests are for C++; save the language and the compiler flags.
 300     # Need to do this so that g++ won't try to link in libstdc++
 301     ac_test_CFLAGS="${CFLAGS+set}"
 302     ac_save_CFLAGS="$CFLAGS"
 303     CFLAGS='-x c++  -Wl,--gc-sections'
 304
 305     # Check for -Wl,--gc-sections
 306     # XXX This test is broken at the moment, as symbols required for linking
 307     # are now in libsupc++ (not built yet).  In addition, this test has
 308     # cored on solaris in the past.  In addition, --gc-sections doesn't
 309     # really work at the moment (keeps on discarding used sections, first
 310     # .eh_frame and now some of the glibc sections for iconv).
 311     # Bzzzzt.  Thanks for playing, maybe next time.
 312     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 313     AC_TRY_RUN([
 314      int main(void)
 315      {
 316        try { throw 1; }
 317        catch (...) { };
 318        return 0;
 319      }
 320     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 321     if test "$ac_test_CFLAGS" = set; then
 322       CFLAGS="$ac_save_CFLAGS"
 323     else
 324       # this is the suspicious part
 325       CFLAGS=''
 326     fi
 327     if test "$ac_sectionLDflags" = "yes"; then
 328       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 329     fi
 330     AC_MSG_RESULT($ac_sectionLDflags)
 331   fi
 332
 333   # Set linker optimization flags.
 334   if test x"$with_gnu_ld" = x"yes"; then
 335     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 336   fi
 337
 338   AC_SUBST(SECTION_LDFLAGS)
 339   AC_SUBST(OPT_LDFLAGS)
 340 ])
 341
 342
 343 dnl
 344 dnl Check to see if this target can enable the wchar_t parts.
 345 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 346 dnl must have been previously checked.)  By default, wide characters are
 347 dnl disabled.
 348 dnl
 349 dnl Defines:
 350 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 351 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 352 dnl
 353 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 354   # Test wchar.h for mbstate_t, which is needed for char_traits and
 355   # others even if wchar_t support is not on.
 356   AC_MSG_CHECKING([for mbstate_t])
 357   AC_TRY_COMPILE([#include <wchar.h>],
 358   [mbstate_t teststate;],
 359   have_mbstate_t=yes, have_mbstate_t=no)
 360   AC_MSG_RESULT($have_mbstate_t)
 361   if test x"$have_mbstate_t" = xyes; then
 362     AC_DEFINE(HAVE_MBSTATE_T)
 363   fi
 364
 365   # Sanity check for existence of ISO C99 headers for extended encoding.
 366   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 367   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 368
 369   # Only continue checking if the ISO C99 headers exist and support is on.
 370   if test x"$ac_has_wchar_h" = xyes &&
 371      test x"$ac_has_wctype_h" = xyes &&
 372      test x"$enable_c_mbchar" != xno; then
 373
 374     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 375     # numeric_limits can instantiate type_traits<wchar_t>
 376     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 377     AC_TRY_COMPILE([#include <wchar.h>],
 378     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 379     has_wchar_minmax=yes, has_wchar_minmax=no)
 380     AC_MSG_RESULT($has_wchar_minmax)
 381
 382     # Test wchar.h for WEOF, which is what we use to determine whether
 383     # to specialize for char_traits<wchar_t> or not.
 384     AC_MSG_CHECKING([for WEOF])
 385     AC_TRY_COMPILE([
 386       #include <wchar.h>
 387       #include <stddef.h>],
 388     [wint_t i = WEOF;],
 389     has_weof=yes, has_weof=no)
 390     AC_MSG_RESULT($has_weof)
 391
 392     # Tests for wide character functions used in char_traits<wchar_t>.
 393     ac_wfuncs=yes
 394     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 395     [],[ac_wfuncs=no])
 396
 397     # Checks for names injected into std:: by the c_std headers.
 398     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 399     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 400     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 401     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 402     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 403     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 404     [],[ac_wfuncs=no])
 405
 406     # Checks for wide character functions that are not required
 407     # for basic wchar_t support.  Don't disable support if they are missing.
 408     # Injection of these is wrapped with guard macros.
 409     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 410
 411     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 412     if test x"$has_weof" = xyes &&
 413        test x"$has_wchar_minmax" = xyes &&
 414        test x"$ac_wfuncs" = xyes;
 415     then
 416       ac_isoC99_wchar_t=yes
 417     else
 418       ac_isoC99_wchar_t=no
 419     fi
 420     AC_MSG_RESULT($ac_isoC99_wchar_t)
 421
 422     # Use iconv for wchar_t to char conversions. As such, check for
 423     # X/Open Portability Guide, version 2 features (XPG2).
 424     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 425     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 426
 427     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 428     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 429     ac_save_LIBS="$LIBS"
 430     LIBS="$LIBS $libiconv"
 431
 432     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 433     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 434
 435     LIBS="$ac_save_LIBS"
 436
 437     AC_MSG_CHECKING([for XPG2 wchar_t support])
 438     if test x"$ac_has_iconv_h" = xyes &&
 439        test x"$ac_has_langinfo_h" = xyes &&
 440        test x"$ac_XPG2funcs" = xyes;
 441     then
 442       ac_XPG2_wchar_t=yes
 443     else
 444       ac_XPG2_wchar_t=no
 445     fi
 446     AC_MSG_RESULT($ac_XPG2_wchar_t)
 447
 448     # At the moment, only enable wchar_t specializations if all the
 449     # above support is present.
 450     if test x"$ac_isoC99_wchar_t" = xyes &&
 451        test x"$ac_XPG2_wchar_t" = xyes;
 452     then
 453       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 454       enable_wchar_t=yes
 455     fi
 456   fi
 457   AC_MSG_CHECKING([for enabled wchar_t specializations])
 458   AC_MSG_RESULT($enable_wchar_t)
 459 ])
 460
 461
 462 dnl
 463 dnl Check for headers for, and arguments to, the setrlimit() function.
 464 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 465 dnl
 466 dnl Defines:
 467 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 468 dnl  various HAVE_MEMLIMIT_* for individual limit names
 469 dnl
 470 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 471   AC_TRY_COMPILE(
 472     [#include <unistd.h>
 473      #include <sys/time.h>
 474      #include <sys/resource.h>
 475     ],
 476     [ int f = RLIMIT_$1 ; ],
 477     [glibcxx_mresult=1], [glibcxx_mresult=0])
 478   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 479                      [Only used in build directory testsuite_hooks.h.])
 480 ])
 481
 482 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 483   setrlimit_have_headers=yes
 484   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 485                    [],
 486                    [setrlimit_have_headers=no])
 487   # If don't have the headers, then we can't run the tests now, and we
 488   # won't be seeing any of these during testsuite compilation.
 489   if test $setrlimit_have_headers = yes; then
 490     # Can't do these in a loop, else the resulting syntax is wrong.
 491     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 492     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 493     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 494     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 495
 496     # Check for rlimit, setrlimit.
 497     AC_CACHE_VAL(ac_setrlimit, [
 498       AC_TRY_COMPILE(
 499         [#include <unistd.h>
 500          #include <sys/time.h>
 501          #include <sys/resource.h>
 502         ],
 503         [struct rlimit r;
 504          setrlimit(0, &r);],
 505         [ac_setrlimit=yes], [ac_setrlimit=no])
 506     ])
 507   fi
 508
 509   AC_MSG_CHECKING([for testsuite memory limit support])
 510   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 511     ac_mem_limits=yes
 512     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 513   else
 514     ac_mem_limits=no
 515   fi
 516   AC_MSG_RESULT($ac_mem_limits)
 517 ])
 518
 519
 520 dnl
 521 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 522 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 523 dnl
 524 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 525   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 526     AC_TRY_LINK(
 527       [#include <sys/stat.h>],
 528       [struct stat buffer;
 529        fstat(0, &buffer);
 530        S_ISREG(buffer.st_mode);],
 531       [glibcxx_cv_S_ISREG=yes],
 532       [glibcxx_cv_S_ISREG=no])
 533   ])
 534   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 535     AC_TRY_LINK(
 536       [#include <sys/stat.h>],
 537       [struct stat buffer;
 538        fstat(0, &buffer);
 539        S_IFREG & buffer.st_mode;],
 540       [glibcxx_cv_S_IFREG=yes],
 541       [glibcxx_cv_S_IFREG=no])
 542   ])
 543   if test $glibcxx_cv_S_ISREG = yes; then
 544     AC_DEFINE(HAVE_S_ISREG)
 545   elif test $glibcxx_cv_S_IFREG = yes; then
 546     AC_DEFINE(HAVE_S_IFREG)
 547   fi
 548 ])
 549
 550
 551 dnl
 552 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 553 dnl
 554 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 555   AC_CACHE_VAL(glibcxx_cv_POLL, [
 556     AC_TRY_LINK(
 557       [#include <poll.h>],
 558       [struct pollfd pfd[1];
 559        pfd[0].events = POLLIN;
 560        poll(pfd, 1, 0);],
 561       [glibcxx_cv_POLL=yes],
 562       [glibcxx_cv_POLL=no])
 563   ])
 564   if test $glibcxx_cv_POLL = yes; then
 565     AC_DEFINE(HAVE_POLL)
 566   fi
 567 ])
 568
 569
 570 dnl
 571 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 572 dnl
 573 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 574   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 575     AC_TRY_LINK(
 576       [#include <sys/uio.h>],
 577       [struct iovec iov[2];
 578        writev(0, iov, 0);],
 579       [glibcxx_cv_WRITEV=yes],
 580       [glibcxx_cv_WRITEV=no])
 581   ])
 582   if test $glibcxx_cv_WRITEV = yes; then
 583     AC_DEFINE(HAVE_WRITEV)
 584   fi
 585 ])
 586
 587
 588 dnl
 589 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 590 dnl
 591 AC_DEFUN(GLIBCXX_CHECK_INT64_T, [
 592   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 593     AC_TRY_COMPILE(
 594       [#include <stdint.h>],
 595       [int64_t var;],
 596       [glibcxx_cv_INT64_T=yes],
 597       [glibcxx_cv_INT64_T=no])
 598   ])
 599   if test $glibcxx_cv_INT64_T = yes; then
 600     AC_DEFINE(HAVE_INT64_T)
 601   fi
 602 ])
 603
 604
 605 dnl
 606 dnl Check whether LFS support is available.
 607 dnl
 608 AC_DEFUN(GLIBCXX_CHECK_LFS, [
 609   AC_LANG_SAVE
 610   AC_LANG_CPLUSPLUS
 611   AC_CACHE_VAL(glibcxx_cv_LFS, [
 612     AC_TRY_LINK(
 613       [#include <unistd.h>
 614        #include <stdio.h>
 615       ],
 616       [FILE* fp;
 617        fopen64("t", "w");
 618        fseeko64(fp, 0, SEEK_CUR);
 619        ftello64(fp);
 620        lseek64(1, 0, SEEK_CUR);],
 621       [glibcxx_cv_LFS=yes],
 622       [glibcxx_cv_LFS=no])
 623   ])
 624   if test $glibcxx_cv_LFS = yes; then
 625     AC_DEFINE(_GLIBCXX_USE_LFS)
 626   fi
 627   AC_LANG_RESTORE
 628 ])
 629
 630
 631 dnl
 632 dnl Does any necessary configuration of the testsuite directory.  Generates
 633 dnl the testsuite_hooks.h header.
 634 dnl
 635 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 636 dnl
 637 dnl Sets:
 638 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 639 dnl Substs:
 640 dnl  baseline_dir
 641 dnl
 642 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 643   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 644     # Do checks for memory limit functions.
 645     GLIBCXX_CHECK_SETRLIMIT
 646
 647     # Look for setenv, so that extended locale tests can be performed.
 648     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 649
 650     if test $enable_symvers = no; then
 651       enable_abi_check=no
 652     else
 653       case "$host" in
 654         *-*-cygwin*)
 655           enable_abi_check=no ;;
 656         *)
 657           enable_abi_check=yes ;;
 658       esac
 659     fi
 660   else
 661     # Only build this as native, since automake does not understand
 662     # CXX_FOR_BUILD.
 663     enable_abi_check=no
 664   fi
 665
 666   # Export file names for ABI checking.
 667   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 668   AC_SUBST(baseline_dir)
 669
 670   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 671   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 672 ])
 673
 674
 675 dnl
 676 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 677 dnl
 678 dnl Substs:
 679 dnl  GLIBCXX_INCLUDES
 680 dnl  TOPLEVEL_INCLUDES
 681 dnl
 682 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 683   # Used for every C++ compile we perform.
 684   GLIBCXX_INCLUDES="\
 685 -I$glibcxx_builddir/include/$host_alias \
 686 -I$glibcxx_builddir/include \
 687 -I$glibcxx_srcdir/libsupc++"
 688
 689   # For Canadian crosses, pick this up too.
 690   if test $CANADIAN = yes; then
 691     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 692   fi
 693
 694   # Stuff in the actual top level.  Currently only used by libsupc++ to
 695   # get unwind* headers from the gcc dir.
 696   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 697   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 698
 699   # Now, export this to all the little Makefiles....
 700   AC_SUBST(GLIBCXX_INCLUDES)
 701   AC_SUBST(TOPLEVEL_INCLUDES)
 702 ])
 703
 704
 705 dnl
 706 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 707 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 708 dnl
 709 dnl Substs:
 710 dnl  OPTIMIZE_CXXFLAGS
 711 dnl  WARN_FLAGS
 712 dnl
 713 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 714   # Optimization flags that are probably a good idea for thrill-seekers. Just
 715   # uncomment the lines below and make, everything else is ready to go...
 716   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 717   OPTIMIZE_CXXFLAGS=
 718   AC_SUBST(OPTIMIZE_CXXFLAGS)
 719
 720   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 721   AC_SUBST(WARN_FLAGS)
 722 ])
 723
 724
 725 dnl
 726 dnl All installation directory information is determined here.
 727 dnl
 728 dnl Substs:
 729 dnl  gxx_install_dir
 730 dnl  glibcxx_prefixdir
 731 dnl  glibcxx_toolexecdir
 732 dnl  glibcxx_toolexeclibdir
 733 dnl
 734 dnl Assumes cross_compiling bits already done, and with_cross_host in
 735 dnl particular.
 736 dnl
 737 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 738   glibcxx_toolexecdir=no
 739   glibcxx_toolexeclibdir=no
 740   glibcxx_prefixdir=$prefix
 741
 742   AC_MSG_CHECKING([for gxx-include-dir])
 743   AC_ARG_WITH([gxx-include-dir],
 744     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 745                    [installation directory for include files]),
 746     [case "$withval" in
 747       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 748       no)  gxx_include_dir=no ;;
 749       *)   gxx_include_dir=$withval ;;
 750      esac],
 751     [gxx_include_dir=no])
 752   AC_MSG_RESULT($gxx_include_dir)
 753
 754   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 755   AC_ARG_ENABLE([version-specific-runtime-libs],
 756     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 757                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 758     [case "$enableval" in
 759       yes) version_specific_libs=yes ;;
 760       no)  version_specific_libs=no ;;
 761       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 762      esac],
 763     [version_specific_libs=no])
 764   AC_MSG_RESULT($version_specific_libs)
 765
 766   # Default case for install directory for include files.
 767   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 768     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 769   fi
 770
 771   # Version-specific runtime libs processing.
 772   if test $version_specific_libs = yes; then
 773     # Need the gcc compiler version to know where to install libraries
 774     # and header files if --enable-version-specific-runtime-libs option
 775     # is selected.
 776     if test x"$gxx_include_dir" = x"no"; then
 777       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 778     fi
 779     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 780     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 781   fi
 782
 783   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 784   # Install a library built with a cross compiler in tooldir, not libdir.
 785   if test x"$glibcxx_toolexecdir" = x"no"; then
 786     if test -n "$with_cross_host" &&
 787        test x"$with_cross_host" != x"no"; then
 788       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 789       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 790     else
 791       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 792       glibcxx_toolexeclibdir='${libdir}'
 793     fi
 794     multi_os_directory=`$CXX -print-multi-os-directory`
 795     case $multi_os_directory in
 796       .) ;; # Avoid trailing /.
 797       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 798     esac
 799   fi
 800
 801   AC_MSG_CHECKING([for install location])
 802   AC_MSG_RESULT($gxx_include_dir)
 803
 804   AC_SUBST(glibcxx_prefixdir)
 805   AC_SUBST(gxx_include_dir)
 806   AC_SUBST(glibcxx_toolexecdir)
 807   AC_SUBST(glibcxx_toolexeclibdir)
 808 ])
 809
 810
 811 dnl
 812 dnl GLIBCXX_ENABLE
 813 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 814 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 815 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 816 dnl
 817 dnl See docs/html/17_intro/configury.html#enable for documentation.
 818 dnl
 819 m4_define([GLIBCXX_ENABLE],[dnl
 820 m4_define([_g_switch],[--enable-$1])dnl
 821 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 822  AC_ARG_ENABLE($1,_g_help,
 823   m4_bmatch([$5],
 824    [^permit ],
 825      [[
 826       case "$enableval" in
 827        m4_bpatsubst([$5],[permit ])) ;;
 828        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 829           dnl Idea for future:  generate a URL pointing to
 830           dnl "onlinedocs/configopts.html#whatever"
 831       esac
 832      ]],
 833    [^$],
 834      [[
 835       case "$enableval" in
 836        yes|no) ;;
 837        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 838       esac
 839      ]],
 840    [[$5]]),
 841   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 842 m4_undefine([_g_switch])dnl
 843 m4_undefine([_g_help])dnl
 844 ])
 845
 846
 847 dnl
 848 dnl Check for ISO/IEC 9899:1999 "C99" support.
 849 dnl
 850 dnl --enable-c99 defines _GLIBCXX_USE_C99
 851 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 852 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 853 dnl       Where DEFAULT is either `yes' or `no'.
 854 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 855 dnl
 856 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 857   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 858
 859   AC_LANG_SAVE
 860   AC_LANG_CPLUSPLUS
 861
 862   # Check for the existence of <math.h> functions used if C99 is enabled.
 863   ac_c99_math=yes;
 864   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 865   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 866   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 867   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 868   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 869   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 870   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 871   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 872   AC_TRY_COMPILE([#include <math.h>],
 873                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 874   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 875   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 876   AC_TRY_COMPILE([#include <math.h>],
 877                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 878   AC_TRY_COMPILE([#include <math.h>],
 879                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 880   AC_MSG_RESULT($ac_c99_math)
 881
 882   # Check for the existence in <stdio.h> of vscanf, et. al.
 883   ac_c99_stdio=yes;
 884   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 885   AC_TRY_COMPILE([#include <stdio.h>],
 886                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 887   AC_TRY_COMPILE([#include <stdio.h>
 888                   #include <stdarg.h>
 889                   void foo(char* fmt, ...)
 890                   {va_list args; va_start(args, fmt);
 891                   vfscanf(stderr, "%i", args);}],
 892                   [],, [ac_c99_stdio=no])
 893   AC_TRY_COMPILE([#include <stdio.h>
 894                   #include <stdarg.h>
 895                   void foo(char* fmt, ...)
 896                   {va_list args; va_start(args, fmt);
 897                   vscanf("%i", args);}],
 898                   [],, [ac_c99_stdio=no])
 899   AC_TRY_COMPILE([#include <stdio.h>
 900                   #include <stdarg.h>
 901                   void foo(char* fmt, ...)
 902                   {va_list args; va_start(args, fmt);
 903                   vsnprintf(fmt, 0, "%i", args);}],
 904                   [],, [ac_c99_stdio=no])
 905   AC_TRY_COMPILE([#include <stdio.h>
 906                   #include <stdarg.h>
 907                   void foo(char* fmt, ...)
 908                   {va_list args; va_start(args, fmt);
 909                   vsscanf(fmt, "%i", args);}],
 910                   [],, [ac_c99_stdio=no])
 911   AC_MSG_RESULT($ac_c99_stdio)
 912
 913   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 914   ac_c99_stdlib=yes;
 915   AC_MSG_CHECKING([for lldiv_t declaration])
 916   AC_CACHE_VAL(ac_c99_lldiv_t, [
 917   AC_TRY_COMPILE([#include <stdlib.h>],
 918                    [ lldiv_t mydivt;],
 919                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 920   ])
 921   AC_MSG_RESULT($ac_c99_lldiv_t)
 922
 923   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 924   AC_TRY_COMPILE([#include <stdlib.h>],
 925                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 926   AC_TRY_COMPILE([#include <stdlib.h>],
 927                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 928   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 929   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 930   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 931   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 932   if test x"$ac_c99_lldiv_t" = x"no"; then
 933     ac_c99_stdlib=no;
 934   fi;
 935   AC_MSG_RESULT($ac_c99_stdlib)
 936
 937   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 938   # XXX the wchar.h checks should be rolled into the general C99 bits.
 939   ac_c99_wchar=yes;
 940   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 941   AC_TRY_COMPILE([#include <wchar.h>],
 942                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 943   AC_TRY_COMPILE([#include <wchar.h>],
 944                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 945   AC_TRY_COMPILE([#include <wchar.h>],
 946                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 947   AC_MSG_RESULT($ac_c99_wchar)
 948
 949   AC_MSG_CHECKING([for enabled ISO C99 support])
 950   if test x"$ac_c99_math" = x"no" ||
 951      test x"$ac_c99_stdio" = x"no" ||
 952      test x"$ac_c99_stdlib" = x"no" ||
 953      test x"$ac_c99_wchar" = x"no"; then
 954     enable_c99=no;
 955   fi;
 956   AC_MSG_RESULT($enable_c99)
 957
 958   # Option parsed, now set things appropriately
 959   if test x"$enable_c99" = x"yes"; then
 960     AC_DEFINE(_GLIBCXX_USE_C99)
 961   fi
 962
 963   AC_LANG_RESTORE
 964 ])
 965
 966
 967 dnl
 968 dnl Check for what type of C headers to use.
 969 dnl
 970 dnl --enable-cheaders= [does stuff].
 971 dnl --disable-cheaders [does not do anything, really].
 972 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 973 dnl       Where DEFAULT is either `c' or `c_std'.
 974 dnl
 975 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 976   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 977     [construct "C" headers for g++], [permit c|c_std])
 978   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 979
 980   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 981
 982   AC_SUBST(C_INCLUDE_DIR)
 983   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 984   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 985   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 986 ])
 987
 988
 989 dnl
 990 dnl Check for which locale library to use.  The choice is mapped to
 991 dnl a subdirectory of config/locale.
 992 dnl
 993 dnl Default is generic.
 994 dnl
 995 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 996   AC_MSG_CHECKING([for C locale to use])
 997   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 998     [use MODEL for target locale package],
 999     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1000
1001   # If they didn't use this option switch, or if they specified --enable
1002   # with no specific model, we'll have to look for one.  If they
1003   # specified --disable (???), do likewise.
1004   if test $enable_clocale = no || test $enable_clocale = yes; then
1005      enable_clocale=auto
1006   fi
1007
1008   # Either a known package, or "auto"
1009   enable_clocale_flag=$enable_clocale
1010
1011   # Probe for locale support if no specific model is specified.
1012   # Default to "generic".
1013   if test $enable_clocale_flag = auto; then
1014     case x${target_os} in
1015       xlinux* | xgnu* | xkfreebsd*-gnu | xknetbsd*-gnu)
1016         AC_EGREP_CPP([_GLIBCXX_ok], [
1017         #include <features.h>
1018         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1019           _GLIBCXX_ok
1020         #endif
1021         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1022
1023         # Test for bugs early in glibc-2.2.x series
1024           if test x$enable_clocale_flag = xgnu; then
1025           AC_TRY_RUN([
1026           #define _GNU_SOURCE 1
1027           #include <locale.h>
1028           #include <string.h>
1029           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1030           extern __typeof(newlocale) __newlocale;
1031           extern __typeof(duplocale) __duplocale;
1032           extern __typeof(strcoll_l) __strcoll_l;
1033           #endif
1034           int main()
1035           {
1036               const char __one[] = "Äuglein Augmen";
1037               const char __two[] = "Äuglein";
1038               int i;
1039               int j;
1040               __locale_t        loc;
1041                __locale_t        loc_dup;
1042               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1043               loc_dup = __duplocale(loc);
1044               i = __strcoll_l(__one, __two, loc);
1045               j = __strcoll_l(__one, __two, loc_dup);
1046               return 0;
1047           }
1048           ],
1049           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1050           [enable_clocale_flag=generic])
1051           fi
1052
1053         # ... at some point put __strxfrm_l tests in as well.
1054         ;;
1055       *)
1056         enable_clocale_flag=generic
1057         ;;
1058     esac
1059   fi
1060
1061   # Deal with gettext issues.  Default to not using it (=no) until we detect
1062   # support for it later.  Let the user turn it off via --e/d, but let that
1063   # default to on for easier handling.
1064   USE_NLS=no
1065   AC_ARG_ENABLE(nls,
1066     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1067     [],
1068     [enable_nls=yes])
1069
1070   # Set configure bits for specified locale package
1071   case ${enable_clocale_flag} in
1072     generic)
1073       AC_MSG_RESULT(generic)
1074
1075       CLOCALE_H=config/locale/generic/c_locale.h
1076       CLOCALE_CC=config/locale/generic/c_locale.cc
1077       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1078       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1079       CCOLLATE_CC=config/locale/generic/collate_members.cc
1080       CCTYPE_CC=config/locale/generic/ctype_members.cc
1081       CMESSAGES_H=config/locale/generic/messages_members.h
1082       CMESSAGES_CC=config/locale/generic/messages_members.cc
1083       CMONEY_CC=config/locale/generic/monetary_members.cc
1084       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1085       CTIME_H=config/locale/generic/time_members.h
1086       CTIME_CC=config/locale/generic/time_members.cc
1087       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1088       ;;
1089     gnu)
1090       AC_MSG_RESULT(gnu)
1091
1092       # Declare intention to use gettext, and add support for specific
1093       # languages.
1094       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1095       ALL_LINGUAS="de fr"
1096
1097       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1098       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1099       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1100         USE_NLS=yes
1101       fi
1102       # Export the build objects.
1103       for ling in $ALL_LINGUAS; do \
1104         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1105         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1106       done
1107       AC_SUBST(glibcxx_MOFILES)
1108       AC_SUBST(glibcxx_POFILES)
1109
1110       CLOCALE_H=config/locale/gnu/c_locale.h
1111       CLOCALE_CC=config/locale/gnu/c_locale.cc
1112       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1113       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1114       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1115       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1116       CMESSAGES_H=config/locale/gnu/messages_members.h
1117       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1118       CMONEY_CC=config/locale/gnu/monetary_members.cc
1119       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1120       CTIME_H=config/locale/gnu/time_members.h
1121       CTIME_CC=config/locale/gnu/time_members.cc
1122       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1123       ;;
1124     ieee_1003.1-2001)
1125       AC_MSG_RESULT(IEEE 1003.1)
1126
1127       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1128       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1129       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1130       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1131       CCOLLATE_CC=config/locale/generic/collate_members.cc
1132       CCTYPE_CC=config/locale/generic/ctype_members.cc
1133       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1134       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1135       CMONEY_CC=config/locale/generic/monetary_members.cc
1136       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1137       CTIME_H=config/locale/generic/time_members.h
1138       CTIME_CC=config/locale/generic/time_members.cc
1139       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1140       ;;
1141   esac
1142
1143   # This is where the testsuite looks for locale catalogs, using the
1144   # -DLOCALEDIR define during testsuite compilation.
1145   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1146   AC_SUBST(glibcxx_localedir)
1147
1148   # A standalone libintl (e.g., GNU libintl) may be in use.
1149   if test $USE_NLS = yes; then
1150     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1151     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1152   fi
1153   if test $USE_NLS = yes; then
1154     AC_DEFINE(_GLIBCXX_USE_NLS)
1155   fi
1156
1157   AC_SUBST(USE_NLS)
1158   AC_SUBST(CLOCALE_H)
1159   AC_SUBST(CCODECVT_H)
1160   AC_SUBST(CMESSAGES_H)
1161   AC_SUBST(CCODECVT_CC)
1162   AC_SUBST(CCOLLATE_CC)
1163   AC_SUBST(CCTYPE_CC)
1164   AC_SUBST(CMESSAGES_CC)
1165   AC_SUBST(CMONEY_CC)
1166   AC_SUBST(CNUMERIC_CC)
1167   AC_SUBST(CTIME_H)
1168   AC_SUBST(CTIME_CC)
1169   AC_SUBST(CLOCALE_CC)
1170   AC_SUBST(CLOCALE_INTERNAL_H)
1171 ])
1172
1173
1174 dnl
1175 dnl Check for whether the Boost-derived checks should be turned on.
1176 dnl
1177 dnl --enable-concept-checks turns them on.
1178 dnl --disable-concept-checks leaves them off.
1179 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1180 dnl       Where DEFAULT is either `yes' or `no'.
1181 dnl
1182 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1183   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1184   if test $enable_concept_checks = yes; then
1185     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1186   fi
1187 ])
1188
1189
1190 dnl
1191 dnl Check for which I/O library to use:  stdio, or something specific.
1192 dnl
1193 dnl Default is stdio.
1194 dnl
1195 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1196   AC_MSG_CHECKING([for underlying I/O to use])
1197   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1198     [use target-specific I/O package], [permit stdio])
1199
1200   # Now that libio has been removed, you can have any color you want as long
1201   # as it's black.  This is one big no-op until other packages are added, but
1202   # showing the framework never hurts.
1203   case ${enable_cstdio} in
1204     stdio)
1205       CSTDIO_H=config/io/c_io_stdio.h
1206       BASIC_FILE_H=config/io/basic_file_stdio.h
1207       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1208       AC_MSG_RESULT(stdio)
1209       ;;
1210   esac
1211
1212   AC_SUBST(CSTDIO_H)
1213   AC_SUBST(BASIC_FILE_H)
1214   AC_SUBST(BASIC_FILE_CC)
1215 ])
1216
1217
1218 dnl
1219 dnl Check for "unusual" flags to pass to the compiler while building.
1220 dnl
1221 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1222 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1223 dnl --disable-cxx-flags passes nothing.
1224 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1225 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1226 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1227 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1228 dnl       If "default flags" is an empty string, the effect is the same
1229 dnl       as --disable or --enable=no.
1230 dnl
1231 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1232   AC_MSG_CHECKING([for extra compiler flags for building])
1233   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1234     [pass compiler FLAGS when building library],
1235     [case "x$enable_cxx_flags" in
1236       xno | x)   enable_cxx_flags= ;;
1237       x-*)       ;;
1238       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1239      esac])
1240
1241   # Run through flags (either default or command-line) and set anything
1242   # extra (e.g., #defines) that must accompany particular g++ options.
1243   if test -n "$enable_cxx_flags"; then
1244     for f in $enable_cxx_flags; do
1245       case "$f" in
1246         -fhonor-std)  ;;
1247         -*)  ;;
1248         *)   # and we're trying to pass /what/ exactly?
1249              AC_MSG_ERROR([compiler flags start with a -]) ;;
1250       esac
1251     done
1252   fi
1253
1254   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1255   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1256   AC_SUBST(EXTRA_CXX_FLAGS)
1257 ])
1258
1259
1260 dnl
1261 dnl Check for wide character support.  Has the same effect as the option
1262 dnl in gcc's configure, but in a form that autoconf can mess with.
1263 dnl
1264 dnl --enable-c-mbchar requests all the wchar_t stuff.
1265 dnl --disable-c-mbchar doesn't.
1266 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1267 dnl       Where DEFAULT is either `yes' or `no'.
1268 dnl
1269 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1270   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1271   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1272 ])
1273
1274
1275 dnl
1276 dnl Check to see if debugging libraries are to be built.
1277 dnl
1278 dnl --enable-libstdcxx-debug
1279 dnl builds a separate set of debugging libraries in addition to the
1280 dnl normal (shared, static) libstdc++ binaries.
1281 dnl
1282 dnl --disable-libstdcxx-debug
1283 dnl builds only one (non-debug) version of libstdc++.
1284 dnl
1285 dnl --enable-libstdcxx-debug-flags=FLAGS
1286 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1287 dnl
1288 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1289 dnl       Where DEFAULT is either `yes' or `no'.
1290 dnl
1291 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1292   AC_MSG_CHECKING([for additional debug build])
1293   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1294   AC_MSG_RESULT($enable_libstdcxx_debug)
1295   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1296 ])
1297
1298
1299 dnl
1300 dnl Check for explicit debug flags.
1301 dnl
1302 dnl --enable-libstdcxx-debug-flags='-O1'
1303 dnl is a general method for passing flags to be used when
1304 dnl building debug libraries with --enable-debug.
1305 dnl
1306 dnl --disable-libstdcxx-debug-flags does nothing.
1307 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1308 dnl       If "default flags" is an empty string, the effect is the same
1309 dnl       as --disable or --enable=no.
1310 dnl
1311 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1312   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1313     [pass compiler FLAGS when building debug library],
1314     [case "x$enable_libstdcxx_debug_flags" in
1315       xno | x)    enable_libstdcxx_debug_flags= ;;
1316       x-*)        ;;
1317       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1318      esac])
1319
1320   # Option parsed, now set things appropriately
1321   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1322   AC_SUBST(DEBUG_FLAGS)
1323
1324   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1325 ])
1326
1327
1328 dnl
1329 dnl Check if the user only wants a freestanding library implementation.
1330 dnl
1331 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1332 dnl installing only the headers required by [17.4.1.3] and the language
1333 dnl support library.  More than that will be built (to keep the Makefiles
1334 dnl conveniently clean), but not installed.
1335 dnl
1336 dnl Sets:
1337 dnl  is_hosted  (yes/no)
1338 dnl
1339 dnl Defines:
1340 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1341 dnl
1342 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1343   AC_ARG_ENABLE([hosted-libstdcxx],
1344     AC_HELP_STRING([--disable-hosted-libstdcxx],
1345                    [only build freestanding C++ runtime support]),,
1346     [enable_hosted_libstdcxx=yes])
1347   if test "$enable_hosted_libstdcxx" = no; then
1348     AC_MSG_NOTICE([Only freestanding libraries will be built])
1349     is_hosted=no
1350     hosted_define=0
1351     enable_abi_check=no
1352     enable_libstdcxx_pch=no
1353   else
1354     is_hosted=yes
1355     hosted_define=1
1356   fi
1357   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1358   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1359     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1360 ])
1361
1362
1363 dnl
1364 dnl Check for libunwind exception handling support.  If enabled, then
1365 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1366 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1367 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1368 dnl on libunwind as well as libgcc.
1369 dnl
1370 dnl --enable-libunwind-exceptions forces the use of libunwind.
1371 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1372 dnl
1373 dnl Substs:
1374 dnl  LIBUNWIND_FLAG
1375 dnl
1376 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1377   AC_MSG_CHECKING([for use of libunwind])
1378   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1379     [force use of libunwind for exceptions])
1380   AC_MSG_RESULT($use_libunwind_exceptions)
1381   if test $enable_libunwind_exceptions = yes; then
1382     LIBUNWIND_FLAG="-lunwind"
1383   else
1384     LIBUNWIND_FLAG=""
1385   fi
1386   AC_SUBST(LIBUNWIND_FLAG)
1387 ])
1388
1389
1390 dnl
1391 dnl Check for template specializations for the 'long long' type extension.
1392 dnl The result determines only whether 'long long' I/O is enabled; things
1393 dnl like numeric_limits<> specializations are always available.
1394 dnl
1395 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1396 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1397 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1398 dnl       Where DEFAULT is either `yes' or `no'.
1399 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1400 dnl
1401 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1402   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1403
1404   AC_LANG_SAVE
1405   AC_LANG_CPLUSPLUS
1406
1407   AC_MSG_CHECKING([for enabled long long I/O support])
1408   # iostreams require strtoll, strtoull to compile
1409   AC_TRY_COMPILE([#include <stdlib.h>],
1410                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1411   AC_TRY_COMPILE([#include <stdlib.h>],
1412                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1413
1414   # Option parsed, now set things appropriately
1415   if test $enable_long_long = yes; then
1416     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1417   fi
1418   AC_MSG_RESULT($enable_long_long)
1419
1420   AC_LANG_RESTORE
1421 ])
1422
1423
1424 dnl
1425 dnl Check to see if building and using a C++ precompiled header can be done.
1426 dnl
1427 dnl --enable-libstdcxx-pch=yes
1428 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1429 dnl may work, after some light-hearted attempts to puzzle out compiler
1430 dnl support, flip bits on in include/Makefile.am
1431 dnl
1432 dnl --disable-libstdcxx-pch
1433 dnl turns off attempts to use or build stdc++.h.gch.
1434 dnl
1435 dnl Substs:
1436 dnl  glibcxx_PCHFLAGS
1437 dnl
1438 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1439   AC_MSG_CHECKING([for enabled PCH])
1440   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1441   AC_MSG_RESULT([$enable_libstdcxx_pch])
1442
1443   if test $enable_libstdcxx_pch = yes; then
1444     AC_CACHE_CHECK([for compiler with PCH support],
1445       [glibcxx_cv_prog_CXX_pch],
1446       [ac_save_CXXFLAGS="$CXXFLAGS"
1447        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1448        AC_LANG_SAVE
1449        AC_LANG_CPLUSPLUS
1450        echo '#include <math.h>' > conftest.h
1451        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1452                           -o conftest.h.gch 1>&5 2>&1 &&
1453                 echo '#error "pch failed"' > conftest.h &&
1454           echo '#include "conftest.h"' > conftest.cc &&
1455                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1456        then
1457          glibcxx_cv_prog_CXX_pch=yes
1458        else
1459          glibcxx_cv_prog_CXX_pch=no
1460        fi
1461        rm -f conftest*
1462        CXXFLAGS=$ac_save_CXXFLAGS
1463        AC_LANG_RESTORE
1464       ])
1465     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1466   fi
1467
1468   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1469   if test $enable_libstdcxx_pch = yes; then
1470     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1471   else
1472     glibcxx_PCHFLAGS=""
1473   fi
1474   AC_SUBST(glibcxx_PCHFLAGS)
1475 ])
1476
1477
1478 dnl
1479 dnl Check for exception handling support.  If an explicit enable/disable
1480 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1481 dnl target may or may not support call frame exceptions.
1482 dnl
1483 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1484 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1485 dnl Neither one forces an attempt at detection.
1486 dnl
1487 dnl Defines:
1488 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1489 dnl
1490 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1491   AC_MSG_CHECKING([for exception model to use])
1492   AC_LANG_SAVE
1493   AC_LANG_CPLUSPLUS
1494   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1495     [force use of builtin_setjmp for exceptions],
1496     [permit yes|no|auto])
1497
1498   if test $enable_sjlj_exceptions = auto; then
1499     # Botheration.  Now we've got to detect the exception model.  Link tests
1500     # against libgcc.a are problematic since we've not been given proper -L
1501     # bits for single-tree newlib and libgloss.
1502     #
1503     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1504     cat > conftest.$ac_ext << EOF
1505 [#]line __oline__ "configure"
1506 struct S { ~S(); };
1507 void bar();
1508 void foo()
1509 {
1510   S s;
1511   bar();
1512 }
1513 EOF
1514     old_CXXFLAGS="$CXXFLAGS"
1515     CXXFLAGS=-S
1516     if AC_TRY_EVAL(ac_compile); then
1517       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1518         enable_sjlj_exceptions=yes
1519       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1520         enable_sjlj_exceptions=no
1521       fi
1522     fi
1523     CXXFLAGS="$old_CXXFLAGS"
1524     rm -f conftest*
1525   fi
1526
1527   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1528   # to two different models.
1529   case $enable_sjlj_exceptions in
1530     yes)
1531       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1532         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1533       ac_exception_model_name=sjlj
1534       ;;
1535     no)
1536       ac_exception_model_name="call frame"
1537       ;;
1538     *)
1539       AC_MSG_ERROR([unable to detect exception model])
1540       ;;
1541   esac
1542  AC_LANG_RESTORE
1543  AC_MSG_RESULT($ac_exception_model_name)
1544 ])
1545
1546
1547 dnl
1548 dnl Add version tags to symbols in shared library (or not), additionally
1549 dnl marking other symbols as private/local (or not).
1550 dnl
1551 dnl --enable-symvers=style adds a version script to the linker call when
1552 dnl       creating the shared library.  The choice of version script is
1553 dnl       controlled by 'style'.
1554 dnl --disable-symvers does not.
1555 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1556 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1557 dnl       choose a default style based on linker characteristics.  Passing
1558 dnl       'no' disables versioning.
1559 dnl
1560 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1561
1562 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1563   [enables symbol versioning of the shared library],
1564   [permit yes|no|gnu])
1565
1566 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1567 # don't know enough about $LD to do tricks...
1568 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1569 # FIXME  The following test is too strict, in theory.
1570 if test $enable_shared = no ||
1571         test "x$LD" = x ||
1572         test x$glibcxx_gnu_ld_version = x; then
1573   enable_symvers=no
1574 fi
1575
1576 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1577 if test $enable_symvers != no; then
1578   AC_MSG_CHECKING([for shared libgcc])
1579   ac_save_CFLAGS="$CFLAGS"
1580   CFLAGS=' -lgcc_s'
1581   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1582   CFLAGS="$ac_save_CFLAGS"
1583   AC_MSG_RESULT($glibcxx_shared_libgcc)
1584 fi
1585
1586 # For GNU ld, we need at least this version.  The format is described in
1587 # GLIBCXX_CHECK_LINKER_FEATURES above.
1588 glibcxx_min_gnu_ld_version=21400
1589 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1590
1591 # Check to see if unspecified "yes" value can win, given results above.
1592 # Change "yes" into either "no" or a style name.
1593 if test $enable_symvers = yes; then
1594   if test $with_gnu_ld = yes &&
1595      test $glibcxx_shared_libgcc = yes;
1596   then
1597     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1598       enable_symvers=gnu
1599     else
1600       # The right tools, the right setup, but too old.  Fallbacks?
1601       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1602       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1603       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1604       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1605       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1606         # Globbing fix is present, proper block support is not.
1607         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1608         dnl enable_symvers=???
1609         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1610         enable_symvers=no
1611       else
1612         # 2.11 or older.
1613         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1614         enable_symvers=no
1615       fi
1616     fi
1617   else
1618     # just fail for now
1619     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1620     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1621     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1622     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1623     enable_symvers=no
1624   fi
1625 fi
1626
1627 # Everything parsed; figure out what file to use.
1628 case $enable_symvers in
1629   no)
1630     SYMVER_MAP=config/linker-map.dummy
1631     ;;
1632   gnu)
1633     SYMVER_MAP=config/linker-map.gnu
1634     AC_DEFINE(_GLIBCXX_SYMVER)
1635     ;;
1636 esac
1637
1638 AC_SUBST(SYMVER_MAP)
1639 AC_SUBST(port_specific_symbol_files)
1640 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1641 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1642 ])
1643
1644
1645 dnl
1646 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1647 dnl We must stage the required headers so that they will be installed
1648 dnl with the library (unlike libgcc, the STL implementation is provided
1649 dnl solely within headers).  Since we must not inject random user-space
1650 dnl macro names into user-provided C++ code, we first stage into <file>-in
1651 dnl and process to <file> with an output command.  The reason for a two-
1652 dnl stage process here is to correctly handle $srcdir!=$objdir without
1653 dnl having to write complex code (the sed commands to clean the macro
1654 dnl namespace are complex and fragile enough as it is).  We must also
1655 dnl add a relative path so that -I- is supported properly.
1656 dnl
1657 dnl Substs:
1658 dnl  glibcxx_thread_h
1659 dnl
1660 dnl Defines:
1661 dnl  HAVE_GTHR_DEFAULT
1662 dnl  _GLIBCXX_SUPPORTS_WEAK
1663 dnl
1664 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1665   AC_MSG_CHECKING([for thread model used by GCC])
1666   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1667   AC_MSG_RESULT([$target_thread_file])
1668
1669   if test $target_thread_file != single; then
1670     AC_DEFINE(HAVE_GTHR_DEFAULT)
1671     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1672   fi
1673
1674   glibcxx_thread_h=gthr-$target_thread_file.h
1675   AC_SUBST(glibcxx_thread_h)
1676 ])
1677
1678
1679 # Check whether LC_MESSAGES is available in <locale.h>.
1680 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1681 #
1682 # This file file be copied and used freely without restrictions.  It can
1683 # be used in projects which are not available under the GNU Public License
1684 # but which still want to provide support for the GNU gettext functionality.
1685 # Please note that the actual code is *not* freely available.
1686
1687 # serial 1
1688 AC_DEFUN(AC_LC_MESSAGES, [
1689   AC_CHECK_HEADER(locale.h, [
1690     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1691       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1692        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1693     if test $ac_cv_val_LC_MESSAGES = yes; then
1694       AC_DEFINE(HAVE_LC_MESSAGES)
1695     fi
1696   ])
1697 ])
1698
1699
1700 sinclude([../libtool.m4])
1701 dnl The lines below arrange for aclocal not to bring an installed
1702 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1703 dnl add a definition of LIBTOOL to Makefile.in.
1704 ifelse(,,,[AC_SUBST(LIBTOOL)
1705 AC_DEFUN([AM_PROG_LIBTOOL])
1706 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1707 AC_DEFUN([AC_PROG_LD])
1708 ])
1709
1710 dnl vim:et:ts=2:sw=2
1711
1712 # AM_CONDITIONAL                                              -*- Autoconf -*-
1713
1714 # Copyright 1997, 2000, 2001 Free Software Foundation, Inc.
1715
1716 # This program is free software; you can redistribute it and/or modify
1717 # it under the terms of the GNU General Public License as published by
1718 # the Free Software Foundation; either version 2, or (at your option)
1719 # any later version.
1720
1721 # This program is distributed in the hope that it will be useful,
1722 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1723 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1724 # GNU General Public License for more details.
1725
1726 # You should have received a copy of the GNU General Public License
1727 # along with this program; if not, write to the Free Software
1728 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1729 # 02111-1307, USA.
1730
1731 # serial 5
1732
1733 AC_PREREQ(2.52)
1734
1735 # AM_CONDITIONAL(NAME, SHELL-CONDITION)
1736 # -------------------------------------
1737 # Define a conditional.
1738 AC_DEFUN([AM_CONDITIONAL],
1739 [ifelse([$1], [TRUE],  [AC_FATAL([$0: invalid condition: $1])],
1740         [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
1741 AC_SUBST([$1_TRUE])
1742 AC_SUBST([$1_FALSE])
1743 if $2; then
1744   $1_TRUE=
1745   $1_FALSE='#'
1746 else
1747   $1_TRUE='#'
1748   $1_FALSE=
1749 fi
1750 AC_CONFIG_COMMANDS_PRE(
1751 [if test -z "${$1_TRUE}" && test -z "${$1_FALSE}"; then
1752   AC_MSG_ERROR([conditional "$1" was never defined.
1753 Usually this means the macro was only invoked conditionally.])
1754 fi])])
1755
1756 # Copyright 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
1757
1758 # This program is free software; you can redistribute it and/or modify
1759 # it under the terms of the GNU General Public License as published by
1760 # the Free Software Foundation; either version 2, or (at your option)
1761 # any later version.
1762
1763 # This program is distributed in the hope that it will be useful,
1764 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1765 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1766 # GNU General Public License for more details.
1767
1768 # You should have received a copy of the GNU General Public License
1769 # along with this program; if not, write to the Free Software
1770 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1771 # 02111-1307, USA.
1772
1773 # serial 3
1774
1775 # AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
1776 # ---------------------------------------------------
1777 # Add --enable-multilib to configure.
1778 AC_DEFUN([AM_ENABLE_MULTILIB],
1779 [# Default to --enable-multilib
1780 AC_ARG_ENABLE(multilib,
1781 [  --enable-multilib         build many library versions (default)],
1782 [case "$enableval" in
1783   yes) multilib=yes ;;
1784   no)  multilib=no ;;
1785   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
1786  esac],
1787               [multilib=yes])
1788
1789 # We may get other options which we leave undocumented:
1790 # --with-target-subdir, --with-multisrctop, --with-multisubdir
1791 # See config-ml.in if you want the gory details.
1792
1793 if test "$srcdir" = "."; then
1794   if test "$with_target_subdir" != "."; then
1795     multi_basedir="$srcdir/$with_multisrctop../$2"
1796   else
1797     multi_basedir="$srcdir/$with_multisrctop$2"
1798   fi
1799 else
1800   multi_basedir="$srcdir/$2"
1801 fi
1802 AC_SUBST(multi_basedir)
1803
1804 AC_OUTPUT_COMMANDS([
1805 # Only add multilib support code if we just rebuilt the top-level
1806 # Makefile.
1807 case " $CONFIG_FILES " in
1808  *" ]m4_default([$1],Makefile)[ "*)
1809    ac_file=]m4_default([$1],Makefile)[ . ${multi_basedir}/config-ml.in
1810    ;;
1811 esac],
1812                    [
1813 srcdir="$srcdir"
1814 host="$host"
1815 target="$target"
1816 with_multisubdir="$with_multisubdir"
1817 with_multisrctop="$with_multisrctop"
1818 with_target_subdir="$with_target_subdir"
1819 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1820 multi_basedir="$multi_basedir"
1821 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1822 CC="$CC"])])dnl
1823
1824 # Add --enable-maintainer-mode option to configure.
1825 # From Jim Meyering
1826
1827 # Copyright 1996, 1998, 2000, 2001, 2002  Free Software Foundation, Inc.
1828
1829 # This program is free software; you can redistribute it and/or modify
1830 # it under the terms of the GNU General Public License as published by
1831 # the Free Software Foundation; either version 2, or (at your option)
1832 # any later version.
1833
1834 # This program is distributed in the hope that it will be useful,
1835 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1836 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1837 # GNU General Public License for more details.
1838
1839 # You should have received a copy of the GNU General Public License
1840 # along with this program; if not, write to the Free Software
1841 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1842 # 02111-1307, USA.
1843
1844 # serial 2
1845
1846 AC_DEFUN([AM_MAINTAINER_MODE],
1847 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1848   dnl maintainer-mode is disabled by default
1849   AC_ARG_ENABLE(maintainer-mode,
1850 [  --enable-maintainer-mode enable make rules and dependencies not useful
1851                           (and sometimes confusing) to the casual installer],
1852       USE_MAINTAINER_MODE=$enableval,
1853       USE_MAINTAINER_MODE=no)
1854   AC_MSG_RESULT([$USE_MAINTAINER_MODE])
1855   AM_CONDITIONAL(MAINTAINER_MODE, [test $USE_MAINTAINER_MODE = yes])
1856   MAINT=$MAINTAINER_MODE_TRUE
1857   AC_SUBST(MAINT)dnl
1858 ]
1859 )
1860
1861 AU_DEFUN([jm_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
1862
1863 # Do all the work for Automake.                            -*- Autoconf -*-
1864
1865 # This macro actually does too much some checks are only needed if
1866 # your package does certain things.  But this isn't really a big deal.
1867
1868 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
1869 # Free Software Foundation, Inc.
1870
1871 # This program is free software; you can redistribute it and/or modify
1872 # it under the terms of the GNU General Public License as published by
1873 # the Free Software Foundation; either version 2, or (at your option)
1874 # any later version.
1875
1876 # This program is distributed in the hope that it will be useful,
1877 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1878 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1879 # GNU General Public License for more details.
1880
1881 # You should have received a copy of the GNU General Public License
1882 # along with this program; if not, write to the Free Software
1883 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
1884 # 02111-1307, USA.
1885
1886 # serial 10
1887
1888 AC_PREREQ([2.54])
1889
1890 # Autoconf 2.50 wants to disallow AM_ names.  We explicitly allow
1891 # the ones we care about.
1892 m4_pattern_allow([^AM_[A-Z]+FLAGS$])dnl
1893
1894 # AM_INIT_AUTOMAKE(PACKAGE, VERSION, [NO-DEFINE])
1895 # AM_INIT_AUTOMAKE([OPTIONS])
1896 # -----------------------------------------------
1897 # The call with PACKAGE and VERSION arguments is the old style
1898 # call (pre autoconf-2.50), which is being phased out.  PACKAGE
1899 # and VERSION should now be passed to AC_INIT and removed from
1900 # the call to AM_INIT_AUTOMAKE.
1901 # We support both call styles for the transition.  After
1902 # the next Automake release, Autoconf can make the AC_INIT
1903 # arguments mandatory, and then we can depend on a new Autoconf
1904 # release and drop the old call support.
1905 AC_DEFUN([AM_INIT_AUTOMAKE],
1906 [AC_REQUIRE([AM_SET_CURRENT_AUTOMAKE_VERSION])dnl
1907  AC_REQUIRE([AC_PROG_INSTALL])dnl
1908 # test to see if srcdir already configured
1909 if test "`cd $srcdir && pwd`" != "`pwd`" &&
1910    test -f $srcdir/config.status; then
1911   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
1912 fi
1913
1914 # test whether we have cygpath
1915 if test -z "$CYGPATH_W"; then
1916   if (cygpath --version) >/dev/null 2>/dev/null; then
1917     CYGPATH_W='cygpath -w'
1918   else
1919     CYGPATH_W=echo
1920   fi
1921 fi
1922 AC_SUBST([CYGPATH_W])
1923
1924 # Define the identity of the package.
1925 dnl Distinguish between old-style and new-style calls.
1926 m4_ifval([$2],
1927 [m4_ifval([$3], [_AM_SET_OPTION([no-define])])dnl
1928  AC_SUBST([PACKAGE], [$1])dnl
1929  AC_SUBST([VERSION], [$2])],
1930 [_AM_SET_OPTIONS([$1])dnl
1931  AC_SUBST([PACKAGE], ['AC_PACKAGE_TARNAME'])dnl
1932  AC_SUBST([VERSION], ['AC_PACKAGE_VERSION'])])dnl
1933
1934 _AM_IF_OPTION([no-define],,
1935 [AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
1936  AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package])])dnl
1937
1938 # Some tools Automake needs.
1939 AC_REQUIRE([AM_SANITY_CHECK])dnl
1940 AC_REQUIRE([AC_ARG_PROGRAM])dnl
1941 AM_MISSING_PROG(ACLOCAL, aclocal-${am__api_version})
1942 AM_MISSING_PROG(AUTOCONF, autoconf)
1943 AM_MISSING_PROG(AUTOMAKE, automake-${am__api_version})
1944 AM_MISSING_PROG(AUTOHEADER, autoheader)
1945 AM_MISSING_PROG(MAKEINFO, makeinfo)
1946 AM_MISSING_PROG(AMTAR, tar)
1947 AM_PROG_INSTALL_SH
1948 AM_PROG_INSTALL_STRIP
1949 # We need awk for the "check" target.  The system "awk" is bad on
1950 # some platforms.
1951 AC_REQUIRE([AC_PROG_AWK])dnl
1952 AC_REQUIRE([AC_PROG_MAKE_SET])dnl
1953 AC_REQUIRE([AM_SET_LEADING_DOT])dnl
1954
1955 _AM_IF_OPTION([no-dependencies],,
1956 [AC_PROVIDE_IFELSE([AC_PROG_CC],
1957                   [_AM_DEPENDENCIES(CC)],
1958                   [define([AC_PROG_CC],
1959                           defn([AC_PROG_CC])[_AM_DEPENDENCIES(CC)])])dnl
1960 AC_PROVIDE_IFELSE([AC_PROG_CXX],
1961                   [_AM_DEPENDENCIES(CXX)],
1962                   [define([AC_PROG_CXX],
1963                           defn([AC_PROG_CXX])[_AM_DEPENDENCIES(CXX)])])dnl
1964 ])
1965 ])
1966
1967
1968 # When config.status generates a header, we must update the stamp-h file.
1969 # This file resides in the same directory as the config header
1970 # that is generated.  The stamp files are numbered to have different names.
1971
1972 # Autoconf calls _AC_AM_CONFIG_HEADER_HOOK (when defined) in the
1973 # loop where config.status creates the headers, so we can generate
1974 # our stamp files there.
1975 AC_DEFUN([_AC_AM_CONFIG_HEADER_HOOK],
1976 [# Compute $1's index in $config_headers.
1977 _am_stamp_count=1
1978 for _am_header in $config_headers :; do
1979   case $_am_header in
1980     $1 | $1:* )
1981       break ;;
1982     * )
1983       _am_stamp_count=`expr $_am_stamp_count + 1` ;;
1984   esac
1985 done
1986 echo "timestamp for $1" >`AS_DIRNAME([$1])`/stamp-h[]$_am_stamp_count])
1987
1988 # Copyright 2002  Free Software Foundation, Inc.
1989
1990 # This program is free software; you can redistribute it and/or modify
1991 # it under the terms of the GNU General Public License as published by
1992 # the Free Software Foundation; either version 2, or (at your option)
1993 # any later version.
1994
1995 # This program is distributed in the hope that it will be useful,
1996 # but WITHOUT ANY WARRANTY; without even the implied warranty of
1997 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1998 # GNU General Public License for more details.
1999
2000 # You should have received a copy of the GNU General Public License
2001 # along with this program; if not, write to the Free Software
2002 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2003
2004 # AM_AUTOMAKE_VERSION(VERSION)
2005 # ----------------------------
2006 # Automake X.Y traces this macro to ensure aclocal.m4 has been
2007 # generated from the m4 files accompanying Automake X.Y.
2008 AC_DEFUN([AM_AUTOMAKE_VERSION],[am__api_version="1.7"])
2009
2010 # AM_SET_CURRENT_AUTOMAKE_VERSION
2011 # -------------------------------
2012 # Call AM_AUTOMAKE_VERSION so it can be traced.
2013 # This function is AC_REQUIREd by AC_INIT_AUTOMAKE.
2014 AC_DEFUN([AM_SET_CURRENT_AUTOMAKE_VERSION],
2015          [AM_AUTOMAKE_VERSION([1.7.9])])
2016
2017 # Helper functions for option handling.                    -*- Autoconf -*-
2018
2019 # Copyright 2001, 2002  Free Software Foundation, Inc.
2020
2021 # This program is free software; you can redistribute it and/or modify
2022 # it under the terms of the GNU General Public License as published by
2023 # the Free Software Foundation; either version 2, or (at your option)
2024 # any later version.
2025
2026 # This program is distributed in the hope that it will be useful,
2027 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2028 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2029 # GNU General Public License for more details.
2030
2031 # You should have received a copy of the GNU General Public License
2032 # along with this program; if not, write to the Free Software
2033 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2034 # 02111-1307, USA.
2035
2036 # serial 2
2037
2038 # _AM_MANGLE_OPTION(NAME)
2039 # -----------------------
2040 AC_DEFUN([_AM_MANGLE_OPTION],
2041 [[_AM_OPTION_]m4_bpatsubst($1, [[^a-zA-Z0-9_]], [_])])
2042
2043 # _AM_SET_OPTION(NAME)
2044 # ------------------------------
2045 # Set option NAME.  Presently that only means defining a flag for this option.
2046 AC_DEFUN([_AM_SET_OPTION],
2047 [m4_define(_AM_MANGLE_OPTION([$1]), 1)])
2048
2049 # _AM_SET_OPTIONS(OPTIONS)
2050 # ----------------------------------
2051 # OPTIONS is a space-separated list of Automake options.
2052 AC_DEFUN([_AM_SET_OPTIONS],
2053 [AC_FOREACH([_AM_Option], [$1], [_AM_SET_OPTION(_AM_Option)])])
2054
2055 # _AM_IF_OPTION(OPTION, IF-SET, [IF-NOT-SET])
2056 # -------------------------------------------
2057 # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
2058 AC_DEFUN([_AM_IF_OPTION],
2059 [m4_ifset(_AM_MANGLE_OPTION([$1]), [$2], [$3])])
2060
2061 #
2062 # Check to make sure that the build environment is sane.
2063 #
2064
2065 # Copyright 1996, 1997, 2000, 2001 Free Software Foundation, Inc.
2066
2067 # This program is free software; you can redistribute it and/or modify
2068 # it under the terms of the GNU General Public License as published by
2069 # the Free Software Foundation; either version 2, or (at your option)
2070 # any later version.
2071
2072 # This program is distributed in the hope that it will be useful,
2073 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2074 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2075 # GNU General Public License for more details.
2076
2077 # You should have received a copy of the GNU General Public License
2078 # along with this program; if not, write to the Free Software
2079 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2080 # 02111-1307, USA.
2081
2082 # serial 3
2083
2084 # AM_SANITY_CHECK
2085 # ---------------
2086 AC_DEFUN([AM_SANITY_CHECK],
2087 [AC_MSG_CHECKING([whether build environment is sane])
2088 # Just in case
2089 sleep 1
2090 echo timestamp > conftest.file
2091 # Do `set' in a subshell so we don't clobber the current shell's
2092 # arguments.  Must try -L first in case configure is actually a
2093 # symlink; some systems play weird games with the mod time of symlinks
2094 # (eg FreeBSD returns the mod time of the symlink's containing
2095 # directory).
2096 if (
2097    set X `ls -Lt $srcdir/configure conftest.file 2> /dev/null`
2098    if test "$[*]" = "X"; then
2099       # -L didn't work.
2100       set X `ls -t $srcdir/configure conftest.file`
2101    fi
2102    rm -f conftest.file
2103    if test "$[*]" != "X $srcdir/configure conftest.file" \
2104       && test "$[*]" != "X conftest.file $srcdir/configure"; then
2105
2106       # If neither matched, then we have a broken ls.  This can happen
2107       # if, for instance, CONFIG_SHELL is bash and it inherits a
2108       # broken ls alias from the environment.  This has actually
2109       # happened.  Such a system could not be considered "sane".
2110       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
2111 alias in your environment])
2112    fi
2113
2114    test "$[2]" = conftest.file
2115    )
2116 then
2117    # Ok.
2118    :
2119 else
2120    AC_MSG_ERROR([newly created file is older than distributed files!
2121 Check your system clock])
2122 fi
2123 AC_MSG_RESULT(yes)])
2124
2125 #  -*- Autoconf -*-
2126
2127
2128 # Copyright 1997, 1999, 2000, 2001 Free Software Foundation, Inc.
2129
2130 # This program is free software; you can redistribute it and/or modify
2131 # it under the terms of the GNU General Public License as published by
2132 # the Free Software Foundation; either version 2, or (at your option)
2133 # any later version.
2134
2135 # This program is distributed in the hope that it will be useful,
2136 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2137 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2138 # GNU General Public License for more details.
2139
2140 # You should have received a copy of the GNU General Public License
2141 # along with this program; if not, write to the Free Software
2142 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2143 # 02111-1307, USA.
2144
2145 # serial 3
2146
2147 # AM_MISSING_PROG(NAME, PROGRAM)
2148 # ------------------------------
2149 AC_DEFUN([AM_MISSING_PROG],
2150 [AC_REQUIRE([AM_MISSING_HAS_RUN])
2151 $1=${$1-"${am_missing_run}$2"}
2152 AC_SUBST($1)])
2153
2154
2155 # AM_MISSING_HAS_RUN
2156 # ------------------
2157 # Define MISSING if not defined so far and test if it supports --run.
2158 # If it does, set am_missing_run to use it, otherwise, to nothing.
2159 AC_DEFUN([AM_MISSING_HAS_RUN],
2160 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
2161 test x"${MISSING+set}" = xset || MISSING="\${SHELL} $am_aux_dir/missing"
2162 # Use eval to expand $SHELL
2163 if eval "$MISSING --run true"; then
2164   am_missing_run="$MISSING --run "
2165 else
2166   am_missing_run=
2167   AC_MSG_WARN([`missing' script is too old or missing])
2168 fi
2169 ])
2170
2171 # AM_AUX_DIR_EXPAND
2172
2173 # Copyright 2001 Free Software Foundation, Inc.
2174
2175 # This program is free software; you can redistribute it and/or modify
2176 # it under the terms of the GNU General Public License as published by
2177 # the Free Software Foundation; either version 2, or (at your option)
2178 # any later version.
2179
2180 # This program is distributed in the hope that it will be useful,
2181 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2182 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2183 # GNU General Public License for more details.
2184
2185 # You should have received a copy of the GNU General Public License
2186 # along with this program; if not, write to the Free Software
2187 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2188 # 02111-1307, USA.
2189
2190 # For projects using AC_CONFIG_AUX_DIR([foo]), Autoconf sets
2191 # $ac_aux_dir to `$srcdir/foo'.  In other projects, it is set to
2192 # `$srcdir', `$srcdir/..', or `$srcdir/../..'.
2193 #
2194 # Of course, Automake must honor this variable whenever it calls a
2195 # tool from the auxiliary directory.  The problem is that $srcdir (and
2196 # therefore $ac_aux_dir as well) can be either absolute or relative,
2197 # depending on how configure is run.  This is pretty annoying, since
2198 # it makes $ac_aux_dir quite unusable in subdirectories: in the top
2199 # source directory, any form will work fine, but in subdirectories a
2200 # relative path needs to be adjusted first.
2201 #
2202 # $ac_aux_dir/missing
2203 #    fails when called from a subdirectory if $ac_aux_dir is relative
2204 # $top_srcdir/$ac_aux_dir/missing
2205 #    fails if $ac_aux_dir is absolute,
2206 #    fails when called from a subdirectory in a VPATH build with
2207 #          a relative $ac_aux_dir
2208 #
2209 # The reason of the latter failure is that $top_srcdir and $ac_aux_dir
2210 # are both prefixed by $srcdir.  In an in-source build this is usually
2211 # harmless because $srcdir is `.', but things will broke when you
2212 # start a VPATH build or use an absolute $srcdir.
2213 #
2214 # So we could use something similar to $top_srcdir/$ac_aux_dir/missing,
2215 # iff we strip the leading $srcdir from $ac_aux_dir.  That would be:
2216 #   am_aux_dir='\$(top_srcdir)/'`expr "$ac_aux_dir" : "$srcdir//*\(.*\)"`
2217 # and then we would define $MISSING as
2218 #   MISSING="\${SHELL} $am_aux_dir/missing"
2219 # This will work as long as MISSING is not called from configure, because
2220 # unfortunately $(top_srcdir) has no meaning in configure.
2221 # However there are other variables, like CC, which are often used in
2222 # configure, and could therefore not use this "fixed" $ac_aux_dir.
2223 #
2224 # Another solution, used here, is to always expand $ac_aux_dir to an
2225 # absolute PATH.  The drawback is that using absolute paths prevent a
2226 # configured tree to be moved without reconfiguration.
2227
2228 # Rely on autoconf to set up CDPATH properly.
2229 AC_PREREQ([2.50])
2230
2231 AC_DEFUN([AM_AUX_DIR_EXPAND], [
2232 # expand $ac_aux_dir to an absolute path
2233 am_aux_dir=`cd $ac_aux_dir && pwd`
2234 ])
2235
2236 # AM_PROG_INSTALL_SH
2237 # ------------------
2238 # Define $install_sh.
2239
2240 # Copyright 2001 Free Software Foundation, Inc.
2241
2242 # This program is free software; you can redistribute it and/or modify
2243 # it under the terms of the GNU General Public License as published by
2244 # the Free Software Foundation; either version 2, or (at your option)
2245 # any later version.
2246
2247 # This program is distributed in the hope that it will be useful,
2248 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2249 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2250 # GNU General Public License for more details.
2251
2252 # You should have received a copy of the GNU General Public License
2253 # along with this program; if not, write to the Free Software
2254 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2255 # 02111-1307, USA.
2256
2257 AC_DEFUN([AM_PROG_INSTALL_SH],
2258 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
2259 install_sh=${install_sh-"$am_aux_dir/install-sh"}
2260 AC_SUBST(install_sh)])
2261
2262 # AM_PROG_INSTALL_STRIP
2263
2264 # Copyright 2001 Free Software Foundation, Inc.
2265
2266 # This program is free software; you can redistribute it and/or modify
2267 # it under the terms of the GNU General Public License as published by
2268 # the Free Software Foundation; either version 2, or (at your option)
2269 # any later version.
2270
2271 # This program is distributed in the hope that it will be useful,
2272 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2273 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2274 # GNU General Public License for more details.
2275
2276 # You should have received a copy of the GNU General Public License
2277 # along with this program; if not, write to the Free Software
2278 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2279 # 02111-1307, USA.
2280
2281 # One issue with vendor `install' (even GNU) is that you can't
2282 # specify the program used to strip binaries.  This is especially
2283 # annoying in cross-compiling environments, where the build's strip
2284 # is unlikely to handle the host's binaries.
2285 # Fortunately install-sh will honor a STRIPPROG variable, so we
2286 # always use install-sh in `make install-strip', and initialize
2287 # STRIPPROG with the value of the STRIP variable (set by the user).
2288 AC_DEFUN([AM_PROG_INSTALL_STRIP],
2289 [AC_REQUIRE([AM_PROG_INSTALL_SH])dnl
2290 # Installed binaries are usually stripped using `strip' when the user
2291 # run `make install-strip'.  However `strip' might not be the right
2292 # tool to use in cross-compilation environments, therefore Automake
2293 # will honor the `STRIP' environment variable to overrule this program.
2294 dnl Don't test for $cross_compiling = yes, because it might be `maybe'.
2295 if test "$cross_compiling" != no; then
2296   AC_CHECK_TOOL([STRIP], [strip], :)
2297 fi
2298 INSTALL_STRIP_PROGRAM="\${SHELL} \$(install_sh) -c -s"
2299 AC_SUBST([INSTALL_STRIP_PROGRAM])])
2300
2301 #                                                          -*- Autoconf -*-
2302 # Copyright (C) 2003  Free Software Foundation, Inc.
2303
2304 # This program is free software; you can redistribute it and/or modify
2305 # it under the terms of the GNU General Public License as published by
2306 # the Free Software Foundation; either version 2, or (at your option)
2307 # any later version.
2308
2309 # This program is distributed in the hope that it will be useful,
2310 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2311 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2312 # GNU General Public License for more details.
2313
2314 # You should have received a copy of the GNU General Public License
2315 # along with this program; if not, write to the Free Software
2316 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2317 # 02111-1307, USA.
2318
2319 # serial 1
2320
2321 # Check whether the underlying file-system supports filenames
2322 # with a leading dot.  For instance MS-DOS doesn't.
2323 AC_DEFUN([AM_SET_LEADING_DOT],
2324 [rm -rf .tst 2>/dev/null
2325 mkdir .tst 2>/dev/null
2326 if test -d .tst; then
2327   am__leading_dot=.
2328 else
2329   am__leading_dot=_
2330 fi
2331 rmdir .tst 2>/dev/null
2332 AC_SUBST([am__leading_dot])])
2333
2334 # serial 5                                              -*- Autoconf -*-
2335
2336 # Copyright (C) 1999, 2000, 2001, 2002, 2003  Free Software Foundation, Inc.
2337
2338 # This program is free software; you can redistribute it and/or modify
2339 # it under the terms of the GNU General Public License as published by
2340 # the Free Software Foundation; either version 2, or (at your option)
2341 # any later version.
2342
2343 # This program is distributed in the hope that it will be useful,
2344 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2345 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2346 # GNU General Public License for more details.
2347
2348 # You should have received a copy of the GNU General Public License
2349 # along with this program; if not, write to the Free Software
2350 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2351 # 02111-1307, USA.
2352
2353
2354 # There are a few dirty hacks below to avoid letting `AC_PROG_CC' be
2355 # written in clear, in which case automake, when reading aclocal.m4,
2356 # will think it sees a *use*, and therefore will trigger all it's
2357 # C support machinery.  Also note that it means that autoscan, seeing
2358 # CC etc. in the Makefile, will ask for an AC_PROG_CC use...
2359
2360
2361
2362 # _AM_DEPENDENCIES(NAME)
2363 # ----------------------
2364 # See how the compiler implements dependency checking.
2365 # NAME is "CC", "CXX", "GCJ", or "OBJC".
2366 # We try a few techniques and use that to set a single cache variable.
2367 #
2368 # We don't AC_REQUIRE the corresponding AC_PROG_CC since the latter was
2369 # modified to invoke _AM_DEPENDENCIES(CC); we would have a circular
2370 # dependency, and given that the user is not expected to run this macro,
2371 # just rely on AC_PROG_CC.
2372 AC_DEFUN([_AM_DEPENDENCIES],
2373 [AC_REQUIRE([AM_SET_DEPDIR])dnl
2374 AC_REQUIRE([AM_OUTPUT_DEPENDENCY_COMMANDS])dnl
2375 AC_REQUIRE([AM_MAKE_INCLUDE])dnl
2376 AC_REQUIRE([AM_DEP_TRACK])dnl
2377
2378 ifelse([$1], CC,   [depcc="$CC"   am_compiler_list=],
2379        [$1], CXX,  [depcc="$CXX"  am_compiler_list=],
2380        [$1], OBJC, [depcc="$OBJC" am_compiler_list='gcc3 gcc'],
2381        [$1], GCJ,  [depcc="$GCJ"  am_compiler_list='gcc3 gcc'],
2382                    [depcc="$$1"   am_compiler_list=])
2383
2384 AC_CACHE_CHECK([dependency style of $depcc],
2385                [am_cv_$1_dependencies_compiler_type],
2386 [if test -z "$AMDEP_TRUE" && test -f "$am_depcomp"; then
2387   # We make a subdir and do the tests there.  Otherwise we can end up
2388   # making bogus files that we don't know about and never remove.  For
2389   # instance it was reported that on HP-UX the gcc test will end up
2390   # making a dummy file named `D' -- because `-MD' means `put the output
2391   # in D'.
2392   mkdir conftest.dir
2393   # Copy depcomp to subdir because otherwise we won't find it if we're
2394   # using a relative directory.
2395   cp "$am_depcomp" conftest.dir
2396   cd conftest.dir
2397   # We will build objects and dependencies in a subdirectory because
2398   # it helps to detect inapplicable dependency modes.  For instance
2399   # both Tru64's cc and ICC support -MD to output dependencies as a
2400   # side effect of compilation, but ICC will put the dependencies in
2401   # the current directory while Tru64 will put them in the object
2402   # directory.
2403   mkdir sub
2404
2405   am_cv_$1_dependencies_compiler_type=none
2406   if test "$am_compiler_list" = ""; then
2407      am_compiler_list=`sed -n ['s/^#*\([a-zA-Z0-9]*\))$/\1/p'] < ./depcomp`
2408   fi
2409   for depmode in $am_compiler_list; do
2410     # Setup a source with many dependencies, because some compilers
2411     # like to wrap large dependency lists on column 80 (with \), and
2412     # we should not choose a depcomp mode which is confused by this.
2413     #
2414     # We need to recreate these files for each test, as the compiler may
2415     # overwrite some of them when testing with obscure command lines.
2416     # This happens at least with the AIX C compiler.
2417     : > sub/conftest.c
2418     for i in 1 2 3 4 5 6; do
2419       echo '#include "conftst'$i'.h"' >> sub/conftest.c
2420       : > sub/conftst$i.h
2421     done
2422     echo "${am__include} ${am__quote}sub/conftest.Po${am__quote}" > confmf
2423
2424     case $depmode in
2425     nosideeffect)
2426       # after this tag, mechanisms are not by side-effect, so they'll
2427       # only be used when explicitly requested
2428       if test "x$enable_dependency_tracking" = xyes; then
2429         continue
2430       else
2431         break
2432       fi
2433       ;;
2434     none) break ;;
2435     esac
2436     # We check with `-c' and `-o' for the sake of the "dashmstdout"
2437     # mode.  It turns out that the SunPro C++ compiler does not properly
2438     # handle `-M -o', and we need to detect this.
2439     if depmode=$depmode \
2440        source=sub/conftest.c object=sub/conftest.${OBJEXT-o} \
2441        depfile=sub/conftest.Po tmpdepfile=sub/conftest.TPo \
2442        $SHELL ./depcomp $depcc -c -o sub/conftest.${OBJEXT-o} sub/conftest.c \
2443          >/dev/null 2>conftest.err &&
2444        grep sub/conftst6.h sub/conftest.Po > /dev/null 2>&1 &&
2445        grep sub/conftest.${OBJEXT-o} sub/conftest.Po > /dev/null 2>&1 &&
2446        ${MAKE-make} -s -f confmf > /dev/null 2>&1; then
2447       # icc doesn't choke on unknown options, it will just issue warnings
2448       # (even with -Werror).  So we grep stderr for any message
2449       # that says an option was ignored.
2450       if grep 'ignoring option' conftest.err >/dev/null 2>&1; then :; else
2451         am_cv_$1_dependencies_compiler_type=$depmode
2452         break
2453       fi
2454     fi
2455   done
2456
2457   cd ..
2458   rm -rf conftest.dir
2459 else
2460   am_cv_$1_dependencies_compiler_type=none
2461 fi
2462 ])
2463 AC_SUBST([$1DEPMODE], [depmode=$am_cv_$1_dependencies_compiler_type])
2464 AM_CONDITIONAL([am__fastdep$1], [
2465   test "x$enable_dependency_tracking" != xno \
2466   && test "$am_cv_$1_dependencies_compiler_type" = gcc3])
2467 ])
2468
2469
2470 # AM_SET_DEPDIR
2471 # -------------
2472 # Choose a directory name for dependency files.
2473 # This macro is AC_REQUIREd in _AM_DEPENDENCIES
2474 AC_DEFUN([AM_SET_DEPDIR],
2475 [AC_REQUIRE([AM_SET_LEADING_DOT])dnl
2476 AC_SUBST([DEPDIR], ["${am__leading_dot}deps"])dnl
2477 ])
2478
2479
2480 # AM_DEP_TRACK
2481 # ------------
2482 AC_DEFUN([AM_DEP_TRACK],
2483 [AC_ARG_ENABLE(dependency-tracking,
2484 [  --disable-dependency-tracking Speeds up one-time builds
2485   --enable-dependency-tracking  Do not reject slow dependency extractors])
2486 if test "x$enable_dependency_tracking" != xno; then
2487   am_depcomp="$ac_aux_dir/depcomp"
2488   AMDEPBACKSLASH='\'
2489 fi
2490 AM_CONDITIONAL([AMDEP], [test "x$enable_dependency_tracking" != xno])
2491 AC_SUBST([AMDEPBACKSLASH])
2492 ])
2493
2494 # Generate code to set up dependency tracking.   -*- Autoconf -*-
2495
2496 # Copyright 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
2497
2498 # This program is free software; you can redistribute it and/or modify
2499 # it under the terms of the GNU General Public License as published by
2500 # the Free Software Foundation; either version 2, or (at your option)
2501 # any later version.
2502
2503 # This program is distributed in the hope that it will be useful,
2504 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2505 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2506 # GNU General Public License for more details.
2507
2508 # You should have received a copy of the GNU General Public License
2509 # along with this program; if not, write to the Free Software
2510 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2511 # 02111-1307, USA.
2512
2513 #serial 2
2514
2515 # _AM_OUTPUT_DEPENDENCY_COMMANDS
2516 # ------------------------------
2517 AC_DEFUN([_AM_OUTPUT_DEPENDENCY_COMMANDS],
2518 [for mf in $CONFIG_FILES; do
2519   # Strip MF so we end up with the name of the file.
2520   mf=`echo "$mf" | sed -e 's/:.*$//'`
2521   # Check whether this is an Automake generated Makefile or not.
2522   # We used to match only the files named `Makefile.in', but
2523   # some people rename them; so instead we look at the file content.
2524   # Grep'ing the first line is not enough: some people post-process
2525   # each Makefile.in and add a new line on top of each file to say so.
2526   # So let's grep whole file.
2527   if grep '^#.*generated by automake' $mf > /dev/null 2>&1; then
2528     dirpart=`AS_DIRNAME("$mf")`
2529   else
2530     continue
2531   fi
2532   grep '^DEP_FILES *= *[[^ @%:@]]' < "$mf" > /dev/null || continue
2533   # Extract the definition of DEP_FILES from the Makefile without
2534   # running `make'.
2535   DEPDIR=`sed -n -e '/^DEPDIR = / s///p' < "$mf"`
2536   test -z "$DEPDIR" && continue
2537   # When using ansi2knr, U may be empty or an underscore; expand it
2538   U=`sed -n -e '/^U = / s///p' < "$mf"`
2539   test -d "$dirpart/$DEPDIR" || mkdir "$dirpart/$DEPDIR"
2540   # We invoke sed twice because it is the simplest approach to
2541   # changing $(DEPDIR) to its actual value in the expansion.
2542   for file in `sed -n -e '
2543     /^DEP_FILES = .*\\\\$/ {
2544       s/^DEP_FILES = //
2545       :loop
2546         s/\\\\$//
2547         p
2548         n
2549         /\\\\$/ b loop
2550       p
2551     }
2552     /^DEP_FILES = / s/^DEP_FILES = //p' < "$mf" | \
2553        sed -e 's/\$(DEPDIR)/'"$DEPDIR"'/g' -e 's/\$U/'"$U"'/g'`; do
2554     # Make sure the directory exists.
2555     test -f "$dirpart/$file" && continue
2556     fdir=`AS_DIRNAME(["$file"])`
2557     AS_MKDIR_P([$dirpart/$fdir])
2558     # echo "creating $dirpart/$file"
2559     echo '# dummy' > "$dirpart/$file"
2560   done
2561 done
2562 ])# _AM_OUTPUT_DEPENDENCY_COMMANDS
2563
2564
2565 # AM_OUTPUT_DEPENDENCY_COMMANDS
2566 # -----------------------------
2567 # This macro should only be invoked once -- use via AC_REQUIRE.
2568 #
2569 # This code is only required when automatic dependency tracking
2570 # is enabled.  FIXME.  This creates each `.P' file that we will
2571 # need in order to bootstrap the dependency handling code.
2572 AC_DEFUN([AM_OUTPUT_DEPENDENCY_COMMANDS],
2573 [AC_CONFIG_COMMANDS([depfiles],
2574      [test x"$AMDEP_TRUE" != x"" || _AM_OUTPUT_DEPENDENCY_COMMANDS],
2575      [AMDEP_TRUE="$AMDEP_TRUE" ac_aux_dir="$ac_aux_dir"])
2576 ])
2577
2578 # Check to see how 'make' treats includes.      -*- Autoconf -*-
2579
2580 # Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
2581
2582 # This program is free software; you can redistribute it and/or modify
2583 # it under the terms of the GNU General Public License as published by
2584 # the Free Software Foundation; either version 2, or (at your option)
2585 # any later version.
2586
2587 # This program is distributed in the hope that it will be useful,
2588 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2589 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2590 # GNU General Public License for more details.
2591
2592 # You should have received a copy of the GNU General Public License
2593 # along with this program; if not, write to the Free Software
2594 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2595 # 02111-1307, USA.
2596
2597 # serial 2
2598
2599 # AM_MAKE_INCLUDE()
2600 # -----------------
2601 # Check to see how make treats includes.
2602 AC_DEFUN([AM_MAKE_INCLUDE],
2603 [am_make=${MAKE-make}
2604 cat > confinc << 'END'
2605 am__doit:
2606         @echo done
2607 .PHONY: am__doit
2608 END
2609 # If we don't find an include directive, just comment out the code.
2610 AC_MSG_CHECKING([for style of include used by $am_make])
2611 am__include="#"
2612 am__quote=
2613 _am_result=none
2614 # First try GNU make style include.
2615 echo "include confinc" > confmf
2616 # We grep out `Entering directory' and `Leaving directory'
2617 # messages which can occur if `w' ends up in MAKEFLAGS.
2618 # In particular we don't look at `^make:' because GNU make might
2619 # be invoked under some other name (usually "gmake"), in which
2620 # case it prints its new name instead of `make'.
2621 if test "`$am_make -s -f confmf 2> /dev/null | grep -v 'ing directory'`" = "done"; then
2622    am__include=include
2623    am__quote=
2624    _am_result=GNU
2625 fi
2626 # Now try BSD make style include.
2627 if test "$am__include" = "#"; then
2628    echo '.include "confinc"' > confmf
2629    if test "`$am_make -s -f confmf 2> /dev/null`" = "done"; then
2630       am__include=.include
2631       am__quote="\""
2632       _am_result=BSD
2633    fi
2634 fi
2635 AC_SUBST([am__include])
2636 AC_SUBST([am__quote])
2637 AC_MSG_RESULT([$_am_result])
2638 rm -f confinc confmf
2639 ])
2640