libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:9:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 AC_LIBTOOL_DLOPEN
  86 AM_PROG_LIBTOOL
  87 AC_SUBST(enable_shared)
  88 AC_SUBST(enable_static)
  89
  90 # Possibly disable most of the library.
  91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  92 ## than just ignoring the results.  Faster /and/ more correct, win win.
  93 GLIBCXX_ENABLE_HOSTED
  94
  95 # Check for compiler support that doesn't require linking.
  96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  97 GLIBCXX_ENABLE_PCH($is_hosted)
  98
  99 # Enable all the variable C++ runtime options.
 100 GLIBCXX_ENABLE_CSTDIO
 101 GLIBCXX_ENABLE_CLOCALE
 102 GLIBCXX_ENABLE_ALLOCATOR
 103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 104 GLIBCXX_ENABLE_LONG_LONG([yes])
 105 GLIBCXX_ENABLE_WCHAR_T([yes])
 106 GLIBCXX_ENABLE_C99([yes])
 107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 109 GLIBCXX_ENABLE_DEBUG([no])
 110 GLIBCXX_ENABLE_CXX_FLAGS
 111 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 112
 113 # No surprises, no surprises...
 114 GLIBCXX_ENABLE_THREADS
 115 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 116 if test $atomicity_dir = cpu/generic/atomic_mutex ; then
 117   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 118   if test $target_thread_file = single; then
 119     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 120     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 121   else
 122     AC_MSG_WARN([They will be faked using a mutex.])
 123     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 124   fi
 125 fi
 126
 127 GLIBCXX_CHECK_COMPILER_FEATURES
 128
 129 if $GLIBCXX_IS_NATIVE; then
 130
 131   # We can do more elaborate tests that assume a working linker.
 132   CANADIAN=no
 133
 134   # Check for available headers.
 135   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 136   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 137   sys/types.h sys/ipc.h sys/sem.h])
 138
 139   GLIBCXX_CHECK_LINKER_FEATURES
 140   GLIBCXX_CHECK_MATH_SUPPORT
 141   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 142   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 143   GLIBCXX_CHECK_STDLIB_SUPPORT
 144
 145   # For showmanyc_helper().
 146   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 147   GLIBCXX_CHECK_POLL
 148   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 149
 150   # For xsputn_2().
 151   AC_CHECK_HEADERS(sys/uio.h)
 152   GLIBCXX_CHECK_WRITEV
 153
 154   # For the __streamoff_base_type typedef.
 155   GLIBCXX_CHECK_INT64_T
 156
 157   # For LFS support.
 158   GLIBCXX_CHECK_LFS
 159
 160   # For C99 support to TR1.
 161   GLIBCXX_CHECK_C99_TR1
 162
 163   # For dev/random and dev/urandom for TR1.
 164   GLIBCXX_CHECK_RANDOM_TR1
 165
 166   # For TLS support.
 167   GCC_CHECK_TLS
 168
 169   # For _Unwind_GetIPInfo.
 170   GCC_CHECK_UNWIND_GETIPINFO
 171
 172   AC_LC_MESSAGES
 173
 174   AC_TRY_COMPILE(
 175     [#include <setjmp.h>],
 176     [sigjmp_buf env;
 177      while (! sigsetjmp (env, 1))
 178        siglongjmp (env, 1);
 179     ],
 180     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 181
 182   AC_FUNC_MMAP
 183
 184   # For iconv support.
 185   AM_ICONV
 186
 187 else
 188
 189   # This lets us hard-code the functionality we know we'll have in the cross
 190   # target environment.  "Let" is a sugar-coated word placed on an especially
 191   # dull and tedious hack, actually.
 192   #
 193   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 194   # that involve linking, can't be used:
 195   #    "cannot open sim-crt0.o"
 196   #    "cannot open crt0.o"
 197   # etc.  All this is because there currently exists no unified, consistent
 198   # way for top level CC information to be passed down to target directories:
 199   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 200   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 201   # crosses can be removed.
 202
 203   # If Canadian cross, then don't pick up tools from the build directory.
 204   # Used only in GLIBCXX_EXPORT_INCLUDES.
 205   if test -n "$with_cross_host" &&
 206      test x"$build_alias" != x"$with_cross_host" &&
 207      test x"$build" != x"$target";
 208   then
 209     CANADIAN=yes
 210   else
 211     CANADIAN=no
 212   fi
 213
 214   # Construct crosses by hand, eliminating bits that need ld...
 215   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 216   # GLIBCXX_CHECK_MATH_SUPPORT
 217
 218   # First, test for "known" system libraries.  We may be using newlib even
 219   # on a hosted environment.
 220   if test "x${with_newlib}" = "xyes"; then
 221     os_include_dir="os/newlib"
 222     AC_DEFINE(HAVE_HYPOT)
 223
 224     # GLIBCXX_CHECK_STDLIB_SUPPORT
 225     AC_DEFINE(HAVE_STRTOF)
 226     # AC_FUNC_MMAP
 227     AC_DEFINE(HAVE_MMAP)
 228
 229     AC_DEFINE(HAVE_ACOSF)
 230     AC_DEFINE(HAVE_ASINF)
 231     AC_DEFINE(HAVE_ATAN2F)
 232     AC_DEFINE(HAVE_ATANF)
 233     AC_DEFINE(HAVE_CEILF)
 234     AC_DEFINE(HAVE_COPYSIGN)
 235     AC_DEFINE(HAVE_COPYSIGNF)
 236     AC_DEFINE(HAVE_COSF)
 237     AC_DEFINE(HAVE_COSHF)
 238     AC_DEFINE(HAVE_EXPF)
 239     AC_DEFINE(HAVE_FABSF)
 240     AC_DEFINE(HAVE_FLOORF)
 241     AC_DEFINE(HAVE_FMODF)
 242     AC_DEFINE(HAVE_FREXPF)
 243     AC_DEFINE(HAVE_LDEXPF)
 244     AC_DEFINE(HAVE_LOG10F)
 245     AC_DEFINE(HAVE_LOGF)
 246     AC_DEFINE(HAVE_MODFF)
 247     AC_DEFINE(HAVE_POWF)
 248     AC_DEFINE(HAVE_SINF)
 249     AC_DEFINE(HAVE_SINHF)
 250     AC_DEFINE(HAVE_SQRTF)
 251     AC_DEFINE(HAVE_TANF)
 252     AC_DEFINE(HAVE_TANHF)
 253
 254     AC_DEFINE(HAVE_S_ISREG)
 255     AC_DEFINE(HAVE_S_IFREG)
 256
 257     AC_DEFINE(HAVE_ICONV)
 258   else
 259     GLIBCXX_CROSSCONFIG
 260   fi
 261
 262   # At some point, we should differentiate between architectures
 263   # like x86, which have long double versions, and alpha/powerpc/etc.,
 264   # which don't. For the time being, punt.
 265   if test x"long_double_math_on_this_cpu" = x"yes"; then
 266     AC_DEFINE(HAVE_ACOSL)
 267     AC_DEFINE(HAVE_ASINL)
 268     AC_DEFINE(HAVE_ATAN2L)
 269     AC_DEFINE(HAVE_ATANL)
 270     AC_DEFINE(HAVE_CEILL)
 271     AC_DEFINE(HAVE_COPYSIGNL)
 272     AC_DEFINE(HAVE_COSL)
 273     AC_DEFINE(HAVE_COSHL)
 274     AC_DEFINE(HAVE_EXPL)
 275     AC_DEFINE(HAVE_FABSL)
 276     AC_DEFINE(HAVE_FLOORL)
 277     AC_DEFINE(HAVE_FMODL)
 278     AC_DEFINE(HAVE_FREXPL)
 279     AC_DEFINE(HAVE_LDEXPL)
 280     AC_DEFINE(HAVE_LOG10L)
 281     AC_DEFINE(HAVE_LOGL)
 282     AC_DEFINE(HAVE_MODFL)
 283     AC_DEFINE(HAVE_POWL)
 284     AC_DEFINE(HAVE_SINCOSL)
 285     AC_DEFINE(HAVE_SINL)
 286     AC_DEFINE(HAVE_SINHL)
 287     AC_DEFINE(HAVE_SQRTL)
 288     AC_DEFINE(HAVE_TANL)
 289     AC_DEFINE(HAVE_TANHL)
 290   fi
 291
 292   # Assume we have _Unwind_GetIPInfo for cross-compiles.
 293   AC_DEFINE(HAVE_GETIPINFO)
 294
 295 fi
 296
 297 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 298 GLIBCXX_ENABLE_SYMVERS([yes])
 299 GLIBCXX_ENABLE_VISIBILITY([yes])
 300
 301 ac_ldbl_compat=no
 302 case "$target" in
 303   powerpc*-*-linux* | \
 304   powerpc*-*-gnu* | \
 305   sparc*-*-linux* | \
 306   s390*-*-linux* | \
 307   alpha*-*-linux*)
 308   AC_TRY_COMPILE(, [
 309 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 310 #error no need for long double compatibility
 311 #endif
 312   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 313   if test "$ac_ldbl_compat" = yes; then
 314     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 315               [Define if compatibility should be provided for -mlong-double-64.])
 316     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 317   fi
 318 esac
 319 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 320
 321 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 322 GLIBCXX_CONFIGURE_TESTSUITE
 323
 324 # Propagate the target-specific source directories through the build chain.
 325 ATOMICITY_SRCDIR=config/${atomicity_dir}
 326 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 327 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 328 OS_INC_SRCDIR=config/${os_include_dir}
 329 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 330 AC_SUBST(ATOMICITY_SRCDIR)
 331 AC_SUBST(ATOMIC_WORD_SRCDIR)
 332 AC_SUBST(CPU_DEFINES_SRCDIR)
 333 AC_SUBST(ABI_TWEAKS_SRCDIR)
 334 AC_SUBST(OS_INC_SRCDIR)
 335
 336
 337 # Determine cross-compile flags and AM_CONDITIONALs.
 338 #AC_SUBST(GLIBCXX_IS_NATIVE)
 339 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 340 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 341 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 342 GLIBCXX_EVALUATE_CONDITIONALS
 343
 344 AC_CACHE_SAVE
 345
 346 if test ${multilib} = yes; then
 347   multilib_arg="--enable-multilib"
 348 else
 349   multilib_arg=
 350 fi
 351
 352 # Export all the install information.
 353 GLIBCXX_EXPORT_INSTALL_INFO
 354
 355 # Export all the include and flag information to Makefiles.
 356 GLIBCXX_EXPORT_INCLUDES
 357 GLIBCXX_EXPORT_FLAGS
 358
 359 if test "$enable_shared" = yes; then
 360   LIBSUPCXX_PICFLAGS="-prefer-pic"
 361 else
 362   LIBSUPCXX_PICFLAGS=
 363 fi
 364 AC_SUBST(LIBSUPCXX_PICFLAGS)
 365
 366 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 367 dnl which can all be called multiple times as needed, plus one (different)
 368 dnl AC_OUTPUT macro.  This one lists the files to be created:
 369 AC_CONFIG_FILES( \
 370   Makefile \
 371   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 372   )
 373 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 374
 375 dnl These commands are run at the end of config.status:
 376 AC_CONFIG_COMMANDS([default],
 377 [if test -n "$CONFIG_FILES"; then
 378    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 379    # that multilib installs will end up installed in the correct place.
 380    # The testsuite needs it for multilib-aware ABI baseline files.
 381    # To work around this not being passed down from config-ml.in ->
 382    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 383    # append it here.  Only modify Makefiles that have just been created.
 384    #
 385    # Also, get rid of this simulated-VPATH thing that automake does.
 386    cat > vpsed << \_EOF
 387 s!`test -f '$<' || echo '$(srcdir)/'`!!
 388 _EOF
 389    for i in $SUBDIRS; do
 390     case $CONFIG_FILES in
 391      *${i}/Makefile*)
 392        #echo "Adding MULTISUBDIR to $i/Makefile"
 393        sed -f vpsed $i/Makefile > tmp
 394        grep '^MULTISUBDIR =' Makefile >> tmp
 395        mv tmp $i/Makefile
 396        ;;
 397     esac
 398    done
 399    rm vpsed
 400  fi
 401  (cd include && ${MAKE-make})
 402 ],
 403 [
 404 # Variables needed in config.status (file generation) which aren't already
 405 # passed by autoconf.
 406 SUBDIRS="$SUBDIRS"
 407 ])
 408
 409 dnl And this actually makes things happen:
 410 AC_OUTPUT