libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 # Libtool setup.
  92 if test "x${with_newlib}" != "xyes"; then
  93   AC_LIBTOOL_DLOPEN
  94 fi
  95 AM_PROG_LIBTOOL
  96 ACX_LT_HOST_FLAGS
  97 AC_SUBST(enable_shared)
  98 AC_SUBST(enable_static)
  99
 100 if test "$enable_vtable_verify" = yes; then
 101   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 102   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 103 fi
 104
 105
 106 # libtool variables for C++ shared and position-independent compiles.
 107 #
 108 # Use glibcxx_lt_pic_flag to designate the automake variable
 109 # used to encapsulate the default libtool approach to creating objects
 110 # with position-independent code. Default: -prefer-pic.
 111 #
 112 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 113 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 114 #
 115 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 116 # creating position-independent objects. This varies with the target
 117 # hardware and operating system, but is often: -DPIC -fPIC.
 118 if test "$enable_shared" = yes; then
 119   glibcxx_lt_pic_flag="-prefer-pic"
 120   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 121   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 122
 123 else
 124   glibcxx_lt_pic_flag=
 125   glibcxx_compiler_pic_flag=
 126   glibcxx_compiler_shared_flag=
 127 fi
 128 AC_SUBST(glibcxx_lt_pic_flag)
 129 AC_SUBST(glibcxx_compiler_pic_flag)
 130 AC_SUBST(glibcxx_compiler_shared_flag)
 131
 132 # Override the libtool's pic_flag and pic_mode.
 133 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 134 # NB: this impacts --with-pic and --without-pic.
 135 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 136 pic_mode='default'
 137
 138 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 139 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 140
 141 # Possibly disable most of the library.
 142 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 143 ## than just ignoring the results.  Faster /and/ more correct, win win.
 144 GLIBCXX_ENABLE_HOSTED
 145
 146 # Enable descriptive messages to standard output on termination.
 147 GLIBCXX_ENABLE_VERBOSE
 148
 149 # Enable compiler support that doesn't require linking.
 150 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 151 GLIBCXX_ENABLE_PCH($is_hosted)
 152 GLIBCXX_ENABLE_THREADS
 153 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 154 GLIBCXX_ENABLE_DECIMAL_FLOAT
 155 GLIBCXX_ENABLE_INT128_FLOAT128
 156
 157 # Checks for compiler support that doesn't require linking.
 158 GLIBCXX_CHECK_COMPILER_FEATURES
 159
 160 # Enable all the variable C++ runtime options that don't require linking.
 161 GLIBCXX_ENABLE_CSTDIO
 162 GLIBCXX_ENABLE_CLOCALE
 163 GLIBCXX_ENABLE_ALLOCATOR
 164 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 165 GLIBCXX_ENABLE_LONG_LONG([yes])
 166 GLIBCXX_ENABLE_WCHAR_T([yes])
 167 GLIBCXX_ENABLE_C99([yes])
 168 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 169 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 170 GLIBCXX_ENABLE_DEBUG([no])
 171 GLIBCXX_ENABLE_PARALLEL([yes])
 172 GLIBCXX_ENABLE_CXX_FLAGS
 173 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 174 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 175 GLIBCXX_ENABLE_PYTHON
 176 GLIBCXX_ENABLE_WERROR([yes])
 177 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 178
 179 # Checks for operating systems support that doesn't require linking.
 180 GLIBCXX_CHECK_STDIO_PROTO
 181 GLIBCXX_CHECK_SYSTEM_ERROR
 182
 183 # For the streamoff typedef.
 184 GLIBCXX_CHECK_INT64_T
 185
 186 # For LFS support.
 187 GLIBCXX_CHECK_LFS
 188
 189 # For showmanyc_helper().
 190 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 191 GLIBCXX_CHECK_POLL
 192 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 193
 194 # For xsputn_2().
 195 AC_CHECK_HEADERS(sys/uio.h)
 196 GLIBCXX_CHECK_WRITEV
 197
 198 # For C99 support to TR1.
 199 GLIBCXX_CHECK_C99_TR1
 200
 201 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 202 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 203
 204 # For gettimeofday support.
 205 GLIBCXX_CHECK_GETTIMEOFDAY
 206
 207 # For clock_gettime, nanosleep and sched_yield support.
 208 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 209
 210 AC_LC_MESSAGES
 211
 212 # For hardware_concurrency
 213 AC_CHECK_HEADERS(sys/sysinfo.h)
 214 GLIBCXX_CHECK_GET_NPROCS
 215 AC_CHECK_HEADERS(unistd.h)
 216 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 217 GLIBCXX_CHECK_SC_NPROC_ONLN
 218 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 219 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 220 GLIBCXX_CHECK_SDT_H
 221
 222 # Check for available headers.
 223 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 224 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 225 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 226 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 227 wchar.h wctype.h])
 228
 229 # Only do link tests if native. Else, hardcode.
 230 if $GLIBCXX_IS_NATIVE; then
 231
 232   # We can do more elaborate tests that assume a working linker.
 233   CANADIAN=no
 234
 235   GLIBCXX_CHECK_LINKER_FEATURES
 236   GLIBCXX_CHECK_MATH_SUPPORT
 237   GLIBCXX_CHECK_STDLIB_SUPPORT
 238
 239   # For /dev/random and /dev/urandom for TR1.
 240   GLIBCXX_CHECK_RANDOM_TR1
 241
 242   # For TLS support.
 243   GCC_CHECK_TLS
 244
 245   AC_CHECK_FUNCS(__cxa_thread_atexit_impl)
 246
 247   # For iconv support.
 248   AM_ICONV
 249
 250 else
 251
 252   # This lets us hard-code the functionality we know we'll have in the cross
 253   # target environment.  "Let" is a sugar-coated word placed on an especially
 254   # dull and tedious hack, actually.
 255   #
 256   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 257   # that involve linking, can't be used:
 258   #    "cannot open sim-crt0.o"
 259   #    "cannot open crt0.o"
 260   # etc.  All this is because there currently exists no unified, consistent
 261   # way for top level CC information to be passed down to target directories:
 262   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 263   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 264   # crosses can be removed.
 265
 266   # If Canadian cross, then don't pick up tools from the build directory.
 267   # Used only in GLIBCXX_EXPORT_INCLUDES.
 268   if test -n "$with_cross_host" &&
 269      test x"$build_alias" != x"$with_cross_host" &&
 270      test x"$build" != x"$target";
 271   then
 272     CANADIAN=yes
 273   else
 274     CANADIAN=no
 275   fi
 276
 277   # Construct crosses by hand, eliminating bits that need ld...
 278   # GLIBCXX_CHECK_MATH_SUPPORT
 279
 280   # First, test for "known" system libraries.  We may be using newlib even
 281   # on a hosted environment.
 282   if test "x${with_newlib}" = "xyes"; then
 283     os_include_dir="os/newlib"
 284     AC_DEFINE(HAVE_HYPOT)
 285
 286     # GLIBCXX_CHECK_STDLIB_SUPPORT
 287     AC_DEFINE(HAVE_STRTOF)
 288
 289     AC_DEFINE(HAVE_ACOSF)
 290     AC_DEFINE(HAVE_ASINF)
 291     AC_DEFINE(HAVE_ATAN2F)
 292     AC_DEFINE(HAVE_ATANF)
 293     AC_DEFINE(HAVE_CEILF)
 294     AC_DEFINE(HAVE_COSF)
 295     AC_DEFINE(HAVE_COSHF)
 296     AC_DEFINE(HAVE_EXPF)
 297     AC_DEFINE(HAVE_FABSF)
 298     AC_DEFINE(HAVE_FLOORF)
 299     AC_DEFINE(HAVE_FMODF)
 300     AC_DEFINE(HAVE_FREXPF)
 301     AC_DEFINE(HAVE_LDEXPF)
 302     AC_DEFINE(HAVE_LOG10F)
 303     AC_DEFINE(HAVE_LOGF)
 304     AC_DEFINE(HAVE_MODFF)
 305     AC_DEFINE(HAVE_POWF)
 306     AC_DEFINE(HAVE_SINF)
 307     AC_DEFINE(HAVE_SINHF)
 308     AC_DEFINE(HAVE_SQRTF)
 309     AC_DEFINE(HAVE_TANF)
 310     AC_DEFINE(HAVE_TANHF)
 311
 312     AC_DEFINE(HAVE_ICONV)
 313   else
 314     GLIBCXX_CROSSCONFIG
 315   fi
 316
 317   # At some point, we should differentiate between architectures
 318   # like x86, which have long double versions, and alpha/powerpc/etc.,
 319   # which don't. For the time being, punt.
 320   if test x"long_double_math_on_this_cpu" = x"yes"; then
 321     AC_DEFINE(HAVE_ACOSL)
 322     AC_DEFINE(HAVE_ASINL)
 323     AC_DEFINE(HAVE_ATAN2L)
 324     AC_DEFINE(HAVE_ATANL)
 325     AC_DEFINE(HAVE_CEILL)
 326     AC_DEFINE(HAVE_COSL)
 327     AC_DEFINE(HAVE_COSHL)
 328     AC_DEFINE(HAVE_EXPL)
 329     AC_DEFINE(HAVE_FABSL)
 330     AC_DEFINE(HAVE_FLOORL)
 331     AC_DEFINE(HAVE_FMODL)
 332     AC_DEFINE(HAVE_FREXPL)
 333     AC_DEFINE(HAVE_LDEXPL)
 334     AC_DEFINE(HAVE_LOG10L)
 335     AC_DEFINE(HAVE_LOGL)
 336     AC_DEFINE(HAVE_MODFL)
 337     AC_DEFINE(HAVE_POWL)
 338     AC_DEFINE(HAVE_SINCOSL)
 339     AC_DEFINE(HAVE_SINL)
 340     AC_DEFINE(HAVE_SINHL)
 341     AC_DEFINE(HAVE_SQRTL)
 342     AC_DEFINE(HAVE_TANL)
 343     AC_DEFINE(HAVE_TANHL)
 344   fi
 345 fi
 346
 347 # Check for _Unwind_GetIPInfo.
 348 GCC_CHECK_UNWIND_GETIPINFO
 349
 350 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 351
 352 GCC_HEADER_STDINT(include/gstdint.h)
 353
 354 GLIBCXX_ENABLE_SYMVERS([yes])
 355 AC_SUBST(libtool_VERSION)
 356
 357 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 358
 359 ac_ldbl_compat=no
 360 case "$target" in
 361   powerpc*-*-linux* | \
 362   sparc*-*-linux* | \
 363   s390*-*-linux* | \
 364   alpha*-*-linux*)
 365   AC_TRY_COMPILE(, [
 366 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 367 #error no need for long double compatibility
 368 #endif
 369   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 370   if test "$ac_ldbl_compat" = yes; then
 371     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 372               [Define if compatibility should be provided for -mlong-double-64.])
 373     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 374   fi
 375 esac
 376 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 377
 378 # Check if assembler supports disabling hardware capability support.
 379 GLIBCXX_CHECK_ASSEMBLER_HWCAP
 380
 381 # Check if assembler supports rdrand opcode.
 382 GLIBCXX_CHECK_X86_RDRAND
 383
 384 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 385 GLIBCXX_CONFIGURE_TESTSUITE
 386
 387 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 388 GLIBCXX_CHECK_GTHREADS
 389
 390 # Define documentation rules conditionally.
 391
 392 # See if makeinfo has been installed and is modern enough
 393 # that we can use it.
 394 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 395                    [GNU texinfo.* \([0-9][0-9.]*\)],
 396                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 397 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 398
 399 # Check for doxygen
 400 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 401 AC_CHECK_PROG([DOT], dot, yes, no)
 402
 403 # Check for docbook
 404 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 405 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 406 GLIBCXX_CONFIGURE_DOCBOOK
 407
 408 # Check for xml/html dependencies.
 409 AM_CONDITIONAL(BUILD_XML,
 410                test $ac_cv_prog_DOXYGEN = "yes" &&
 411                test $ac_cv_prog_DOT = "yes" &&
 412                test $ac_cv_prog_XSLTPROC = "yes" &&
 413                test $ac_cv_prog_XMLLINT = "yes" &&
 414                test $glibcxx_stylesheets = "yes")
 415
 416 AM_CONDITIONAL(BUILD_HTML,
 417                test $ac_cv_prog_DOXYGEN = "yes" &&
 418                test $ac_cv_prog_DOT = "yes" &&
 419                test $ac_cv_prog_XSLTPROC = "yes" &&
 420                test $ac_cv_prog_XMLLINT = "yes" &&
 421                test $glibcxx_stylesheets = "yes")
 422
 423 # Check for man dependencies.
 424 AM_CONDITIONAL(BUILD_MAN,
 425                test $ac_cv_prog_DOXYGEN = "yes" &&
 426                test $ac_cv_prog_DOT = "yes")
 427
 428 # Check for pdf dependencies.
 429 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 430 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 431 AM_CONDITIONAL(BUILD_PDF,
 432                test $ac_cv_prog_DBLATEX = "yes" &&
 433                test $ac_cv_prog_PDFLATEX = "yes")
 434
 435
 436 # Propagate the target-specific source directories through the build chain.
 437 ATOMICITY_SRCDIR=config/${atomicity_dir}
 438 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 439 ATOMIC_FLAGS=${atomic_flags}
 440 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 441 OS_INC_SRCDIR=config/${os_include_dir}
 442 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 443 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 444 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 445 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 446 AC_SUBST(ATOMICITY_SRCDIR)
 447 AC_SUBST(ATOMIC_WORD_SRCDIR)
 448 AC_SUBST(ATOMIC_FLAGS)
 449 AC_SUBST(CPU_DEFINES_SRCDIR)
 450 AC_SUBST(ABI_TWEAKS_SRCDIR)
 451 AC_SUBST(OS_INC_SRCDIR)
 452 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 453 AC_SUBST(CPU_OPT_EXT_RANDOM)
 454 AC_SUBST(CPU_OPT_BITS_RANDOM)
 455
 456
 457 # Determine cross-compile flags and AM_CONDITIONALs.
 458 #AC_SUBST(GLIBCXX_IS_NATIVE)
 459 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 460 GLIBCXX_EVALUATE_CONDITIONALS
 461
 462 AC_CACHE_SAVE
 463
 464 if test ${multilib} = yes; then
 465   multilib_arg="--enable-multilib"
 466 else
 467   multilib_arg=
 468 fi
 469
 470 # Export all the install information.
 471 GLIBCXX_EXPORT_INSTALL_INFO
 472
 473 # Export all the include and flag information to Makefiles.
 474 GLIBCXX_EXPORT_INCLUDES
 475 GLIBCXX_EXPORT_FLAGS
 476
 477 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 478 dnl which can all be called multiple times as needed, plus one (different)
 479 dnl AC_OUTPUT macro.  This one lists the files to be created:
 480 AC_CONFIG_FILES(Makefile)
 481 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 482 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 483 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 484
 485 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 486 # that multilib installs will end up installed in the correct place.
 487 # The testsuite needs it for multilib-aware ABI baseline files.
 488 # To work around this not being passed down from config-ml.in ->
 489 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 490 # append it here.  Only modify Makefiles that have just been created.
 491 #
 492 # Also, get rid of this simulated-VPATH thing that automake does.
 493 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 494   [cat > vpsed$$ << \_EOF
 495 s!`test -f '$<' || echo '$(srcdir)/'`!!
 496 _EOF
 497    sed -f vpsed$$ $ac_file > tmp$$
 498    mv tmp$$ $ac_file
 499    rm vpsed$$
 500    echo 'MULTISUBDIR =' >> $ac_file
 501    ml_norecursion=yes
 502    . ${multi_basedir}/config-ml.in
 503    AS_UNSET([ml_norecursion])
 504 ])
 505
 506 AC_CONFIG_COMMANDS([generate-headers],
 507   [(cd include && ${MAKE-make} pch_build= )])
 508
 509 dnl And this actually makes things happen:
 510 AC_OUTPUT