opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_USE_SYSTEM_EXTENSIONS
  23
  24 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  25 dnl to call AC_CHECK_PROG.
  26 AC_CHECK_TOOL(AR, ar)
  27 AC_CHECK_TOOL(RANLIB, ranlib, :)
  28
  29 dnl Default to a non shared library.  This may be overridden by the
  30 dnl configure option --enable-shared.
  31 AM_DISABLE_SHARED
  32
  33 AM_PROG_LIBTOOL
  34
  35 AC_ARG_ENABLE(targets,
  36 [  --enable-targets        alternative target configurations],
  37 [case "${enableval}" in
  38   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  39             ;;
  40   no)       enable_targets= ;;
  41   *)        enable_targets=$enableval ;;
  42 esac])dnl
  43 AC_ARG_ENABLE(commonbfdlib,
  44 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  45 [case "${enableval}" in
  46   yes) commonbfdlib=true ;;
  47   no)  commonbfdlib=false ;;
  48   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  49 esac])dnl
  50
  51 AM_BINUTILS_WARNINGS
  52
  53 AM_CONFIG_HEADER(config.h:config.in)
  54
  55 if test -z "$target" ; then
  56     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  57 fi
  58
  59 AM_MAINTAINER_MODE
  60 AM_INSTALL_LIBBFD
  61 AC_EXEEXT
  62
  63 # host-specific stuff:
  64
  65 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN"
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67 AM_PO_SUBDIRS
  68
  69 . ${srcdir}/../bfd/configure.host
  70
  71 BFD_CC_FOR_BUILD
  72
  73 AC_SUBST(HDEFINES)
  74 AC_PROG_INSTALL
  75
  76 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  77
  78 AC_CHECK_DECLS([basename, stpcpy])
  79
  80 cgen_maint=no
  81 cgendir='$(srcdir)/../cgen'
  82
  83 AC_ARG_ENABLE(cgen-maint,
  84 [  --enable-cgen-maint[=dir]    build cgen generated files],
  85 [case "${enableval}" in
  86   yes)  cgen_maint=yes ;;
  87   no)   cgen_maint=no ;;
  88   *)
  89         # argument is cgen install directory (not implemented yet).
  90         # Having a `share' directory might be more appropriate for the .scm,
  91         # .cpu, etc. files.
  92         cgen_maint=yes
  93         cgendir=${cgen_maint}/lib/cgen
  94         ;;
  95 esac])dnl
  96 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
  97 AC_SUBST(cgendir)
  98
  99 using_cgen=no
 100
 101 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 102 SHARED_LDFLAGS=
 103 SHARED_LIBADD=
 104 SHARED_DEPENDENCIES=
 105 if test "$enable_shared" = "yes"; then
 106   case "${host}" in
 107     *-*-cygwin*)
 108       SHARED_LDFLAGS="-no-undefined"
 109       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 110       ;;
 111    *-*-darwin*)
 112      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib"
 113      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 114      ;;
 115     *)
 116       case "$host_vendor" in
 117         hp)
 118           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl"
 119           ;;
 120         *)
 121           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so"
 122           ;;
 123       esac
 124       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 125       ;;
 126   esac
 127 fi
 128 AC_SUBST(SHARED_LDFLAGS)
 129 AC_SUBST(SHARED_LIBADD)
 130 AC_SUBST(SHARED_DEPENDENCIES)
 131
 132 # target-specific stuff:
 133
 134 # Canonicalize the secondary target names.
 135 if test -n "$enable_targets" ; then
 136     for targ in `echo $enable_targets | sed 's/,/ /g'`
 137     do
 138         result=`$ac_config_sub $targ 2>/dev/null`
 139         if test -n "$result" ; then
 140             canon_targets="$canon_targets $result"
 141         else
 142             # Allow targets that config.sub doesn't recognize, like "all".
 143             canon_targets="$canon_targets $targ"
 144         fi
 145     done
 146 fi
 147
 148 all_targets=false
 149 selarchs=
 150 for targ in $target $canon_targets
 151 do
 152     if test "x$targ" = "xall" ; then
 153         all_targets=true
 154     else
 155         . $srcdir/../bfd/config.bfd
 156         selarchs="$selarchs $targ_archs"
 157     fi
 158 done
 159
 160 # Utility var, documents generic cgen support files.
 161
 162 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 163
 164 # We don't do any links based on the target system, just makefile config.
 165
 166 if test x${all_targets} = xfalse ; then
 167
 168     # Target architecture .o files.
 169     ta=
 170
 171     for arch in $selarchs
 172     do
 173         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 174         archdefs="$archdefs -DARCH_$ad"
 175         case "$arch" in
 176         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 177         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 178         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 179         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 180         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 181         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 182         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 183         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 184         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 185         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 186         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 187         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 188         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 189         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 190         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 191         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 192         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 193         bfd_i386_arch)          ta="$ta i386-dis.lo i386-opc.lo" ;;
 194         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 195         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 196         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 197         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 198         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 199         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 200         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 201         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 202         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 203         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 204         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 205         bfd_maxq_arch)          ta="$ta maxq-dis.lo" ;;
 206         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 207         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 208         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 209         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 210         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 211         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 212         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 213         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 214         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 215         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 216         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 217         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 218         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 219         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 220         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 221         bfd_pyramid_arch)       ;;
 222         bfd_romp_arch)          ;;
 223         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 224         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 225         bfd_score_arch)         ta="$ta score-dis.lo" ;;
 226         bfd_sh_arch)
 227           # We can't decide what we want just from the CPU family.
 228           # We want SH5 support unless a specific version of sh is
 229           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 230           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 231           for t in $target $canon_targets; do
 232             case $t in
 233               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 234               sh-*-linux* | shl-*-linux*)
 235                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 236                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 237                                 break;;
 238             esac;
 239           done
 240                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 241         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 242         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 243         bfd_tahoe_arch)         ;;
 244         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 245         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 246         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 247         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 248         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 249         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 250         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 251         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 252         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 253         bfd_we32k_arch)         ;;
 254         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 255         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 256         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 257         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 258         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 259
 260         "")                     ;;
 261         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 262         esac
 263     done
 264
 265     if test $using_cgen = yes ; then
 266         ta="$ta $cgen_files"
 267     fi
 268
 269     # Weed out duplicate .o files.
 270     f=""
 271     for i in $ta ; do
 272         case " $f " in
 273         *" $i "*) ;;
 274         *) f="$f $i" ;;
 275         esac
 276     done
 277     ta="$f"
 278
 279     # And duplicate -D flags.
 280     f=""
 281     for i in $archdefs ; do
 282         case " $f " in
 283         *" $i "*) ;;
 284         *) f="$f $i" ;;
 285         esac
 286     done
 287     archdefs="$f"
 288
 289     BFD_MACHINES="$ta"
 290
 291 else    # all_targets is true
 292     archdefs=-DARCH_all
 293     BFD_MACHINES='$(ALL_MACHINES)'
 294 fi
 295
 296 AC_SUBST(archdefs)
 297 AC_SUBST(BFD_MACHINES)
 298
 299 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 300 AC_OUTPUT