libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:17:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  no-dist:  we don't want 'dist' and related rules.
  76 #  -Wall:  turns on all automake warnings...
  77 #  -Wno-portability:  ...except this one, since GNU make is now required.
  78 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  79 AH_TEMPLATE(PACKAGE, [Name of package])
  80 AH_TEMPLATE(VERSION, [Version number of package])
  81
  82 # -fno-builtin must be present here so that a non-conflicting form of
  83 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  84
  85 save_CXXFLAGS="$CXXFLAGS"
  86 CXXFLAGS="$CXXFLAGS -fno-builtin"
  87 AC_PROG_CC
  88 AC_PROG_CXX
  89 CXXFLAGS="$save_CXXFLAGS"
  90
  91 # Runs configure.host, and assorted other critical bits.  Sets
  92 # up critical shell variables.
  93 GLIBCXX_CONFIGURE
  94
  95 if test "x${with_newlib}" != "xyes"; then
  96   AC_LIBTOOL_DLOPEN
  97 fi
  98 AM_PROG_LIBTOOL
  99 ACX_LT_HOST_FLAGS
 100 AC_SUBST(enable_shared)
 101 AC_SUBST(enable_static)
 102
 103 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 104 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 105
 106 # Possibly disable most of the library.
 107 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 108 ## than just ignoring the results.  Faster /and/ more correct, win win.
 109 GLIBCXX_ENABLE_HOSTED
 110
 111 # Enable compiler support that doesn't require linking.
 112 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 113 GLIBCXX_ENABLE_PCH($is_hosted)
 114 GLIBCXX_ENABLE_THREADS
 115 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 116 GLIBCXX_ENABLE_DECIMAL_FLOAT
 117
 118 # Checks for compiler support that doesn't require linking.
 119 GLIBCXX_CHECK_COMPILER_FEATURES
 120
 121 # Enable all the variable C++ runtime options that don't require linking.
 122 GLIBCXX_ENABLE_CSTDIO
 123 GLIBCXX_ENABLE_CLOCALE
 124 GLIBCXX_ENABLE_ALLOCATOR
 125 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 126 GLIBCXX_ENABLE_LONG_LONG([yes])
 127 GLIBCXX_ENABLE_WCHAR_T([yes])
 128 GLIBCXX_ENABLE_C99([yes])
 129 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 130 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 131 GLIBCXX_ENABLE_DEBUG([no])
 132 GLIBCXX_ENABLE_PARALLEL([yes])
 133 GLIBCXX_ENABLE_CXX_FLAGS
 134 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 135 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 136
 137 # Checks for operating systems support that doesn't require linking.
 138 GLIBCXX_CHECK_MATH_PROTO
 139 GLIBCXX_CHECK_STDLIB_PROTO
 140 GLIBCXX_CHECK_SYSTEM_ERROR
 141
 142 # For the streamoff typedef.
 143 GLIBCXX_CHECK_INT64_T
 144
 145 # For LFS support.
 146 GLIBCXX_CHECK_LFS
 147
 148 # For showmanyc_helper().
 149 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 150 GLIBCXX_CHECK_POLL
 151 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 152
 153 # For xsputn_2().
 154 AC_CHECK_HEADERS(sys/uio.h)
 155 GLIBCXX_CHECK_WRITEV
 156
 157 # For C99 support to TR1.
 158 GLIBCXX_CHECK_C99_TR1
 159
 160 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 161 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 162
 163 # For gettimeofday support.
 164 GLIBCXX_CHECK_GETTIMEOFDAY
 165
 166 # For clock_gettime, nanosleep and sched_yield support.
 167 # NB: The default is [no], because otherwise it requires linking.
 168 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 169
 170 # For gthread support
 171 GLIBCXX_CHECK_GTHREADS
 172
 173 AC_LC_MESSAGES
 174
 175 # For hardware_concurrency
 176 AC_CHECK_HEADERS(sys/sysinfo.h)
 177 GLIBCXX_CHECK_GET_NPROCS
 178 AC_CHECK_HEADERS(unistd.h)
 179 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 180
 181 # Check for available headers.
 182 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 183 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 184 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 185 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 186 wchar.h wctype.h])
 187
 188 # Only do link tests if native. Else, hardcode.
 189 if $GLIBCXX_IS_NATIVE; then
 190
 191   # We can do more elaborate tests that assume a working linker.
 192   CANADIAN=no
 193
 194   GLIBCXX_CHECK_LINKER_FEATURES
 195   GLIBCXX_CHECK_MATH_SUPPORT
 196   GLIBCXX_CHECK_STDLIB_SUPPORT
 197
 198   # For /dev/random and /dev/urandom for TR1.
 199   GLIBCXX_CHECK_RANDOM_TR1
 200
 201   # For TLS support.
 202   GCC_CHECK_TLS
 203
 204   # For iconv support.
 205   AM_ICONV
 206
 207 else
 208
 209   # This lets us hard-code the functionality we know we'll have in the cross
 210   # target environment.  "Let" is a sugar-coated word placed on an especially
 211   # dull and tedious hack, actually.
 212   #
 213   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 214   # that involve linking, can't be used:
 215   #    "cannot open sim-crt0.o"
 216   #    "cannot open crt0.o"
 217   # etc.  All this is because there currently exists no unified, consistent
 218   # way for top level CC information to be passed down to target directories:
 219   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 220   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 221   # crosses can be removed.
 222
 223   # If Canadian cross, then don't pick up tools from the build directory.
 224   # Used only in GLIBCXX_EXPORT_INCLUDES.
 225   if test -n "$with_cross_host" &&
 226      test x"$build_alias" != x"$with_cross_host" &&
 227      test x"$build" != x"$target";
 228   then
 229     CANADIAN=yes
 230   else
 231     CANADIAN=no
 232   fi
 233
 234   # Construct crosses by hand, eliminating bits that need ld...
 235   # GLIBCXX_CHECK_MATH_SUPPORT
 236
 237   # First, test for "known" system libraries.  We may be using newlib even
 238   # on a hosted environment.
 239   if test "x${with_newlib}" = "xyes"; then
 240     os_include_dir="os/newlib"
 241     AC_DEFINE(HAVE_HYPOT)
 242
 243     # GLIBCXX_CHECK_STDLIB_SUPPORT
 244     AC_DEFINE(HAVE_STRTOF)
 245
 246     AC_DEFINE(HAVE_ACOSF)
 247     AC_DEFINE(HAVE_ASINF)
 248     AC_DEFINE(HAVE_ATAN2F)
 249     AC_DEFINE(HAVE_ATANF)
 250     AC_DEFINE(HAVE_CEILF)
 251     AC_DEFINE(HAVE_COSF)
 252     AC_DEFINE(HAVE_COSHF)
 253     AC_DEFINE(HAVE_EXPF)
 254     AC_DEFINE(HAVE_FABSF)
 255     AC_DEFINE(HAVE_FLOORF)
 256     AC_DEFINE(HAVE_FMODF)
 257     AC_DEFINE(HAVE_FREXPF)
 258     AC_DEFINE(HAVE_LDEXPF)
 259     AC_DEFINE(HAVE_LOG10F)
 260     AC_DEFINE(HAVE_LOGF)
 261     AC_DEFINE(HAVE_MODFF)
 262     AC_DEFINE(HAVE_POWF)
 263     AC_DEFINE(HAVE_SINF)
 264     AC_DEFINE(HAVE_SINHF)
 265     AC_DEFINE(HAVE_SQRTF)
 266     AC_DEFINE(HAVE_TANF)
 267     AC_DEFINE(HAVE_TANHF)
 268
 269     AC_DEFINE(HAVE_ICONV)
 270   else
 271     GLIBCXX_CROSSCONFIG
 272   fi
 273
 274   # At some point, we should differentiate between architectures
 275   # like x86, which have long double versions, and alpha/powerpc/etc.,
 276   # which don't. For the time being, punt.
 277   if test x"long_double_math_on_this_cpu" = x"yes"; then
 278     AC_DEFINE(HAVE_ACOSL)
 279     AC_DEFINE(HAVE_ASINL)
 280     AC_DEFINE(HAVE_ATAN2L)
 281     AC_DEFINE(HAVE_ATANL)
 282     AC_DEFINE(HAVE_CEILL)
 283     AC_DEFINE(HAVE_COSL)
 284     AC_DEFINE(HAVE_COSHL)
 285     AC_DEFINE(HAVE_EXPL)
 286     AC_DEFINE(HAVE_FABSL)
 287     AC_DEFINE(HAVE_FLOORL)
 288     AC_DEFINE(HAVE_FMODL)
 289     AC_DEFINE(HAVE_FREXPL)
 290     AC_DEFINE(HAVE_LDEXPL)
 291     AC_DEFINE(HAVE_LOG10L)
 292     AC_DEFINE(HAVE_LOGL)
 293     AC_DEFINE(HAVE_MODFL)
 294     AC_DEFINE(HAVE_POWL)
 295     AC_DEFINE(HAVE_SINCOSL)
 296     AC_DEFINE(HAVE_SINL)
 297     AC_DEFINE(HAVE_SINHL)
 298     AC_DEFINE(HAVE_SQRTL)
 299     AC_DEFINE(HAVE_TANL)
 300     AC_DEFINE(HAVE_TANHL)
 301   fi
 302 fi
 303
 304 # Check for _Unwind_GetIPInfo.
 305 GCC_CHECK_UNWIND_GETIPINFO
 306
 307
 308 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 309
 310 GCC_HEADER_STDINT(include/gstdint.h)
 311
 312 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 313 GLIBCXX_ENABLE_SYMVERS([yes])
 314 GLIBCXX_ENABLE_VISIBILITY([yes])
 315
 316 ac_ldbl_compat=no
 317 case "$target" in
 318   powerpc*-*-linux* | \
 319   sparc*-*-linux* | \
 320   s390*-*-linux* | \
 321   alpha*-*-linux*)
 322   AC_TRY_COMPILE(, [
 323 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 324 #error no need for long double compatibility
 325 #endif
 326   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 327   if test "$ac_ldbl_compat" = yes; then
 328     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 329               [Define if compatibility should be provided for -mlong-double-64.])
 330     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 331   fi
 332 esac
 333 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 334
 335 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 336 GLIBCXX_CONFIGURE_TESTSUITE
 337
 338 # Define documentation rules conditionally.
 339
 340 # See if makeinfo has been installed and is modern enough
 341 # that we can use it.
 342 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 343                    [GNU texinfo.* \([0-9][0-9.]*\)],
 344                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 345 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 346
 347 # Check for doxygen
 348 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 349 AC_CHECK_PROG([DOT], dot, yes, no)
 350
 351 # Check for docbook
 352 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 353 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 354 GLIBCXX_CONFIGURE_DOCBOOK
 355
 356 # Check for xml/html dependencies.
 357 AM_CONDITIONAL(BUILD_XML,
 358                test $ac_cv_prog_DOXYGEN = "yes" &&
 359                test $ac_cv_prog_DOT = "yes" &&
 360                test $ac_cv_prog_XSLTPROC = "yes" &&
 361                test $ac_cv_prog_XMLLINT = "yes" &&
 362                test $glibcxx_stylesheets = "yes")
 363
 364 AM_CONDITIONAL(BUILD_HTML,
 365                test $ac_cv_prog_DOXYGEN = "yes" &&
 366                test $ac_cv_prog_DOT = "yes" &&
 367                test $ac_cv_prog_XSLTPROC = "yes" &&
 368                test $ac_cv_prog_XMLLINT = "yes" &&
 369                test $glibcxx_stylesheets = "yes")
 370
 371 # Check for man dependencies.
 372 AM_CONDITIONAL(BUILD_MAN,
 373                test $ac_cv_prog_DOXYGEN = "yes" &&
 374                test $ac_cv_prog_DOT = "yes")
 375
 376 # Check for pdf/epub dependencies.
 377 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 378 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 379 AM_CONDITIONAL(BUILD_PDF,
 380                test $ac_cv_prog_DBLATEX = "yes" &&
 381                test $ac_cv_prog_PDFLATEX = "yes")
 382
 383 AC_CHECK_PROG([RUBY], ruby, yes, no)
 384 AC_CHECK_PROG([DBTOEPUB], dbtoepub, yes, no)
 385 AM_CONDITIONAL(BUILD_EPUB,
 386                test $ac_cv_prog_RUBY = "yes" &&
 387                test $ac_cv_prog_DBTOEPUB = "yes")
 388
 389
 390 # Propagate the target-specific source directories through the build chain.
 391 ATOMICITY_SRCDIR=config/${atomicity_dir}
 392 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 393 ATOMIC_FLAGS=${atomic_flags}
 394 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 395 OS_INC_SRCDIR=config/${os_include_dir}
 396 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 397 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 398 AC_SUBST(ATOMICITY_SRCDIR)
 399 AC_SUBST(ATOMIC_WORD_SRCDIR)
 400 AC_SUBST(ATOMIC_FLAGS)
 401 AC_SUBST(CPU_DEFINES_SRCDIR)
 402 AC_SUBST(ABI_TWEAKS_SRCDIR)
 403 AC_SUBST(OS_INC_SRCDIR)
 404 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 405
 406
 407 # Determine cross-compile flags and AM_CONDITIONALs.
 408 #AC_SUBST(GLIBCXX_IS_NATIVE)
 409 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 410 GLIBCXX_EVALUATE_CONDITIONALS
 411
 412 AC_CACHE_SAVE
 413
 414 if test ${multilib} = yes; then
 415   multilib_arg="--enable-multilib"
 416 else
 417   multilib_arg=
 418 fi
 419
 420 # Export all the install information.
 421 GLIBCXX_EXPORT_INSTALL_INFO
 422
 423 # Export all the include and flag information to Makefiles.
 424 GLIBCXX_EXPORT_INCLUDES
 425 GLIBCXX_EXPORT_FLAGS
 426
 427 if test "$enable_shared" = yes; then
 428   LIBSUPCXX_PICFLAGS="-prefer-pic"
 429 else
 430   LIBSUPCXX_PICFLAGS=
 431 fi
 432 AC_SUBST(LIBSUPCXX_PICFLAGS)
 433
 434 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 435 dnl which can all be called multiple times as needed, plus one (different)
 436 dnl AC_OUTPUT macro.  This one lists the files to be created:
 437 AC_CONFIG_FILES(Makefile)
 438 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 439 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 440
 441 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 442 # that multilib installs will end up installed in the correct place.
 443 # The testsuite needs it for multilib-aware ABI baseline files.
 444 # To work around this not being passed down from config-ml.in ->
 445 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 446 # append it here.  Only modify Makefiles that have just been created.
 447 #
 448 # Also, get rid of this simulated-VPATH thing that automake does.
 449 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 450   [cat > vpsed$$ << \_EOF
 451 s!`test -f '$<' || echo '$(srcdir)/'`!!
 452 _EOF
 453    sed -f vpsed$$ $ac_file > tmp$$
 454    mv tmp$$ $ac_file
 455    rm vpsed$$
 456    echo 'MULTISUBDIR =' >> $ac_file
 457    ml_norecursion=yes
 458    . ${multi_basedir}/config-ml.in
 459    AS_UNSET([ml_norecursion])
 460 ])
 461
 462 AC_CONFIG_COMMANDS([generate-headers],
 463   [(cd include && ${MAKE-make} pch_build= )])
 464
 465 dnl And this actually makes things happen:
 466 AC_OUTPUT