opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_USE_SYSTEM_EXTENSIONS
  23
  24 dnl These must be called before LT_INIT, because it may want
  25 dnl to call AC_CHECK_PROG.
  26 AC_CHECK_TOOL(AR, ar)
  27 AC_CHECK_TOOL(RANLIB, ranlib, :)
  28
  29 dnl Default to a non shared library.  This may be overridden by the
  30 dnl configure option --enable-shared.
  31 AC_DISABLE_SHARED
  32
  33 LT_INIT
  34
  35 AC_ARG_ENABLE(targets,
  36 [  --enable-targets        alternative target configurations],
  37 [case "${enableval}" in
  38   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  39             ;;
  40   no)       enable_targets= ;;
  41   *)        enable_targets=$enableval ;;
  42 esac])dnl
  43
  44 AM_BINUTILS_WARNINGS
  45
  46 AC_CONFIG_HEADERS(config.h:config.in)
  47
  48 if test -z "$target" ; then
  49     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  50 fi
  51
  52 AM_MAINTAINER_MODE
  53 AM_INSTALL_LIBBFD
  54 AC_EXEEXT
  55
  56 # host-specific stuff:
  57
  58 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN"
  59 ZW_GNU_GETTEXT_SISTER_DIR
  60 AM_PO_SUBDIRS
  61
  62 . ${srcdir}/../bfd/configure.host
  63
  64 BFD_CC_FOR_BUILD
  65
  66 AC_SUBST(HDEFINES)
  67 AC_PROG_INSTALL
  68
  69 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  70
  71 AC_CHECK_DECLS([basename, stpcpy])
  72
  73 cgen_maint=no
  74 cgendir='$(srcdir)/../cgen'
  75
  76 AC_ARG_ENABLE(cgen-maint,
  77 [  --enable-cgen-maint[=dir]    build cgen generated files],
  78 [case "${enableval}" in
  79   yes)  cgen_maint=yes ;;
  80   no)   cgen_maint=no ;;
  81   *)
  82         # argument is cgen install directory (not implemented yet).
  83         # Having a `share' directory might be more appropriate for the .scm,
  84         # .cpu, etc. files.
  85         cgen_maint=yes
  86         cgendir=${cgen_maint}/lib/cgen
  87         ;;
  88 esac])dnl
  89 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
  90 AC_SUBST(cgendir)
  91
  92 using_cgen=no
  93
  94 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
  95 SHARED_LDFLAGS=
  96 SHARED_LIBADD=
  97 SHARED_DEPENDENCIES=
  98 if test "$enable_shared" = "yes"; then
  99 # When building a shared libopcodes, link against the pic version of libiberty
 100 # so that apps that use libopcodes won't need libiberty just to satisfy any
 101 # libopcodes references.
 102 # We can't do that if a pic libiberty is unavailable since including non-pic
 103 # code would insert text relocations into libopcodes.
 104 # Note that linking against libbfd as we do here, which is itself linked
 105 # against libiberty, may not satisfy all the libopcodes libiberty references
 106 # since libbfd may not pull in the entirety of libiberty.
 107 changequote(,)dnl
 108   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 109 changequote([,])dnl
 110   if test -n "$x"; then
 111     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 112   fi
 113
 114   case "${host}" in
 115     *-*-cygwin*)
 116       SHARED_LDFLAGS="-no-undefined"
 117       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 118       ;;
 119    *-*-darwin*)
 120      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib ${SHARED_LIBADD}"
 121      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 122      ;;
 123     *)
 124       case "$host_vendor" in
 125         hp)
 126           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl ${SHARED_LIBADD}"
 127           ;;
 128         *)
 129           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so ${SHARED_LIBADD}"
 130           ;;
 131       esac
 132       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 133       ;;
 134   esac
 135 fi
 136 AC_SUBST(SHARED_LDFLAGS)
 137 AC_SUBST(SHARED_LIBADD)
 138 AC_SUBST(SHARED_DEPENDENCIES)
 139
 140 # target-specific stuff:
 141
 142 # Canonicalize the secondary target names.
 143 if test -n "$enable_targets" ; then
 144     for targ in `echo $enable_targets | sed 's/,/ /g'`
 145     do
 146         result=`$ac_config_sub $targ 2>/dev/null`
 147         if test -n "$result" ; then
 148             canon_targets="$canon_targets $result"
 149         else
 150             # Allow targets that config.sub doesn't recognize, like "all".
 151             canon_targets="$canon_targets $targ"
 152         fi
 153     done
 154 fi
 155
 156 all_targets=false
 157 selarchs=
 158 for targ in $target $canon_targets
 159 do
 160     if test "x$targ" = "xall" ; then
 161         all_targets=true
 162     else
 163         . $srcdir/../bfd/config.bfd
 164         selarchs="$selarchs $targ_archs"
 165     fi
 166 done
 167
 168 # Utility var, documents generic cgen support files.
 169
 170 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 171
 172 # We don't do any links based on the target system, just makefile config.
 173
 174 if test x${all_targets} = xfalse ; then
 175
 176     # Target architecture .o files.
 177     ta=
 178
 179     for arch in $selarchs
 180     do
 181         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 182         archdefs="$archdefs -DARCH_$ad"
 183         case "$arch" in
 184         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 185         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 186         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 187         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 188         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 189         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 190         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 191         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 192         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 193         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 194         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 195         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 196         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 197         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 198         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 199         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 200         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 201         bfd_i386_arch)          ta="$ta i386-dis.lo i386-opc.lo" ;;
 202         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 203         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 204         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 205         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 206         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 207         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 208         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 209         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 210         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 211         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 212         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 213         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 214         bfd_maxq_arch)          ta="$ta maxq-dis.lo" ;;
 215         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 216         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 217         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 218         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 219         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 220         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 221         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 222         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 223         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 224         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 225         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 226         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 227         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 228         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 229         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 230         bfd_pyramid_arch)       ;;
 231         bfd_romp_arch)          ;;
 232         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 233         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 234         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 235         bfd_sh_arch)
 236           # We can't decide what we want just from the CPU family.
 237           # We want SH5 support unless a specific version of sh is
 238           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 239           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 240           for t in $target $canon_targets; do
 241             case $t in
 242               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 243               sh-*-linux* | shl-*-linux*)
 244                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 245                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 246                                 break;;
 247             esac;
 248           done
 249                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 250         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 251         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 252         bfd_tahoe_arch)         ;;
 253         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 254         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 255         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 256         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 257         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 258         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 259         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 260         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 261         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 262         bfd_we32k_arch)         ;;
 263         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 264         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 265         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 266         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 267         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 268
 269         "")                     ;;
 270         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 271         esac
 272     done
 273
 274     if test $using_cgen = yes ; then
 275         ta="$ta $cgen_files"
 276     fi
 277
 278     # Weed out duplicate .o files.
 279     f=""
 280     for i in $ta ; do
 281         case " $f " in
 282         *" $i "*) ;;
 283         *) f="$f $i" ;;
 284         esac
 285     done
 286     ta="$f"
 287
 288     # And duplicate -D flags.
 289     f=""
 290     for i in $archdefs ; do
 291         case " $f " in
 292         *" $i "*) ;;
 293         *) f="$f $i" ;;
 294         esac
 295     done
 296     archdefs="$f"
 297
 298     BFD_MACHINES="$ta"
 299
 300 else    # all_targets is true
 301     archdefs=-DARCH_all
 302     BFD_MACHINES='$(ALL_MACHINES)'
 303 fi
 304
 305 AC_SUBST(archdefs)
 306 AC_SUBST(BFD_MACHINES)
 307
 308 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 309 AC_OUTPUT