projects / mesa.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
glsl: Handle the inout qualifier in fragment shader output declarations.
[mesa.git] / src / compiler / glsl / glsl_parser.yy
1 %{
2 /*
3 * Copyright © 2008, 2009 Intel Corporation
4 *
5 * Permission is hereby granted, free of charge, to any person obtaining a
6 * copy of this software and associated documentation files (the "Software"),
7 * to deal in the Software without restriction, including without limitation
8 * the rights to use, copy, modify, merge, publish, distribute, sublicense,
9 * and/or sell copies of the Software, and to permit persons to whom the
10 * Software is furnished to do so, subject to the following conditions:
11 *
12 * The above copyright notice and this permission notice (including the next
13 * paragraph) shall be included in all copies or substantial portions of the
14 * Software.
15 *
16 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
17 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
18 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
19 * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
20 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
21 * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
22 * DEALINGS IN THE SOFTWARE.
23 */
24 #include <stdio.h>
25 #include <stdlib.h>
26 #include <string.h>
27 #ifndef _MSC_VER
28 #include <strings.h>
29 #endif
30 #include <assert.h>
31
32 #include "ast.h"
33 #include "glsl_parser_extras.h"
34 #include "compiler/glsl_types.h"
35 #include "main/context.h"
36
37 #ifdef _MSC_VER
38 #pragma warning( disable : 4065 ) // switch statement contains 'default' but no 'case' labels
39 #endif
40
41 #undef yyerror
42
43 static void yyerror(YYLTYPE *loc, _mesa_glsl_parse_state *st, const char *msg)
44 {
45 _mesa_glsl_error(loc, st, "%s", msg);
46 }
47
48 static int
49 _mesa_glsl_lex(YYSTYPE *val, YYLTYPE *loc, _mesa_glsl_parse_state *state)
50 {
51 return _mesa_glsl_lexer_lex(val, loc, state->scanner);
52 }
53
54 static bool match_layout_qualifier(const char *s1, const char *s2,
55 _mesa_glsl_parse_state *state)
56 {
57 /* From the GLSL 1.50 spec, section 4.3.8 (Layout Qualifiers):
58 *
59 * "The tokens in any layout-qualifier-id-list ... are not case
60 * sensitive, unless explicitly noted otherwise."
61 *
62 * The text "unless explicitly noted otherwise" appears to be
63 * vacuous--no desktop GLSL spec (up through GLSL 4.40) notes
64 * otherwise.
65 *
66 * However, the GLSL ES 3.00 spec says, in section 4.3.8 (Layout
67 * Qualifiers):
68 *
69 * "As for other identifiers, they are case sensitive."
70 *
71 * So we need to do a case-sensitive or a case-insensitive match,
72 * depending on whether we are compiling for GLSL ES.
73 */
74 if (state->es_shader)
75 return strcmp(s1, s2);
76 else
77 return strcasecmp(s1, s2);
78 }
79 %}
80
81 %expect 0
82
83 %pure-parser
84 %error-verbose
85
86 %locations
87 %initial-action {
88 @$.first_line = 1;
89 @$.first_column = 1;
90 @$.last_line = 1;
91 @$.last_column = 1;
92 @$.source = 0;
93 }
94
95 %lex-param {struct _mesa_glsl_parse_state *state}
96 %parse-param {struct _mesa_glsl_parse_state *state}
97
98 %union {
99 int n;
100 float real;
101 double dreal;
102 const char *identifier;
103
104 struct ast_type_qualifier type_qualifier;
105
106 ast_node *node;
107 ast_type_specifier *type_specifier;
108 ast_array_specifier *array_specifier;
109 ast_fully_specified_type *fully_specified_type;
110 ast_function *function;
111 ast_parameter_declarator *parameter_declarator;
112 ast_function_definition *function_definition;
113 ast_compound_statement *compound_statement;
114 ast_expression *expression;
115 ast_declarator_list *declarator_list;
116 ast_struct_specifier *struct_specifier;
117 ast_declaration *declaration;
118 ast_switch_body *switch_body;
119 ast_case_label *case_label;
120 ast_case_label_list *case_label_list;
121 ast_case_statement *case_statement;
122 ast_case_statement_list *case_statement_list;
123 ast_interface_block *interface_block;
124 ast_subroutine_list *subroutine_list;
125 struct {
126 ast_node *cond;
127 ast_expression *rest;
128 } for_rest_statement;
129
130 struct {
131 ast_node *then_statement;
132 ast_node *else_statement;
133 } selection_rest_statement;
134 }
135
136 %token ATTRIBUTE CONST_TOK BOOL_TOK FLOAT_TOK INT_TOK UINT_TOK DOUBLE_TOK
137 %token BREAK BUFFER CONTINUE DO ELSE FOR IF DISCARD RETURN SWITCH CASE DEFAULT
138 %token BVEC2 BVEC3 BVEC4 IVEC2 IVEC3 IVEC4 UVEC2 UVEC3 UVEC4 VEC2 VEC3 VEC4 DVEC2 DVEC3 DVEC4
139 %token CENTROID IN_TOK OUT_TOK INOUT_TOK UNIFORM VARYING SAMPLE
140 %token NOPERSPECTIVE FLAT SMOOTH
141 %token MAT2X2 MAT2X3 MAT2X4
142 %token MAT3X2 MAT3X3 MAT3X4
143 %token MAT4X2 MAT4X3 MAT4X4
144 %token DMAT2X2 DMAT2X3 DMAT2X4
145 %token DMAT3X2 DMAT3X3 DMAT3X4
146 %token DMAT4X2 DMAT4X3 DMAT4X4
147 %token SAMPLER1D SAMPLER2D SAMPLER3D SAMPLERCUBE SAMPLER1DSHADOW SAMPLER2DSHADOW
148 %token SAMPLERCUBESHADOW SAMPLER1DARRAY SAMPLER2DARRAY SAMPLER1DARRAYSHADOW
149 %token SAMPLER2DARRAYSHADOW SAMPLERCUBEARRAY SAMPLERCUBEARRAYSHADOW
150 %token ISAMPLER1D ISAMPLER2D ISAMPLER3D ISAMPLERCUBE
151 %token ISAMPLER1DARRAY ISAMPLER2DARRAY ISAMPLERCUBEARRAY
152 %token USAMPLER1D USAMPLER2D USAMPLER3D USAMPLERCUBE USAMPLER1DARRAY
153 %token USAMPLER2DARRAY USAMPLERCUBEARRAY
154 %token SAMPLER2DRECT ISAMPLER2DRECT USAMPLER2DRECT SAMPLER2DRECTSHADOW
155 %token SAMPLERBUFFER ISAMPLERBUFFER USAMPLERBUFFER
156 %token SAMPLER2DMS ISAMPLER2DMS USAMPLER2DMS
157 %token SAMPLER2DMSARRAY ISAMPLER2DMSARRAY USAMPLER2DMSARRAY
158 %token SAMPLEREXTERNALOES
159 %token IMAGE1D IMAGE2D IMAGE3D IMAGE2DRECT IMAGECUBE IMAGEBUFFER
160 %token IMAGE1DARRAY IMAGE2DARRAY IMAGECUBEARRAY IMAGE2DMS IMAGE2DMSARRAY
161 %token IIMAGE1D IIMAGE2D IIMAGE3D IIMAGE2DRECT IIMAGECUBE IIMAGEBUFFER
162 %token IIMAGE1DARRAY IIMAGE2DARRAY IIMAGECUBEARRAY IIMAGE2DMS IIMAGE2DMSARRAY
163 %token UIMAGE1D UIMAGE2D UIMAGE3D UIMAGE2DRECT UIMAGECUBE UIMAGEBUFFER
164 %token UIMAGE1DARRAY UIMAGE2DARRAY UIMAGECUBEARRAY UIMAGE2DMS UIMAGE2DMSARRAY
165 %token IMAGE1DSHADOW IMAGE2DSHADOW IMAGE1DARRAYSHADOW IMAGE2DARRAYSHADOW
166 %token COHERENT VOLATILE RESTRICT READONLY WRITEONLY
167 %token ATOMIC_UINT
168 %token SHARED
169 %token STRUCT VOID_TOK WHILE
170 %token <identifier> IDENTIFIER TYPE_IDENTIFIER NEW_IDENTIFIER
171 %type <identifier> any_identifier
172 %type <interface_block> instance_name_opt
173 %token <real> FLOATCONSTANT
174 %token <dreal> DOUBLECONSTANT
175 %token <n> INTCONSTANT UINTCONSTANT BOOLCONSTANT
176 %token <identifier> FIELD_SELECTION
177 %token LEFT_OP RIGHT_OP
178 %token INC_OP DEC_OP LE_OP GE_OP EQ_OP NE_OP
179 %token AND_OP OR_OP XOR_OP MUL_ASSIGN DIV_ASSIGN ADD_ASSIGN
180 %token MOD_ASSIGN LEFT_ASSIGN RIGHT_ASSIGN AND_ASSIGN XOR_ASSIGN OR_ASSIGN
181 %token SUB_ASSIGN
182 %token INVARIANT PRECISE
183 %token LOWP MEDIUMP HIGHP SUPERP PRECISION
184
185 %token VERSION_TOK EXTENSION LINE COLON EOL INTERFACE OUTPUT
186 %token PRAGMA_DEBUG_ON PRAGMA_DEBUG_OFF
187 %token PRAGMA_OPTIMIZE_ON PRAGMA_OPTIMIZE_OFF
188 %token PRAGMA_INVARIANT_ALL
189 %token LAYOUT_TOK
190 %token DOT_TOK
191 /* Reserved words that are not actually used in the grammar.
192 */
193 %token ASM CLASS UNION ENUM TYPEDEF TEMPLATE THIS PACKED_TOK GOTO
194 %token INLINE_TOK NOINLINE PUBLIC_TOK STATIC EXTERN EXTERNAL
195 %token LONG_TOK SHORT_TOK HALF FIXED_TOK UNSIGNED INPUT_TOK
196 %token HVEC2 HVEC3 HVEC4 FVEC2 FVEC3 FVEC4
197 %token SAMPLER3DRECT
198 %token SIZEOF CAST NAMESPACE USING
199 %token RESOURCE PATCH
200 %token SUBROUTINE
201
202 %token ERROR_TOK
203
204 %token COMMON PARTITION ACTIVE FILTER ROW_MAJOR
205
206 %type <identifier> variable_identifier
207 %type <node> statement
208 %type <node> statement_list
209 %type <node> simple_statement
210 %type <n> precision_qualifier
211 %type <type_qualifier> type_qualifier
212 %type <type_qualifier> auxiliary_storage_qualifier
213 %type <type_qualifier> storage_qualifier
214 %type <type_qualifier> interpolation_qualifier
215 %type <type_qualifier> layout_qualifier
216 %type <type_qualifier> layout_qualifier_id_list layout_qualifier_id
217 %type <type_qualifier> interface_block_layout_qualifier
218 %type <type_qualifier> memory_qualifier
219 %type <type_qualifier> subroutine_qualifier
220 %type <subroutine_list> subroutine_type_list
221 %type <type_qualifier> interface_qualifier
222 %type <type_specifier> type_specifier
223 %type <type_specifier> type_specifier_nonarray
224 %type <array_specifier> array_specifier
225 %type <identifier> basic_type_specifier_nonarray
226 %type <fully_specified_type> fully_specified_type
227 %type <function> function_prototype
228 %type <function> function_header
229 %type <function> function_header_with_parameters
230 %type <function> function_declarator
231 %type <parameter_declarator> parameter_declarator
232 %type <parameter_declarator> parameter_declaration
233 %type <type_qualifier> parameter_qualifier
234 %type <type_qualifier> parameter_direction_qualifier
235 %type <type_specifier> parameter_type_specifier
236 %type <function_definition> function_definition
237 %type <compound_statement> compound_statement_no_new_scope
238 %type <compound_statement> compound_statement
239 %type <node> statement_no_new_scope
240 %type <node> expression_statement
241 %type <expression> expression
242 %type <expression> primary_expression
243 %type <expression> assignment_expression
244 %type <expression> conditional_expression
245 %type <expression> logical_or_expression
246 %type <expression> logical_xor_expression
247 %type <expression> logical_and_expression
248 %type <expression> inclusive_or_expression
249 %type <expression> exclusive_or_expression
250 %type <expression> and_expression
251 %type <expression> equality_expression
252 %type <expression> relational_expression
253 %type <expression> shift_expression
254 %type <expression> additive_expression
255 %type <expression> multiplicative_expression
256 %type <expression> unary_expression
257 %type <expression> constant_expression
258 %type <expression> integer_expression
259 %type <expression> postfix_expression
260 %type <expression> function_call_header_with_parameters
261 %type <expression> function_call_header_no_parameters
262 %type <expression> function_call_header
263 %type <expression> function_call_generic
264 %type <expression> function_call_or_method
265 %type <expression> function_call
266 %type <n> assignment_operator
267 %type <n> unary_operator
268 %type <expression> function_identifier
269 %type <node> external_declaration
270 %type <declarator_list> init_declarator_list
271 %type <declarator_list> single_declaration
272 %type <expression> initializer
273 %type <expression> initializer_list
274 %type <node> declaration
275 %type <node> declaration_statement
276 %type <node> jump_statement
277 %type <node> interface_block
278 %type <interface_block> basic_interface_block
279 %type <struct_specifier> struct_specifier
280 %type <declarator_list> struct_declaration_list
281 %type <declarator_list> struct_declaration
282 %type <declaration> struct_declarator
283 %type <declaration> struct_declarator_list
284 %type <declarator_list> member_list
285 %type <declarator_list> member_declaration
286 %type <node> selection_statement
287 %type <selection_rest_statement> selection_rest_statement
288 %type <node> switch_statement
289 %type <switch_body> switch_body
290 %type <case_label_list> case_label_list
291 %type <case_label> case_label
292 %type <case_statement> case_statement
293 %type <case_statement_list> case_statement_list
294 %type <node> iteration_statement
295 %type <node> condition
296 %type <node> conditionopt
297 %type <node> for_init_statement
298 %type <for_rest_statement> for_rest_statement
299 %type <node> layout_defaults
300 %type <node> layout_uniform_defaults
301 %type <node> layout_buffer_defaults
302 %type <node> layout_in_defaults
303 %type <node> layout_out_defaults
304
305 %right THEN ELSE
306 %%
307
308 translation_unit:
309 version_statement extension_statement_list
310 {
311 _mesa_glsl_initialize_types(state);
312 }
313 external_declaration_list
314 {
315 delete state->symbols;
316 state->symbols = new(ralloc_parent(state)) glsl_symbol_table;
317 if (state->es_shader) {
318 if (state->stage == MESA_SHADER_FRAGMENT) {
319 state->symbols->add_default_precision_qualifier("int", ast_precision_medium);
320 } else {
321 state->symbols->add_default_precision_qualifier("float", ast_precision_high);
322 state->symbols->add_default_precision_qualifier("int", ast_precision_high);
323 }
324 state->symbols->add_default_precision_qualifier("sampler2D", ast_precision_low);
325 state->symbols->add_default_precision_qualifier("samplerExternalOES", ast_precision_low);
326 state->symbols->add_default_precision_qualifier("samplerCube", ast_precision_low);
327 state->symbols->add_default_precision_qualifier("atomic_uint", ast_precision_high);
328 }
329 _mesa_glsl_initialize_types(state);
330 }
331 ;
332
333 version_statement:
334 /* blank - no #version specified: defaults are already set */
335 | VERSION_TOK INTCONSTANT EOL
336 {
337 state->process_version_directive(&@2, $2, NULL);
338 if (state->error) {
339 YYERROR;
340 }
341 }
342 | VERSION_TOK INTCONSTANT any_identifier EOL
343 {
344 state->process_version_directive(&@2, $2, $3);
345 if (state->error) {
346 YYERROR;
347 }
348 }
349 ;
350
351 pragma_statement:
352 PRAGMA_DEBUG_ON EOL
353 | PRAGMA_DEBUG_OFF EOL
354 | PRAGMA_OPTIMIZE_ON EOL
355 | PRAGMA_OPTIMIZE_OFF EOL
356 | PRAGMA_INVARIANT_ALL EOL
357 {
358 /* Pragma invariant(all) cannot be used in a fragment shader.
359 *
360 * Page 27 of the GLSL 1.20 spec, Page 53 of the GLSL ES 3.00 spec:
361 *
362 * "It is an error to use this pragma in a fragment shader."
363 */
364 if (state->is_version(120, 300) &&
365 state->stage == MESA_SHADER_FRAGMENT) {
366 _mesa_glsl_error(& @1, state,
367 "pragma `invariant(all)' cannot be used "
368 "in a fragment shader.");
369 } else if (!state->is_version(120, 100)) {
370 _mesa_glsl_warning(& @1, state,
371 "pragma `invariant(all)' not supported in %s "
372 "(GLSL ES 1.00 or GLSL 1.20 required)",
373 state->get_version_string());
374 } else {
375 state->all_invariant = true;
376 }
377 }
378 ;
379
380 extension_statement_list:
381
382 | extension_statement_list extension_statement
383 ;
384
385 any_identifier:
386 IDENTIFIER
387 | TYPE_IDENTIFIER
388 | NEW_IDENTIFIER
389 ;
390
391 extension_statement:
392 EXTENSION any_identifier COLON any_identifier EOL
393 {
394 if (!_mesa_glsl_process_extension($2, & @2, $4, & @4, state)) {
395 YYERROR;
396 }
397 }
398 ;
399
400 external_declaration_list:
401 external_declaration
402 {
403 /* FINISHME: The NULL test is required because pragmas are set to
404 * FINISHME: NULL. (See production rule for external_declaration.)
405 */
406 if ($1 != NULL)
407 state->translation_unit.push_tail(& $1->link);
408 }
409 | external_declaration_list external_declaration
410 {
411 /* FINISHME: The NULL test is required because pragmas are set to
412 * FINISHME: NULL. (See production rule for external_declaration.)
413 */
414 if ($2 != NULL)
415 state->translation_unit.push_tail(& $2->link);
416 }
417 | external_declaration_list extension_statement {
418 if (!state->allow_extension_directive_midshader) {
419 _mesa_glsl_error(& @2, state,
420 "#extension directive is not allowed "
421 "in the middle of a shader");
422 YYERROR;
423 }
424 }
425 ;
426
427 variable_identifier:
428 IDENTIFIER
429 | NEW_IDENTIFIER
430 ;
431
432 primary_expression:
433 variable_identifier
434 {
435 void *ctx = state;
436 $$ = new(ctx) ast_expression(ast_identifier, NULL, NULL, NULL);
437 $$->set_location(@1);
438 $$->primary_expression.identifier = $1;
439 }
440 | INTCONSTANT
441 {
442 void *ctx = state;
443 $$ = new(ctx) ast_expression(ast_int_constant, NULL, NULL, NULL);
444 $$->set_location(@1);
445 $$->primary_expression.int_constant = $1;
446 }
447 | UINTCONSTANT
448 {
449 void *ctx = state;
450 $$ = new(ctx) ast_expression(ast_uint_constant, NULL, NULL, NULL);
451 $$->set_location(@1);
452 $$->primary_expression.uint_constant = $1;
453 }
454 | FLOATCONSTANT
455 {
456 void *ctx = state;
457 $$ = new(ctx) ast_expression(ast_float_constant, NULL, NULL, NULL);
458 $$->set_location(@1);
459 $$->primary_expression.float_constant = $1;
460 }
461 | DOUBLECONSTANT
462 {
463 void *ctx = state;
464 $$ = new(ctx) ast_expression(ast_double_constant, NULL, NULL, NULL);
465 $$->set_location(@1);
466 $$->primary_expression.double_constant = $1;
467 }
468 | BOOLCONSTANT
469 {
470 void *ctx = state;
471 $$ = new(ctx) ast_expression(ast_bool_constant, NULL, NULL, NULL);
472 $$->set_location(@1);
473 $$->primary_expression.bool_constant = $1;
474 }
475 | '(' expression ')'
476 {
477 $$ = $2;
478 }
479 ;
480
481 postfix_expression:
482 primary_expression
483 | postfix_expression '[' integer_expression ']'
484 {
485 void *ctx = state;
486 $$ = new(ctx) ast_expression(ast_array_index, $1, $3, NULL);
487 $$->set_location_range(@1, @4);
488 }
489 | function_call
490 {
491 $$ = $1;
492 }
493 | postfix_expression DOT_TOK FIELD_SELECTION
494 {
495 void *ctx = state;
496 $$ = new(ctx) ast_expression(ast_field_selection, $1, NULL, NULL);
497 $$->set_location_range(@1, @3);
498 $$->primary_expression.identifier = $3;
499 }
500 | postfix_expression INC_OP
501 {
502 void *ctx = state;
503 $$ = new(ctx) ast_expression(ast_post_inc, $1, NULL, NULL);
504 $$->set_location_range(@1, @2);
505 }
506 | postfix_expression DEC_OP
507 {
508 void *ctx = state;
509 $$ = new(ctx) ast_expression(ast_post_dec, $1, NULL, NULL);
510 $$->set_location_range(@1, @2);
511 }
512 ;
513
514 integer_expression:
515 expression
516 ;
517
518 function_call:
519 function_call_or_method
520 ;
521
522 function_call_or_method:
523 function_call_generic
524 ;
525
526 function_call_generic:
527 function_call_header_with_parameters ')'
528 | function_call_header_no_parameters ')'
529 ;
530
531 function_call_header_no_parameters:
532 function_call_header VOID_TOK
533 | function_call_header
534 ;
535
536 function_call_header_with_parameters:
537 function_call_header assignment_expression
538 {
539 $$ = $1;
540 $$->set_location(@1);
541 $$->expressions.push_tail(& $2->link);
542 }
543 | function_call_header_with_parameters ',' assignment_expression
544 {
545 $$ = $1;
546 $$->set_location(@1);
547 $$->expressions.push_tail(& $3->link);
548 }
549 ;
550
551 // Grammar Note: Constructors look like functions, but lexical
552 // analysis recognized most of them as keywords. They are now
553 // recognized through "type_specifier".
554 function_call_header:
555 function_identifier '('
556 ;
557
558 function_identifier:
559 type_specifier
560 {
561 void *ctx = state;
562 $$ = new(ctx) ast_function_expression($1);
563 $$->set_location(@1);
564 }
565 | postfix_expression
566 {
567 void *ctx = state;
568 $$ = new(ctx) ast_function_expression($1);
569 $$->set_location(@1);
570 }
571 ;
572
573 // Grammar Note: Constructors look like methods, but lexical
574 // analysis recognized most of them as keywords. They are now
575 // recognized through "type_specifier".
576
577 // Grammar Note: No traditional style type casts.
578 unary_expression:
579 postfix_expression
580 | INC_OP unary_expression
581 {
582 void *ctx = state;
583 $$ = new(ctx) ast_expression(ast_pre_inc, $2, NULL, NULL);
584 $$->set_location(@1);
585 }
586 | DEC_OP unary_expression
587 {
588 void *ctx = state;
589 $$ = new(ctx) ast_expression(ast_pre_dec, $2, NULL, NULL);
590 $$->set_location(@1);
591 }
592 | unary_operator unary_expression
593 {
594 void *ctx = state;
595 $$ = new(ctx) ast_expression($1, $2, NULL, NULL);
596 $$->set_location_range(@1, @2);
597 }
598 ;
599
600 // Grammar Note: No '*' or '&' unary ops. Pointers are not supported.
601 unary_operator:
602 '+' { $$ = ast_plus; }
603 | '-' { $$ = ast_neg; }
604 | '!' { $$ = ast_logic_not; }
605 | '~' { $$ = ast_bit_not; }
606 ;
607
608 multiplicative_expression:
609 unary_expression
610 | multiplicative_expression '*' unary_expression
611 {
612 void *ctx = state;
613 $$ = new(ctx) ast_expression_bin(ast_mul, $1, $3);
614 $$->set_location_range(@1, @3);
615 }
616 | multiplicative_expression '/' unary_expression
617 {
618 void *ctx = state;
619 $$ = new(ctx) ast_expression_bin(ast_div, $1, $3);
620 $$->set_location_range(@1, @3);
621 }
622 | multiplicative_expression '%' unary_expression
623 {
624 void *ctx = state;
625 $$ = new(ctx) ast_expression_bin(ast_mod, $1, $3);
626 $$->set_location_range(@1, @3);
627 }
628 ;
629
630 additive_expression:
631 multiplicative_expression
632 | additive_expression '+' multiplicative_expression
633 {
634 void *ctx = state;
635 $$ = new(ctx) ast_expression_bin(ast_add, $1, $3);
636 $$->set_location_range(@1, @3);
637 }
638 | additive_expression '-' multiplicative_expression
639 {
640 void *ctx = state;
641 $$ = new(ctx) ast_expression_bin(ast_sub, $1, $3);
642 $$->set_location_range(@1, @3);
643 }
644 ;
645
646 shift_expression:
647 additive_expression
648 | shift_expression LEFT_OP additive_expression
649 {
650 void *ctx = state;
651 $$ = new(ctx) ast_expression_bin(ast_lshift, $1, $3);
652 $$->set_location_range(@1, @3);
653 }
654 | shift_expression RIGHT_OP additive_expression
655 {
656 void *ctx = state;
657 $$ = new(ctx) ast_expression_bin(ast_rshift, $1, $3);
658 $$->set_location_range(@1, @3);
659 }
660 ;
661
662 relational_expression:
663 shift_expression
664 | relational_expression '<' shift_expression
665 {
666 void *ctx = state;
667 $$ = new(ctx) ast_expression_bin(ast_less, $1, $3);
668 $$->set_location_range(@1, @3);
669 }
670 | relational_expression '>' shift_expression
671 {
672 void *ctx = state;
673 $$ = new(ctx) ast_expression_bin(ast_greater, $1, $3);
674 $$->set_location_range(@1, @3);
675 }
676 | relational_expression LE_OP shift_expression
677 {
678 void *ctx = state;
679 $$ = new(ctx) ast_expression_bin(ast_lequal, $1, $3);
680 $$->set_location_range(@1, @3);
681 }
682 | relational_expression GE_OP shift_expression
683 {
684 void *ctx = state;
685 $$ = new(ctx) ast_expression_bin(ast_gequal, $1, $3);
686 $$->set_location_range(@1, @3);
687 }
688 ;
689
690 equality_expression:
691 relational_expression
692 | equality_expression EQ_OP relational_expression
693 {
694 void *ctx = state;
695 $$ = new(ctx) ast_expression_bin(ast_equal, $1, $3);
696 $$->set_location_range(@1, @3);
697 }
698 | equality_expression NE_OP relational_expression
699 {
700 void *ctx = state;
701 $$ = new(ctx) ast_expression_bin(ast_nequal, $1, $3);
702 $$->set_location_range(@1, @3);
703 }
704 ;
705
706 and_expression:
707 equality_expression
708 | and_expression '&' equality_expression
709 {
710 void *ctx = state;
711 $$ = new(ctx) ast_expression_bin(ast_bit_and, $1, $3);
712 $$->set_location_range(@1, @3);
713 }
714 ;
715
716 exclusive_or_expression:
717 and_expression
718 | exclusive_or_expression '^' and_expression
719 {
720 void *ctx = state;
721 $$ = new(ctx) ast_expression_bin(ast_bit_xor, $1, $3);
722 $$->set_location_range(@1, @3);
723 }
724 ;
725
726 inclusive_or_expression:
727 exclusive_or_expression
728 | inclusive_or_expression '|' exclusive_or_expression
729 {
730 void *ctx = state;
731 $$ = new(ctx) ast_expression_bin(ast_bit_or, $1, $3);
732 $$->set_location_range(@1, @3);
733 }
734 ;
735
736 logical_and_expression:
737 inclusive_or_expression
738 | logical_and_expression AND_OP inclusive_or_expression
739 {
740 void *ctx = state;
741 $$ = new(ctx) ast_expression_bin(ast_logic_and, $1, $3);
742 $$->set_location_range(@1, @3);
743 }
744 ;
745
746 logical_xor_expression:
747 logical_and_expression
748 | logical_xor_expression XOR_OP logical_and_expression
749 {
750 void *ctx = state;
751 $$ = new(ctx) ast_expression_bin(ast_logic_xor, $1, $3);
752 $$->set_location_range(@1, @3);
753 }
754 ;
755
756 logical_or_expression:
757 logical_xor_expression
758 | logical_or_expression OR_OP logical_xor_expression
759 {
760 void *ctx = state;
761 $$ = new(ctx) ast_expression_bin(ast_logic_or, $1, $3);
762 $$->set_location_range(@1, @3);
763 }
764 ;
765
766 conditional_expression:
767 logical_or_expression
768 | logical_or_expression '?' expression ':' assignment_expression
769 {
770 void *ctx = state;
771 $$ = new(ctx) ast_expression(ast_conditional, $1, $3, $5);
772 $$->set_location_range(@1, @5);
773 }
774 ;
775
776 assignment_expression:
777 conditional_expression
778 | unary_expression assignment_operator assignment_expression
779 {
780 void *ctx = state;
781 $$ = new(ctx) ast_expression($2, $1, $3, NULL);
782 $$->set_location_range(@1, @3);
783 }
784 ;
785
786 assignment_operator:
787 '=' { $$ = ast_assign; }
788 | MUL_ASSIGN { $$ = ast_mul_assign; }
789 | DIV_ASSIGN { $$ = ast_div_assign; }
790 | MOD_ASSIGN { $$ = ast_mod_assign; }
791 | ADD_ASSIGN { $$ = ast_add_assign; }
792 | SUB_ASSIGN { $$ = ast_sub_assign; }
793 | LEFT_ASSIGN { $$ = ast_ls_assign; }
794 | RIGHT_ASSIGN { $$ = ast_rs_assign; }
795 | AND_ASSIGN { $$ = ast_and_assign; }
796 | XOR_ASSIGN { $$ = ast_xor_assign; }
797 | OR_ASSIGN { $$ = ast_or_assign; }
798 ;
799
800 expression:
801 assignment_expression
802 {
803 $$ = $1;
804 }
805 | expression ',' assignment_expression
806 {
807 void *ctx = state;
808 if ($1->oper != ast_sequence) {
809 $$ = new(ctx) ast_expression(ast_sequence, NULL, NULL, NULL);
810 $$->set_location_range(@1, @3);
811 $$->expressions.push_tail(& $1->link);
812 } else {
813 $$ = $1;
814 }
815
816 $$->expressions.push_tail(& $3->link);
817 }
818 ;
819
820 constant_expression:
821 conditional_expression
822 ;
823
824 declaration:
825 function_prototype ';'
826 {
827 state->symbols->pop_scope();
828 $$ = $1;
829 }
830 | init_declarator_list ';'
831 {
832 $$ = $1;
833 }
834 | PRECISION precision_qualifier type_specifier ';'
835 {
836 $3->default_precision = $2;
837 $$ = $3;
838 }
839 | interface_block
840 {
841 $$ = $1;
842 }
843 ;
844
845 function_prototype:
846 function_declarator ')'
847 ;
848
849 function_declarator:
850 function_header
851 | function_header_with_parameters
852 ;
853
854 function_header_with_parameters:
855 function_header parameter_declaration
856 {
857 $$ = $1;
858 $$->parameters.push_tail(& $2->link);
859 }
860 | function_header_with_parameters ',' parameter_declaration
861 {
862 $$ = $1;
863 $$->parameters.push_tail(& $3->link);
864 }
865 ;
866
867 function_header:
868 fully_specified_type variable_identifier '('
869 {
870 void *ctx = state;
871 $$ = new(ctx) ast_function();
872 $$->set_location(@2);
873 $$->return_type = $1;
874 $$->identifier = $2;
875
876 if ($1->qualifier.flags.q.subroutine) {
877 /* add type for IDENTIFIER search */
878 state->symbols->add_type($2, glsl_type::get_subroutine_instance($2));
879 } else
880 state->symbols->add_function(new(state) ir_function($2));
881 state->symbols->push_scope();
882 }
883 ;
884
885 parameter_declarator:
886 type_specifier any_identifier
887 {
888 void *ctx = state;
889 $$ = new(ctx) ast_parameter_declarator();
890 $$->set_location_range(@1, @2);
891 $$->type = new(ctx) ast_fully_specified_type();
892 $$->type->set_location(@1);
893 $$->type->specifier = $1;
894 $$->identifier = $2;
895 state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
896 }
897 | type_specifier any_identifier array_specifier
898 {
899 void *ctx = state;
900 $$ = new(ctx) ast_parameter_declarator();
901 $$->set_location_range(@1, @3);
902 $$->type = new(ctx) ast_fully_specified_type();
903 $$->type->set_location(@1);
904 $$->type->specifier = $1;
905 $$->identifier = $2;
906 $$->array_specifier = $3;
907 state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
908 }
909 ;
910
911 parameter_declaration:
912 parameter_qualifier parameter_declarator
913 {
914 $$ = $2;
915 $$->type->qualifier = $1;
916 }
917 | parameter_qualifier parameter_type_specifier
918 {
919 void *ctx = state;
920 $$ = new(ctx) ast_parameter_declarator();
921 $$->set_location(@2);
922 $$->type = new(ctx) ast_fully_specified_type();
923 $$->type->set_location_range(@1, @2);
924 $$->type->qualifier = $1;
925 $$->type->specifier = $2;
926 }
927 ;
928
929 parameter_qualifier:
930 /* empty */
931 {
932 memset(& $$, 0, sizeof($$));
933 }
934 | CONST_TOK parameter_qualifier
935 {
936 if ($2.flags.q.constant)
937 _mesa_glsl_error(&@1, state, "duplicate const qualifier");
938
939 $$ = $2;
940 $$.flags.q.constant = 1;
941 }
942 | PRECISE parameter_qualifier
943 {
944 if ($2.flags.q.precise)
945 _mesa_glsl_error(&@1, state, "duplicate precise qualifier");
946
947 $$ = $2;
948 $$.flags.q.precise = 1;
949 }
950 | parameter_direction_qualifier parameter_qualifier
951 {
952 if (($1.flags.q.in || $1.flags.q.out) && ($2.flags.q.in || $2.flags.q.out))
953 _mesa_glsl_error(&@1, state, "duplicate in/out/inout qualifier");
954
955 if (!state->has_420pack_or_es31() && $2.flags.q.constant)
956 _mesa_glsl_error(&@1, state, "in/out/inout must come after const "
957 "or precise");
958
959 $$ = $1;
960 $$.merge_qualifier(&@1, state, $2, false);
961 }
962 | precision_qualifier parameter_qualifier
963 {
964 if ($2.precision != ast_precision_none)
965 _mesa_glsl_error(&@1, state, "duplicate precision qualifier");
966
967 if (!state->has_420pack_or_es31() &&
968 $2.flags.i != 0)
969 _mesa_glsl_error(&@1, state, "precision qualifiers must come last");
970
971 $$ = $2;
972 $$.precision = $1;
973 }
974 | memory_qualifier parameter_qualifier
975 {
976 $$ = $1;
977 $$.merge_qualifier(&@1, state, $2, false);
978 }
979
980 parameter_direction_qualifier:
981 IN_TOK
982 {
983 memset(& $$, 0, sizeof($$));
984 $$.flags.q.in = 1;
985 }
986 | OUT_TOK
987 {
988 memset(& $$, 0, sizeof($$));
989 $$.flags.q.out = 1;
990 }
991 | INOUT_TOK
992 {
993 memset(& $$, 0, sizeof($$));
994 $$.flags.q.in = 1;
995 $$.flags.q.out = 1;
996 }
997 ;
998
999 parameter_type_specifier:
1000 type_specifier
1001 ;
1002
1003 init_declarator_list:
1004 single_declaration
1005 | init_declarator_list ',' any_identifier
1006 {
1007 void *ctx = state;
1008 ast_declaration *decl = new(ctx) ast_declaration($3, NULL, NULL);
1009 decl->set_location(@3);
1010
1011 $$ = $1;
1012 $$->declarations.push_tail(&decl->link);
1013 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1014 }
1015 | init_declarator_list ',' any_identifier array_specifier
1016 {
1017 void *ctx = state;
1018 ast_declaration *decl = new(ctx) ast_declaration($3, $4, NULL);
1019 decl->set_location_range(@3, @4);
1020
1021 $$ = $1;
1022 $$->declarations.push_tail(&decl->link);
1023 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1024 }
1025 | init_declarator_list ',' any_identifier array_specifier '=' initializer
1026 {
1027 void *ctx = state;
1028 ast_declaration *decl = new(ctx) ast_declaration($3, $4, $6);
1029 decl->set_location_range(@3, @4);
1030
1031 $$ = $1;
1032 $$->declarations.push_tail(&decl->link);
1033 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1034 }
1035 | init_declarator_list ',' any_identifier '=' initializer
1036 {
1037 void *ctx = state;
1038 ast_declaration *decl = new(ctx) ast_declaration($3, NULL, $5);
1039 decl->set_location(@3);
1040
1041 $$ = $1;
1042 $$->declarations.push_tail(&decl->link);
1043 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1044 }
1045 ;
1046
1047 // Grammar Note: No 'enum', or 'typedef'.
1048 single_declaration:
1049 fully_specified_type
1050 {
1051 void *ctx = state;
1052 /* Empty declaration list is valid. */
1053 $$ = new(ctx) ast_declarator_list($1);
1054 $$->set_location(@1);
1055 }
1056 | fully_specified_type any_identifier
1057 {
1058 void *ctx = state;
1059 ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1060 decl->set_location(@2);
1061
1062 $$ = new(ctx) ast_declarator_list($1);
1063 $$->set_location_range(@1, @2);
1064 $$->declarations.push_tail(&decl->link);
1065 state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
1066 }
1067 | fully_specified_type any_identifier array_specifier
1068 {
1069 void *ctx = state;
1070 ast_declaration *decl = new(ctx) ast_declaration($2, $3, NULL);
1071 decl->set_location_range(@2, @3);
1072
1073 $$ = new(ctx) ast_declarator_list($1);
1074 $$->set_location_range(@1, @3);
1075 $$->declarations.push_tail(&decl->link);
1076 state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
1077 }
1078 | fully_specified_type any_identifier array_specifier '=' initializer
1079 {
1080 void *ctx = state;
1081 ast_declaration *decl = new(ctx) ast_declaration($2, $3, $5);
1082 decl->set_location_range(@2, @3);
1083
1084 $$ = new(ctx) ast_declarator_list($1);
1085 $$->set_location_range(@1, @3);
1086 $$->declarations.push_tail(&decl->link);
1087 state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
1088 }
1089 | fully_specified_type any_identifier '=' initializer
1090 {
1091 void *ctx = state;
1092 ast_declaration *decl = new(ctx) ast_declaration($2, NULL, $4);
1093 decl->set_location(@2);
1094
1095 $$ = new(ctx) ast_declarator_list($1);
1096 $$->set_location_range(@1, @2);
1097 $$->declarations.push_tail(&decl->link);
1098 state->symbols->add_variable(new(state) ir_variable(NULL, $2, ir_var_auto));
1099 }
1100 | INVARIANT variable_identifier
1101 {
1102 void *ctx = state;
1103 ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1104 decl->set_location(@2);
1105
1106 $$ = new(ctx) ast_declarator_list(NULL);
1107 $$->set_location_range(@1, @2);
1108 $$->invariant = true;
1109
1110 $$->declarations.push_tail(&decl->link);
1111 }
1112 | PRECISE variable_identifier
1113 {
1114 void *ctx = state;
1115 ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1116 decl->set_location(@2);
1117
1118 $$ = new(ctx) ast_declarator_list(NULL);
1119 $$->set_location_range(@1, @2);
1120 $$->precise = true;
1121
1122 $$->declarations.push_tail(&decl->link);
1123 }
1124 ;
1125
1126 fully_specified_type:
1127 type_specifier
1128 {
1129 void *ctx = state;
1130 $$ = new(ctx) ast_fully_specified_type();
1131 $$->set_location(@1);
1132 $$->specifier = $1;
1133 }
1134 | type_qualifier type_specifier
1135 {
1136 void *ctx = state;
1137 $$ = new(ctx) ast_fully_specified_type();
1138 $$->set_location_range(@1, @2);
1139 $$->qualifier = $1;
1140 $$->specifier = $2;
1141 if ($$->specifier->structure != NULL &&
1142 $$->specifier->structure->is_declaration) {
1143 $$->specifier->structure->layout = &$$->qualifier;
1144 }
1145 }
1146 ;
1147
1148 layout_qualifier:
1149 LAYOUT_TOK '(' layout_qualifier_id_list ')'
1150 {
1151 $$ = $3;
1152 }
1153 ;
1154
1155 layout_qualifier_id_list:
1156 layout_qualifier_id
1157 | layout_qualifier_id_list ',' layout_qualifier_id
1158 {
1159 $$ = $1;
1160 if (!$$.merge_qualifier(& @3, state, $3, true)) {
1161 YYERROR;
1162 }
1163 }
1164 ;
1165
1166 layout_qualifier_id:
1167 any_identifier
1168 {
1169 memset(& $$, 0, sizeof($$));
1170
1171 /* Layout qualifiers for ARB_fragment_coord_conventions. */
1172 if (!$$.flags.i && (state->ARB_fragment_coord_conventions_enable ||
1173 state->is_version(150, 0))) {
1174 if (match_layout_qualifier($1, "origin_upper_left", state) == 0) {
1175 $$.flags.q.origin_upper_left = 1;
1176 } else if (match_layout_qualifier($1, "pixel_center_integer",
1177 state) == 0) {
1178 $$.flags.q.pixel_center_integer = 1;
1179 }
1180
1181 if ($$.flags.i && state->ARB_fragment_coord_conventions_warn) {
1182 _mesa_glsl_warning(& @1, state,
1183 "GL_ARB_fragment_coord_conventions layout "
1184 "identifier `%s' used", $1);
1185 }
1186 }
1187
1188 /* Layout qualifiers for AMD/ARB_conservative_depth. */
1189 if (!$$.flags.i &&
1190 (state->AMD_conservative_depth_enable ||
1191 state->ARB_conservative_depth_enable ||
1192 state->is_version(420, 0))) {
1193 if (match_layout_qualifier($1, "depth_any", state) == 0) {
1194 $$.flags.q.depth_any = 1;
1195 } else if (match_layout_qualifier($1, "depth_greater", state) == 0) {
1196 $$.flags.q.depth_greater = 1;
1197 } else if (match_layout_qualifier($1, "depth_less", state) == 0) {
1198 $$.flags.q.depth_less = 1;
1199 } else if (match_layout_qualifier($1, "depth_unchanged",
1200 state) == 0) {
1201 $$.flags.q.depth_unchanged = 1;
1202 }
1203
1204 if ($$.flags.i && state->AMD_conservative_depth_warn) {
1205 _mesa_glsl_warning(& @1, state,
1206 "GL_AMD_conservative_depth "
1207 "layout qualifier `%s' is used", $1);
1208 }
1209 if ($$.flags.i && state->ARB_conservative_depth_warn) {
1210 _mesa_glsl_warning(& @1, state,
1211 "GL_ARB_conservative_depth "
1212 "layout qualifier `%s' is used", $1);
1213 }
1214 }
1215
1216 /* See also interface_block_layout_qualifier. */
1217 if (!$$.flags.i && state->has_uniform_buffer_objects()) {
1218 if (match_layout_qualifier($1, "std140", state) == 0) {
1219 $$.flags.q.std140 = 1;
1220 } else if (match_layout_qualifier($1, "shared", state) == 0) {
1221 $$.flags.q.shared = 1;
1222 } else if (match_layout_qualifier($1, "std430", state) == 0) {
1223 $$.flags.q.std430 = 1;
1224 } else if (match_layout_qualifier($1, "column_major", state) == 0) {
1225 $$.flags.q.column_major = 1;
1226 /* "row_major" is a reserved word in GLSL 1.30+. Its token is parsed
1227 * below in the interface_block_layout_qualifier rule.
1228 *
1229 * It is not a reserved word in GLSL ES 3.00, so it's handled here as
1230 * an identifier.
1231 *
1232 * Also, this takes care of alternate capitalizations of
1233 * "row_major" (which is necessary because layout qualifiers
1234 * are case-insensitive in desktop GLSL).
1235 */
1236 } else if (match_layout_qualifier($1, "row_major", state) == 0) {
1237 $$.flags.q.row_major = 1;
1238 /* "packed" is a reserved word in GLSL, and its token is
1239 * parsed below in the interface_block_layout_qualifier rule.
1240 * However, we must take care of alternate capitalizations of
1241 * "packed", because layout qualifiers are case-insensitive
1242 * in desktop GLSL.
1243 */
1244 } else if (match_layout_qualifier($1, "packed", state) == 0) {
1245 $$.flags.q.packed = 1;
1246 }
1247
1248 if ($$.flags.i && state->ARB_uniform_buffer_object_warn) {
1249 _mesa_glsl_warning(& @1, state,
1250 "#version 140 / GL_ARB_uniform_buffer_object "
1251 "layout qualifier `%s' is used", $1);
1252 }
1253 }
1254
1255 /* Layout qualifiers for GLSL 1.50 geometry shaders. */
1256 if (!$$.flags.i) {
1257 static const struct {
1258 const char *s;
1259 GLenum e;
1260 } map[] = {
1261 { "points", GL_POINTS },
1262 { "lines", GL_LINES },
1263 { "lines_adjacency", GL_LINES_ADJACENCY },
1264 { "line_strip", GL_LINE_STRIP },
1265 { "triangles", GL_TRIANGLES },
1266 { "triangles_adjacency", GL_TRIANGLES_ADJACENCY },
1267 { "triangle_strip", GL_TRIANGLE_STRIP },
1268 };
1269 for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1270 if (match_layout_qualifier($1, map[i].s, state) == 0) {
1271 $$.flags.q.prim_type = 1;
1272 $$.prim_type = map[i].e;
1273 break;
1274 }
1275 }
1276
1277 if ($$.flags.i && !state->has_geometry_shader() &&
1278 !state->has_tessellation_shader()) {
1279 _mesa_glsl_error(& @1, state, "#version 150 layout "
1280 "qualifier `%s' used", $1);
1281 }
1282 }
1283
1284 /* Layout qualifiers for ARB_shader_image_load_store. */
1285 if (state->ARB_shader_image_load_store_enable ||
1286 state->is_version(420, 310)) {
1287 if (!$$.flags.i) {
1288 static const struct {
1289 const char *name;
1290 GLenum format;
1291 glsl_base_type base_type;
1292 /** Minimum desktop GLSL version required for the image
1293 * format. Use 130 if already present in the original
1294 * ARB extension.
1295 */
1296 unsigned required_glsl;
1297 /** Minimum GLSL ES version required for the image format. */
1298 unsigned required_essl;
1299 } map[] = {
1300 { "rgba32f", GL_RGBA32F, GLSL_TYPE_FLOAT, 130, 310 },
1301 { "rgba16f", GL_RGBA16F, GLSL_TYPE_FLOAT, 130, 310 },
1302 { "rg32f", GL_RG32F, GLSL_TYPE_FLOAT, 130, 0 },
1303 { "rg16f", GL_RG16F, GLSL_TYPE_FLOAT, 130, 0 },
1304 { "r11f_g11f_b10f", GL_R11F_G11F_B10F, GLSL_TYPE_FLOAT, 130, 0 },
1305 { "r32f", GL_R32F, GLSL_TYPE_FLOAT, 130, 310 },
1306 { "r16f", GL_R16F, GLSL_TYPE_FLOAT, 130, 0 },
1307 { "rgba32ui", GL_RGBA32UI, GLSL_TYPE_UINT, 130, 310 },
1308 { "rgba16ui", GL_RGBA16UI, GLSL_TYPE_UINT, 130, 310 },
1309 { "rgb10_a2ui", GL_RGB10_A2UI, GLSL_TYPE_UINT, 130, 0 },
1310 { "rgba8ui", GL_RGBA8UI, GLSL_TYPE_UINT, 130, 310 },
1311 { "rg32ui", GL_RG32UI, GLSL_TYPE_UINT, 130, 0 },
1312 { "rg16ui", GL_RG16UI, GLSL_TYPE_UINT, 130, 0 },
1313 { "rg8ui", GL_RG8UI, GLSL_TYPE_UINT, 130, 0 },
1314 { "r32ui", GL_R32UI, GLSL_TYPE_UINT, 130, 310 },
1315 { "r16ui", GL_R16UI, GLSL_TYPE_UINT, 130, 0 },
1316 { "r8ui", GL_R8UI, GLSL_TYPE_UINT, 130, 0 },
1317 { "rgba32i", GL_RGBA32I, GLSL_TYPE_INT, 130, 310 },
1318 { "rgba16i", GL_RGBA16I, GLSL_TYPE_INT, 130, 310 },
1319 { "rgba8i", GL_RGBA8I, GLSL_TYPE_INT, 130, 310 },
1320 { "rg32i", GL_RG32I, GLSL_TYPE_INT, 130, 0 },
1321 { "rg16i", GL_RG16I, GLSL_TYPE_INT, 130, 0 },
1322 { "rg8i", GL_RG8I, GLSL_TYPE_INT, 130, 0 },
1323 { "r32i", GL_R32I, GLSL_TYPE_INT, 130, 310 },
1324 { "r16i", GL_R16I, GLSL_TYPE_INT, 130, 0 },
1325 { "r8i", GL_R8I, GLSL_TYPE_INT, 130, 0 },
1326 { "rgba16", GL_RGBA16, GLSL_TYPE_FLOAT, 130, 0 },
1327 { "rgb10_a2", GL_RGB10_A2, GLSL_TYPE_FLOAT, 130, 0 },
1328 { "rgba8", GL_RGBA8, GLSL_TYPE_FLOAT, 130, 310 },
1329 { "rg16", GL_RG16, GLSL_TYPE_FLOAT, 130, 0 },
1330 { "rg8", GL_RG8, GLSL_TYPE_FLOAT, 130, 0 },
1331 { "r16", GL_R16, GLSL_TYPE_FLOAT, 130, 0 },
1332 { "r8", GL_R8, GLSL_TYPE_FLOAT, 130, 0 },
1333 { "rgba16_snorm", GL_RGBA16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1334 { "rgba8_snorm", GL_RGBA8_SNORM, GLSL_TYPE_FLOAT, 130, 310 },
1335 { "rg16_snorm", GL_RG16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1336 { "rg8_snorm", GL_RG8_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1337 { "r16_snorm", GL_R16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1338 { "r8_snorm", GL_R8_SNORM, GLSL_TYPE_FLOAT, 130, 0 }
1339 };
1340
1341 for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1342 if (state->is_version(map[i].required_glsl,
1343 map[i].required_essl) &&
1344 match_layout_qualifier($1, map[i].name, state) == 0) {
1345 $$.flags.q.explicit_image_format = 1;
1346 $$.image_format = map[i].format;
1347 $$.image_base_type = map[i].base_type;
1348 break;
1349 }
1350 }
1351 }
1352
1353 if (!$$.flags.i &&
1354 match_layout_qualifier($1, "early_fragment_tests", state) == 0) {
1355 /* From section 4.4.1.3 of the GLSL 4.50 specification
1356 * (Fragment Shader Inputs):
1357 *
1358 * "Fragment shaders also allow the following layout
1359 * qualifier on in only (not with variable declarations)
1360 * layout-qualifier-id
1361 * early_fragment_tests
1362 * [...]"
1363 */
1364 if (state->stage != MESA_SHADER_FRAGMENT) {
1365 _mesa_glsl_error(& @1, state,
1366 "early_fragment_tests layout qualifier only "
1367 "valid in fragment shaders");
1368 }
1369
1370 $$.flags.q.early_fragment_tests = 1;
1371 }
1372 }
1373
1374 /* Layout qualifiers for tessellation evaluation shaders. */
1375 if (!$$.flags.i) {
1376 static const struct {
1377 const char *s;
1378 GLenum e;
1379 } map[] = {
1380 /* triangles already parsed by gs-specific code */
1381 { "quads", GL_QUADS },
1382 { "isolines", GL_ISOLINES },
1383 };
1384 for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1385 if (match_layout_qualifier($1, map[i].s, state) == 0) {
1386 $$.flags.q.prim_type = 1;
1387 $$.prim_type = map[i].e;
1388 break;
1389 }
1390 }
1391
1392 if ($$.flags.i && !state->has_tessellation_shader()) {
1393 _mesa_glsl_error(& @1, state,
1394 "primitive mode qualifier `%s' requires "
1395 "GLSL 4.00 or ARB_tessellation_shader", $1);
1396 }
1397 }
1398 if (!$$.flags.i) {
1399 static const struct {
1400 const char *s;
1401 GLenum e;
1402 } map[] = {
1403 { "equal_spacing", GL_EQUAL },
1404 { "fractional_odd_spacing", GL_FRACTIONAL_ODD },
1405 { "fractional_even_spacing", GL_FRACTIONAL_EVEN },
1406 };
1407 for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1408 if (match_layout_qualifier($1, map[i].s, state) == 0) {
1409 $$.flags.q.vertex_spacing = 1;
1410 $$.vertex_spacing = map[i].e;
1411 break;
1412 }
1413 }
1414
1415 if ($$.flags.i && !state->has_tessellation_shader()) {
1416 _mesa_glsl_error(& @1, state,
1417 "vertex spacing qualifier `%s' requires "
1418 "GLSL 4.00 or ARB_tessellation_shader", $1);
1419 }
1420 }
1421 if (!$$.flags.i) {
1422 if (match_layout_qualifier($1, "cw", state) == 0) {
1423 $$.flags.q.ordering = 1;
1424 $$.ordering = GL_CW;
1425 } else if (match_layout_qualifier($1, "ccw", state) == 0) {
1426 $$.flags.q.ordering = 1;
1427 $$.ordering = GL_CCW;
1428 }
1429
1430 if ($$.flags.i && !state->has_tessellation_shader()) {
1431 _mesa_glsl_error(& @1, state,
1432 "ordering qualifier `%s' requires "
1433 "GLSL 4.00 or ARB_tessellation_shader", $1);
1434 }
1435 }
1436 if (!$$.flags.i) {
1437 if (match_layout_qualifier($1, "point_mode", state) == 0) {
1438 $$.flags.q.point_mode = 1;
1439 $$.point_mode = true;
1440 }
1441
1442 if ($$.flags.i && !state->has_tessellation_shader()) {
1443 _mesa_glsl_error(& @1, state,
1444 "qualifier `point_mode' requires "
1445 "GLSL 4.00 or ARB_tessellation_shader");
1446 }
1447 }
1448
1449 if (!$$.flags.i) {
1450 _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1451 "`%s'", $1);
1452 YYERROR;
1453 }
1454 }
1455 | any_identifier '=' constant_expression
1456 {
1457 memset(& $$, 0, sizeof($$));
1458 void *ctx = state;
1459
1460 if ($3->oper != ast_int_constant &&
1461 $3->oper != ast_uint_constant &&
1462 !state->has_enhanced_layouts()) {
1463 _mesa_glsl_error(& @1, state,
1464 "compile-time constant expressions require "
1465 "GLSL 4.40 or ARB_enhanced_layouts");
1466 }
1467
1468 if (match_layout_qualifier("align", $1, state) == 0) {
1469 if (!state->has_enhanced_layouts()) {
1470 _mesa_glsl_error(& @1, state,
1471 "align qualifier requires "
1472 "GLSL 4.40 or ARB_enhanced_layouts");
1473 } else {
1474 $$.flags.q.explicit_align = 1;
1475 $$.align = $3;
1476 }
1477 }
1478
1479 if (match_layout_qualifier("location", $1, state) == 0) {
1480 $$.flags.q.explicit_location = 1;
1481
1482 if ($$.flags.q.attribute == 1 &&
1483 state->ARB_explicit_attrib_location_warn) {
1484 _mesa_glsl_warning(& @1, state,
1485 "GL_ARB_explicit_attrib_location layout "
1486 "identifier `%s' used", $1);
1487 }
1488 $$.location = $3;
1489 }
1490
1491 if (match_layout_qualifier("component", $1, state) == 0) {
1492 if (!state->has_enhanced_layouts()) {
1493 _mesa_glsl_error(& @1, state,
1494 "component qualifier requires "
1495 "GLSL 4.40 or ARB_enhanced_layouts");
1496 } else {
1497 $$.flags.q.explicit_component = 1;
1498 $$.component = $3;
1499 }
1500 }
1501
1502 if (match_layout_qualifier("index", $1, state) == 0) {
1503 if (state->es_shader && !state->EXT_blend_func_extended_enable) {
1504 _mesa_glsl_error(& @3, state, "index layout qualifier requires EXT_blend_func_extended");
1505 YYERROR;
1506 }
1507
1508 $$.flags.q.explicit_index = 1;
1509 $$.index = $3;
1510 }
1511
1512 if ((state->has_420pack_or_es31() ||
1513 state->has_atomic_counters() ||
1514 state->has_shader_storage_buffer_objects()) &&
1515 match_layout_qualifier("binding", $1, state) == 0) {
1516 $$.flags.q.explicit_binding = 1;
1517 $$.binding = $3;
1518 }
1519
1520 if ((state->has_atomic_counters() ||
1521 state->has_enhanced_layouts()) &&
1522 match_layout_qualifier("offset", $1, state) == 0) {
1523 $$.flags.q.explicit_offset = 1;
1524 $$.offset = $3;
1525 }
1526
1527 if (match_layout_qualifier("max_vertices", $1, state) == 0) {
1528 $$.flags.q.max_vertices = 1;
1529 $$.max_vertices = new(ctx) ast_layout_expression(@1, $3);
1530 if (!state->has_geometry_shader()) {
1531 _mesa_glsl_error(& @3, state,
1532 "#version 150 max_vertices qualifier "
1533 "specified", $3);
1534 }
1535 }
1536
1537 if (state->stage == MESA_SHADER_GEOMETRY) {
1538 if (match_layout_qualifier("stream", $1, state) == 0 &&
1539 state->check_explicit_attrib_stream_allowed(& @3)) {
1540 $$.flags.q.stream = 1;
1541 $$.flags.q.explicit_stream = 1;
1542 $$.stream = $3;
1543 }
1544 }
1545
1546 if (state->has_enhanced_layouts()) {
1547 if (match_layout_qualifier("xfb_buffer", $1, state) == 0) {
1548 $$.flags.q.xfb_buffer = 1;
1549 $$.flags.q.explicit_xfb_buffer = 1;
1550 $$.xfb_buffer = $3;
1551 }
1552
1553 if (match_layout_qualifier("xfb_offset", $1, state) == 0) {
1554 $$.flags.q.explicit_xfb_offset = 1;
1555 $$.offset = $3;
1556 }
1557
1558 if (match_layout_qualifier("xfb_stride", $1, state) == 0) {
1559 $$.flags.q.xfb_stride = 1;
1560 $$.flags.q.explicit_xfb_stride = 1;
1561 $$.xfb_stride = $3;
1562 }
1563 }
1564
1565 static const char * const local_size_qualifiers[3] = {
1566 "local_size_x",
1567 "local_size_y",
1568 "local_size_z",
1569 };
1570 for (int i = 0; i < 3; i++) {
1571 if (match_layout_qualifier(local_size_qualifiers[i], $1,
1572 state) == 0) {
1573 if (!state->has_compute_shader()) {
1574 _mesa_glsl_error(& @3, state,
1575 "%s qualifier requires GLSL 4.30 or "
1576 "GLSL ES 3.10 or ARB_compute_shader",
1577 local_size_qualifiers[i]);
1578 YYERROR;
1579 } else {
1580 $$.flags.q.local_size |= (1 << i);
1581 $$.local_size[i] = new(ctx) ast_layout_expression(@1, $3);
1582 }
1583 break;
1584 }
1585 }
1586
1587 if (match_layout_qualifier("invocations", $1, state) == 0) {
1588 $$.flags.q.invocations = 1;
1589 $$.invocations = new(ctx) ast_layout_expression(@1, $3);
1590 if (!state->is_version(400, 0) &&
1591 !state->ARB_gpu_shader5_enable) {
1592 _mesa_glsl_error(& @3, state,
1593 "GL_ARB_gpu_shader5 invocations "
1594 "qualifier specified", $3);
1595 }
1596 }
1597
1598 /* Layout qualifiers for tessellation control shaders. */
1599 if (match_layout_qualifier("vertices", $1, state) == 0) {
1600 $$.flags.q.vertices = 1;
1601 $$.vertices = new(ctx) ast_layout_expression(@1, $3);
1602 if (!state->has_tessellation_shader()) {
1603 _mesa_glsl_error(& @1, state,
1604 "vertices qualifier requires GLSL 4.00 or "
1605 "ARB_tessellation_shader");
1606 }
1607 }
1608
1609 /* If the identifier didn't match any known layout identifiers,
1610 * emit an error.
1611 */
1612 if (!$$.flags.i) {
1613 _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1614 "`%s'", $1);
1615 YYERROR;
1616 }
1617 }
1618 | interface_block_layout_qualifier
1619 {
1620 $$ = $1;
1621 /* Layout qualifiers for ARB_uniform_buffer_object. */
1622 if ($$.flags.q.uniform && !state->has_uniform_buffer_objects()) {
1623 _mesa_glsl_error(& @1, state,
1624 "#version 140 / GL_ARB_uniform_buffer_object "
1625 "layout qualifier `%s' is used", $1);
1626 } else if ($$.flags.q.uniform && state->ARB_uniform_buffer_object_warn) {
1627 _mesa_glsl_warning(& @1, state,
1628 "#version 140 / GL_ARB_uniform_buffer_object "
1629 "layout qualifier `%s' is used", $1);
1630 }
1631 }
1632 ;
1633
1634 /* This is a separate language rule because we parse these as tokens
1635 * (due to them being reserved keywords) instead of identifiers like
1636 * most qualifiers. See the any_identifier path of
1637 * layout_qualifier_id for the others.
1638 *
1639 * Note that since layout qualifiers are case-insensitive in desktop
1640 * GLSL, all of these qualifiers need to be handled as identifiers as
1641 * well (by the any_identifier path of layout_qualifier_id).
1642 */
1643 interface_block_layout_qualifier:
1644 ROW_MAJOR
1645 {
1646 memset(& $$, 0, sizeof($$));
1647 $$.flags.q.row_major = 1;
1648 }
1649 | PACKED_TOK
1650 {
1651 memset(& $$, 0, sizeof($$));
1652 $$.flags.q.packed = 1;
1653 }
1654 | SHARED
1655 {
1656 memset(& $$, 0, sizeof($$));
1657 $$.flags.q.shared = 1;
1658 }
1659 ;
1660
1661 subroutine_qualifier:
1662 SUBROUTINE
1663 {
1664 memset(& $$, 0, sizeof($$));
1665 $$.flags.q.subroutine = 1;
1666 }
1667 | SUBROUTINE '(' subroutine_type_list ')'
1668 {
1669 memset(& $$, 0, sizeof($$));
1670 $$.flags.q.subroutine_def = 1;
1671 $$.subroutine_list = $3;
1672 }
1673 ;
1674
1675 subroutine_type_list:
1676 any_identifier
1677 {
1678 void *ctx = state;
1679 ast_declaration *decl = new(ctx) ast_declaration($1, NULL, NULL);
1680 decl->set_location(@1);
1681
1682 $$ = new(ctx) ast_subroutine_list();
1683 $$->declarations.push_tail(&decl->link);
1684 }
1685 | subroutine_type_list ',' any_identifier
1686 {
1687 void *ctx = state;
1688 ast_declaration *decl = new(ctx) ast_declaration($3, NULL, NULL);
1689 decl->set_location(@3);
1690
1691 $$ = $1;
1692 $$->declarations.push_tail(&decl->link);
1693 }
1694 ;
1695
1696 interpolation_qualifier:
1697 SMOOTH
1698 {
1699 memset(& $$, 0, sizeof($$));
1700 $$.flags.q.smooth = 1;
1701 }
1702 | FLAT
1703 {
1704 memset(& $$, 0, sizeof($$));
1705 $$.flags.q.flat = 1;
1706 }
1707 | NOPERSPECTIVE
1708 {
1709 memset(& $$, 0, sizeof($$));
1710 $$.flags.q.noperspective = 1;
1711 }
1712 ;
1713
1714 type_qualifier:
1715 /* Single qualifiers */
1716 INVARIANT
1717 {
1718 memset(& $$, 0, sizeof($$));
1719 $$.flags.q.invariant = 1;
1720 }
1721 | PRECISE
1722 {
1723 memset(& $$, 0, sizeof($$));
1724 $$.flags.q.precise = 1;
1725 }
1726 | auxiliary_storage_qualifier
1727 | storage_qualifier
1728 | interpolation_qualifier
1729 | layout_qualifier
1730 | memory_qualifier
1731 | subroutine_qualifier
1732 | precision_qualifier
1733 {
1734 memset(&$$, 0, sizeof($$));
1735 $$.precision = $1;
1736 }
1737
1738 /* Multiple qualifiers:
1739 * In GLSL 4.20, these can be specified in any order. In earlier versions,
1740 * they appear in this order (see GLSL 1.50 section 4.7 & comments below):
1741 *
1742 * invariant interpolation auxiliary storage precision ...or...
1743 * layout storage precision
1744 *
1745 * Each qualifier's rule ensures that the accumulated qualifiers on the right
1746 * side don't contain any that must appear on the left hand side.
1747 * For example, when processing a storage qualifier, we check that there are
1748 * no auxiliary, interpolation, layout, invariant, or precise qualifiers to the right.
1749 */
1750 | PRECISE type_qualifier
1751 {
1752 if ($2.flags.q.precise)
1753 _mesa_glsl_error(&@1, state, "duplicate \"precise\" qualifier");
1754
1755 $$ = $2;
1756 $$.flags.q.precise = 1;
1757 }
1758 | INVARIANT type_qualifier
1759 {
1760 if ($2.flags.q.invariant)
1761 _mesa_glsl_error(&@1, state, "duplicate \"invariant\" qualifier");
1762
1763 if (!state->has_420pack_or_es31() && $2.flags.q.precise)
1764 _mesa_glsl_error(&@1, state,
1765 "\"invariant\" must come after \"precise\"");
1766
1767 $$ = $2;
1768 $$.flags.q.invariant = 1;
1769
1770 /* GLSL ES 3.00 spec, section 4.6.1 "The Invariant Qualifier":
1771 *
1772 * "Only variables output from a shader can be candidates for invariance.
1773 * This includes user-defined output variables and the built-in output
1774 * variables. As only outputs can be declared as invariant, an invariant
1775 * output from one shader stage will still match an input of a subsequent
1776 * stage without the input being declared as invariant."
1777 *
1778 * On the desktop side, this text first appears in GLSL 4.30.
1779 */
1780 if (state->is_version(430, 300) && $$.flags.q.in)
1781 _mesa_glsl_error(&@1, state, "invariant qualifiers cannot be used with shader inputs");
1782 }
1783 | interpolation_qualifier type_qualifier
1784 {
1785 /* Section 4.3 of the GLSL 1.40 specification states:
1786 * "...qualified with one of these interpolation qualifiers"
1787 *
1788 * GLSL 1.30 claims to allow "one or more", but insists that:
1789 * "These interpolation qualifiers may only precede the qualifiers in,
1790 * centroid in, out, or centroid out in a declaration."
1791 *
1792 * ...which means that e.g. smooth can't precede smooth, so there can be
1793 * only one after all, and the 1.40 text is a clarification, not a change.
1794 */
1795 if ($2.has_interpolation())
1796 _mesa_glsl_error(&@1, state, "duplicate interpolation qualifier");
1797
1798 if (!state->has_420pack_or_es31() &&
1799 ($2.flags.q.precise || $2.flags.q.invariant)) {
1800 _mesa_glsl_error(&@1, state, "interpolation qualifiers must come "
1801 "after \"precise\" or \"invariant\"");
1802 }
1803
1804 $$ = $1;
1805 $$.merge_qualifier(&@1, state, $2, false);
1806 }
1807 | layout_qualifier type_qualifier
1808 {
1809 /* In the absence of ARB_shading_language_420pack, layout qualifiers may
1810 * appear no later than auxiliary storage qualifiers. There is no
1811 * particularly clear spec language mandating this, but in all examples
1812 * the layout qualifier precedes the storage qualifier.
1813 *
1814 * We allow combinations of layout with interpolation, invariant or
1815 * precise qualifiers since these are useful in ARB_separate_shader_objects.
1816 * There is no clear spec guidance on this either.
1817 */
1818 if (!state->has_420pack_or_es31() && $2.has_layout())
1819 _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
1820
1821 $$ = $1;
1822 $$.merge_qualifier(&@1, state, $2, false);
1823 }
1824 | subroutine_qualifier type_qualifier
1825 {
1826 $$ = $1;
1827 $$.merge_qualifier(&@1, state, $2, false);
1828 }
1829 | auxiliary_storage_qualifier type_qualifier
1830 {
1831 if ($2.has_auxiliary_storage()) {
1832 _mesa_glsl_error(&@1, state,
1833 "duplicate auxiliary storage qualifier (centroid or sample)");
1834 }
1835
1836 if (!state->has_420pack_or_es31() &&
1837 ($2.flags.q.precise || $2.flags.q.invariant ||
1838 $2.has_interpolation() || $2.has_layout())) {
1839 _mesa_glsl_error(&@1, state, "auxiliary storage qualifiers must come "
1840 "just before storage qualifiers");
1841 }
1842 $$ = $1;
1843 $$.merge_qualifier(&@1, state, $2, false);
1844 }
1845 | storage_qualifier type_qualifier
1846 {
1847 /* Section 4.3 of the GLSL 1.20 specification states:
1848 * "Variable declarations may have a storage qualifier specified..."
1849 * 1.30 clarifies this to "may have one storage qualifier".
1850 */
1851 if ($2.has_storage())
1852 _mesa_glsl_error(&@1, state, "duplicate storage qualifier");
1853
1854 if (!state->has_420pack_or_es31() &&
1855 ($2.flags.q.precise || $2.flags.q.invariant || $2.has_interpolation() ||
1856 $2.has_layout() || $2.has_auxiliary_storage())) {
1857 _mesa_glsl_error(&@1, state, "storage qualifiers must come after "
1858 "precise, invariant, interpolation, layout and auxiliary "
1859 "storage qualifiers");
1860 }
1861
1862 $$ = $1;
1863 $$.merge_qualifier(&@1, state, $2, false);
1864 }
1865 | precision_qualifier type_qualifier
1866 {
1867 if ($2.precision != ast_precision_none)
1868 _mesa_glsl_error(&@1, state, "duplicate precision qualifier");
1869
1870 if (!(state->has_420pack_or_es31()) &&
1871 $2.flags.i != 0)
1872 _mesa_glsl_error(&@1, state, "precision qualifiers must come last");
1873
1874 $$ = $2;
1875 $$.precision = $1;
1876 }
1877 | memory_qualifier type_qualifier
1878 {
1879 $$ = $1;
1880 $$.merge_qualifier(&@1, state, $2, false);
1881 }
1882 ;
1883
1884 auxiliary_storage_qualifier:
1885 CENTROID
1886 {
1887 memset(& $$, 0, sizeof($$));
1888 $$.flags.q.centroid = 1;
1889 }
1890 | SAMPLE
1891 {
1892 memset(& $$, 0, sizeof($$));
1893 $$.flags.q.sample = 1;
1894 }
1895 | PATCH
1896 {
1897 memset(& $$, 0, sizeof($$));
1898 $$.flags.q.patch = 1;
1899 }
1900
1901 storage_qualifier:
1902 CONST_TOK
1903 {
1904 memset(& $$, 0, sizeof($$));
1905 $$.flags.q.constant = 1;
1906 }
1907 | ATTRIBUTE
1908 {
1909 memset(& $$, 0, sizeof($$));
1910 $$.flags.q.attribute = 1;
1911 }
1912 | VARYING
1913 {
1914 memset(& $$, 0, sizeof($$));
1915 $$.flags.q.varying = 1;
1916 }
1917 | IN_TOK
1918 {
1919 memset(& $$, 0, sizeof($$));
1920 $$.flags.q.in = 1;
1921 }
1922 | OUT_TOK
1923 {
1924 memset(& $$, 0, sizeof($$));
1925 $$.flags.q.out = 1;
1926
1927 if (state->stage == MESA_SHADER_GEOMETRY &&
1928 state->has_explicit_attrib_stream()) {
1929 /* Section 4.3.8.2 (Output Layout Qualifiers) of the GLSL 4.00
1930 * spec says:
1931 *
1932 * "If the block or variable is declared with the stream
1933 * identifier, it is associated with the specified stream;
1934 * otherwise, it is associated with the current default stream."
1935 */
1936 $$.flags.q.stream = 1;
1937 $$.flags.q.explicit_stream = 0;
1938 $$.stream = state->out_qualifier->stream;
1939 }
1940
1941 if (state->has_enhanced_layouts()) {
1942 $$.flags.q.xfb_buffer = 1;
1943 $$.flags.q.explicit_xfb_buffer = 0;
1944 $$.xfb_buffer = state->out_qualifier->xfb_buffer;
1945 }
1946 }
1947 | INOUT_TOK
1948 {
1949 memset(& $$, 0, sizeof($$));
1950 $$.flags.q.in = 1;
1951 $$.flags.q.out = 1;
1952
1953 if (!state->has_framebuffer_fetch() ||
1954 !state->is_version(130, 300) ||
1955 state->stage != MESA_SHADER_FRAGMENT)
1956 _mesa_glsl_error(&@1, state, "A single interface variable cannot be "
1957 "declared as both input and output");
1958 }
1959 | UNIFORM
1960 {
1961 memset(& $$, 0, sizeof($$));
1962 $$.flags.q.uniform = 1;
1963 }
1964 | BUFFER
1965 {
1966 memset(& $$, 0, sizeof($$));
1967 $$.flags.q.buffer = 1;
1968 }
1969 | SHARED
1970 {
1971 memset(& $$, 0, sizeof($$));
1972 $$.flags.q.shared_storage = 1;
1973 }
1974 ;
1975
1976 memory_qualifier:
1977 COHERENT
1978 {
1979 memset(& $$, 0, sizeof($$));
1980 $$.flags.q.coherent = 1;
1981 }
1982 | VOLATILE
1983 {
1984 memset(& $$, 0, sizeof($$));
1985 $$.flags.q._volatile = 1;
1986 }
1987 | RESTRICT
1988 {
1989 STATIC_ASSERT(sizeof($$.flags.q) <= sizeof($$.flags.i));
1990 memset(& $$, 0, sizeof($$));
1991 $$.flags.q.restrict_flag = 1;
1992 }
1993 | READONLY
1994 {
1995 memset(& $$, 0, sizeof($$));
1996 $$.flags.q.read_only = 1;
1997 }
1998 | WRITEONLY
1999 {
2000 memset(& $$, 0, sizeof($$));
2001 $$.flags.q.write_only = 1;
2002 }
2003 ;
2004
2005 array_specifier:
2006 '[' ']'
2007 {
2008 void *ctx = state;
2009 $$ = new(ctx) ast_array_specifier(@1, new(ctx) ast_expression(
2010 ast_unsized_array_dim, NULL,
2011 NULL, NULL));
2012 $$->set_location_range(@1, @2);
2013 }
2014 | '[' constant_expression ']'
2015 {
2016 void *ctx = state;
2017 $$ = new(ctx) ast_array_specifier(@1, $2);
2018 $$->set_location_range(@1, @3);
2019 }
2020 | array_specifier '[' ']'
2021 {
2022 void *ctx = state;
2023 $$ = $1;
2024
2025 if (state->check_arrays_of_arrays_allowed(& @1)) {
2026 $$->add_dimension(new(ctx) ast_expression(ast_unsized_array_dim, NULL,
2027 NULL, NULL));
2028 }
2029 }
2030 | array_specifier '[' constant_expression ']'
2031 {
2032 $$ = $1;
2033
2034 if (state->check_arrays_of_arrays_allowed(& @1)) {
2035 $$->add_dimension($3);
2036 }
2037 }
2038 ;
2039
2040 type_specifier:
2041 type_specifier_nonarray
2042 | type_specifier_nonarray array_specifier
2043 {
2044 $$ = $1;
2045 $$->array_specifier = $2;
2046 }
2047 ;
2048
2049 type_specifier_nonarray:
2050 basic_type_specifier_nonarray
2051 {
2052 void *ctx = state;
2053 $$ = new(ctx) ast_type_specifier($1);
2054 $$->set_location(@1);
2055 }
2056 | struct_specifier
2057 {
2058 void *ctx = state;
2059 $$ = new(ctx) ast_type_specifier($1);
2060 $$->set_location(@1);
2061 }
2062 | TYPE_IDENTIFIER
2063 {
2064 void *ctx = state;
2065 $$ = new(ctx) ast_type_specifier($1);
2066 $$->set_location(@1);
2067 }
2068 ;
2069
2070 basic_type_specifier_nonarray:
2071 VOID_TOK { $$ = "void"; }
2072 | FLOAT_TOK { $$ = "float"; }
2073 | DOUBLE_TOK { $$ = "double"; }
2074 | INT_TOK { $$ = "int"; }
2075 | UINT_TOK { $$ = "uint"; }
2076 | BOOL_TOK { $$ = "bool"; }
2077 | VEC2 { $$ = "vec2"; }
2078 | VEC3 { $$ = "vec3"; }
2079 | VEC4 { $$ = "vec4"; }
2080 | BVEC2 { $$ = "bvec2"; }
2081 | BVEC3 { $$ = "bvec3"; }
2082 | BVEC4 { $$ = "bvec4"; }
2083 | IVEC2 { $$ = "ivec2"; }
2084 | IVEC3 { $$ = "ivec3"; }
2085 | IVEC4 { $$ = "ivec4"; }
2086 | UVEC2 { $$ = "uvec2"; }
2087 | UVEC3 { $$ = "uvec3"; }
2088 | UVEC4 { $$ = "uvec4"; }
2089 | DVEC2 { $$ = "dvec2"; }
2090 | DVEC3 { $$ = "dvec3"; }
2091 | DVEC4 { $$ = "dvec4"; }
2092 | MAT2X2 { $$ = "mat2"; }
2093 | MAT2X3 { $$ = "mat2x3"; }
2094 | MAT2X4 { $$ = "mat2x4"; }
2095 | MAT3X2 { $$ = "mat3x2"; }
2096 | MAT3X3 { $$ = "mat3"; }
2097 | MAT3X4 { $$ = "mat3x4"; }
2098 | MAT4X2 { $$ = "mat4x2"; }
2099 | MAT4X3 { $$ = "mat4x3"; }
2100 | MAT4X4 { $$ = "mat4"; }
2101 | DMAT2X2 { $$ = "dmat2"; }
2102 | DMAT2X3 { $$ = "dmat2x3"; }
2103 | DMAT2X4 { $$ = "dmat2x4"; }
2104 | DMAT3X2 { $$ = "dmat3x2"; }
2105 | DMAT3X3 { $$ = "dmat3"; }
2106 | DMAT3X4 { $$ = "dmat3x4"; }
2107 | DMAT4X2 { $$ = "dmat4x2"; }
2108 | DMAT4X3 { $$ = "dmat4x3"; }
2109 | DMAT4X4 { $$ = "dmat4"; }
2110 | SAMPLER1D { $$ = "sampler1D"; }
2111 | SAMPLER2D { $$ = "sampler2D"; }
2112 | SAMPLER2DRECT { $$ = "sampler2DRect"; }
2113 | SAMPLER3D { $$ = "sampler3D"; }
2114 | SAMPLERCUBE { $$ = "samplerCube"; }
2115 | SAMPLEREXTERNALOES { $$ = "samplerExternalOES"; }
2116 | SAMPLER1DSHADOW { $$ = "sampler1DShadow"; }
2117 | SAMPLER2DSHADOW { $$ = "sampler2DShadow"; }
2118 | SAMPLER2DRECTSHADOW { $$ = "sampler2DRectShadow"; }
2119 | SAMPLERCUBESHADOW { $$ = "samplerCubeShadow"; }
2120 | SAMPLER1DARRAY { $$ = "sampler1DArray"; }
2121 | SAMPLER2DARRAY { $$ = "sampler2DArray"; }
2122 | SAMPLER1DARRAYSHADOW { $$ = "sampler1DArrayShadow"; }
2123 | SAMPLER2DARRAYSHADOW { $$ = "sampler2DArrayShadow"; }
2124 | SAMPLERBUFFER { $$ = "samplerBuffer"; }
2125 | SAMPLERCUBEARRAY { $$ = "samplerCubeArray"; }
2126 | SAMPLERCUBEARRAYSHADOW { $$ = "samplerCubeArrayShadow"; }
2127 | ISAMPLER1D { $$ = "isampler1D"; }
2128 | ISAMPLER2D { $$ = "isampler2D"; }
2129 | ISAMPLER2DRECT { $$ = "isampler2DRect"; }
2130 | ISAMPLER3D { $$ = "isampler3D"; }
2131 | ISAMPLERCUBE { $$ = "isamplerCube"; }
2132 | ISAMPLER1DARRAY { $$ = "isampler1DArray"; }
2133 | ISAMPLER2DARRAY { $$ = "isampler2DArray"; }
2134 | ISAMPLERBUFFER { $$ = "isamplerBuffer"; }
2135 | ISAMPLERCUBEARRAY { $$ = "isamplerCubeArray"; }
2136 | USAMPLER1D { $$ = "usampler1D"; }
2137 | USAMPLER2D { $$ = "usampler2D"; }
2138 | USAMPLER2DRECT { $$ = "usampler2DRect"; }
2139 | USAMPLER3D { $$ = "usampler3D"; }
2140 | USAMPLERCUBE { $$ = "usamplerCube"; }
2141 | USAMPLER1DARRAY { $$ = "usampler1DArray"; }
2142 | USAMPLER2DARRAY { $$ = "usampler2DArray"; }
2143 | USAMPLERBUFFER { $$ = "usamplerBuffer"; }
2144 | USAMPLERCUBEARRAY { $$ = "usamplerCubeArray"; }
2145 | SAMPLER2DMS { $$ = "sampler2DMS"; }
2146 | ISAMPLER2DMS { $$ = "isampler2DMS"; }
2147 | USAMPLER2DMS { $$ = "usampler2DMS"; }
2148 | SAMPLER2DMSARRAY { $$ = "sampler2DMSArray"; }
2149 | ISAMPLER2DMSARRAY { $$ = "isampler2DMSArray"; }
2150 | USAMPLER2DMSARRAY { $$ = "usampler2DMSArray"; }
2151 | IMAGE1D { $$ = "image1D"; }
2152 | IMAGE2D { $$ = "image2D"; }
2153 | IMAGE3D { $$ = "image3D"; }
2154 | IMAGE2DRECT { $$ = "image2DRect"; }
2155 | IMAGECUBE { $$ = "imageCube"; }
2156 | IMAGEBUFFER { $$ = "imageBuffer"; }
2157 | IMAGE1DARRAY { $$ = "image1DArray"; }
2158 | IMAGE2DARRAY { $$ = "image2DArray"; }
2159 | IMAGECUBEARRAY { $$ = "imageCubeArray"; }
2160 | IMAGE2DMS { $$ = "image2DMS"; }
2161 | IMAGE2DMSARRAY { $$ = "image2DMSArray"; }
2162 | IIMAGE1D { $$ = "iimage1D"; }
2163 | IIMAGE2D { $$ = "iimage2D"; }
2164 | IIMAGE3D { $$ = "iimage3D"; }
2165 | IIMAGE2DRECT { $$ = "iimage2DRect"; }
2166 | IIMAGECUBE { $$ = "iimageCube"; }
2167 | IIMAGEBUFFER { $$ = "iimageBuffer"; }
2168 | IIMAGE1DARRAY { $$ = "iimage1DArray"; }
2169 | IIMAGE2DARRAY { $$ = "iimage2DArray"; }
2170 | IIMAGECUBEARRAY { $$ = "iimageCubeArray"; }
2171 | IIMAGE2DMS { $$ = "iimage2DMS"; }
2172 | IIMAGE2DMSARRAY { $$ = "iimage2DMSArray"; }
2173 | UIMAGE1D { $$ = "uimage1D"; }
2174 | UIMAGE2D { $$ = "uimage2D"; }
2175 | UIMAGE3D { $$ = "uimage3D"; }
2176 | UIMAGE2DRECT { $$ = "uimage2DRect"; }
2177 | UIMAGECUBE { $$ = "uimageCube"; }
2178 | UIMAGEBUFFER { $$ = "uimageBuffer"; }
2179 | UIMAGE1DARRAY { $$ = "uimage1DArray"; }
2180 | UIMAGE2DARRAY { $$ = "uimage2DArray"; }
2181 | UIMAGECUBEARRAY { $$ = "uimageCubeArray"; }
2182 | UIMAGE2DMS { $$ = "uimage2DMS"; }
2183 | UIMAGE2DMSARRAY { $$ = "uimage2DMSArray"; }
2184 | ATOMIC_UINT { $$ = "atomic_uint"; }
2185 ;
2186
2187 precision_qualifier:
2188 HIGHP
2189 {
2190 state->check_precision_qualifiers_allowed(&@1);
2191 $$ = ast_precision_high;
2192 }
2193 | MEDIUMP
2194 {
2195 state->check_precision_qualifiers_allowed(&@1);
2196 $$ = ast_precision_medium;
2197 }
2198 | LOWP
2199 {
2200 state->check_precision_qualifiers_allowed(&@1);
2201 $$ = ast_precision_low;
2202 }
2203 ;
2204
2205 struct_specifier:
2206 STRUCT any_identifier '{' struct_declaration_list '}'
2207 {
2208 void *ctx = state;
2209 $$ = new(ctx) ast_struct_specifier($2, $4);
2210 $$->set_location_range(@2, @5);
2211 state->symbols->add_type($2, glsl_type::void_type);
2212 }
2213 | STRUCT '{' struct_declaration_list '}'
2214 {
2215 void *ctx = state;
2216 $$ = new(ctx) ast_struct_specifier(NULL, $3);
2217 $$->set_location_range(@2, @4);
2218 }
2219 ;
2220
2221 struct_declaration_list:
2222 struct_declaration
2223 {
2224 $$ = $1;
2225 $1->link.self_link();
2226 }
2227 | struct_declaration_list struct_declaration
2228 {
2229 $$ = $1;
2230 $$->link.insert_before(& $2->link);
2231 }
2232 ;
2233
2234 struct_declaration:
2235 fully_specified_type struct_declarator_list ';'
2236 {
2237 void *ctx = state;
2238 ast_fully_specified_type *const type = $1;
2239 type->set_location(@1);
2240
2241 if (type->qualifier.flags.i != 0)
2242 _mesa_glsl_error(&@1, state,
2243 "only precision qualifiers may be applied to "
2244 "structure members");
2245
2246 $$ = new(ctx) ast_declarator_list(type);
2247 $$->set_location(@2);
2248
2249 $$->declarations.push_degenerate_list_at_head(& $2->link);
2250 }
2251 ;
2252
2253 struct_declarator_list:
2254 struct_declarator
2255 {
2256 $$ = $1;
2257 $1->link.self_link();
2258 }
2259 | struct_declarator_list ',' struct_declarator
2260 {
2261 $$ = $1;
2262 $$->link.insert_before(& $3->link);
2263 }
2264 ;
2265
2266 struct_declarator:
2267 any_identifier
2268 {
2269 void *ctx = state;
2270 $$ = new(ctx) ast_declaration($1, NULL, NULL);
2271 $$->set_location(@1);
2272 }
2273 | any_identifier array_specifier
2274 {
2275 void *ctx = state;
2276 $$ = new(ctx) ast_declaration($1, $2, NULL);
2277 $$->set_location_range(@1, @2);
2278 }
2279 ;
2280
2281 initializer:
2282 assignment_expression
2283 | '{' initializer_list '}'
2284 {
2285 $$ = $2;
2286 }
2287 | '{' initializer_list ',' '}'
2288 {
2289 $$ = $2;
2290 }
2291 ;
2292
2293 initializer_list:
2294 initializer
2295 {
2296 void *ctx = state;
2297 $$ = new(ctx) ast_aggregate_initializer();
2298 $$->set_location(@1);
2299 $$->expressions.push_tail(& $1->link);
2300 }
2301 | initializer_list ',' initializer
2302 {
2303 $1->expressions.push_tail(& $3->link);
2304 }
2305 ;
2306
2307 declaration_statement:
2308 declaration
2309 ;
2310
2311 // Grammar Note: labeled statements for SWITCH only; 'goto' is not
2312 // supported.
2313 statement:
2314 compound_statement { $$ = (ast_node *) $1; }
2315 | simple_statement
2316 ;
2317
2318 simple_statement:
2319 declaration_statement
2320 | expression_statement
2321 | selection_statement
2322 | switch_statement
2323 | iteration_statement
2324 | jump_statement
2325 ;
2326
2327 compound_statement:
2328 '{' '}'
2329 {
2330 void *ctx = state;
2331 $$ = new(ctx) ast_compound_statement(true, NULL);
2332 $$->set_location_range(@1, @2);
2333 }
2334 | '{'
2335 {
2336 state->symbols->push_scope();
2337 }
2338 statement_list '}'
2339 {
2340 void *ctx = state;
2341 $$ = new(ctx) ast_compound_statement(true, $3);
2342 $$->set_location_range(@1, @4);
2343 state->symbols->pop_scope();
2344 }
2345 ;
2346
2347 statement_no_new_scope:
2348 compound_statement_no_new_scope { $$ = (ast_node *) $1; }
2349 | simple_statement
2350 ;
2351
2352 compound_statement_no_new_scope:
2353 '{' '}'
2354 {
2355 void *ctx = state;
2356 $$ = new(ctx) ast_compound_statement(false, NULL);
2357 $$->set_location_range(@1, @2);
2358 }
2359 | '{' statement_list '}'
2360 {
2361 void *ctx = state;
2362 $$ = new(ctx) ast_compound_statement(false, $2);
2363 $$->set_location_range(@1, @3);
2364 }
2365 ;
2366
2367 statement_list:
2368 statement
2369 {
2370 if ($1 == NULL) {
2371 _mesa_glsl_error(& @1, state, "<nil> statement");
2372 assert($1 != NULL);
2373 }
2374
2375 $$ = $1;
2376 $$->link.self_link();
2377 }
2378 | statement_list statement
2379 {
2380 if ($2 == NULL) {
2381 _mesa_glsl_error(& @2, state, "<nil> statement");
2382 assert($2 != NULL);
2383 }
2384 $$ = $1;
2385 $$->link.insert_before(& $2->link);
2386 }
2387 ;
2388
2389 expression_statement:
2390 ';'
2391 {
2392 void *ctx = state;
2393 $$ = new(ctx) ast_expression_statement(NULL);
2394 $$->set_location(@1);
2395 }
2396 | expression ';'
2397 {
2398 void *ctx = state;
2399 $$ = new(ctx) ast_expression_statement($1);
2400 $$->set_location(@1);
2401 }
2402 ;
2403
2404 selection_statement:
2405 IF '(' expression ')' selection_rest_statement
2406 {
2407 $$ = new(state) ast_selection_statement($3, $5.then_statement,
2408 $5.else_statement);
2409 $$->set_location_range(@1, @5);
2410 }
2411 ;
2412
2413 selection_rest_statement:
2414 statement ELSE statement
2415 {
2416 $$.then_statement = $1;
2417 $$.else_statement = $3;
2418 }
2419 | statement %prec THEN
2420 {
2421 $$.then_statement = $1;
2422 $$.else_statement = NULL;
2423 }
2424 ;
2425
2426 condition:
2427 expression
2428 {
2429 $$ = (ast_node *) $1;
2430 }
2431 | fully_specified_type any_identifier '=' initializer
2432 {
2433 void *ctx = state;
2434 ast_declaration *decl = new(ctx) ast_declaration($2, NULL, $4);
2435 ast_declarator_list *declarator = new(ctx) ast_declarator_list($1);
2436 decl->set_location_range(@2, @4);
2437 declarator->set_location(@1);
2438
2439 declarator->declarations.push_tail(&decl->link);
2440 $$ = declarator;
2441 }
2442 ;
2443
2444 /*
2445 * switch_statement grammar is based on the syntax described in the body
2446 * of the GLSL spec, not in it's appendix!!!
2447 */
2448 switch_statement:
2449 SWITCH '(' expression ')' switch_body
2450 {
2451 $$ = new(state) ast_switch_statement($3, $5);
2452 $$->set_location_range(@1, @5);
2453 }
2454 ;
2455
2456 switch_body:
2457 '{' '}'
2458 {
2459 $$ = new(state) ast_switch_body(NULL);
2460 $$->set_location_range(@1, @2);
2461 }
2462 | '{' case_statement_list '}'
2463 {
2464 $$ = new(state) ast_switch_body($2);
2465 $$->set_location_range(@1, @3);
2466 }
2467 ;
2468
2469 case_label:
2470 CASE expression ':'
2471 {
2472 $$ = new(state) ast_case_label($2);
2473 $$->set_location(@2);
2474 }
2475 | DEFAULT ':'
2476 {
2477 $$ = new(state) ast_case_label(NULL);
2478 $$->set_location(@2);
2479 }
2480 ;
2481
2482 case_label_list:
2483 case_label
2484 {
2485 ast_case_label_list *labels = new(state) ast_case_label_list();
2486
2487 labels->labels.push_tail(& $1->link);
2488 $$ = labels;
2489 $$->set_location(@1);
2490 }
2491 | case_label_list case_label
2492 {
2493 $$ = $1;
2494 $$->labels.push_tail(& $2->link);
2495 }
2496 ;
2497
2498 case_statement:
2499 case_label_list statement
2500 {
2501 ast_case_statement *stmts = new(state) ast_case_statement($1);
2502 stmts->set_location(@2);
2503
2504 stmts->stmts.push_tail(& $2->link);
2505 $$ = stmts;
2506 }
2507 | case_statement statement
2508 {
2509 $$ = $1;
2510 $$->stmts.push_tail(& $2->link);
2511 }
2512 ;
2513
2514 case_statement_list:
2515 case_statement
2516 {
2517 ast_case_statement_list *cases= new(state) ast_case_statement_list();
2518 cases->set_location(@1);
2519
2520 cases->cases.push_tail(& $1->link);
2521 $$ = cases;
2522 }
2523 | case_statement_list case_statement
2524 {
2525 $$ = $1;
2526 $$->cases.push_tail(& $2->link);
2527 }
2528 ;
2529
2530 iteration_statement:
2531 WHILE '(' condition ')' statement_no_new_scope
2532 {
2533 void *ctx = state;
2534 $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_while,
2535 NULL, $3, NULL, $5);
2536 $$->set_location_range(@1, @4);
2537 }
2538 | DO statement WHILE '(' expression ')' ';'
2539 {
2540 void *ctx = state;
2541 $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_do_while,
2542 NULL, $5, NULL, $2);
2543 $$->set_location_range(@1, @6);
2544 }
2545 | FOR '(' for_init_statement for_rest_statement ')' statement_no_new_scope
2546 {
2547 void *ctx = state;
2548 $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_for,
2549 $3, $4.cond, $4.rest, $6);
2550 $$->set_location_range(@1, @6);
2551 }
2552 ;
2553
2554 for_init_statement:
2555 expression_statement
2556 | declaration_statement
2557 ;
2558
2559 conditionopt:
2560 condition
2561 | /* empty */
2562 {
2563 $$ = NULL;
2564 }
2565 ;
2566
2567 for_rest_statement:
2568 conditionopt ';'
2569 {
2570 $$.cond = $1;
2571 $$.rest = NULL;
2572 }
2573 | conditionopt ';' expression
2574 {
2575 $$.cond = $1;
2576 $$.rest = $3;
2577 }
2578 ;
2579
2580 // Grammar Note: No 'goto'. Gotos are not supported.
2581 jump_statement:
2582 CONTINUE ';'
2583 {
2584 void *ctx = state;
2585 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_continue, NULL);
2586 $$->set_location(@1);
2587 }
2588 | BREAK ';'
2589 {
2590 void *ctx = state;
2591 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_break, NULL);
2592 $$->set_location(@1);
2593 }
2594 | RETURN ';'
2595 {
2596 void *ctx = state;
2597 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, NULL);
2598 $$->set_location(@1);
2599 }
2600 | RETURN expression ';'
2601 {
2602 void *ctx = state;
2603 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, $2);
2604 $$->set_location_range(@1, @2);
2605 }
2606 | DISCARD ';' // Fragment shader only.
2607 {
2608 void *ctx = state;
2609 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_discard, NULL);
2610 $$->set_location(@1);
2611 }
2612 ;
2613
2614 external_declaration:
2615 function_definition { $$ = $1; }
2616 | declaration { $$ = $1; }
2617 | pragma_statement { $$ = NULL; }
2618 | layout_defaults { $$ = $1; }
2619 ;
2620
2621 function_definition:
2622 function_prototype compound_statement_no_new_scope
2623 {
2624 void *ctx = state;
2625 $$ = new(ctx) ast_function_definition();
2626 $$->set_location_range(@1, @2);
2627 $$->prototype = $1;
2628 $$->body = $2;
2629
2630 state->symbols->pop_scope();
2631 }
2632 ;
2633
2634 /* layout_qualifieropt is packed into this rule */
2635 interface_block:
2636 basic_interface_block
2637 {
2638 $$ = $1;
2639 }
2640 | layout_qualifier interface_block
2641 {
2642 ast_interface_block *block = (ast_interface_block *) $2;
2643
2644 if (!state->has_420pack_or_es31() && block->layout.has_layout() &&
2645 !block->layout.is_default_qualifier) {
2646 _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2647 YYERROR;
2648 }
2649
2650 if (!block->layout.merge_qualifier(& @1, state, $1, false)) {
2651 YYERROR;
2652 }
2653
2654 block->layout.is_default_qualifier = false;
2655
2656 $$ = block;
2657 }
2658 | memory_qualifier interface_block
2659 {
2660 ast_interface_block *block = (ast_interface_block *)$2;
2661
2662 if (!block->layout.flags.q.buffer) {
2663 _mesa_glsl_error(& @1, state,
2664 "memory qualifiers can only be used in the "
2665 "declaration of shader storage blocks");
2666 }
2667 if (!block->layout.merge_qualifier(& @1, state, $1, false)) {
2668 YYERROR;
2669 }
2670 $$ = block;
2671 }
2672 ;
2673
2674 basic_interface_block:
2675 interface_qualifier NEW_IDENTIFIER '{' member_list '}' instance_name_opt ';'
2676 {
2677 ast_interface_block *const block = $6;
2678
2679 if ($1.flags.q.uniform) {
2680 block->layout = *state->default_uniform_qualifier;
2681 } else if ($1.flags.q.buffer) {
2682 block->layout = *state->default_shader_storage_qualifier;
2683 }
2684 block->block_name = $2;
2685 block->declarations.push_degenerate_list_at_head(& $4->link);
2686
2687 _mesa_ast_process_interface_block(& @1, state, block, $1);
2688
2689 $$ = block;
2690 }
2691 ;
2692
2693 interface_qualifier:
2694 IN_TOK
2695 {
2696 memset(& $$, 0, sizeof($$));
2697 $$.flags.q.in = 1;
2698 }
2699 | OUT_TOK
2700 {
2701 memset(& $$, 0, sizeof($$));
2702 $$.flags.q.out = 1;
2703 }
2704 | UNIFORM
2705 {
2706 memset(& $$, 0, sizeof($$));
2707 $$.flags.q.uniform = 1;
2708 }
2709 | BUFFER
2710 {
2711 memset(& $$, 0, sizeof($$));
2712 $$.flags.q.buffer = 1;
2713 }
2714 ;
2715
2716 instance_name_opt:
2717 /* empty */
2718 {
2719 $$ = new(state) ast_interface_block(NULL, NULL);
2720 }
2721 | NEW_IDENTIFIER
2722 {
2723 $$ = new(state) ast_interface_block($1, NULL);
2724 $$->set_location(@1);
2725 }
2726 | NEW_IDENTIFIER array_specifier
2727 {
2728 $$ = new(state) ast_interface_block($1, $2);
2729 $$->set_location_range(@1, @2);
2730 }
2731 ;
2732
2733 member_list:
2734 member_declaration
2735 {
2736 $$ = $1;
2737 $1->link.self_link();
2738 }
2739 | member_declaration member_list
2740 {
2741 $$ = $1;
2742 $2->link.insert_before(& $$->link);
2743 }
2744 ;
2745
2746 member_declaration:
2747 fully_specified_type struct_declarator_list ';'
2748 {
2749 void *ctx = state;
2750 ast_fully_specified_type *type = $1;
2751 type->set_location(@1);
2752
2753 if (type->qualifier.flags.q.attribute) {
2754 _mesa_glsl_error(& @1, state,
2755 "keyword 'attribute' cannot be used with "
2756 "interface block member");
2757 } else if (type->qualifier.flags.q.varying) {
2758 _mesa_glsl_error(& @1, state,
2759 "keyword 'varying' cannot be used with "
2760 "interface block member");
2761 }
2762
2763 $$ = new(ctx) ast_declarator_list(type);
2764 $$->set_location(@2);
2765
2766 $$->declarations.push_degenerate_list_at_head(& $2->link);
2767 }
2768 ;
2769
2770 layout_uniform_defaults:
2771 layout_qualifier layout_uniform_defaults
2772 {
2773 $$ = NULL;
2774 if (!state->has_420pack_or_es31()) {
2775 _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2776 YYERROR;
2777 } else {
2778 if (!state->default_uniform_qualifier->
2779 merge_qualifier(& @1, state, $1, false)) {
2780 YYERROR;
2781 }
2782 }
2783 }
2784 | layout_qualifier UNIFORM ';'
2785 {
2786 if (!state->default_uniform_qualifier->
2787 merge_qualifier(& @1, state, $1, false)) {
2788 YYERROR;
2789 }
2790 $$ = NULL;
2791 }
2792 ;
2793
2794 layout_buffer_defaults:
2795 layout_qualifier layout_buffer_defaults
2796 {
2797 $$ = NULL;
2798 if (!state->has_420pack_or_es31()) {
2799 _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2800 YYERROR;
2801 } else {
2802 if (!state->default_shader_storage_qualifier->
2803 merge_qualifier(& @1, state, $1, false)) {
2804 YYERROR;
2805 }
2806 }
2807 }
2808 | layout_qualifier BUFFER ';'
2809 {
2810 if (!state->default_shader_storage_qualifier->
2811 merge_qualifier(& @1, state, $1, false)) {
2812 YYERROR;
2813 }
2814
2815 /* From the GLSL 4.50 spec, section 4.4.5:
2816 *
2817 * "It is a compile-time error to specify the binding identifier for
2818 * the global scope or for block member declarations."
2819 */
2820 if (state->default_shader_storage_qualifier->flags.q.explicit_binding) {
2821 _mesa_glsl_error(& @1, state,
2822 "binding qualifier cannot be set for default layout");
2823 }
2824
2825 $$ = NULL;
2826 }
2827 ;
2828
2829 layout_in_defaults:
2830 layout_qualifier layout_in_defaults
2831 {
2832 $$ = NULL;
2833 if (!state->has_420pack_or_es31()) {
2834 _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2835 YYERROR;
2836 } else {
2837 if (!state->in_qualifier->
2838 merge_in_qualifier(& @1, state, $1, $$, false)) {
2839 YYERROR;
2840 }
2841 $$ = $2;
2842 }
2843 }
2844 | layout_qualifier IN_TOK ';'
2845 {
2846 $$ = NULL;
2847 if (!state->in_qualifier->
2848 merge_in_qualifier(& @1, state, $1, $$, true)) {
2849 YYERROR;
2850 }
2851 }
2852 ;
2853
2854 layout_out_defaults:
2855 layout_qualifier layout_out_defaults
2856 {
2857 $$ = NULL;
2858 if (!state->has_420pack_or_es31()) {
2859 _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
2860 YYERROR;
2861 } else {
2862 if (!state->out_qualifier->
2863 merge_out_qualifier(& @1, state, $1, $$, false)) {
2864 YYERROR;
2865 }
2866 $$ = $2;
2867 }
2868 }
2869 | layout_qualifier OUT_TOK ';'
2870 {
2871 $$ = NULL;
2872 if (!state->out_qualifier->
2873 merge_out_qualifier(& @1, state, $1, $$, true))
2874 YYERROR;
2875 }
2876 ;
2877
2878 layout_defaults:
2879 layout_uniform_defaults
2880 | layout_buffer_defaults
2881 | layout_in_defaults
2882 | layout_out_defaults
2883 ;