opcodes/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2021 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([opcodes], BFD_VERSION)
  22 AC_CONFIG_SRCDIR([z8k-dis.c])
  23
  24 AC_CANONICAL_TARGET
  25
  26 AM_INIT_AUTOMAKE
  27 AM_SILENT_RULES([yes])
  28
  29 AC_PROG_CC
  30 AC_GNU_SOURCE
  31 AC_USE_SYSTEM_EXTENSIONS
  32
  33 dnl These must be called before LT_INIT, because it may want
  34 dnl to call AC_CHECK_PROG.
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_CHECK_TOOL(RANLIB, ranlib, :)
  37
  38 dnl Default to a non shared library.  This may be overridden by the
  39 dnl configure option --enable-shared.
  40 AC_DISABLE_SHARED
  41
  42 LT_INIT
  43
  44 ac_checking=
  45 . ${srcdir}/../bfd/development.sh
  46 test "$development" = true && ac_checking=yes
  47 AC_ARG_ENABLE(checking,
  48 [  --enable-checking       enable run-time checks],
  49 [case "${enableval}" in
  50   no|none)  ac_checking= ;;
  51   *)        ac_checking=yes ;;
  52 esac])dnl
  53 if test x$ac_checking != x ; then
  54   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  55 fi
  56
  57 AC_ARG_ENABLE(targets,
  58 [  --enable-targets        alternative target configurations],
  59 [case "${enableval}" in
  60   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  61             ;;
  62   no)       enable_targets= ;;
  63   *)        enable_targets=$enableval ;;
  64 esac])dnl
  65
  66 AM_BINUTILS_WARNINGS
  67
  68 AC_CONFIG_HEADERS(config.h:config.in)
  69
  70 # PR 14072
  71 AH_VERBATIM([00_CONFIG_H_CHECK],
  72 [/* Check that config.h is #included before system headers
  73    (this works only for glibc, but that should be enough).  */
  74 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  75 #  error config.h must be #included before system headers
  76 #endif
  77 #define __CONFIG_H__ 1])
  78
  79 if test -z "$target" ; then
  80     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  81 fi
  82
  83 AM_MAINTAINER_MODE
  84 AM_INSTALL_LIBBFD
  85 AC_EXEEXT
  86
  87 # host-specific stuff:
  88
  89 ALL_LINGUAS="da de es fi fr ga id it nl pt_BR ro sr sv tr uk vi zh_CN"
  90 ZW_GNU_GETTEXT_SISTER_DIR
  91 AM_PO_SUBDIRS
  92
  93 . ${srcdir}/../bfd/configure.host
  94
  95 BFD_CC_FOR_BUILD
  96
  97 AC_SUBST(HDEFINES)
  98 AC_PROG_INSTALL
  99
 100 AC_CHECK_DECLS([basename, stpcpy])
 101
 102 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 103 # since sigsetjmp might only be defined as a macro.
 104 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 105 [AC_TRY_COMPILE([
 106 #include <setjmp.h>
 107 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 108 bfd_cv_func_sigsetjmp=yes, bfd_cv_func_sigsetjmp=no)])
 109 if test $bfd_cv_func_sigsetjmp = yes; then
 110   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 111 fi
 112
 113 cgen_maint=no
 114 cgendir='$(srcdir)/../cgen'
 115
 116 AC_ARG_ENABLE(cgen-maint,
 117 [  --enable-cgen-maint[=dir]    build cgen generated files],
 118 [case "${enableval}" in
 119   yes)  cgen_maint=yes ;;
 120   no)   cgen_maint=no ;;
 121   *)
 122         # Argument is a directory where cgen can be found.  In some
 123         # future world cgen could be installable, but right now this
 124         # is not the case.  Instead we assume the directory is a path
 125         # to the cgen source tree.
 126         cgen_maint=yes
 127         if test -r ${enableval}/iformat.scm; then
 128           # This looks like a cgen source tree.
 129           cgendir=${enableval}
 130         else
 131           AC_MSG_ERROR(${enableval} doesn't look like a cgen source tree)
 132         fi
 133         ;;
 134 esac])dnl
 135 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 136 AC_SUBST(cgendir)
 137
 138 using_cgen=no
 139
 140 # Check if linker supports --as-needed and --no-as-needed options
 141 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 142         [bfd_cv_ld_as_needed=no
 143         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 144                 bfd_cv_ld_as_needed=yes
 145         fi
 146         ])
 147
 148 LT_LIB_M
 149
 150 #Libs for generator progs
 151 if test "x$cross_compiling" = "xno"; then
 152   BUILD_LIBS=../libiberty/libiberty.a
 153   BUILD_LIB_DEPS=$BUILD_LIBS
 154 else
 155   # if cross-compiling, assume that the system provides -liberty
 156   # and that the version is compatible with new headers.
 157   BUILD_LIBS=-liberty
 158   BUILD_LIB_DEPS=
 159 fi
 160 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 161 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 162
 163 AC_SUBST(BUILD_LIBS)
 164 AC_SUBST(BUILD_LIB_DEPS)
 165
 166 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 167 SHARED_LDFLAGS=
 168 SHARED_LIBADD=
 169 SHARED_DEPENDENCIES=
 170 if test "$enable_shared" = "yes"; then
 171 # When building a shared libopcodes, link against the pic version of libiberty
 172 # so that apps that use libopcodes won't need libiberty just to satisfy any
 173 # libopcodes references.
 174 # We can't do that if a pic libiberty is unavailable since including non-pic
 175 # code would insert text relocations into libopcodes.
 176 # Note that linking against libbfd as we do here, which is itself linked
 177 # against libiberty, may not satisfy all the libopcodes libiberty references
 178 # since libbfd may not pull in the entirety of libiberty.
 179 # Also, jam libintl into the right place in all of this: after libiberty,
 180 # which uses it, but before -lcygwin, which it uses.
 181 changequote(,)dnl
 182   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 183 changequote([,])dnl
 184   if test -n "$x"; then
 185     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 186   fi
 187 fi
 188
 189 SHARED_LIBADD="$SHARED_LIBADD $LIBINTL"
 190
 191 if test "$enable_shared" = "yes"; then
 192   case "${host}" in
 193     *-*-cygwin*)
 194       SHARED_LDFLAGS="-no-undefined"
 195       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty $SHARED_LIBADD"
 196       ;;
 197     *)
 198       SHARED_LIBADD="../bfd/libbfd.la ${SHARED_LIBADD}"
 199       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 200       ;;
 201   esac
 202
 203   if test -n "$SHARED_LIBADD"; then
 204     if test -n "$LIBM"; then
 205       if test x"$bfd_cv_ld_as_needed" = xyes; then
 206         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 207         # to stop libtool reordering these options.
 208         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 209       else
 210         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 211       fi
 212     fi
 213   fi
 214 fi
 215 AC_SUBST(SHARED_LDFLAGS)
 216 AC_SUBST(SHARED_LIBADD)
 217 AC_SUBST(SHARED_DEPENDENCIES)
 218
 219 # target-specific stuff:
 220
 221 # Canonicalize the secondary target names.
 222 if test -n "$enable_targets" ; then
 223     for targ in `echo $enable_targets | sed 's/,/ /g'`
 224     do
 225         result=`$ac_config_sub $targ 2>/dev/null`
 226         if test -n "$result" ; then
 227             canon_targets="$canon_targets $result"
 228         else
 229             # Allow targets that config.sub doesn't recognize, like "all".
 230             canon_targets="$canon_targets $targ"
 231         fi
 232     done
 233 fi
 234
 235 all_targets=false
 236 selarchs=
 237 for targ in $target $canon_targets
 238 do
 239     if test "x$targ" = "xall" ; then
 240         all_targets=true
 241     else
 242         . $srcdir/../bfd/config.bfd
 243         selarchs="$selarchs $targ_archs"
 244     fi
 245 done
 246
 247 # Utility var, documents generic cgen support files.
 248
 249 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 250
 251 # We don't do any links based on the target system, just makefile config.
 252
 253 if test x${all_targets} = xfalse ; then
 254
 255     # Target architecture .o files.
 256     ta=
 257
 258     for arch in $selarchs
 259     do
 260         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 261         archdefs="$archdefs -DARCH_$ad"
 262         case "$arch" in
 263         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 264         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 265         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 266         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 267         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 268         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 269         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 270         bfd_cris_arch)          ta="$ta cris-desc.lo cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 271         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 272         bfd_csky_arch)          ta="$ta csky-dis.lo" ;;
 273         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 274         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 275         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 276         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 277         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 278         bfd_ft32_arch)          ta="$ta ft32-opc.lo ft32-dis.lo" ;;
 279         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 280         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 281         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 282         bfd_i386_arch|bfd_iamcu_arch|bfd_l1om_arch|bfd_k1om_arch)
 283                                 ta="$ta i386-dis.lo i386-opc.lo" ;;
 284         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 285         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 286         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 287         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 288         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 289         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 290         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 291         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 292         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 293         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 294         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 295         bfd_s12z_arch)          ta="$ta s12z-dis.lo s12z-opc.lo" ;;
 296         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 297         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 298         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 299         bfd_metag_arch)         ta="$ta metag-dis.lo" ;;
 300         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 301         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 302         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 303         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 304         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 305         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 306         bfd_msp430_arch)        ta="$ta msp430-dis.lo msp430-decode.lo" ;;
 307         bfd_nds32_arch)         ta="$ta nds32-asm.lo nds32-dis.lo" ;;
 308         bfd_nfp_arch)           ta="$ta nfp-dis.lo" ;;
 309         bfd_nios2_arch)         ta="$ta nios2-dis.lo nios2-opc.lo" ;;
 310         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 311         bfd_or1k_arch)          ta="$ta or1k-asm.lo or1k-desc.lo or1k-dis.lo or1k-ibld.lo or1k-opc.lo" using_cgen=yes ;;
 312         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 313         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 314         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 315         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 316         bfd_pru_arch)           ta="$ta pru-dis.lo pru-opc.lo" ;;
 317         bfd_pyramid_arch)       ;;
 318         bfd_romp_arch)          ;;
 319         bfd_riscv_arch)         ta="$ta riscv-dis.lo riscv-opc.lo" ;;
 320         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 321         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 322         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 323         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 324         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 325         bfd_sh_arch)            ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 326         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 327         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 328         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 329         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 330         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 331         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 332         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 333         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 334         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 335         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 336         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 337         bfd_v850_rh850_arch)    ta="$ta v850-opc.lo v850-dis.lo" ;;
 338         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 339         bfd_visium_arch)        ta="$ta visium-dis.lo visium-opc.lo" ;;
 340         bfd_wasm32_arch)        ta="$ta wasm32-dis.lo" ;;
 341         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 342         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 343         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 344         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 345         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 346         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 347         bfd_bpf_arch)           ta="$ta bpf-asm.lo bpf-desc.lo bpf-dis.lo bpf-ibld.lo bpf-opc.lo" using_cgen=yes ;;
 348         bfd_loongarch_arch)     ta="$ta loongarch-dis.lo loongarch-opc.lo loongarch-coder.lo" ;;
 349
 350         "")                     ;;
 351         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 352         esac
 353     done
 354
 355     if test $using_cgen = yes ; then
 356         ta="$ta $cgen_files"
 357     fi
 358
 359     # Weed out duplicate .o files.
 360     f=""
 361     for i in $ta ; do
 362         case " $f " in
 363         *" $i "*) ;;
 364         *) f="$f $i" ;;
 365         esac
 366     done
 367     ta="$f"
 368
 369     # And duplicate -D flags.
 370     f=""
 371     for i in $archdefs ; do
 372         case " $f " in
 373         *" $i "*) ;;
 374         *) f="$f $i" ;;
 375         esac
 376     done
 377     archdefs="$f"
 378
 379     BFD_MACHINES="$ta"
 380
 381 else    # all_targets is true
 382     archdefs=-DARCH_all
 383     if grep '#define BFD_ARCH_SIZE 64' ../bfd/bfd-in3.h > /dev/null; then
 384         BFD_MACHINES='$(ALL32_MACHINES) $(ALL64_MACHINES)'
 385     else
 386         BFD_MACHINES='$(ALL32_MACHINES)'
 387     fi
 388 fi
 389
 390 AC_SUBST(archdefs)
 391 AC_SUBST(BFD_MACHINES)
 392
 393 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 394 AC_OUTPUT
 395
 396 GNU_MAKE_JOBSERVER