libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  62 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  63 #  1.x:  minimum required version
  64 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  65 #              of other PACKAGE_* variables will, however, and there's nothing
  66 #              we can do about that; they come from AC_INIT).
  67 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  68 #            file in the top srcdir, etc, etc), so stop complaining.
  69 #  no-dependencies:  turns off auto dependency generation (just for now)
  70 #  no-dist:  we don't want 'dist' and related rules.
  71 #  -Wall:  turns on all automake warnings...
  72 #  -Wno-portability:  ...except this one, since GNU make is now required.
  73 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  74 AH_TEMPLATE(PACKAGE, [Name of package])
  75 AH_TEMPLATE(VERSION, [Version number of package])
  76
  77 # -fno-builtin must be present here so that a non-conflicting form of
  78 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  79
  80 save_CXXFLAGS="$CXXFLAGS"
  81 CXXFLAGS="$CXXFLAGS -fno-builtin"
  82 AC_PROG_CC
  83 AC_PROG_CXX
  84 CXXFLAGS="$save_CXXFLAGS"
  85
  86 AC_SYS_LARGEFILE
  87
  88 # Runs configure.host, and assorted other critical bits.  Sets
  89 # up critical shell variables.
  90 GLIBCXX_CONFIGURE
  91
  92 # Libtool setup.
  93 if test "x${with_newlib}" != "xyes"; then
  94   AC_LIBTOOL_DLOPEN
  95 fi
  96 AM_PROG_LIBTOOL
  97 ACX_LT_HOST_FLAGS
  98 AC_SUBST(enable_shared)
  99 AC_SUBST(enable_static)
 100
 101 if test "$enable_vtable_verify" = yes; then
 102   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 103   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 104 fi
 105
 106
 107 # libtool variables for C++ shared and position-independent compiles.
 108 #
 109 # Use glibcxx_lt_pic_flag to designate the automake variable
 110 # used to encapsulate the default libtool approach to creating objects
 111 # with position-independent code. Default: -prefer-pic.
 112 #
 113 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 114 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 115 #
 116 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 117 # creating position-independent objects. This varies with the target
 118 # hardware and operating system, but is often: -DPIC -fPIC.
 119 if test "$enable_shared" = yes; then
 120   glibcxx_lt_pic_flag="-prefer-pic"
 121   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 122   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 123
 124 else
 125   glibcxx_lt_pic_flag=
 126   glibcxx_compiler_pic_flag=
 127   glibcxx_compiler_shared_flag=
 128 fi
 129 AC_SUBST(glibcxx_lt_pic_flag)
 130 AC_SUBST(glibcxx_compiler_pic_flag)
 131 AC_SUBST(glibcxx_compiler_shared_flag)
 132
 133 # Override the libtool's pic_flag and pic_mode.
 134 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 135 # NB: this impacts --with-pic and --without-pic.
 136 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 137 pic_mode='default'
 138
 139 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 140 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 141
 142 # Possibly disable most of the library.
 143 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 144 ## than just ignoring the results.  Faster /and/ more correct, win win.
 145 GLIBCXX_ENABLE_HOSTED
 146
 147 # Enable descriptive messages to standard output on termination.
 148 GLIBCXX_ENABLE_VERBOSE
 149
 150 # Enable compiler support that doesn't require linking.
 151 GLIBCXX_ENABLE_PCH($is_hosted)
 152 GLIBCXX_ENABLE_THREADS
 153 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 154 GLIBCXX_ENABLE_LOCK_POLICY
 155 GLIBCXX_ENABLE_DECIMAL_FLOAT
 156 GLIBCXX_ENABLE_INT128_FLOAT128
 157 if test "$enable_float128" = yes; then
 158   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 159 fi
 160
 161 # Checks for compiler support that doesn't require linking.
 162 GLIBCXX_CHECK_COMPILER_FEATURES
 163
 164 # Enable all the variable C++ runtime options that don't require linking.
 165 GLIBCXX_ENABLE_CSTDIO
 166 GLIBCXX_ENABLE_CLOCALE
 167 GLIBCXX_ENABLE_ALLOCATOR
 168 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 169 GLIBCXX_ENABLE_LONG_LONG([yes])
 170 GLIBCXX_ENABLE_WCHAR_T([yes])
 171 GLIBCXX_ENABLE_C99([yes])
 172 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 173 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 174 GLIBCXX_ENABLE_DEBUG([no])
 175 GLIBCXX_ENABLE_PARALLEL([yes])
 176 GLIBCXX_ENABLE_CXX_FLAGS
 177 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 178 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 179 GLIBCXX_ENABLE_PYTHON
 180 GLIBCXX_ENABLE_WERROR([no])
 181 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 182
 183 # Checks for operating systems support that doesn't require linking.
 184 GLIBCXX_CHECK_STDIO_PROTO
 185 GLIBCXX_CHECK_MATH11_PROTO
 186 GLIBCXX_CHECK_SYSTEM_ERROR
 187 GLIBCXX_CHECK_UCHAR_H
 188
 189 # For the streamoff typedef.
 190 GLIBCXX_CHECK_INT64_T
 191
 192 # For LFS support.
 193 GLIBCXX_CHECK_LFS
 194
 195 # For showmanyc_helper().
 196 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 197 GLIBCXX_CHECK_POLL
 198 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 199
 200 # For xsputn_2().
 201 AC_CHECK_HEADERS(sys/uio.h)
 202 GLIBCXX_CHECK_WRITEV
 203
 204 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 205 # so that the check is done with the C compiler (not C++).
 206 # Checking with C++ can break a canadian cross build if either
 207 # file does not exist in C but does in C++.
 208 AC_CHECK_HEADERS(fenv.h complex.h)
 209
 210 # For C99 support to TR1.
 211 GLIBCXX_CHECK_C99_TR1
 212
 213 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 214 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 215
 216 # For gettimeofday support.
 217 GLIBCXX_CHECK_GETTIMEOFDAY
 218
 219 # For clock_gettime, nanosleep and sched_yield support.
 220 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 221
 222 # Check for tmpnam which is obsolescent in POSIX.1-2008
 223 GLIBCXX_CHECK_TMPNAM
 224
 225 # For pthread_cond_clockwait
 226 GLIBCXX_CHECK_PTHREAD_COND_CLOCKWAIT
 227
 228 # For pthread_mutex_clocklock
 229 GLIBCXX_CHECK_PTHREAD_MUTEX_CLOCKLOCK
 230
 231 # For pthread_rwlock_clockrdlock and pthread_rwlock_clockwrlock
 232 GLIBCXX_CHECK_PTHREAD_RWLOCK_CLOCKLOCK
 233
 234 AC_LC_MESSAGES
 235
 236 # For hardware_concurrency
 237 AC_CHECK_HEADERS(sys/sysinfo.h)
 238 GLIBCXX_CHECK_GET_NPROCS
 239 AC_CHECK_HEADERS(unistd.h)
 240 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 241 GLIBCXX_CHECK_SC_NPROC_ONLN
 242 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 243 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 244 GLIBCXX_CHECK_SDT_H
 245
 246 # Check for available headers.
 247 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 248 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 249 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 250 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 251 wchar.h wctype.h linux/types.h])
 252
 253 AC_CHECK_HEADERS([linux/random.h], [], [],
 254 [[#ifdef HAVE_LINUX_TYPES_H
 255 # include <linux/types.h>
 256 #endif
 257 ]])
 258
 259 AC_CHECK_HEADERS([xlocale.h])
 260
 261 # Only do link tests if native. Else, hardcode.
 262 if $GLIBCXX_IS_NATIVE; then
 263
 264   # We can do more elaborate tests that assume a working linker.
 265   CANADIAN=no
 266
 267   GLIBCXX_CHECK_LINKER_FEATURES
 268   GLIBCXX_CHECK_MATH_SUPPORT
 269   GLIBCXX_CHECK_STDLIB_SUPPORT
 270
 271   # For /dev/random and /dev/urandom for std::random_device.
 272   GLIBCXX_CHECK_DEV_RANDOM
 273
 274   # For TLS support.
 275   GCC_CHECK_TLS
 276
 277   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 278   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 279   AC_CHECK_FUNCS(_wfopen)
 280
 281   # C11 functions for C++17 library
 282   AC_CHECK_FUNCS(timespec_get)
 283
 284   # For Networking TS.
 285   AC_CHECK_FUNCS(sockatmark)
 286
 287   # Non-standard functions used by C++17 std::from_chars
 288   AC_CHECK_FUNCS(uselocale)
 289
 290   # For iconv support.
 291   AM_ICONV
 292
 293 else
 294
 295   # This lets us hard-code the functionality we know we'll have in the cross
 296   # target environment.  "Let" is a sugar-coated word placed on an especially
 297   # dull and tedious hack, actually.
 298   #
 299   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 300   # that involve linking, can't be used:
 301   #    "cannot open sim-crt0.o"
 302   #    "cannot open crt0.o"
 303   # etc.  All this is because there currently exists no unified, consistent
 304   # way for top level CC information to be passed down to target directories:
 305   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 306   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 307   # crosses can be removed.
 308
 309   # If Canadian cross, then don't pick up tools from the build directory.
 310   # Used only in GLIBCXX_EXPORT_INCLUDES.
 311   if test -n "$with_cross_host" &&
 312      test x"$build_alias" != x"$with_cross_host" &&
 313      test x"$build" != x"$target";
 314   then
 315     CANADIAN=yes
 316   else
 317     CANADIAN=no
 318   fi
 319
 320   # Construct crosses by hand, eliminating bits that need ld...
 321   # GLIBCXX_CHECK_MATH_SUPPORT
 322
 323   # First, test for "known" system libraries.  We may be using newlib even
 324   # on a hosted environment.
 325   if test "x${with_newlib}" = "xyes"; then
 326     os_include_dir="os/newlib"
 327     AC_DEFINE(HAVE_HYPOT)
 328
 329     # GLIBCXX_CHECK_STDLIB_SUPPORT
 330     AC_DEFINE(HAVE_STRTOF)
 331
 332     AC_DEFINE(HAVE_ACOSF)
 333     AC_DEFINE(HAVE_ASINF)
 334     AC_DEFINE(HAVE_ATAN2F)
 335     AC_DEFINE(HAVE_ATANF)
 336     AC_DEFINE(HAVE_CEILF)
 337     AC_DEFINE(HAVE_COSF)
 338     AC_DEFINE(HAVE_COSHF)
 339     AC_DEFINE(HAVE_EXPF)
 340     AC_DEFINE(HAVE_FABSF)
 341     AC_DEFINE(HAVE_FLOORF)
 342     AC_DEFINE(HAVE_FMODF)
 343     AC_DEFINE(HAVE_FREXPF)
 344     AC_DEFINE(HAVE_LDEXPF)
 345     AC_DEFINE(HAVE_LOG10F)
 346     AC_DEFINE(HAVE_LOGF)
 347     AC_DEFINE(HAVE_MODFF)
 348     AC_DEFINE(HAVE_POWF)
 349     AC_DEFINE(HAVE_SINF)
 350     AC_DEFINE(HAVE_SINHF)
 351     AC_DEFINE(HAVE_SQRTF)
 352     AC_DEFINE(HAVE_TANF)
 353     AC_DEFINE(HAVE_TANHF)
 354
 355     AC_DEFINE(HAVE_ICONV)
 356     AC_DEFINE(HAVE_MEMALIGN)
 357   else
 358     GLIBCXX_CROSSCONFIG
 359   fi
 360
 361   # At some point, we should differentiate between architectures
 362   # like x86, which have long double versions, and alpha/powerpc/etc.,
 363   # which don't. For the time being, punt.
 364   if test x"long_double_math_on_this_cpu" = x"yes"; then
 365     AC_DEFINE(HAVE_ACOSL)
 366     AC_DEFINE(HAVE_ASINL)
 367     AC_DEFINE(HAVE_ATAN2L)
 368     AC_DEFINE(HAVE_ATANL)
 369     AC_DEFINE(HAVE_CEILL)
 370     AC_DEFINE(HAVE_COSL)
 371     AC_DEFINE(HAVE_COSHL)
 372     AC_DEFINE(HAVE_EXPL)
 373     AC_DEFINE(HAVE_FABSL)
 374     AC_DEFINE(HAVE_FLOORL)
 375     AC_DEFINE(HAVE_FMODL)
 376     AC_DEFINE(HAVE_FREXPL)
 377     AC_DEFINE(HAVE_LDEXPL)
 378     AC_DEFINE(HAVE_LOG10L)
 379     AC_DEFINE(HAVE_LOGL)
 380     AC_DEFINE(HAVE_MODFL)
 381     AC_DEFINE(HAVE_POWL)
 382     AC_DEFINE(HAVE_SINCOSL)
 383     AC_DEFINE(HAVE_SINL)
 384     AC_DEFINE(HAVE_SINHL)
 385     AC_DEFINE(HAVE_SQRTL)
 386     AC_DEFINE(HAVE_TANL)
 387     AC_DEFINE(HAVE_TANHL)
 388   fi
 389 fi
 390
 391 # Check for _Unwind_GetIPInfo.
 392 GCC_CHECK_UNWIND_GETIPINFO
 393
 394 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 395
 396 GCC_HEADER_STDINT(include/gstdint.h)
 397
 398 GLIBCXX_ENABLE_SYMVERS([yes])
 399 AC_SUBST(libtool_VERSION)
 400
 401 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 402
 403 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 404 GLIBCXX_DEFAULT_ABI
 405
 406 ac_ldbl_compat=no
 407 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 408 case "$target" in
 409   powerpc*-*-linux* | \
 410   sparc*-*-linux* | \
 411   s390*-*-linux* | \
 412   alpha*-*-linux*)
 413   AC_TRY_COMPILE(, [
 414 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 415 #error no need for long double compatibility
 416 #endif
 417   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 418   if test "$ac_ldbl_compat" = yes; then
 419     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 420               [Define if compatibility should be provided for -mlong-double-64.])
 421     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 422     case "$target" in
 423       powerpc*-*-linux*)
 424         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute" ;;
 425     esac
 426   fi
 427 esac
 428 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 429 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 430
 431 # Check if assembler supports disabling hardware capability support.
 432 GCC_CHECK_ASSEMBLER_HWCAP
 433
 434 # Check if assembler supports rdrand opcode.
 435 GLIBCXX_CHECK_X86_RDRAND
 436 # Check if assembler supports rdseed opcode.
 437 GLIBCXX_CHECK_X86_RDSEED
 438
 439 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 440 GLIBCXX_CONFIGURE_TESTSUITE
 441
 442 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 443 GLIBCXX_CHECK_GTHREADS
 444
 445 # For Filesystem TS.
 446 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 447 GLIBCXX_ENABLE_FILESYSTEM_TS
 448 GLIBCXX_CHECK_FILESYSTEM_DEPS
 449
 450 # For Networking TS.
 451 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 452
 453 # For Transactional Memory TS
 454 GLIBCXX_CHECK_SIZE_T_MANGLING
 455
 456 # Check which release added std::exception_ptr for the target
 457 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 458
 459 # Define documentation rules conditionally.
 460
 461 # See if makeinfo has been installed and is modern enough
 462 # that we can use it.
 463 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 464                    [GNU texinfo.* \([0-9][0-9.]*\)],
 465                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 466 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 467
 468 # Check for doxygen
 469 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 470 AC_CHECK_PROG([DOT], dot, yes, no)
 471
 472 # Check for docbook
 473 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 474 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 475 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 476 GLIBCXX_CONFIGURE_DOCBOOK
 477
 478 # Check for xml/html dependencies.
 479 AM_CONDITIONAL(BUILD_XML,
 480                test $ac_cv_prog_DOXYGEN = "yes" &&
 481                test $ac_cv_prog_DOT = "yes" &&
 482                test $ac_cv_prog_XSLTPROC = "yes" &&
 483                test $ac_cv_prog_XMLLINT = "yes" &&
 484                test $glibcxx_stylesheets = "yes")
 485
 486 AM_CONDITIONAL(BUILD_HTML,
 487                test $ac_cv_prog_DOXYGEN = "yes" &&
 488                test $ac_cv_prog_DOT = "yes" &&
 489                test $ac_cv_prog_XSLTPROC = "yes" &&
 490                test $ac_cv_prog_XMLLINT = "yes" &&
 491                test $glibcxx_stylesheets = "yes")
 492
 493 # Check for man dependencies.
 494 AM_CONDITIONAL(BUILD_MAN,
 495                test $ac_cv_prog_DOXYGEN = "yes" &&
 496                test $ac_cv_prog_DOT = "yes")
 497
 498 # Check for pdf dependencies.
 499 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 500 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 501 AM_CONDITIONAL(BUILD_PDF,
 502                test $ac_cv_prog_DOXYGEN = "yes" &&
 503                test $ac_cv_prog_DOT = "yes" &&
 504                test $ac_cv_prog_XSLTPROC = "yes" &&
 505                test $ac_cv_prog_XMLLINT = "yes" &&
 506                test $ac_cv_prog_DBLATEX = "yes" &&
 507                test $ac_cv_prog_PDFLATEX = "yes")
 508
 509 case "$build" in
 510  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 511  * ) glibcxx_include_dir_notparallel=no ;;
 512 esac
 513 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 514                test $glibcxx_include_dir_notparallel = "yes")
 515
 516 # Propagate the target-specific source directories through the build chain.
 517 ATOMICITY_SRCDIR=config/${atomicity_dir}
 518 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 519 ATOMIC_FLAGS=${atomic_flags}
 520 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 521 OS_INC_SRCDIR=config/${os_include_dir}
 522 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 523 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 524 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 525 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 526 AC_SUBST(ATOMICITY_SRCDIR)
 527 AC_SUBST(ATOMIC_WORD_SRCDIR)
 528 AC_SUBST(ATOMIC_FLAGS)
 529 AC_SUBST(CPU_DEFINES_SRCDIR)
 530 AC_SUBST(ABI_TWEAKS_SRCDIR)
 531 AC_SUBST(OS_INC_SRCDIR)
 532 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 533 AC_SUBST(CPU_OPT_EXT_RANDOM)
 534 AC_SUBST(CPU_OPT_BITS_RANDOM)
 535
 536 # Conditionalize the makefile for this target machine.
 537 tmake_file_=
 538 for f in ${tmake_file}
 539 do
 540         if test -f ${srcdir}/config/$f
 541         then
 542                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 543         fi
 544 done
 545 tmake_file="${tmake_file_}"
 546 AC_SUBST(tmake_file)
 547
 548 # Add CET specific flags if Intel CET is enabled.
 549 GCC_CET_FLAGS(CET_FLAGS)
 550 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 551 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 552 AC_SUBST(EXTRA_CFLAGS)
 553 AC_SUBST(EXTRA_CXX_FLAGS)
 554
 555 # Determine cross-compile flags and AM_CONDITIONALs.
 556 #AC_SUBST(GLIBCXX_IS_NATIVE)
 557 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 558 GLIBCXX_EVALUATE_CONDITIONALS
 559
 560 AC_CACHE_SAVE
 561
 562 if test ${multilib} = yes; then
 563   multilib_arg="--enable-multilib"
 564 else
 565   multilib_arg=
 566 fi
 567
 568 # Export all the install information.
 569 GLIBCXX_EXPORT_INSTALL_INFO
 570
 571 # Export all the include and flag information to Makefiles.
 572 GLIBCXX_EXPORT_INCLUDES
 573 GLIBCXX_EXPORT_FLAGS
 574
 575 # Determine what GCC version number to use in filesystem paths.
 576 GCC_BASE_VER
 577
 578 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 579 dnl which can all be called multiple times as needed, plus one (different)
 580 dnl AC_OUTPUT macro.  This one lists the files to be created:
 581 AC_CONFIG_FILES(Makefile)
 582 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 583 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 584 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 585
 586 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 587 # that multilib installs will end up installed in the correct place.
 588 # The testsuite needs it for multilib-aware ABI baseline files.
 589 # To work around this not being passed down from config-ml.in ->
 590 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 591 # append it here.  Only modify Makefiles that have just been created.
 592 #
 593 # Also, get rid of this simulated-VPATH thing that automake does.
 594 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 595   [cat > vpsed$$ << \_EOF
 596 s!`test -f '$<' || echo '$(srcdir)/'`!!
 597 _EOF
 598    sed -f vpsed$$ $ac_file > tmp$$
 599    mv tmp$$ $ac_file
 600    rm vpsed$$
 601    echo 'MULTISUBDIR =' >> $ac_file
 602    ml_norecursion=yes
 603    . ${multi_basedir}/config-ml.in
 604    AS_UNSET([ml_norecursion])
 605 ])
 606
 607 AC_CONFIG_COMMANDS([generate-headers],
 608   [(cd include && ${MAKE-make} pch_build= )])
 609
 610 dnl And this actually makes things happen:
 611 AC_OUTPUT