sim/m4/sim_ac_toolchain.m4

   1 dnl Copyright (C) 1997-2022 Free Software Foundation, Inc.
   2 dnl
   3 dnl This program is free software; you can redistribute it and/or modify
   4 dnl it under the terms of the GNU General Public License as published by
   5 dnl the Free Software Foundation; either version 3 of the License, or
   6 dnl (at your option) any later version.
   7 dnl
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 dnl GNU General Public License for more details.
  12 dnl
  13 dnl You should have received a copy of the GNU General Public License
  14 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15 dnl
  16 dnl Setup the toolchain variables.
  17 AC_DEFUN([SIM_AC_TOOLCHAIN],
  18 [dnl
  19 AC_CANONICAL_SYSTEM
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_REQUIRE([AC_PROG_CC])
  22 AC_REQUIRE([AC_PROG_CPP])
  23 AC_C_BIGENDIAN
  24 AC_ARG_PROGRAM
  25 AC_PROG_INSTALL
  26
  27 AC_CHECK_TOOL(DTC, dtc)
  28
  29 dnl Setup toolchain settings for build-time tools..
  30 if test "x$cross_compiling" = "xno"; then
  31   : "${AR_FOR_BUILD:=\$(AR)}"
  32   : "${CC_FOR_BUILD:=\$(CC)}"
  33   : "${RANLIB_FOR_BUILD:=\$(RANLIB)}"
  34   : "${CFLAGS_FOR_BUILD:=\$(CFLAGS)}"
  35   : "${LDFLAGS_FOR_BUILD:=\$(LDFLAGS)}"
  36 else
  37   : "${AR_FOR_BUILD:=ar}"
  38   : "${CC_FOR_BUILD:=gcc}"
  39   : "${RANLIB_FOR_BUILD:=ranlib}"
  40   : "${CFLAGS_FOR_BUILD:=-g -O}"
  41   : "${LDLFAGS_FOR_BUILD:=}"
  42 fi
  43 AC_SUBST(AR_FOR_BUILD)
  44 AC_SUBST(CC_FOR_BUILD)
  45 AC_SUBST(RANLIB_FOR_BUILD)
  46 AC_SUBST(CFLAGS_FOR_BUILD)
  47 AC_SUBST(LDFLAGS_FOR_BUILD)
  48
  49 AC_SUBST(CFLAGS)
  50 AC_CHECK_TOOL(AR, ar)
  51 AC_PROG_RANLIB
  52 PKG_PROG_PKG_CONFIG
  53
  54 # Require C11 or newer.  Autoconf-2.70 provides ac_cv_prog_cc_c11 when using
  55 # AC_PROG_CC, but we're still using Autoconf-2.69, and the newest it understands
  56 # is C99.  So handle it ourselves.
  57 m4_version_prereq([2.70], [AC_MSG_ERROR([clean this up!])], [:])
  58 C_DIALECT=
  59 AC_MSG_CHECKING([whether C11 is supported by default])
  60 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  61 #if !defined __STDC_VERSION__ || __STDC_VERSION__ < 201112L
  62 # error "C11 support not found"
  63 #endif
  64 ])], [AC_MSG_RESULT([yes])], [
  65   AC_MSG_RESULT([no])
  66   AC_MSG_CHECKING([for -std=c11 support])
  67   ac_save_CC="$CC"
  68   CC="$CC -std=c11"
  69   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  70 #if !defined __STDC_VERSION__ || __STDC_VERSION__ < 201112L
  71 # error "C11 support not found"
  72 #endif
  73 ])], [
  74   AC_MSG_RESULT([yes])
  75   CC="$ac_save_CC"
  76   C_DIALECT="-std=c11"
  77 ], [AC_MSG_ERROR([C11 is required])])])
  78 AC_SUBST(C_DIALECT)
  79 ])
  80 dnl
  81
  82 AC_DEFUN([SIM_AC_CHECK_TOOLCHAIN_FOR_PRIMARY_TARGET],
  83 [dnl
  84 GCC_TARGET_TOOL([cc], [CC_FOR_TARGET], [CC], [${target_alias}-gcc])
  85 GCC_TARGET_TOOL([as], [AS_FOR_TARGET], [AS], [\$(abs_builddir)/../gas/as-new])
  86 GCC_TARGET_TOOL([ld], [LD_FOR_TARGET], [LD], [\$(abs_builddir)/../ld/ld-new])
  87 ])
  88
  89 SIM_TOOLCHAIN_VARS=
  90 AC_SUBST(SIM_TOOLCHAIN_VARS)
  91 AC_DEFUN([_SIM_AC_TOOLCHAIN_FOR_TARGET],
  92 [dnl
  93 AC_REQUIRE([SIM_AC_CHECK_TOOLCHAIN_FOR_PRIMARY_TARGET])
  94 AC_ARG_VAR(AS_FOR_TARGET_$2, [Assembler for $1 tests])
  95 AC_ARG_VAR(LD_FOR_TARGET_$2, [Linker for $1 tests])
  96 AC_ARG_VAR(CC_FOR_TARGET_$2, [C compiler for $1 tests])
  97 m4_bmatch($1, [example-], [dnl
  98   : "${AS_FOR_TARGET_$2:=\$(AS_FOR_TARGET)}"
  99   : "${LD_FOR_TARGET_$2:=\$(LD_FOR_TARGET)}"
 100   : "${CC_FOR_TARGET_$2:=\$(CC)}"
 101 ], [dnl
 102   AS_IF([test "$SIM_PRIMARY_TARGET" = "$1"], [dnl
 103     : "${AS_FOR_TARGET_$2:=\$(AS_FOR_TARGET)}"
 104     : "${LD_FOR_TARGET_$2:=\$(LD_FOR_TARGET)}"
 105     : "${CC_FOR_TARGET_$2:=\$(CC_FOR_TARGET)}"
 106   ])
 107 ])
 108 AS_VAR_APPEND([SIM_TOOLCHAIN_VARS], [" AS_FOR_TARGET_$2 LD_FOR_TARGET_$2 CC_FOR_TARGET_$2"])
 109 ])
 110 AC_DEFUN([SIM_AC_TOOLCHAIN_FOR_TARGET],
 111 [_SIM_AC_TOOLCHAIN_FOR_TARGET($1, m4_toupper(m4_translit($1, [-], [_])))])