libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  62 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  63 #  1.x:  minimum required version
  64 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  65 #              of other PACKAGE_* variables will, however, and there's nothing
  66 #              we can do about that; they come from AC_INIT).
  67 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  68 #            file in the top srcdir, etc, etc), so stop complaining.
  69 #  no-dependencies:  turns off auto dependency generation (just for now)
  70 #  no-dist:  we don't want 'dist' and related rules.
  71 #  -Wall:  turns on all automake warnings...
  72 #  -Wno-portability:  ...except this one, since GNU make is now required.
  73 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  74 AH_TEMPLATE(PACKAGE, [Name of package])
  75 AH_TEMPLATE(VERSION, [Version number of package])
  76
  77 # -fno-builtin must be present here so that a non-conflicting form of
  78 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  79
  80 save_CXXFLAGS="$CXXFLAGS"
  81 CXXFLAGS="$CXXFLAGS -fno-builtin"
  82 AC_PROG_CC
  83 AC_PROG_CXX
  84 CXXFLAGS="$save_CXXFLAGS"
  85
  86 # Runs configure.host, and assorted other critical bits.  Sets
  87 # up critical shell variables.
  88 GLIBCXX_CONFIGURE
  89
  90 # Libtool setup.
  91 if test "x${with_newlib}" != "xyes"; then
  92   AC_LIBTOOL_DLOPEN
  93 fi
  94 AM_PROG_LIBTOOL
  95 ACX_LT_HOST_FLAGS
  96 AC_SUBST(enable_shared)
  97 AC_SUBST(enable_static)
  98
  99 if test "$enable_vtable_verify" = yes; then
 100   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 101   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 102 fi
 103
 104
 105 # libtool variables for C++ shared and position-independent compiles.
 106 #
 107 # Use glibcxx_lt_pic_flag to designate the automake variable
 108 # used to encapsulate the default libtool approach to creating objects
 109 # with position-independent code. Default: -prefer-pic.
 110 #
 111 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 112 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 113 #
 114 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 115 # creating position-independent objects. This varies with the target
 116 # hardware and operating system, but is often: -DPIC -fPIC.
 117 if test "$enable_shared" = yes; then
 118   glibcxx_lt_pic_flag="-prefer-pic"
 119   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 120   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 121
 122 else
 123   glibcxx_lt_pic_flag=
 124   glibcxx_compiler_pic_flag=
 125   glibcxx_compiler_shared_flag=
 126 fi
 127 AC_SUBST(glibcxx_lt_pic_flag)
 128 AC_SUBST(glibcxx_compiler_pic_flag)
 129 AC_SUBST(glibcxx_compiler_shared_flag)
 130
 131 # Override the libtool's pic_flag and pic_mode.
 132 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 133 # NB: this impacts --with-pic and --without-pic.
 134 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 135 pic_mode='default'
 136
 137 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 138 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 139
 140 # Possibly disable most of the library.
 141 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 142 ## than just ignoring the results.  Faster /and/ more correct, win win.
 143 GLIBCXX_ENABLE_HOSTED
 144
 145 # Enable descriptive messages to standard output on termination.
 146 GLIBCXX_ENABLE_VERBOSE
 147
 148 # Enable compiler support that doesn't require linking.
 149 GLIBCXX_ENABLE_PCH($is_hosted)
 150 GLIBCXX_ENABLE_THREADS
 151 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 152 GLIBCXX_ENABLE_LOCK_POLICY
 153 GLIBCXX_ENABLE_DECIMAL_FLOAT
 154 GLIBCXX_ENABLE_INT128_FLOAT128
 155 if test "$enable_float128" = yes; then
 156   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 157 fi
 158
 159 # Checks for compiler support that doesn't require linking.
 160 GLIBCXX_CHECK_COMPILER_FEATURES
 161
 162 # Enable all the variable C++ runtime options that don't require linking.
 163 GLIBCXX_ENABLE_CSTDIO
 164 GLIBCXX_ENABLE_CLOCALE
 165 GLIBCXX_ENABLE_ALLOCATOR
 166 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 167 GLIBCXX_ENABLE_LONG_LONG([yes])
 168 GLIBCXX_ENABLE_WCHAR_T([yes])
 169 GLIBCXX_ENABLE_C99([yes])
 170 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 171 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 172 GLIBCXX_ENABLE_DEBUG([no])
 173 GLIBCXX_ENABLE_PARALLEL([yes])
 174 GLIBCXX_ENABLE_CXX_FLAGS
 175 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 176 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 177 GLIBCXX_ENABLE_PYTHON
 178 GLIBCXX_ENABLE_WERROR([no])
 179 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 180
 181 # Checks for operating systems support that doesn't require linking.
 182 GLIBCXX_CHECK_STDIO_PROTO
 183 GLIBCXX_CHECK_MATH11_PROTO
 184 GLIBCXX_CHECK_SYSTEM_ERROR
 185 GLIBCXX_CHECK_UCHAR_H
 186
 187 # For the streamoff typedef.
 188 GLIBCXX_CHECK_INT64_T
 189
 190 # For LFS support.
 191 GLIBCXX_CHECK_LFS
 192
 193 # For showmanyc_helper().
 194 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 195 GLIBCXX_CHECK_POLL
 196 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 197
 198 # For xsputn_2().
 199 AC_CHECK_HEADERS(sys/uio.h)
 200 GLIBCXX_CHECK_WRITEV
 201
 202 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 203 # so that the check is done with the C compiler (not C++).
 204 # Checking with C++ can break a canadian cross build if either
 205 # file does not exist in C but does in C++.
 206 AC_CHECK_HEADERS(fenv.h complex.h)
 207
 208 # For C99 support to TR1.
 209 GLIBCXX_CHECK_C99_TR1
 210
 211 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 212 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 213
 214 # For gettimeofday support.
 215 GLIBCXX_CHECK_GETTIMEOFDAY
 216
 217 # For clock_gettime, nanosleep and sched_yield support.
 218 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 219
 220 # Check for tmpnam which is obsolescent in POSIX.1-2008
 221 GLIBCXX_CHECK_TMPNAM
 222
 223 AC_LC_MESSAGES
 224
 225 # For hardware_concurrency
 226 AC_CHECK_HEADERS(sys/sysinfo.h)
 227 GLIBCXX_CHECK_GET_NPROCS
 228 AC_CHECK_HEADERS(unistd.h)
 229 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 230 GLIBCXX_CHECK_SC_NPROC_ONLN
 231 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 232 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 233 GLIBCXX_CHECK_SDT_H
 234
 235 # Check for available headers.
 236 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 237 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 238 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 239 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 240 wchar.h wctype.h linux/types.h])
 241
 242 AC_CHECK_HEADERS([linux/random.h], [], [],
 243 [[#ifdef HAVE_LINUX_TYPES_H
 244 # include <linux/types.h>
 245 #endif
 246 ]])
 247
 248 # Only do link tests if native. Else, hardcode.
 249 if $GLIBCXX_IS_NATIVE; then
 250
 251   # We can do more elaborate tests that assume a working linker.
 252   CANADIAN=no
 253
 254   GLIBCXX_CHECK_LINKER_FEATURES
 255   GLIBCXX_CHECK_MATH_SUPPORT
 256   GLIBCXX_CHECK_STDLIB_SUPPORT
 257
 258   # For /dev/random and /dev/urandom for std::random_device.
 259   GLIBCXX_CHECK_DEV_RANDOM
 260
 261   # For TLS support.
 262   GCC_CHECK_TLS
 263
 264   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 265   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 266   AC_CHECK_FUNCS(_wfopen)
 267
 268   # C11 functions for C++17 library
 269   AC_CHECK_FUNCS(timespec_get)
 270
 271   # For iconv support.
 272   AM_ICONV
 273
 274 else
 275
 276   # This lets us hard-code the functionality we know we'll have in the cross
 277   # target environment.  "Let" is a sugar-coated word placed on an especially
 278   # dull and tedious hack, actually.
 279   #
 280   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 281   # that involve linking, can't be used:
 282   #    "cannot open sim-crt0.o"
 283   #    "cannot open crt0.o"
 284   # etc.  All this is because there currently exists no unified, consistent
 285   # way for top level CC information to be passed down to target directories:
 286   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 287   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 288   # crosses can be removed.
 289
 290   # If Canadian cross, then don't pick up tools from the build directory.
 291   # Used only in GLIBCXX_EXPORT_INCLUDES.
 292   if test -n "$with_cross_host" &&
 293      test x"$build_alias" != x"$with_cross_host" &&
 294      test x"$build" != x"$target";
 295   then
 296     CANADIAN=yes
 297   else
 298     CANADIAN=no
 299   fi
 300
 301   # Construct crosses by hand, eliminating bits that need ld...
 302   # GLIBCXX_CHECK_MATH_SUPPORT
 303
 304   # First, test for "known" system libraries.  We may be using newlib even
 305   # on a hosted environment.
 306   if test "x${with_newlib}" = "xyes"; then
 307     os_include_dir="os/newlib"
 308     AC_DEFINE(HAVE_HYPOT)
 309
 310     # GLIBCXX_CHECK_STDLIB_SUPPORT
 311     AC_DEFINE(HAVE_STRTOF)
 312
 313     AC_DEFINE(HAVE_ACOSF)
 314     AC_DEFINE(HAVE_ASINF)
 315     AC_DEFINE(HAVE_ATAN2F)
 316     AC_DEFINE(HAVE_ATANF)
 317     AC_DEFINE(HAVE_CEILF)
 318     AC_DEFINE(HAVE_COSF)
 319     AC_DEFINE(HAVE_COSHF)
 320     AC_DEFINE(HAVE_EXPF)
 321     AC_DEFINE(HAVE_FABSF)
 322     AC_DEFINE(HAVE_FLOORF)
 323     AC_DEFINE(HAVE_FMODF)
 324     AC_DEFINE(HAVE_FREXPF)
 325     AC_DEFINE(HAVE_LDEXPF)
 326     AC_DEFINE(HAVE_LOG10F)
 327     AC_DEFINE(HAVE_LOGF)
 328     AC_DEFINE(HAVE_MODFF)
 329     AC_DEFINE(HAVE_POWF)
 330     AC_DEFINE(HAVE_SINF)
 331     AC_DEFINE(HAVE_SINHF)
 332     AC_DEFINE(HAVE_SQRTF)
 333     AC_DEFINE(HAVE_TANF)
 334     AC_DEFINE(HAVE_TANHF)
 335
 336     AC_DEFINE(HAVE_ICONV)
 337     AC_DEFINE(HAVE_MEMALIGN)
 338   else
 339     GLIBCXX_CROSSCONFIG
 340   fi
 341
 342   # At some point, we should differentiate between architectures
 343   # like x86, which have long double versions, and alpha/powerpc/etc.,
 344   # which don't. For the time being, punt.
 345   if test x"long_double_math_on_this_cpu" = x"yes"; then
 346     AC_DEFINE(HAVE_ACOSL)
 347     AC_DEFINE(HAVE_ASINL)
 348     AC_DEFINE(HAVE_ATAN2L)
 349     AC_DEFINE(HAVE_ATANL)
 350     AC_DEFINE(HAVE_CEILL)
 351     AC_DEFINE(HAVE_COSL)
 352     AC_DEFINE(HAVE_COSHL)
 353     AC_DEFINE(HAVE_EXPL)
 354     AC_DEFINE(HAVE_FABSL)
 355     AC_DEFINE(HAVE_FLOORL)
 356     AC_DEFINE(HAVE_FMODL)
 357     AC_DEFINE(HAVE_FREXPL)
 358     AC_DEFINE(HAVE_LDEXPL)
 359     AC_DEFINE(HAVE_LOG10L)
 360     AC_DEFINE(HAVE_LOGL)
 361     AC_DEFINE(HAVE_MODFL)
 362     AC_DEFINE(HAVE_POWL)
 363     AC_DEFINE(HAVE_SINCOSL)
 364     AC_DEFINE(HAVE_SINL)
 365     AC_DEFINE(HAVE_SINHL)
 366     AC_DEFINE(HAVE_SQRTL)
 367     AC_DEFINE(HAVE_TANL)
 368     AC_DEFINE(HAVE_TANHL)
 369   fi
 370 fi
 371
 372 # Check for _Unwind_GetIPInfo.
 373 GCC_CHECK_UNWIND_GETIPINFO
 374
 375 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 376
 377 GCC_HEADER_STDINT(include/gstdint.h)
 378
 379 GLIBCXX_ENABLE_SYMVERS([yes])
 380 AC_SUBST(libtool_VERSION)
 381
 382 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 383
 384 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 385 GLIBCXX_DEFAULT_ABI
 386
 387 ac_ldbl_compat=no
 388 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 389 case "$target" in
 390   powerpc*-*-linux* | \
 391   sparc*-*-linux* | \
 392   s390*-*-linux* | \
 393   alpha*-*-linux*)
 394   AC_TRY_COMPILE(, [
 395 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 396 #error no need for long double compatibility
 397 #endif
 398   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 399   if test "$ac_ldbl_compat" = yes; then
 400     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 401               [Define if compatibility should be provided for -mlong-double-64.])
 402     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 403     case "$target" in
 404       powerpc*-*-linux*)
 405         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute" ;;
 406     esac
 407   fi
 408 esac
 409 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 410 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 411
 412 # Check if assembler supports disabling hardware capability support.
 413 GCC_CHECK_ASSEMBLER_HWCAP
 414
 415 # Check if assembler supports rdrand opcode.
 416 GLIBCXX_CHECK_X86_RDRAND
 417
 418 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 419 GLIBCXX_CONFIGURE_TESTSUITE
 420
 421 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 422 GLIBCXX_CHECK_GTHREADS
 423
 424 # For Filesystem TS.
 425 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 426 GLIBCXX_ENABLE_FILESYSTEM_TS
 427 GLIBCXX_CHECK_FILESYSTEM_DEPS
 428
 429 # For Networking TS.
 430 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 431
 432 # For Transactional Memory TS
 433 GLIBCXX_CHECK_SIZE_T_MANGLING
 434
 435 # Check which release added std::exception_ptr for the target
 436 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 437
 438 # Define documentation rules conditionally.
 439
 440 # See if makeinfo has been installed and is modern enough
 441 # that we can use it.
 442 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 443                    [GNU texinfo.* \([0-9][0-9.]*\)],
 444                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 445 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 446
 447 # Check for doxygen
 448 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 449 AC_CHECK_PROG([DOT], dot, yes, no)
 450
 451 # Check for docbook
 452 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 453 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 454 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 455 GLIBCXX_CONFIGURE_DOCBOOK
 456
 457 # Check for xml/html dependencies.
 458 AM_CONDITIONAL(BUILD_XML,
 459                test $ac_cv_prog_DOXYGEN = "yes" &&
 460                test $ac_cv_prog_DOT = "yes" &&
 461                test $ac_cv_prog_XSLTPROC = "yes" &&
 462                test $ac_cv_prog_XMLLINT = "yes" &&
 463                test $glibcxx_stylesheets = "yes")
 464
 465 AM_CONDITIONAL(BUILD_HTML,
 466                test $ac_cv_prog_DOXYGEN = "yes" &&
 467                test $ac_cv_prog_DOT = "yes" &&
 468                test $ac_cv_prog_XSLTPROC = "yes" &&
 469                test $ac_cv_prog_XMLLINT = "yes" &&
 470                test $glibcxx_stylesheets = "yes")
 471
 472 # Check for man dependencies.
 473 AM_CONDITIONAL(BUILD_MAN,
 474                test $ac_cv_prog_DOXYGEN = "yes" &&
 475                test $ac_cv_prog_DOT = "yes")
 476
 477 # Check for pdf dependencies.
 478 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 479 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 480 AM_CONDITIONAL(BUILD_PDF,
 481                test $ac_cv_prog_DBLATEX = "yes" &&
 482                test $ac_cv_prog_PDFLATEX = "yes")
 483
 484 case "$build" in
 485  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 486  * ) glibcxx_include_dir_notparallel=no ;;
 487 esac
 488 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 489                test $glibcxx_include_dir_notparallel = "yes")
 490
 491 # Propagate the target-specific source directories through the build chain.
 492 ATOMICITY_SRCDIR=config/${atomicity_dir}
 493 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 494 ATOMIC_FLAGS=${atomic_flags}
 495 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 496 OS_INC_SRCDIR=config/${os_include_dir}
 497 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 498 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 499 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 500 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 501 AC_SUBST(ATOMICITY_SRCDIR)
 502 AC_SUBST(ATOMIC_WORD_SRCDIR)
 503 AC_SUBST(ATOMIC_FLAGS)
 504 AC_SUBST(CPU_DEFINES_SRCDIR)
 505 AC_SUBST(ABI_TWEAKS_SRCDIR)
 506 AC_SUBST(OS_INC_SRCDIR)
 507 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 508 AC_SUBST(CPU_OPT_EXT_RANDOM)
 509 AC_SUBST(CPU_OPT_BITS_RANDOM)
 510
 511
 512 # Add CET specific flags if Intel CET is enabled.
 513 GCC_CET_FLAGS(CET_FLAGS)
 514 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 515 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 516 AC_SUBST(EXTRA_CFLAGS)
 517 AC_SUBST(EXTRA_CXX_FLAGS)
 518
 519 # Determine cross-compile flags and AM_CONDITIONALs.
 520 #AC_SUBST(GLIBCXX_IS_NATIVE)
 521 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 522 GLIBCXX_EVALUATE_CONDITIONALS
 523
 524 AC_CACHE_SAVE
 525
 526 if test ${multilib} = yes; then
 527   multilib_arg="--enable-multilib"
 528 else
 529   multilib_arg=
 530 fi
 531
 532 # Export all the install information.
 533 GLIBCXX_EXPORT_INSTALL_INFO
 534
 535 # Export all the include and flag information to Makefiles.
 536 GLIBCXX_EXPORT_INCLUDES
 537 GLIBCXX_EXPORT_FLAGS
 538
 539 # Determine what GCC version number to use in filesystem paths.
 540 GCC_BASE_VER
 541
 542 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 543 dnl which can all be called multiple times as needed, plus one (different)
 544 dnl AC_OUTPUT macro.  This one lists the files to be created:
 545 AC_CONFIG_FILES(Makefile)
 546 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 547 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 548 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 549
 550 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 551 # that multilib installs will end up installed in the correct place.
 552 # The testsuite needs it for multilib-aware ABI baseline files.
 553 # To work around this not being passed down from config-ml.in ->
 554 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 555 # append it here.  Only modify Makefiles that have just been created.
 556 #
 557 # Also, get rid of this simulated-VPATH thing that automake does.
 558 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 559   [cat > vpsed$$ << \_EOF
 560 s!`test -f '$<' || echo '$(srcdir)/'`!!
 561 _EOF
 562    sed -f vpsed$$ $ac_file > tmp$$
 563    mv tmp$$ $ac_file
 564    rm vpsed$$
 565    echo 'MULTISUBDIR =' >> $ac_file
 566    ml_norecursion=yes
 567    . ${multi_basedir}/config-ml.in
 568    AS_UNSET([ml_norecursion])
 569 ])
 570
 571 AC_CONFIG_COMMANDS([generate-headers],
 572   [(cd include && ${MAKE-make} pch_build= )])
 573
 574 dnl And this actually makes things happen:
 575 AC_OUTPUT