libstdc++-v3/configure.in

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal, autoconf, autoheader, automake
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(src/ios.cc)
   6
   7 PACKAGE=libstdc++
   8 AC_SUBST(PACKAGE)
   9 # For typical GNU versioning info, format is MAJOR.MINOR.MICRO
  10 release_VERSION=3.1.0
  11 AC_SUBST(release_VERSION)
  12 # For libtool versioning info, format is CURRENT:REVISION:AGE
  13 libtool_VERSION=4:0:0
  14 AC_SUBST(libtool_VERSION)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 # AC 2.50 sets target_alias iff the user specified --target, but we use it
  18 # everywhere, so we set it here just to be sure.
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$target}
  21 AC_SUBST(target_alias)
  22
  23 AM_INIT_AUTOMAKE($PACKAGE, $release_VERSION)
  24 AM_CONFIG_HEADER(config.h)
  25
  26 # Runs configure.host and configure.target, as well as finds CC, CXX
  27 # and assorted other critical bits. Have to run this before the
  28 # GLIBCPP_ENABLE_* macros below.
  29 GLIBCPP_CONFIGURE(.)
  30
  31 AC_LIBTOOL_DLOPEN
  32 AM_PROG_LIBTOOL
  33 AC_SUBST(enable_shared)
  34 AC_SUBST(enable_static)
  35
  36 # Check for c++ or library specific bits that don't require linking.
  37 #GLIBCPP_CHECK_COMPILER_VERSION
  38 GLIBCPP_CHECK_GNU_MAKE
  39
  40 # Enable all the variable C++ stuff.  C_MBCHAR must come early.
  41 GLIBCPP_ENABLE_DEBUG($USE_MAINTAINER_MODE)
  42 GLIBCPP_ENABLE_CSTDIO
  43 GLIBCPP_ENABLE_CLOCALE
  44 GLIBCPP_ENABLE_C_MBCHAR([yes])
  45 GLIBCPP_ENABLE_C99([yes])
  46 GLIBCPP_ENABLE_LONG_LONG([yes])
  47 GLIBCPP_ENABLE_CHEADERS([c_std])
  48 GLIBCPP_ENABLE_THREADS
  49 GLIBCPP_ENABLE_CXX_FLAGS([none])
  50 GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
  51 GLIBCPP_ENABLE_CONCEPT_CHECKS
  52
  53
  54 if test -n "$with_cross_host" || test x"$build" != x"$host"; then
  55
  56   # This lets us hard-code the functionality we know
  57   # we'll have in the cross target environment. "Let" is a
  58   # sugar-coated word placed on an especially dull and tedious hack, actually.
  59   # Here's why GLIBCPP_CHECK_MATH_SUPPORT, and other autoconf macros
  60   # that involve linking can't be used:
  61   # "cannot open sim-crt0.o"
  62   # "cannot open crt0.o"
  63   # etc. All this is because there currently exists no unified,
  64   # consistent way for top level CC information to be passed down
  65   # to target directories: newlib includes, newlib linking info,
  66   # libgloss versus newlib crt0.o, etc. When all of this is done, all
  67   # of this hokey, excessive AC_DEFINE junk for crosses can be removed.
  68
  69   # We are being configured with some form of cross compiler.
  70   GLIBCPP_IS_CROSS_COMPILING=1
  71
  72   # If Canadian cross, then don't pick up tools from the build
  73   # directory.
  74   if test -n "$with_cross_host" && test x"$build" != x"$with_cross_host"; then
  75     CANADIAN=yes
  76   else
  77     CANADIAN=no
  78   fi
  79
  80   # Construct crosses by hand, eliminating bits that need ld...
  81   # GLIBCPP_CHECK_COMPILER_FEATURES
  82   # GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
  83   # GLIBCPP_CHECK_MATH_SUPPORT
  84
  85   case "$target_alias" in
  86     *-linux*)
  87       # Check for available headers.
  88       AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h \
  89         machine/endian.h machine/param.h sys/machine.h sys/types.h \
  90         fp.h locale.h float.h inttypes.h])
  91       SECTION_FLAGS='-ffunction-sections -fdata-sections'
  92       AC_SUBST(SECTION_FLAGS)
  93       GLIBCPP_CHECK_LINKER_FEATURES
  94       GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
  95       GLIBCPP_CHECK_WCHAR_T_SUPPORT
  96       os_include_dir="config/os/gnu-linux"
  97       AC_DEFINE(HAVE_COPYSIGN)
  98       AC_DEFINE(HAVE_COPYSIGNF)
  99       AC_DEFINE(HAVE_FINITEF)
 100       AC_DEFINE(HAVE_FREXPF)
 101       AC_DEFINE(HAVE_HYPOTF)
 102       AC_DEFINE(HAVE_SINCOS)
 103       AC_DEFINE(HAVE_SINCOSF)
 104       if test x"long_double_math_on_this_cpu" = x"yes"; then
 105         AC_DEFINE(HAVE_HYPOTL)
 106       fi
 107       ;;
 108     *-hpux*)
 109       # Check for available headers.
 110       AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h \
 111         machine/endian.h machine/param.h sys/machine.h sys/types.h \
 112         fp.h locale.h float.h inttypes.h])
 113       SECTION_FLAGS='-ffunction-sections -fdata-sections'
 114       AC_SUBST(SECTION_FLAGS)
 115       GLIBCPP_CHECK_LINKER_FEATURES
 116       GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 117       GLIBCPP_CHECK_WCHAR_T_SUPPORT
 118       os_include_dir="config/os/hpux"
 119       AC_DEFINE(HAVE_COPYSIGN)
 120       AC_DEFINE(HAVE_COPYSIGNF)
 121       AC_DEFINE(HAVE_FINITEF)
 122       AC_DEFINE(HAVE_FREXPF)
 123       AC_DEFINE(HAVE_HYPOT)
 124       AC_DEFINE(HAVE_SINCOS)
 125       AC_DEFINE(HAVE_SINCOSF)
 126       ;;
 127     *)
 128       os_include_dir="config/os/newlib"
 129       AC_DEFINE(HAVE_HYPOT)
 130       ;;
 131   esac
 132
 133   # GLIBCPP_CHECK_STDLIB_SUPPORT
 134   AC_DEFINE(HAVE_STRTOF)
 135   AC_DEFINE(HAVE_STRTOLD)
 136   # AC_FUNC_MMAP
 137   AC_DEFINE(HAVE_MMAP)
 138
 139   AC_DEFINE(HAVE_ACOSF)
 140   AC_DEFINE(HAVE_ASINF)
 141   AC_DEFINE(HAVE_ATAN2F)
 142   AC_DEFINE(HAVE_ATANF)
 143   AC_DEFINE(HAVE_CEILF)
 144   AC_DEFINE(HAVE_COPYSIGN)
 145   AC_DEFINE(HAVE_COPYSIGNF)
 146   AC_DEFINE(HAVE_COSF)
 147   AC_DEFINE(HAVE_COSHF)
 148   AC_DEFINE(HAVE_EXPF)
 149   AC_DEFINE(HAVE_FABSF)
 150   AC_DEFINE(HAVE_FINITE)
 151   AC_DEFINE(HAVE_FINITEF)
 152   AC_DEFINE(HAVE_FLOORF)
 153   AC_DEFINE(HAVE_FMODF)
 154   AC_DEFINE(HAVE_FREXPF)
 155   AC_DEFINE(HAVE_ISINF)
 156   AC_DEFINE(HAVE_ISINFF)
 157   AC_DEFINE(HAVE_ISNAN)
 158   AC_DEFINE(HAVE_ISNANF)
 159   AC_DEFINE(HAVE_LDEXPF)
 160   AC_DEFINE(HAVE_LOG10F)
 161   AC_DEFINE(HAVE_LOGF)
 162   AC_DEFINE(HAVE_MODFF)
 163   AC_DEFINE(HAVE_POWF)
 164   AC_DEFINE(HAVE_SINF)
 165   AC_DEFINE(HAVE_SINHF)
 166   AC_DEFINE(HAVE_SQRTF)
 167   AC_DEFINE(HAVE_TANF)
 168   AC_DEFINE(HAVE_TANHF)
 169
 170   # At some point, we should differentiate between architectures
 171   # like x86, which have long double versions, and alpha/powerpc/etc.,
 172   # which don't. For the time being, punt.
 173   if test x"long_double_math_on_this_cpu" = x"yes"; then
 174     AC_DEFINE(HAVE_ACOSL)
 175     AC_DEFINE(HAVE_ASINL)
 176     AC_DEFINE(HAVE_ATAN2L)
 177     AC_DEFINE(HAVE_ATANL)
 178     AC_DEFINE(HAVE_CEILL)
 179     AC_DEFINE(HAVE_COPYSIGNL)
 180     AC_DEFINE(HAVE_COSL)
 181     AC_DEFINE(HAVE_COSHL)
 182     AC_DEFINE(HAVE_EXPL)
 183     AC_DEFINE(HAVE_FABSL)
 184     AC_DEFINE(HAVE_FINITEL)
 185     AC_DEFINE(HAVE_FLOORL)
 186     AC_DEFINE(HAVE_FMODL)
 187     AC_DEFINE(HAVE_FREXPL)
 188     AC_DEFINE(HAVE_ISINFL)
 189     AC_DEFINE(HAVE_ISNANL)
 190     AC_DEFINE(HAVE_LDEXPL)
 191     AC_DEFINE(HAVE_LOG10L)
 192     AC_DEFINE(HAVE_LOGL)
 193     AC_DEFINE(HAVE_MODFL)
 194     AC_DEFINE(HAVE_POWL)
 195     AC_DEFINE(HAVE_SINCOSL)
 196     AC_DEFINE(HAVE_SINL)
 197     AC_DEFINE(HAVE_SINHL)
 198     AC_DEFINE(HAVE_SQRTL)
 199     AC_DEFINE(HAVE_TANL)
 200     AC_DEFINE(HAVE_TANHL)
 201   fi
 202 else
 203
 204   # We are being configured natively. We can do more elaborate tests
 205   # that include AC_TRY_COMPILE now, as the linker is assumed to be
 206   # working.
 207   GLIBCPP_IS_CROSS_COMPILING=0
 208   CANADIAN=no
 209
 210   # Check for available headers.
 211   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 212   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h])
 213
 214   GLIBCPP_CHECK_COMPILER_FEATURES
 215   GLIBCPP_CHECK_LINKER_FEATURES
 216   GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 217   GLIBCPP_CHECK_MATH_SUPPORT
 218   GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 219   GLIBCPP_CHECK_WCHAR_T_SUPPORT
 220   GLIBCPP_CHECK_STDLIB_SUPPORT
 221   AC_LC_MESSAGES
 222
 223   AC_TRY_COMPILE([
 224   #include <setjmp.h>
 225   ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 226   [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.  ])
 227   ])
 228
 229   AC_FUNC_MMAP
 230
 231   # Establish limits on memory usage during 'make check'
 232   GLIBCPP_CONFIGURE_TESTSUITE
 233 fi
 234
 235
 236 # Propagate the target-specific source directories through the build chain.
 237 OS_INC_SRCDIR=$os_include_dir/bits
 238 ATOMICITY_INC_SRCDIR=$ATOMICITYH/bits
 239 CPU_LIMITS_INC_SRCDIR=$CPULIMITSH/bits
 240 AC_SUBST(OS_INC_SRCDIR)
 241 AC_SUBST(ATOMICITY_INC_SRCDIR)
 242 AC_SUBST(CPU_LIMITS_INC_SRCDIR)
 243
 244 # Set up cross-compile flags
 245 AC_SUBST(GLIBCPP_IS_CROSS_COMPILING)
 246 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 247
 248 AC_CACHE_SAVE
 249
 250 if test "${multilib}" = "yes"; then
 251   multilib_arg="--enable-multilib"
 252 else
 253   multilib_arg=
 254 fi
 255
 256 # Needed so that g++ can find the correct include subdir automatically.
 257 INTERFACE=v3
 258
 259 # Export all the install information
 260 GLIBCPP_EXPORT_INSTALL_INFO
 261
 262 # Export all the include and flag information to makefiles.
 263 GLIBCPP_EXPORT_INCLUDES
 264 GLIBCPP_EXPORT_FLAGS
 265
 266 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 267    grep "enable shared" > /dev/null; then
 268   LIBSUPCXX_PICFLAGS=-prefer-pic
 269 else
 270   LIBSUPCXX_PICFLAGS=
 271 fi
 272 AC_SUBST(LIBSUPCXX_PICFLAGS)
 273
 274 # Generate the various Makefiles, include files, and scripts.
 275 # NB: Multilibs need MULTISUBDIR defined correctly in src/Makefile.am
 276 # and libsupc++/Makefile.am so that multilib installs will end up
 277 # installed in the correct place. To work around this not being passed
 278 # down from config-ml.in -> top_srcdir/Makefile.am ->
 279 # top_srcdir/{src,libsupc++}/Makefile.am, manually append it here.
 280 AC_OUTPUT(Makefile \
 281     include/Makefile src/Makefile \
 282     libmath/Makefile libio/Makefile libsupc++/Makefile \
 283     po/Makefile testsuite/Makefile mkcheck testsuite_flags,
 284 [if test -n "$CONFIG_FILES"; then
 285   ac_file=Makefile . ${glibcpp_basedir}/../config-ml.in
 286   grep '^MULTISUBDIR =' Makefile >> src/Makefile
 287   grep '^MULTISUBDIR =' Makefile >> libsupc++/Makefile
 288 fi
 289 chmod +x mkcheck
 290 chmod +x testsuite_flags
 291 ],
 292 srcdir=${srcdir}
 293 host=${host}
 294 target=${target}
 295 with_multisubdir=${with_multisubdir}
 296 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 297 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 298 glibcpp_basedir=${glibcpp_basedir}
 299 CC="${CC}"
 300 CXX="${CXX}"
 301 )
 302
 303
 304 # Sanity checking & User-visible messages.
 305 # Checks down here, otherwise they get scrolled off before
 306 # the user will notice.
 307
 308 # Trying to get more people to read documentation.  Possibly remove
 309 # check and warn all the time. There is no "informational" AC_MSG_
 310 # macro, so these are going to be printed even when --quiet/--silent
 311 # is given.
 312 if test ! -f stamp-sanity-warned; then
 313   touch stamp-sanity-warned
 314   echo ""
 315   echo "Please make certain that you read the installation information here:"
 316   echo "  faster => ${srcdir}/docs/install.html"
 317   echo "  slower => <URL:http://gcc.gnu.org/onlinedocs/libstdc++/install.html>"
 318   echo ""
 319   echo "and the configuration information here:"
 320   echo "  faster => ${srcdir}/docs/configopts.html"
 321   echo "  slower => <URL:http://gcc.gnu.org/onlinedocs/libstdc++/configopts.html>"
 322   echo ""
 323   echo "before proceeding with ${_cv_gnu_make_command}."
 324   echo ""
 325 fi