src/freedreno/computerator/ir3_lexer.l

   1 /*
   2  * Copyright (c) 2013 Rob Clark <robclark@freedesktop.org>
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a
   5  * copy of this software and associated documentation files (the "Software"),
   6  * to deal in the Software without restriction, including without limitation
   7  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   8  * and/or sell copies of the Software, and to permit persons to whom the
   9  * Software is furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice (including the next
  12  * paragraph) shall be included in all copies or substantial portions of the
  13  * Software.
  14  *
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  18  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21  * SOFTWARE.
  22  */
  23
  24 %{
  25 #include <stdlib.h>
  26 #include "ir3/ir3.h"
  27 #include "ir3_parser.h"
  28
  29 #define YY_NO_INPUT
  30 #define YY_NO_UNPUT
  31 #define TOKEN(t) (ir3_yylval.tok = t)
  32 extern YYSTYPE ir3_yylval;
  33
  34 static int parse_wrmask(const char *src)
  35 {
  36         int i, num = 0;
  37         for (i = 0; i < 4; i++) {
  38                 if ("xyzw"[i] == src[1]) {
  39                         num |= (1 << i);
  40                         src++;
  41                 }
  42         }
  43         return num;
  44 }
  45
  46 static int parse_reg(const char *str)
  47 {
  48         int num = 0;
  49         if (str[0] == 'h') {
  50                 str++;
  51                 num++;
  52         }
  53         str++;
  54         num += strtol(str, (char **)&str, 10) << 3;
  55         switch (str[1]) {
  56         case 'x': num += 0; break;
  57         case 'y': num += 2; break;
  58         case 'z': num += 4; break;
  59         case 'w': num += 6; break;
  60         default: assert(0); break;
  61         }
  62         return num;
  63 }
  64 %}
  65
  66 %option noyywrap
  67 %option prefix="ir3_yy"
  68
  69 %%
  70 "\n"                              yylineno++;
  71 [ \t]                             ; /* ignore whitespace */
  72 ";"[^\n]*"\n"                     yylineno++; /* ignore comments */
  73 [0-9]+"."[0-9]+                   ir3_yylval.flt = strtod(yytext, NULL);       return T_FLOAT;
  74 [0-9]*                            ir3_yylval.num = strtoul(yytext, NULL, 0);    return T_INT;
  75 "0x"[0-9a-fA-F]*                  ir3_yylval.num = strtoul(yytext, NULL, 0);    return T_HEX;
  76 "@localsize"                      return TOKEN(T_A_LOCALSIZE);
  77 "@const"                          return TOKEN(T_A_CONST);
  78 "@buf"                            return TOKEN(T_A_BUF);
  79 "@invocationid"                   return TOKEN(T_A_INVOCATIONID);
  80 "@wgid"                           return TOKEN(T_A_WGID);
  81 "@numwg"                          return TOKEN(T_A_NUMWG);
  82 "(sy)"                            return TOKEN(T_SY);
  83 "(ss)"                            return TOKEN(T_SS);
  84 "(absneg)"                        return TOKEN(T_ABSNEG);
  85 "(neg)"                           return TOKEN(T_NEG);
  86 "(abs)"                           return TOKEN(T_ABS);
  87 "(r)"                             return TOKEN(T_R);
  88 "(ul)"                            return TOKEN(T_UL);
  89 "(even)"                          return TOKEN(T_EVEN);
  90 "(pos_infinity)"                  return TOKEN(T_POS_INFINITY);
  91 "(ei)"                            return TOKEN(T_EI);
  92 "(jp)"                            return TOKEN(T_JP);
  93 "(rpt"[0-7]")"                    ir3_yylval.num = strtol(yytext+4, NULL, 10); return T_RPT;
  94 "("[x]?[y]?[z]?[w]?")"            ir3_yylval.num = parse_wrmask(yytext); return T_WRMASK;
  95
  96 [h]?"r"[0-9]+"."[xyzw]            ir3_yylval.num = parse_reg(yytext); return T_REGISTER;
  97 [h]?"c"[0-9]+"."[xyzw]            ir3_yylval.num = parse_reg(yytext); return T_CONSTANT;
  98 "a0."[xyzw]                       ir3_yylval.num = parse_reg(yytext); return T_A0;
  99 "p0."[xyzw]                       ir3_yylval.num = parse_reg(yytext); return T_P0;
 100 "s#"[0-9]+                        ir3_yylval.num = strtol(yytext+2, NULL, 10); return T_SAMP;
 101 "t#"[0-9]+                        ir3_yylval.num = strtol(yytext+2, NULL, 10); return T_TEX;
 102
 103                                   /* category 0: */
 104 "nop"                             return TOKEN(T_OP_NOP);
 105 "br"                              return TOKEN(T_OP_BR);
 106 "jump"                            return TOKEN(T_OP_JUMP);
 107 "call"                            return TOKEN(T_OP_CALL);
 108 "ret"                             return TOKEN(T_OP_RET);
 109 "kill"                            return TOKEN(T_OP_KILL);
 110 "end"                             return TOKEN(T_OP_END);
 111 "emit"                            return TOKEN(T_OP_EMIT);
 112 "cut"                             return TOKEN(T_OP_CUT);
 113 "chmask"                          return TOKEN(T_OP_CHMASK);
 114 "chsh"                            return TOKEN(T_OP_CHSH);
 115 "flow_rev"                        return TOKEN(T_OP_FLOW_REV);
 116
 117                                   /* category 1: */
 118 "mova"                            return TOKEN(T_OP_MOVA);
 119 "mov"                             return TOKEN(T_OP_MOV);
 120 "cov"                             return TOKEN(T_OP_COV);
 121
 122 ("f16"|"f32"|"u16"|"u32"|"s16"|"s32"|"u8"|"s8"){2} ir3_yylval.str = yytext; return T_CAT1_TYPE_TYPE;
 123
 124                                   /* category 2: */
 125 "add.f"                           return TOKEN(T_OP_ADD_F);
 126 "min.f"                           return TOKEN(T_OP_MIN_F);
 127 "max.f"                           return TOKEN(T_OP_MAX_F);
 128 "mul.f"                           return TOKEN(T_OP_MUL_F);
 129 "sign.f"                          return TOKEN(T_OP_SIGN_F);
 130 "cmps.f"                          return TOKEN(T_OP_CMPS_F);
 131 "absneg.f"                        return TOKEN(T_OP_ABSNEG_F);
 132 "cmpv.f"                          return TOKEN(T_OP_CMPV_F);
 133 "floor.f"                         return TOKEN(T_OP_FLOOR_F);
 134 "ceil.f"                          return TOKEN(T_OP_CEIL_F);
 135 "rndne.f"                         return TOKEN(T_OP_RNDNE_F);
 136 "rndaz.f"                         return TOKEN(T_OP_RNDAZ_F);
 137 "trunc.f"                         return TOKEN(T_OP_TRUNC_F);
 138 "add.u"                           return TOKEN(T_OP_ADD_U);
 139 "add.s"                           return TOKEN(T_OP_ADD_S);
 140 "sub.u"                           return TOKEN(T_OP_SUB_U);
 141 "sub.s"                           return TOKEN(T_OP_SUB_S);
 142 "cmps.u"                          return TOKEN(T_OP_CMPS_U);
 143 "cmps.s"                          return TOKEN(T_OP_CMPS_S);
 144 "min.u"                           return TOKEN(T_OP_MIN_U);
 145 "min.s"                           return TOKEN(T_OP_MIN_S);
 146 "max.u"                           return TOKEN(T_OP_MAX_U);
 147 "max.s"                           return TOKEN(T_OP_MAX_S);
 148 "absneg.s"                        return TOKEN(T_OP_ABSNEG_S);
 149 "and.b"                           return TOKEN(T_OP_AND_B);
 150 "or.b"                            return TOKEN(T_OP_OR_B);
 151 "not.b"                           return TOKEN(T_OP_NOT_B);
 152 "xor.b"                           return TOKEN(T_OP_XOR_B);
 153 "cmpv.u"                          return TOKEN(T_OP_CMPV_U);
 154 "cmpv.s"                          return TOKEN(T_OP_CMPV_S);
 155 "mul.u24"                         return TOKEN(T_OP_MUL_U24);
 156 "mul.s24"                         return TOKEN(T_OP_MUL_S24);
 157 "mull.u"                          return TOKEN(T_OP_MULL_U);
 158 "bfrev.b"                         return TOKEN(T_OP_BFREV_B);
 159 "clz.s"                           return TOKEN(T_OP_CLZ_S);
 160 "clz.b"                           return TOKEN(T_OP_CLZ_B);
 161 "shl.b"                           return TOKEN(T_OP_SHL_B);
 162 "shr.b"                           return TOKEN(T_OP_SHR_B);
 163 "ashr.b"                          return TOKEN(T_OP_ASHR_B);
 164 "bary.f"                          return TOKEN(T_OP_BARY_F);
 165 "mgen.b"                          return TOKEN(T_OP_MGEN_B);
 166 "getbit.b"                        return TOKEN(T_OP_GETBIT_B);
 167 "setrm"                           return TOKEN(T_OP_SETRM);
 168 "cbits.b"                         return TOKEN(T_OP_CBITS_B);
 169 "shb"                             return TOKEN(T_OP_SHB);
 170 "msad"                            return TOKEN(T_OP_MSAD);
 171
 172                                   /* category 3: */
 173 "mad.u16"                         return TOKEN(T_OP_MAD_U16);
 174 "madsh.u16"                       return TOKEN(T_OP_MADSH_U16);
 175 "mad.s16"                         return TOKEN(T_OP_MAD_S16);
 176 "madsh.m16"                       return TOKEN(T_OP_MADSH_M16);
 177 "mad.u24"                         return TOKEN(T_OP_MAD_U24);
 178 "mad.s24"                         return TOKEN(T_OP_MAD_S24);
 179 "mad.f16"                         return TOKEN(T_OP_MAD_F16);
 180 "mad.f32"                         return TOKEN(T_OP_MAD_F32);
 181 "sel.b16"                         return TOKEN(T_OP_SEL_B16);
 182 "sel.b32"                         return TOKEN(T_OP_SEL_B32);
 183 "sel.s16"                         return TOKEN(T_OP_SEL_S16);
 184 "sel.s32"                         return TOKEN(T_OP_SEL_S32);
 185 "sel.f16"                         return TOKEN(T_OP_SEL_F16);
 186 "sel.f32"                         return TOKEN(T_OP_SEL_F32);
 187 "sad.s16"                         return TOKEN(T_OP_SAD_S16);
 188 "sad.s32"                         return TOKEN(T_OP_SAD_S32);
 189
 190                                   /* category 4: */
 191 "rcp"                             return TOKEN(T_OP_RCP);
 192 "rsq"                             return TOKEN(T_OP_RSQ);
 193 "log2"                            return TOKEN(T_OP_LOG2);
 194 "exp2"                            return TOKEN(T_OP_EXP2);
 195 "sin"                             return TOKEN(T_OP_SIN);
 196 "cos"                             return TOKEN(T_OP_COS);
 197 "sqrt"                            return TOKEN(T_OP_SQRT);
 198 "hrsq"                            return TOKEN(T_OP_HRSQ);
 199 "hlog2"                           return TOKEN(T_OP_HLOG2);
 200 "hexp2"                           return TOKEN(T_OP_HEXP2);
 201
 202                                   /* category 5: */
 203 "isam"                            return TOKEN(T_OP_ISAM);
 204 "isaml"                           return TOKEN(T_OP_ISAML);
 205 "isamm"                           return TOKEN(T_OP_ISAMM);
 206 "sam"                             return TOKEN(T_OP_SAM);
 207 "samb"                            return TOKEN(T_OP_SAMB);
 208 "saml"                            return TOKEN(T_OP_SAML);
 209 "samgq"                           return TOKEN(T_OP_SAMGQ);
 210 "getlod"                          return TOKEN(T_OP_GETLOD);
 211 "conv"                            return TOKEN(T_OP_CONV);
 212 "convm"                           return TOKEN(T_OP_CONVM);
 213 "getsize"                         return TOKEN(T_OP_GETSIZE);
 214 "getbuf"                          return TOKEN(T_OP_GETBUF);
 215 "getpos"                          return TOKEN(T_OP_GETPOS);
 216 "getinfo"                         return TOKEN(T_OP_GETINFO);
 217 "dsx"                             return TOKEN(T_OP_DSX);
 218 "dsy"                             return TOKEN(T_OP_DSY);
 219 "gather4r"                        return TOKEN(T_OP_GATHER4R);
 220 "gather4g"                        return TOKEN(T_OP_GATHER4G);
 221 "gather4b"                        return TOKEN(T_OP_GATHER4B);
 222 "gather4a"                        return TOKEN(T_OP_GATHER4A);
 223 "samgp0"                          return TOKEN(T_OP_SAMGP0);
 224 "samgp1"                          return TOKEN(T_OP_SAMGP1);
 225 "samgp2"                          return TOKEN(T_OP_SAMGP2);
 226 "samgp3"                          return TOKEN(T_OP_SAMGP3);
 227 "dsxpp.1"                         return TOKEN(T_OP_DSXPP_1);
 228 "dsypp.1"                         return TOKEN(T_OP_DSYPP_1);
 229 "rgetpos"                         return TOKEN(T_OP_RGETPOS);
 230 "rgetinfo"                        return TOKEN(T_OP_RGETINFO);
 231
 232                                   /* category 6: */
 233 "ldg"                             return TOKEN(T_OP_LDG);
 234 "ldl"                             return TOKEN(T_OP_LDL);
 235 "ldp"                             return TOKEN(T_OP_LDP);
 236 "stg"                             return TOKEN(T_OP_STG);
 237 "stl"                             return TOKEN(T_OP_STL);
 238 "stp"                             return TOKEN(T_OP_STP);
 239 "ldib"                            return TOKEN(T_OP_LDIB);
 240 "g2l"                             return TOKEN(T_OP_G2L);
 241 "l2g"                             return TOKEN(T_OP_L2G);
 242 "prefetch"                        return TOKEN(T_OP_PREFETCH);
 243 "ldlw"                            return TOKEN(T_OP_LDLW);
 244 "stlw"                            return TOKEN(T_OP_STLW);
 245 "resfmt"                          return TOKEN(T_OP_RESFMT);
 246 "resinf"                          return TOKEN(T_OP_RESINF);
 247 "atomic.add"                      return TOKEN(T_OP_ATOMIC_ADD);
 248 "atomic.sub"                      return TOKEN(T_OP_ATOMIC_SUB);
 249 "atomic.xchg"                     return TOKEN(T_OP_ATOMIC_XCHG);
 250 "atomic.inc"                      return TOKEN(T_OP_ATOMIC_INC);
 251 "atomic.dec"                      return TOKEN(T_OP_ATOMIC_DEC);
 252 "atomic.cmpxchg"                  return TOKEN(T_OP_ATOMIC_CMPXCHG);
 253 "atomic.min"                      return TOKEN(T_OP_ATOMIC_MIN);
 254 "atomic.max"                      return TOKEN(T_OP_ATOMIC_MAX);
 255 "atomic.and"                      return TOKEN(T_OP_ATOMIC_AND);
 256 "atomic.or"                       return TOKEN(T_OP_ATOMIC_OR);
 257 "atomic.xor"                      return TOKEN(T_OP_ATOMIC_XOR);
 258 "ldgb"                            return TOKEN(T_OP_LDGB);
 259 "stgb"                            return TOKEN(T_OP_STGB);
 260 "stib"                            return TOKEN(T_OP_STIB);
 261 "ldc"                             return TOKEN(T_OP_LDC);
 262 "ldlv"                            return TOKEN(T_OP_LDLV);
 263
 264 "f16"                             return TOKEN(T_TYPE_F16);
 265 "f32"                             return TOKEN(T_TYPE_F32);
 266 "u16"                             return TOKEN(T_TYPE_U16);
 267 "u32"                             return TOKEN(T_TYPE_U32);
 268 "s16"                             return TOKEN(T_TYPE_S16);
 269 "s32"                             return TOKEN(T_TYPE_S32);
 270 "u8"                              return TOKEN(T_TYPE_U8);
 271 "s8"                              return TOKEN(T_TYPE_S8);
 272
 273 "untyped"                         return TOKEN(T_UNTYPED);
 274 "typed"                           return TOKEN(T_TYPED);
 275
 276 "1d"                              return TOKEN(T_1D);
 277 "2d"                              return TOKEN(T_2D);
 278 "3d"                              return TOKEN(T_3D);
 279 "4d"                              return TOKEN(T_4D);
 280
 281 "lt"                              return TOKEN(T_LT);
 282 "le"                              return TOKEN(T_LE);
 283 "gt"                              return TOKEN(T_GT);
 284 "ge"                              return TOKEN(T_GE);
 285 "eq"                              return TOKEN(T_EQ);
 286 "ne"                              return TOKEN(T_NE);
 287
 288 "a"                               return 'a';
 289 "o"                               return 'o';
 290 "p"                               return 'p';
 291 "s2en"                            return TOKEN(T_S2EN);
 292 "s"                               return 's';
 293
 294 "="                               return '=';
 295 "("                               return '(';
 296 ")"                               return ')';
 297 "["                               return '[';
 298 "]"                               return ']';
 299 ","                               return ',';
 300 "."                               return '.';
 301 "-"                               return '-';
 302 "+"                               return '+';
 303 "|"                               return '|';
 304 "c"                               return 'c';
 305 "r"                               return 'r';
 306 "g"                               return 'g';
 307 "l"                               return 'l';
 308 "<"                               return '<';
 309 ">"                               return '>';
 310 "!"                               return '!';
 311 "#"                               return '#';
 312
 313 "nan"                             return TOKEN(T_NAN);
 314 "inf"                             return TOKEN(T_INF);
 315
 316 [a-zA-Z_][a-zA-Z_0-9]*            ir3_yylval.str = yytext;     return T_IDENTIFIER;
 317 .                                 fprintf(stderr, "error at line %d: Unknown token: %s\n", ir3_yyget_lineno(), yytext); yyterminate();
 318 %%