src/gallium/drivers/radeon/R600Instructions.td

   1 //===-- R600Instructions.td - R600 Instruction defs  -------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // R600 Tablegen instruction definitions
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "R600Intrinsics.td"
  15
  16 class InstR600 <bits<32> inst, dag outs, dag ins, string asm, list<dag> pattern,
  17                 InstrItinClass itin>
  18     : AMDGPUInst <outs, ins, asm, pattern> {
  19
  20   field bits<32> Inst;
  21         bit Trig = 0;
  22   bit Op3 = 0;
  23
  24   let Inst = inst;
  25   let Namespace = "AMDIL";
  26   let OutOperandList = outs;
  27   let InOperandList = ins;
  28   let AsmString = asm;
  29   let Pattern = pattern;
  30   let Itinerary = itin;
  31
  32   let TSFlags{4} = Trig;
  33   let TSFlags{5} = Op3;
  34 }
  35
  36 class InstR600ISA <dag outs, dag ins, string asm, list<dag> pattern> :
  37     AMDGPUInst <outs, ins, asm, pattern>
  38 {
  39   field bits<64> Inst;
  40
  41   let Namespace = "AMDIL";
  42 }
  43
  44 def MEMri : Operand<iPTRAny> {
  45   let MIOperandInfo = (ops R600_Reg32:$ptr, R600_Reg32:$index);
  46 }
  47
  48 def ADDRParam : ComplexPattern<i32, 2, "SelectADDRParam", [], []>;
  49
  50 class R600_ALU {
  51
  52   bits<7> DST_GPR = 0;
  53   bits<9> SRC0_SEL = 0;
  54   bits<1> SRC0_NEG = 0;
  55   bits<9> SRC1_SEL = 0;
  56   bits<1> SRC1_NEG = 0;
  57   bits<1> CLAMP = 0;
  58
  59 }
  60
  61
  62 class R600_1OP <bits<32> inst, string opName, list<dag> pattern,
  63                 InstrItinClass itin = AnyALU> :
  64   InstR600 <inst,
  65           (outs R600_Reg32:$dst),
  66           (ins R600_Reg32:$src, variable_ops),
  67           !strconcat(opName, " $dst, $src"),
  68           pattern,
  69           itin
  70   >;
  71
  72 class R600_2OP <bits<32> inst, string opName, list<dag> pattern,
  73                 InstrItinClass itin = AnyALU> :
  74   InstR600 <inst,
  75           (outs R600_Reg32:$dst),
  76           (ins R600_Reg32:$src0, R600_Reg32:$src1, variable_ops),
  77           !strconcat(opName, " $dst, $src0, $src1"),
  78           pattern,
  79           itin
  80   >;
  81
  82 class R600_3OP <bits<32> inst, string opName, list<dag> pattern,
  83                 InstrItinClass itin = AnyALU> :
  84   InstR600 <inst,
  85           (outs R600_Reg32:$dst),
  86           (ins R600_Reg32:$src0, R600_Reg32:$src1, R600_Reg32:$src2, variable_ops),
  87           !strconcat(opName, " $dst, $src0, $src1, $src2"),
  88           pattern,
  89           itin>{
  90
  91     let Op3 = 1;
  92   }
  93
  94 class R600_REDUCTION <bits<32> inst, dag ins, string asm, list<dag> pattern,
  95                       InstrItinClass itin = VecALU> :
  96   InstR600 <inst,
  97           (outs R600_Reg32:$dst),
  98           ins,
  99           asm,
 100           pattern,
 101           itin
 102
 103   >;
 104
 105 class R600_TEX <bits<32> inst, string opName, list<dag> pattern,
 106                 InstrItinClass itin = AnyALU> :
 107   InstR600 <inst,
 108           (outs R600_Reg128:$dst),
 109           (ins R600_Reg128:$src0, i32imm:$src1, i32imm:$src2),
 110           !strconcat(opName, "$dst, $src0, $src1, $src2"),
 111           pattern,
 112           itin
 113   >;
 114
 115 def TEX_SHADOW : PatLeaf<
 116   (imm),
 117   [{uint32_t TType = (uint32_t)N->getZExtValue();
 118     return (TType >= 6 && TType <= 8) || TType == 11 || TType == 12;
 119   }]
 120 >;
 121
 122 def FP_ZERO : PatLeaf <
 123   (fpimm),
 124   [{return N->getValueAPF().isZero();}]
 125 >;
 126
 127 def FP_ONE : PatLeaf <
 128   (fpimm),
 129   [{return N->isExactlyValue(1.0);}]
 130 >;
 131
 132 def COND_EQ : PatLeaf <
 133   (cond),
 134   [{switch(N->get()){{default: return false;
 135                      case ISD::SETOEQ: case ISD::SETUEQ:
 136                      case ISD::SETEQ: return true;}}}]
 137 >;
 138
 139 def COND_NE : PatLeaf <
 140   (cond),
 141   [{switch(N->get()){{default: return false;
 142                      case ISD::SETONE: case ISD::SETUNE:
 143                      case ISD::SETNE: return true;}}}]
 144 >;
 145 def COND_GT : PatLeaf <
 146   (cond),
 147   [{switch(N->get()){{default: return false;
 148                      case ISD::SETOGT: case ISD::SETUGT:
 149                      case ISD::SETGT: return true;}}}]
 150 >;
 151
 152 def COND_GE : PatLeaf <
 153   (cond),
 154   [{switch(N->get()){{default: return false;
 155                      case ISD::SETOGE: case ISD::SETUGE:
 156                      case ISD::SETGE: return true;}}}]
 157 >;
 158
 159 def COND_LT : PatLeaf <
 160   (cond),
 161   [{switch(N->get()){{default: return false;
 162                      case ISD::SETOLT: case ISD::SETULT:
 163                      case ISD::SETLT: return true;}}}]
 164 >;
 165
 166 def COND_LE : PatLeaf <
 167   (cond),
 168   [{switch(N->get()){{default: return false;
 169                      case ISD::SETOLE: case ISD::SETULE:
 170                      case ISD::SETLE: return true;}}}]
 171 >;
 172
 173 class EG_CF_RAT <bits <8> cf_inst, bits <6> rat_inst, dag outs, dag ins,
 174                  string asm> :
 175     InstR600ISA <outs, ins, asm, []>
 176 {
 177   bits<7>  RW_GPR;
 178   bits<7>  INDEX_GPR;
 179   bits<4>  RAT_ID;
 180
 181   bits<2>  RIM;
 182   bits<2>  TYPE;
 183   bits<1>  RW_REL;
 184   bits<2>  ELEM_SIZE;
 185
 186   bits<12> ARRAY_SIZE;
 187   bits<4>  COMP_MASK;
 188   bits<4>  BURST_COUNT;
 189   bits<1>  VPM;
 190   bits<1>  EOP;
 191   bits<1>  MARK;
 192   bits<1>  BARRIER;
 193
 194   /* CF_ALLOC_EXPORT_WORD0_RAT */
 195   let Inst{3-0}   = RAT_ID;
 196   let Inst{9-4}   = rat_inst;
 197   let Inst{10}    = 0; /* Reserved */
 198   let Inst{12-11} = RIM;
 199   let Inst{14-13} = TYPE;
 200   let Inst{21-15} = RW_GPR;
 201   let Inst{22}    = RW_REL;
 202   let Inst{29-23} = INDEX_GPR;
 203   let Inst{31-30} = ELEM_SIZE;
 204
 205   /* CF_ALLOC_EXPORT_WORD1_BUF */
 206   let Inst{43-32} = ARRAY_SIZE;
 207   let Inst{47-44} = COMP_MASK;
 208   let Inst{51-48} = BURST_COUNT;
 209   let Inst{52}    = VPM;
 210   let Inst{53}    = EOP;
 211   let Inst{61-54} = cf_inst;
 212   let Inst{62}    = MARK;
 213   let Inst{63}    = BARRIER;
 214 }
 215
 216 /*
 217 def store_global : PatFrag<(ops node:$value, node:$ptr),
 218                            (store node:$value, node:$ptr),
 219                            [{
 220                             const Value *Src;
 221                             const PointerType *Type;
 222                             if ((src = cast<StoreSDNode>(N)->getSrcValue() &&
 223                                  PT = dyn_cast<PointerType>(Src->getType()))) {
 224                               return PT->getAddressSpace() == 1;
 225                             }
 226                             return false;
 227                            }]>;
 228
 229 */
 230
 231 def load_param : PatFrag<(ops node:$ptr),
 232                          (load node:$ptr),
 233                           [{
 234                            return true;
 235                            const Value *Src = cast<LoadSDNode>(N)->getSrcValue();
 236                            if (Src) {
 237                                 PointerType * PT = dyn_cast<PointerType>(Src->getType());
 238                                 return PT && PT->getAddressSpace() == AMDILAS::PARAM_I_ADDRESS;
 239                            }
 240                            return false;
 241                           }]>;
 242
 243 //class EG_CF <bits<32> inst, string asm> :
 244 //    InstR600 <inst, (outs), (ins), asm, []>;
 245
 246 /* XXX: We will use this when we emit the real ISA.
 247   bits<24> ADDR = 0;
 248   bits<3> JTS = 0;
 249
 250   bits<3> PC = 0;
 251   bits<5> CF_CONS = 0;
 252   bits<2> COND = 0;
 253   bits<6> COUNT = 0;
 254   bits<1> VPM = 0;
 255   bits<1> EOP = 0;
 256   bits<8> CF_INST = 0;
 257   bits<1> WQM = 0;
 258   bits<1> B = 0;
 259
 260   let Inst{23-0} = ADDR;
 261   let Inst{26-24} = JTS;
 262   let Inst{34-32} = PC;
 263   let Inst{39-35} = CF_CONST;
 264   let Inst{41-40} = COND;
 265   let Inst{47-42} = COUNT;
 266   let Inst{52} = VPM;
 267   let Inst{53} = EOP;
 268   let Inst{61-54} = CF_INST;
 269   let Inst{62} = WQM;
 270   let Inst{63} = B;
 271 //}
 272 */
 273 def isR600 : Predicate<"Subtarget.device()"
 274                             "->getGeneration() == AMDILDeviceInfo::HD4XXX">;
 275 def isEG : Predicate<"Subtarget.device()"
 276                             "->getGeneration() >= AMDILDeviceInfo::HD5XXX && "
 277                             "Subtarget.device()->getDeviceFlag() != OCL_DEVICE_CAYMAN">;
 278 def isCayman : Predicate<"Subtarget.device()"
 279                             "->getDeviceFlag() == OCL_DEVICE_CAYMAN">;
 280 def isEGorCayman : Predicate<"Subtarget.device()"
 281                             "->getGeneration() == AMDILDeviceInfo::HD5XXX"
 282                             "|| Subtarget.device()->getGeneration() =="
 283                             "AMDILDeviceInfo::HD6XXX">;
 284
 285 def isR600toCayman : Predicate<
 286                      "Subtarget.device()->getGeneration() <= AMDILDeviceInfo::HD6XXX">;
 287
 288
 289 let Predicates = [isR600toCayman] in {
 290
 291 /* ------------------------------------------- */
 292 /* Common Instructions R600, R700, Evergreen, Cayman */
 293 /* ------------------------------------------- */
 294 def ADD : R600_2OP <
 295   0x0, "ADD",
 296   [(set R600_Reg32:$dst, (fadd R600_Reg32:$src0, R600_Reg32:$src1))]
 297 >;
 298
 299 // Non-IEEE MUL: 0 * anything = 0
 300 def MUL : R600_2OP <
 301   0x1, "MUL NON-IEEE",
 302   [(set R600_Reg32:$dst, (int_AMDGPU_mul R600_Reg32:$src0, R600_Reg32:$src1))]
 303 >;
 304
 305 def MUL_IEEE : R600_2OP <
 306   0x2, "MUL_IEEE",
 307   [(set R600_Reg32:$dst, (fmul R600_Reg32:$src0, R600_Reg32:$src1))]
 308 >;
 309
 310 def MAX : R600_2OP <
 311   0x3, "MAX",
 312   [(set R600_Reg32:$dst, (AMDGPUfmax R600_Reg32:$src0, R600_Reg32:$src1))]
 313 >;
 314
 315 def MIN : R600_2OP <
 316   0x4, "MIN",
 317   [(set R600_Reg32:$dst, (AMDGPUfmin R600_Reg32:$src0, R600_Reg32:$src1))]
 318 >;
 319
 320 /* For the SET* instructions there is a naming conflict in TargetSelectionDAG.td,
 321  * so some of the instruction names don't match the asm string.
 322  * XXX: Use the defs in TargetSelectionDAG.td instead of intrinsics.
 323  */
 324
 325 def SETE : R600_2OP <
 326   0x08, "SETE",
 327   [(set R600_Reg32:$dst,
 328    (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO,
 329              COND_EQ))]
 330 >;
 331
 332 def SGT : R600_2OP <
 333   0x09, "SETGT",
 334   [(set R600_Reg32:$dst,
 335    (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO,
 336               COND_GT))]
 337 >;
 338
 339 def SGE : R600_2OP <
 340   0xA, "SETGE",
 341   [(set R600_Reg32:$dst,
 342    (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO,
 343               COND_GE))]
 344 >;
 345
 346 def SNE : R600_2OP <
 347   0xB, "SETNE",
 348   [(set R600_Reg32:$dst,
 349    (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO,
 350     COND_NE))]
 351 >;
 352
 353 def FRACT : R600_1OP <
 354   0x10, "FRACT",
 355   [(set R600_Reg32:$dst, (AMDGPUfract R600_Reg32:$src))]
 356 >;
 357
 358 def TRUNC : R600_1OP <
 359   0x11, "TRUNC",
 360   [(set R600_Reg32:$dst, (int_AMDGPU_trunc R600_Reg32:$src))]
 361 >;
 362
 363 def CEIL : R600_1OP <
 364   0x12, "CEIL",
 365   [(set R600_Reg32:$dst, (fceil R600_Reg32:$src))]
 366 >;
 367
 368 def RNDNE : R600_1OP <
 369   0x13, "RNDNE",
 370   [(set R600_Reg32:$dst, (frint R600_Reg32:$src))]
 371 >;
 372
 373 def FLOOR : R600_1OP <
 374   0x14, "FLOOR",
 375   [(set R600_Reg32:$dst, (int_AMDGPU_floor R600_Reg32:$src))]
 376 >;
 377
 378 def MOV : R600_1OP <0x19, "MOV", []>;
 379
 380 def KILLGT : R600_2OP <
 381   0x2D, "KILLGT",
 382   []
 383 >;
 384
 385 def AND_INT : R600_2OP <
 386   0x30, "AND_INT",
 387   [(set R600_Reg32:$dst, (and R600_Reg32:$src0, R600_Reg32:$src1))]
 388 >;
 389
 390 def OR_INT : R600_2OP <
 391   0x31, "OR_INT",
 392   [(set R600_Reg32:$dst, (or R600_Reg32:$src0, R600_Reg32:$src1))]
 393 >;
 394
 395 def XOR_INT : R600_2OP <
 396   0x32, "XOR_INT",
 397   [(set R600_Reg32:$dst, (xor R600_Reg32:$src0, R600_Reg32:$src1))]
 398 >;
 399
 400 def NOT_INT : R600_1OP <
 401   0x33, "NOT_INT",
 402   [(set R600_Reg32:$dst, (not R600_Reg32:$src))]
 403 >;
 404
 405 def ADD_INT : R600_2OP <
 406   0x34, "ADD_INT",
 407   [(set R600_Reg32:$dst, (add R600_Reg32:$src0, R600_Reg32:$src1))]
 408 >;
 409
 410 def SUB_INT : R600_2OP <
 411         0x35, "SUB_INT",
 412         [(set R600_Reg32:$dst, (sub R600_Reg32:$src0, R600_Reg32:$src1))]
 413 >;
 414
 415 def MAX_INT : R600_2OP <
 416   0x36, "MAX_INT",
 417   [(set R600_Reg32:$dst, (AMDGPUsmax R600_Reg32:$src0, R600_Reg32:$src1))]>;
 418
 419 def MIN_INT : R600_2OP <
 420   0x37, "MIN_INT",
 421   [(set R600_Reg32:$dst, (AMDGPUsmin R600_Reg32:$src0, R600_Reg32:$src1))]>;
 422
 423 def MAX_UINT : R600_2OP <
 424   0x38, "MAX_UINT",
 425   [(set R600_Reg32:$dst, (AMDGPUsmax R600_Reg32:$src0, R600_Reg32:$src1))]
 426 >;
 427
 428 def MIN_UINT : R600_2OP <
 429   0x39, "MIN_UINT",
 430   [(set R600_Reg32:$dst, (AMDGPUumin R600_Reg32:$src0, R600_Reg32:$src1))]
 431 >;
 432
 433 def SETE_INT : R600_2OP <
 434   0x3A, "SETE_INT",
 435   [(set (i32 R600_Reg32:$dst),
 436    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETEQ))]
 437 >;
 438
 439 def SETGT_INT : R600_2OP <
 440   0x3B, "SGT_INT",
 441   [(set (i32 R600_Reg32:$dst),
 442    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETGT))]
 443 >;
 444
 445 def SETGE_INT : R600_2OP <
 446         0x3C, "SETGE_INT",
 447         [(set (i32 R600_Reg32:$dst),
 448    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETGE))]
 449 >;
 450
 451 def SETNE_INT : R600_2OP <
 452   0x3D, "SETNE_INT",
 453   [(set (i32 R600_Reg32:$dst),
 454    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETNE))]
 455 >;
 456
 457 def SETGT_UINT : R600_2OP <
 458   0x3E, "SETGT_UINT",
 459   [(set (i32 R600_Reg32:$dst),
 460    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETUGT))]
 461 >;
 462
 463 def SETGE_UINT : R600_2OP <
 464   0x3F, "SETGE_UINT",
 465   [(set (i32 R600_Reg32:$dst),
 466     (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETUGE))]
 467 >;
 468
 469 def CNDE_INT : R600_3OP <
 470         0x1C, "CNDE_INT",
 471   [(set (i32 R600_Reg32:$dst),
 472    (IL_cmov_logical R600_Reg32:$src0, R600_Reg32:$src2, R600_Reg32:$src1))]
 473 >;
 474
 475 /* Texture instructions */
 476
 477
 478 def TEX_LD : R600_TEX <
 479   0x03, "TEX_LD",
 480   [(set R600_Reg128:$dst, (int_AMDGPU_txf R600_Reg128:$src0, imm:$src1, imm:$src2, imm:$src3, imm:$src4, imm:$src5))]
 481 > {
 482 let AsmString = "TEX_LD $dst, $src0, $src1, $src2, $src3, $src4, $src5";
 483 let InOperandList = (ins R600_Reg128:$src0, i32imm:$src1, i32imm:$src2, i32imm:$src3, i32imm:$src4, i32imm:$src5);
 484 }
 485
 486 def TEX_GET_TEXTURE_RESINFO : R600_TEX <
 487   0x04, "TEX_GET_TEXTURE_RESINFO",
 488   [(set R600_Reg128:$dst, (int_AMDGPU_txq R600_Reg128:$src0, imm:$src1, imm:$src2))]
 489 >;
 490
 491 def TEX_GET_GRADIENTS_H : R600_TEX <
 492   0x07, "TEX_GET_GRADIENTS_H",
 493   [(set R600_Reg128:$dst, (int_AMDGPU_ddx R600_Reg128:$src0, imm:$src1, imm:$src2))]
 494 >;
 495
 496 def TEX_GET_GRADIENTS_V : R600_TEX <
 497   0x08, "TEX_GET_GRADIENTS_V",
 498   [(set R600_Reg128:$dst, (int_AMDGPU_ddy R600_Reg128:$src0, imm:$src1, imm:$src2))]
 499 >;
 500
 501 def TEX_SET_GRADIENTS_H : R600_TEX <
 502   0x0B, "TEX_SET_GRADIENTS_H",
 503   []
 504 >;
 505
 506 def TEX_SET_GRADIENTS_V : R600_TEX <
 507   0x0C, "TEX_SET_GRADIENTS_V",
 508   []
 509 >;
 510
 511 def TEX_SAMPLE : R600_TEX <
 512   0x10, "TEX_SAMPLE",
 513   [(set R600_Reg128:$dst, (int_AMDGPU_tex R600_Reg128:$src0, imm:$src1, imm:$src2))]
 514 >;
 515
 516 def TEX_SAMPLE_C : R600_TEX <
 517   0x18, "TEX_SAMPLE_C",
 518   [(set R600_Reg128:$dst, (int_AMDGPU_tex R600_Reg128:$src0, imm:$src1, TEX_SHADOW:$src2))]
 519 >;
 520
 521 def TEX_SAMPLE_L : R600_TEX <
 522   0x11, "TEX_SAMPLE_L",
 523   [(set R600_Reg128:$dst, (int_AMDGPU_txl R600_Reg128:$src0, imm:$src1, imm:$src2))]
 524 >;
 525
 526 def TEX_SAMPLE_C_L : R600_TEX <
 527   0x19, "TEX_SAMPLE_C_L",
 528   [(set R600_Reg128:$dst, (int_AMDGPU_txl R600_Reg128:$src0, imm:$src1, TEX_SHADOW:$src2))]
 529 >;
 530
 531 def TEX_SAMPLE_LB : R600_TEX <
 532   0x12, "TEX_SAMPLE_LB",
 533   [(set R600_Reg128:$dst, (int_AMDGPU_txb R600_Reg128:$src0, imm:$src1, imm:$src2))]
 534 >;
 535
 536 def TEX_SAMPLE_C_LB : R600_TEX <
 537   0x1A, "TEX_SAMPLE_C_LB",
 538   [(set R600_Reg128:$dst, (int_AMDGPU_txb R600_Reg128:$src0, imm:$src1, TEX_SHADOW:$src2))]
 539 >;
 540
 541 def TEX_SAMPLE_G : R600_TEX <
 542   0x14, "TEX_SAMPLE_G",
 543   []
 544 >;
 545
 546 def TEX_SAMPLE_C_G : R600_TEX <
 547   0x1C, "TEX_SAMPLE_C_G",
 548   []
 549 >;
 550
 551 def KILP : Pat <
 552   (int_AMDGPU_kilp),
 553   (MASK_WRITE (KILLGT (f32 ONE), (f32 ZERO)))
 554 >;
 555
 556 def KIL : Pat <
 557   (int_AMDGPU_kill R600_Reg32:$src0),
 558   (MASK_WRITE (KILLGT (f32 ZERO), (f32 R600_Reg32:$src0)))
 559 >;
 560
 561 /* Helper classes for common instructions */
 562
 563 class MUL_LIT_Common <bits<32> inst> : R600_3OP <
 564   inst, "MUL_LIT",
 565   []
 566 >;
 567
 568 class MULADD_Common <bits<32> inst> : R600_3OP <
 569   inst, "MULADD",
 570   [(set (f32 R600_Reg32:$dst),
 571    (IL_mad R600_Reg32:$src0, R600_Reg32:$src1, R600_Reg32:$src2))]
 572 >;
 573
 574 class CNDE_Common <bits<32> inst> : R600_3OP <
 575   inst, "CNDE",
 576   [(set (f32 R600_Reg32:$dst),
 577    (IL_cmov_logical R600_Reg32:$src0, R600_Reg32:$src2, R600_Reg32:$src1))]
 578 >;
 579
 580 class CNDGT_Common <bits<32> inst> : R600_3OP <
 581   inst, "CNDGT",
 582   []
 583 >;
 584
 585 class CNDGE_Common <bits<32> inst> : R600_3OP <
 586   inst, "CNDGE",
 587   [(set R600_Reg32:$dst, (int_AMDGPU_cndlt R600_Reg32:$src0, R600_Reg32:$src2, R600_Reg32:$src1))]
 588 >;
 589
 590 class DOT4_Common <bits<32> inst> : R600_REDUCTION <
 591   inst,
 592   (ins R600_Reg128:$src0, R600_Reg128:$src1),
 593   "DOT4 $dst $src0, $src1",
 594   [(set R600_Reg32:$dst, (int_AMDGPU_dp4 R600_Reg128:$src0, R600_Reg128:$src1))]
 595 >;
 596
 597 class CUBE_Common <bits<32> inst> : InstR600 <
 598   inst,
 599   (outs R600_Reg128:$dst),
 600   (ins R600_Reg128:$src),
 601   "CUBE $dst $src",
 602   [(set R600_Reg128:$dst, (int_AMDGPU_cube R600_Reg128:$src))],
 603   VecALU
 604 >;
 605
 606 class EXP_IEEE_Common <bits<32> inst> : R600_1OP <
 607   inst, "EXP_IEEE",
 608   [(set R600_Reg32:$dst, (fexp2 R600_Reg32:$src))]
 609 >;
 610
 611 class FLT_TO_INT_Common <bits<32> inst> : R600_1OP <
 612   inst, "FLT_TO_INT",
 613   [(set R600_Reg32:$dst, (fp_to_sint R600_Reg32:$src))]
 614 >;
 615
 616 class INT_TO_FLT_Common <bits<32> inst> : R600_1OP <
 617   inst, "INT_TO_FLT",
 618   [(set R600_Reg32:$dst, (sint_to_fp R600_Reg32:$src))]
 619 >;
 620
 621 class FLT_TO_UINT_Common <bits<32> inst> : R600_1OP <
 622   inst, "FLT_TO_UINT",
 623   [(set R600_Reg32:$dst, (fp_to_uint R600_Reg32:$src))]
 624 >;
 625
 626 class UINT_TO_FLT_Common <bits<32> inst> : R600_1OP <
 627   inst, "UINT_TO_FLT",
 628   [(set R600_Reg32:$dst, (uint_to_fp R600_Reg32:$src))]
 629 >;
 630
 631 class LOG_CLAMPED_Common <bits<32> inst> : R600_1OP <
 632   inst, "LOG_CLAMPED",
 633   []
 634 >;
 635
 636 class LOG_IEEE_Common <bits<32> inst> : R600_1OP <
 637   inst, "LOG_IEEE",
 638   [(set R600_Reg32:$dst, (int_AMDIL_log R600_Reg32:$src))]
 639 >;
 640
 641 class LSHL_Common <bits<32> inst> : R600_2OP <
 642   inst, "LSHL $dst, $src0, $src1",
 643   [(set R600_Reg32:$dst, (shl R600_Reg32:$src0, R600_Reg32:$src1))]
 644 >;
 645
 646 class LSHR_Common <bits<32> inst> : R600_2OP <
 647   inst, "LSHR $dst, $src0, $src1",
 648   [(set R600_Reg32:$dst, (srl R600_Reg32:$src0, R600_Reg32:$src1))]
 649 >;
 650
 651 class ASHR_Common <bits<32> inst> : R600_2OP <
 652   inst, "ASHR $dst, $src0, $src1",
 653   [(set R600_Reg32:$dst, (sra R600_Reg32:$src0, R600_Reg32:$src1))]
 654 >;
 655
 656 class MULHI_INT_Common <bits<32> inst> : R600_2OP <
 657   inst, "MULHI_INT $dst, $src0, $src1",
 658   [(set R600_Reg32:$dst, (mulhs R600_Reg32:$src0, R600_Reg32:$src1))]
 659 >;
 660
 661 class MULHI_UINT_Common <bits<32> inst> : R600_2OP <
 662   inst, "MULHI $dst, $src0, $src1",
 663   [(set R600_Reg32:$dst, (mulhu R600_Reg32:$src0, R600_Reg32:$src1))]
 664 >;
 665
 666 class MULLO_INT_Common <bits<32> inst> : R600_2OP <
 667   inst, "MULLO_INT $dst, $src0, $src1",
 668   [(set R600_Reg32:$dst, (mul R600_Reg32:$src0, R600_Reg32:$src1))]
 669 >;
 670
 671 class MULLO_UINT_Common <bits<32> inst> : R600_2OP <
 672   inst, "MULLO_UINT $dst, $src0, $src1",
 673   []
 674 >;
 675
 676 class RECIP_CLAMPED_Common <bits<32> inst> : R600_1OP <
 677   inst, "RECIP_CLAMPED",
 678   []
 679 >;
 680
 681 class RECIP_IEEE_Common <bits<32> inst> : R600_1OP <
 682   inst, "RECIP_IEEE",
 683   [(set R600_Reg32:$dst, (int_AMDGPU_rcp R600_Reg32:$src))]
 684 >;
 685
 686 class RECIP_UINT_Common <bits<32> inst> : R600_1OP <
 687   inst, "RECIP_INT $dst, $src",
 688   [(set R600_Reg32:$dst, (AMDGPUurecip R600_Reg32:$src))]
 689 >;
 690
 691 class RECIPSQRT_CLAMPED_Common <bits<32> inst> : R600_1OP <
 692   inst, "RECIPSQRT_CLAMPED",
 693   [(set R600_Reg32:$dst, (int_AMDGPU_rsq R600_Reg32:$src))]
 694 >;
 695
 696 class RECIPSQRT_IEEE_Common <bits<32> inst> : R600_1OP <
 697   inst, "RECIPSQRT_IEEE",
 698   []
 699 >;
 700
 701 class SIN_Common <bits<32> inst> : R600_1OP <
 702   inst, "SIN",
 703   [(set R600_Reg32:$dst, (int_AMDIL_sin R600_Reg32:$src))]>{
 704   let Trig = 1;
 705 }
 706
 707 class COS_Common <bits<32> inst> : R600_1OP <
 708   inst, "COS",
 709   [(set R600_Reg32:$dst, (int_AMDIL_cos R600_Reg32:$src))]> {
 710   let Trig = 1;
 711 }
 712
 713 /* Helper patterns for complex intrinsics */
 714 /* -------------------------------------- */
 715
 716 class DIV_Common <InstR600 recip_ieee> : Pat<
 717   (int_AMDGPU_div R600_Reg32:$src0, R600_Reg32:$src1),
 718   (MUL R600_Reg32:$src0, (recip_ieee R600_Reg32:$src1))
 719 >;
 720
 721 class SSG_Common <InstR600 cndgt, InstR600 cndge> : Pat <
 722   (int_AMDGPU_ssg R600_Reg32:$src),
 723   (cndgt R600_Reg32:$src, (f32 ONE), (cndge R600_Reg32:$src, (f32 ZERO), (f32 NEG_ONE)))
 724 >;
 725
 726 class TGSI_LIT_Z_Common <InstR600 mul_lit, InstR600 log_clamped, InstR600 exp_ieee> : Pat <
 727   (int_TGSI_lit_z R600_Reg32:$src_x, R600_Reg32:$src_y, R600_Reg32:$src_w),
 728   (exp_ieee (mul_lit (log_clamped (MAX R600_Reg32:$src_y, (f32 ZERO))), R600_Reg32:$src_w, R600_Reg32:$src_x))
 729 >;
 730
 731 /* ---------------------- */
 732 /* R600 / R700 Only Instructions */
 733 /* ---------------------- */
 734
 735 let Predicates = [isR600] in {
 736
 737   def MUL_LIT_r600 : MUL_LIT_Common<0x0C>;
 738   def MULADD_r600 : MULADD_Common<0x10>;
 739   def CNDE_r600 : CNDE_Common<0x18>;
 740   def CNDGT_r600 : CNDGT_Common<0x19>;
 741   def CNDGE_r600 : CNDGE_Common<0x1A>;
 742   def DOT4_r600 : DOT4_Common<0x50>;
 743   def CUBE_r600 : CUBE_Common<0x52>;
 744   def EXP_IEEE_r600 : EXP_IEEE_Common<0x61>;
 745   def LOG_CLAMPED_r600 : LOG_CLAMPED_Common<0x62>;
 746   def LOG_IEEE_r600 : LOG_IEEE_Common<0x63>;
 747   def RECIP_CLAMPED_r600 : RECIP_CLAMPED_Common<0x64>;
 748   def RECIP_IEEE_r600 : RECIP_IEEE_Common<0x66>;
 749   def RECIPSQRT_CLAMPED_r600 : RECIPSQRT_CLAMPED_Common<0x67>;
 750   def RECIPSQRT_IEEE_r600 : RECIPSQRT_IEEE_Common<0x69>;
 751   def FLT_TO_INT_r600 : FLT_TO_INT_Common<0x6b>;
 752   def INT_TO_FLT_r600 : INT_TO_FLT_Common<0x6c>;
 753   def FLT_TO_UINT_r600 : FLT_TO_UINT_Common<0x79>;
 754   def UINT_TO_FLT_r600 : UINT_TO_FLT_Common<0x6d>;
 755   def SIN_r600 : SIN_Common<0x6E>;
 756   def COS_r600 : COS_Common<0x6F>;
 757   def ASHR_r600 : ASHR_Common<0x70>;
 758   def LSHR_r600 : LSHR_Common<0x71>;
 759   def LSHL_r600 : LSHL_Common<0x72>;
 760   def MULLO_INT_r600 : MULLO_INT_Common<0x73>;
 761   def MULHI_INT_r600 : MULHI_INT_Common<0x74>;
 762   def MULLO_UINT_r600 : MULLO_UINT_Common<0x75>;
 763   def MULHI_UINT_r600 : MULHI_UINT_Common<0x76>;
 764   def RECIP_UINT_r600 : RECIP_UINT_Common <0x78>;
 765
 766   def DIV_r600 : DIV_Common<RECIP_IEEE_r600>;
 767   def POW_r600 : POW_Common<LOG_IEEE_r600, EXP_IEEE_r600, MUL, GPRF32>;
 768   def SSG_r600 : SSG_Common<CNDGT_r600, CNDGE_r600>;
 769   def TGSI_LIT_Z_r600 : TGSI_LIT_Z_Common<MUL_LIT_r600, LOG_CLAMPED_r600, EXP_IEEE_r600>;
 770
 771 }
 772
 773 /* ----------------- */
 774 /* R700+ Trig helper */
 775 /* ----------------- */
 776
 777 /*
 778 class TRIG_HELPER_r700 <InstR600 trig_inst>: Pat <
 779   (trig_inst R600_Reg32:$src),
 780   (trig_inst (fmul R600_Reg32:$src, (PI))))
 781 >;
 782 */
 783
 784 /* ---------------------- */
 785 /* Evergreen Instructions */
 786 /* ---------------------- */
 787
 788
 789 let Predicates = [isEG] in {
 790
 791 def RAT_WRITE_CACHELESS_eg :
 792     EG_CF_RAT <0x57, 0x2, (outs), (ins R600_TReg32_X:$rw_gpr,
 793                                    R600_TReg32_X:$index_gpr, i32imm:$rat_id), "">
 794 {
 795   let RIM         = 0;
 796   /* XXX: Have a separate instruction for non-indexed writes. */
 797   let TYPE        = 1;
 798   let RW_REL      = 0;
 799   let ELEM_SIZE   = 0;
 800
 801   let ARRAY_SIZE  = 0;
 802   let COMP_MASK   = 1;
 803   let BURST_COUNT = 0;
 804   let VPM         = 0;
 805   let EOP         = 0;
 806   let MARK        = 0;
 807   let BARRIER     = 1;
 808 }
 809
 810 def VTX_READ_eg : InstR600ISA < (outs R600_TReg32_X:$dst),
 811                                 (ins R600_TReg32_X:$src, i32imm:$buffer_id),
 812                                 "VTX_READ_eg $dst, $src", []>
 813 {
 814 /*
 815   bits<7> DST_GPR;
 816   bits<7> SRC_GPR;
 817   bits<8> BUFFER_ID;
 818 */
 819   /* If any of these field below need to be calculated at compile time, and
 820    * a ins operand for them and move them to the list of operands above. */
 821
 822   /* XXX: This instruction is manual encoded, so none of these values are used.
 823    */
 824 /*
 825   bits<5> VC_INST          = 0; //VC_INST_FETCH
 826   bits<2> FETCH_TYPE       = 2;
 827   bits<1> FETCH_WHOLE_QUAD = 1;
 828   bits<1> SRC_REL          = 0;
 829   bits<2> SRC_SEL_X        = 0;
 830   bits<6> MEGA_FETCH_COUNT = 4;
 831 */
 832 /*
 833
 834   bits<1> DST_REL          = 0;
 835   bits<3> DST_SEL_X        = 0;
 836   bits<3> DST_SEL_Y        = 7; //Masked
 837   bits<3> DST_SEL_Z        = 7; //Masked
 838   bits<3> DST_SEL_W        = 7; //Masked
 839   bits<1> USE_CONST_FIELDS = 1; //Masked
 840   bits<6> DATA_FORMAT      = 0;
 841   bits<2> NUM_FORMAT_ALL   = 0;
 842   bits<1> FORMAT_COMP_ALL  = 0;
 843   bits<1> SRF_MODE_ALL     = 0;
 844 */
 845
 846 /*
 847   let Inst{4-0}   = VC_INST;
 848   let Inst{6-5}   = FETCH_TYPE;
 849   let Inst{7}     = FETCH_WHOLE_QUAD;
 850   let Inst{15-8}  = BUFFER_ID;
 851   let Inst{22-16} = SRC_GPR;
 852   let Inst{23}    = SRC_REL;
 853   let Inst{25-24} = SRC_SEL_X;
 854   let Inst{31-26} = MEGA_FETCH_COUNT;
 855 */
 856   /* DST_GPR is OK to leave uncommented, because LLVM 3.0 only prevents you
 857    * from statically setting bits > 31.  This field will be set by
 858    * getMachineValueOp which can set bits > 31.
 859    */
 860 //  let Inst{32-38} = DST_GPR;
 861
 862   /* XXX: Uncomment for LLVM 3.1 which supports 64-bit instructions */
 863
 864 /*
 865   let Inst{39}    = DST_REL;
 866   let Inst{40}    = 0; //Reserved
 867   let Inst{43-41} = DST_SEL_X;
 868   let Inst{46-44} = DST_SEL_Y;
 869   let Inst{49-47} = DST_SEL_Z;
 870   let Inst{52-50} = DST_SEL_W;
 871   let Inst{53}    = USE_CONST_FIELDS;
 872   let Inst{59-54} = DATA_FORMAT;
 873   let Inst{61-60} = NUM_FORMAT_ALL;
 874   let Inst{62}    = FORMAT_COMP_ALL;
 875   let Inst{63}    = SRF_MODE_ALL;
 876 */
 877 }
 878
 879 /* XXX: Need to convert PTR to rat_id */
 880 /*
 881 def : Pat <(store_global (f32 R600_Reg32:$value), node:$ptr),
 882            (RAT_WRITE_CACHELESS_eg (INSERT_SUBREG (v4f32 (IMPLICIT_DEF)),
 883                                                   (f32 R600_Reg32:$value),
 884                                                    sel_x),
 885                                     (f32 ZERO), 0, R600_Reg32:$ptr)>;
 886 */
 887
 888 class VTX_Param_Read_Pattern <ValueType vt> : Pat <
 889     (vt (load_param ADDRParam:$mem)),
 890     (VTX_READ_eg (i32 R600_Reg32:$mem), 0)>;
 891
 892 def : VTX_Param_Read_Pattern <f32>;
 893 def : VTX_Param_Read_Pattern <i32>;
 894
 895 } // End isEG Predicate
 896
 897 /* ------------------------------- */
 898 /* Evergreen / Cayman Instructions */
 899 /* ------------------------------- */
 900
 901 let Predicates = [isEGorCayman] in {
 902
 903 class TRIG_eg <InstR600 trig, Intrinsic intr> : Pat<
 904   (intr R600_Reg32:$src),
 905   (trig (MUL (MOV (LOADCONST_i32 CONST.TWO_PI_INV)), R600_Reg32:$src))
 906 >;
 907
 908   def MULADD_eg : MULADD_Common<0x14>;
 909   def ASHR_eg : ASHR_Common<0x15>;
 910   def LSHR_eg : LSHR_Common<0x16>;
 911   def LSHL_eg : LSHL_Common<0x17>;
 912   def CNDE_eg : CNDE_Common<0x19>;
 913   def CNDGT_eg : CNDGT_Common<0x1A>;
 914   def CNDGE_eg : CNDGE_Common<0x1B>;
 915   def MUL_LIT_eg : MUL_LIT_Common<0x1F>;
 916   def EXP_IEEE_eg : EXP_IEEE_Common<0x81>;
 917   def LOG_CLAMPED_eg : LOG_CLAMPED_Common<0x82>;
 918   def LOG_IEEE_eg : LOG_IEEE_Common<0x83>;
 919   def RECIP_CLAMPED_eg : RECIP_CLAMPED_Common<0x84>;
 920   def RECIP_IEEE_eg : RECIP_IEEE_Common<0x86>;
 921   def RECIPSQRT_CLAMPED_eg : RECIPSQRT_CLAMPED_Common<0x87>;
 922   def RECIPSQRT_IEEE_eg : RECIPSQRT_IEEE_Common<0x89>;
 923   def SIN_eg : SIN_Common<0x8D>;
 924   def COS_eg : COS_Common<0x8E>;
 925   def MULLO_INT_eg : MULLO_INT_Common<0x8F>;
 926   def MULHI_INT_eg : MULHI_INT_Common<0x90>;
 927   def MULLO_UINT_eg : MULLO_UINT_Common<0x91>;
 928   def MULHI_UINT_eg : MULHI_UINT_Common<0x92>;
 929   def RECIP_UINT_eg : RECIP_UINT_Common<0x94>;
 930   def DOT4_eg : DOT4_Common<0xBE>;
 931   def CUBE_eg : CUBE_Common<0xC0>;
 932
 933   def DIV_eg : DIV_Common<RECIP_IEEE_eg>;
 934   def POW_eg : POW_Common<LOG_IEEE_eg, EXP_IEEE_eg, MUL, GPRF32>;
 935   def SSG_eg : SSG_Common<CNDGT_eg, CNDGE_eg>;
 936   def TGSI_LIT_Z_eg : TGSI_LIT_Z_Common<MUL_LIT_eg, LOG_CLAMPED_eg, EXP_IEEE_eg>;
 937
 938   def : TRIG_eg <SIN_eg, int_AMDGPU_sin>;
 939   def : TRIG_eg <COS_eg, int_AMDGPU_cos>;
 940
 941   def FLT_TO_INT_eg : FLT_TO_INT_Common<0x50> {
 942     let Pattern = [];
 943   }
 944
 945   def INT_TO_FLT_eg : INT_TO_FLT_Common<0x9B>;
 946
 947   def FLT_TO_UINT_eg : FLT_TO_UINT_Common<0x9A> {
 948     let Pattern = [];
 949   }
 950
 951   def UINT_TO_FLT_eg : UINT_TO_FLT_Common<0x9C>;
 952
 953   def : Pat<(fp_to_sint R600_Reg32:$src),
 954     (FLT_TO_INT_eg (TRUNC R600_Reg32:$src))>;
 955
 956   def : Pat<(fp_to_uint R600_Reg32:$src),
 957     (FLT_TO_UINT_eg (TRUNC R600_Reg32:$src))>;
 958 }
 959
 960 let Predicates = [isCayman] in {
 961
 962   /* XXX: I'm not sure if this opcode is correct. */
 963   def RECIP_UINT_cm : RECIP_UINT_Common<0x77>;
 964
 965 } // End isCayman
 966
 967 /* Other Instructions */
 968
 969 let isCodeGenOnly = 1 in {
 970 /*
 971   def SWIZZLE : AMDGPUShaderInst <
 972     (outs GPRV4F32:$dst),
 973     (ins GPRV4F32:$src0, i32imm:$src1),
 974     "SWIZZLE $dst, $src0, $src1",
 975     [(set GPRV4F32:$dst, (int_AMDGPU_swizzle GPRV4F32:$src0, imm:$src1))]
 976   >;
 977 */
 978
 979   def LAST : AMDGPUShaderInst <
 980     (outs),
 981     (ins),
 982     "LAST",
 983     []
 984   >;
 985
 986   def GET_CHAN : AMDGPUShaderInst <
 987     (outs R600_Reg32:$dst),
 988     (ins R600_Reg128:$src0, i32imm:$src1),
 989     "GET_CHAN $dst, $src0, $src1",
 990     []
 991   >;
 992
 993   def MULLIT : AMDGPUShaderInst <
 994     (outs R600_Reg128:$dst),
 995     (ins R600_Reg32:$src0, R600_Reg32:$src1, R600_Reg32:$src2),
 996     "MULLIT $dst, $src0, $src1",
 997     [(set R600_Reg128:$dst, (int_AMDGPU_mullit R600_Reg32:$src0, R600_Reg32:$src1, R600_Reg32:$src2))]
 998   >;
 999
1000 let usesCustomInserter = 1, isPseudo = 1 in {
1001
1002 class R600PreloadInst <string asm, Intrinsic intr> : AMDGPUInst <
1003   (outs R600_TReg32:$dst),
1004   (ins),
1005   asm,
1006   [(set R600_TReg32:$dst, (intr))]
1007 >;
1008
1009 def TGID_X : R600PreloadInst <"TGID_X", int_r600_read_tgid_x>;
1010 def TGID_Y : R600PreloadInst <"TGID_Y", int_r600_read_tgid_y>;
1011 def TGID_Z : R600PreloadInst <"TGID_Z", int_r600_read_tgid_z>;
1012
1013 def TIDIG_X : R600PreloadInst <"TIDIG_X", int_r600_read_tidig_x>;
1014 def TIDIG_Y : R600PreloadInst <"TIDIG_Y", int_r600_read_tidig_y>;
1015 def TIDIG_Z : R600PreloadInst <"TIDIG_Z", int_r600_read_tidig_z>;
1016
1017 def NGROUPS_X : R600PreloadInst <"NGROUPS_X", int_r600_read_ngroups_x>;
1018 def NGROUPS_Y : R600PreloadInst <"NGROUPS_Y", int_r600_read_ngroups_y>;
1019 def NGROUPS_Z : R600PreloadInst <"NGROUPS_Z", int_r600_read_ngroups_z>;
1020
1021 def GLOBAL_SIZE_X : R600PreloadInst <"GLOBAL_SIZE_X",
1022                                      int_r600_read_global_size_x>;
1023 def GLOBAL_SIZE_Y : R600PreloadInst <"GLOBAL_SIZE_Y",
1024                                      int_r600_read_global_size_y>;
1025 def GLOBAL_SIZE_Z : R600PreloadInst <"GLOBAL_SIZE_Z",
1026                                      int_r600_read_global_size_z>;
1027
1028 def LOCAL_SIZE_X : R600PreloadInst <"LOCAL_SIZE_X",
1029                                     int_r600_read_local_size_x>;
1030 def LOCAL_SIZE_Y : R600PreloadInst <"LOCAL_SIZE_Y",
1031                                     int_r600_read_local_size_y>;
1032 def LOCAL_SIZE_Z : R600PreloadInst <"LOCAL_SIZE_Z",
1033                                     int_r600_read_local_size_z>;
1034
1035 def R600_LOAD_CONST : AMDGPUShaderInst <
1036   (outs R600_Reg32:$dst),
1037   (ins i32imm:$src0),
1038   "R600_LOAD_CONST $dst, $src0",
1039   [(set R600_Reg32:$dst, (int_AMDGPU_load_const imm:$src0))]
1040 >;
1041
1042 def LOAD_INPUT : AMDGPUShaderInst <
1043   (outs R600_Reg32:$dst),
1044   (ins i32imm:$src),
1045   "LOAD_INPUT $dst, $src",
1046   [(set R600_Reg32:$dst, (int_R600_load_input imm:$src))]
1047 >;
1048
1049 def RESERVE_REG : AMDGPUShaderInst <
1050   (outs),
1051   (ins i32imm:$src),
1052   "RESERVE_REG $src",
1053   [(int_AMDGPU_reserve_reg imm:$src)]
1054 >;
1055
1056 def STORE_OUTPUT: AMDGPUShaderInst <
1057   (outs),
1058   (ins R600_Reg32:$src0, i32imm:$src1),
1059   "STORE_OUTPUT $src0, $src1",
1060   [(int_AMDGPU_store_output R600_Reg32:$src0, imm:$src1)]
1061 >;
1062
1063 def TXD: AMDGPUShaderInst <
1064   (outs R600_Reg128:$dst),
1065   (ins R600_Reg128:$src0, R600_Reg128:$src1, R600_Reg128:$src2, i32imm:$src3, i32imm:$src4),
1066   "TXD $dst, $src0, $src1, $src2, $src3, $src4",
1067   [(set R600_Reg128:$dst, (int_AMDGPU_txd R600_Reg128:$src0, R600_Reg128:$src1, R600_Reg128:$src2, imm:$src3, imm:$src4))]
1068 >;
1069
1070 def TXD_SHADOW: AMDGPUShaderInst <
1071   (outs R600_Reg128:$dst),
1072   (ins R600_Reg128:$src0, R600_Reg128:$src1, R600_Reg128:$src2, i32imm:$src3, i32imm:$src4),
1073   "TXD_SHADOW $dst, $src0, $src1, $src2, $src3, $src4",
1074   [(set R600_Reg128:$dst, (int_AMDGPU_txd R600_Reg128:$src0, R600_Reg128:$src1, R600_Reg128:$src2, imm:$src3, TEX_SHADOW:$src4))]
1075 >;
1076
1077 } // End usesCustomInserter = 1, isPseudo = 1
1078
1079 } // End isCodeGenOnly = 1
1080
1081
1082
1083 let isPseudo = 1 in {
1084
1085 def LOAD_VTX : AMDGPUShaderInst <
1086     (outs R600_Reg32:$dst),
1087     (ins MEMri:$mem),
1088     "LOAD_VTX",
1089     [(set (i32 R600_Reg32:$dst), (load_param ADDRParam:$mem))]
1090 >;
1091
1092
1093 } //End isPseudo
1094
1095 //===----------------------------------------------------------------------===//
1096 // ISel Patterns
1097 //===----------------------------------------------------------------------===//
1098
1099 // SGT Reverse args
1100 def : Pat <
1101   (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO, COND_LT),
1102   (SGT R600_Reg32:$src1, R600_Reg32:$src0)
1103 >;
1104
1105 // SGE Reverse args
1106 def : Pat <
1107   (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO, COND_LE),
1108   (SGE R600_Reg32:$src1, R600_Reg32:$src0)
1109 >;
1110
1111 // SETGT_INT reverse args
1112 def : Pat <
1113   (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETLT),
1114   (SETGT_INT R600_Reg32:$src1, R600_Reg32:$src0)
1115 >;
1116
1117 // SETGE_INT reverse args
1118 def : Pat <
1119   (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETLE),
1120   (SETGE_INT R600_Reg32:$src1, R600_Reg32:$src0)
1121 >;
1122
1123 // SETGT_UINT reverse args
1124 def : Pat <
1125   (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETULT),
1126   (SETGT_UINT R600_Reg32:$src1, R600_Reg32:$src0)
1127 >;
1128
1129 // SETGE_UINT reverse args
1130 def : Pat <
1131   (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETULE),
1132   (SETGE_UINT R600_Reg32:$src0, R600_Reg32:$src1)
1133 >;
1134
1135 // The next two patterns are special cases for handling 'true if ordered' and
1136 // 'true if unordered' conditionals.  The assumption here is that the behavior of
1137 // SETE and SNE conforms to the Direct3D 10 rules for floating point values
1138 // described here:
1139 // http://msdn.microsoft.com/en-us/library/windows/desktop/cc308050.aspx#alpha_32_bit
1140 // We assume that  SETE returns false when one of the operands is NAN and
1141 // SNE returns true when on of the operands is NAN
1142
1143 //SETE - 'true if ordered'
1144 def : Pat <
1145   (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO, SETO),
1146   (SETE R600_Reg32:$src0, R600_Reg32:$src1)
1147 >;
1148
1149 //SNE - 'true if unordered'
1150 def : Pat <
1151   (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO, SETUO),
1152   (SNE R600_Reg32:$src0, R600_Reg32:$src1)
1153 >;
1154
1155 def : Extract_Element <f32, v4f32, R600_Reg128, 0, sel_x>;
1156 def : Extract_Element <f32, v4f32, R600_Reg128, 1, sel_y>;
1157 def : Extract_Element <f32, v4f32, R600_Reg128, 2, sel_z>;
1158 def : Extract_Element <f32, v4f32, R600_Reg128, 3, sel_w>;
1159
1160 def : Insert_Element <f32, v4f32, R600_Reg32, R600_Reg128, 4, sel_x>;
1161 def : Insert_Element <f32, v4f32, R600_Reg32, R600_Reg128, 5, sel_y>;
1162 def : Insert_Element <f32, v4f32, R600_Reg32, R600_Reg128, 6, sel_z>;
1163 def : Insert_Element <f32, v4f32, R600_Reg32, R600_Reg128, 7, sel_w>;
1164
1165 def : Extract_Element <i32, v4i32, R600_Reg128, 0, sel_x>;
1166 def : Extract_Element <i32, v4i32, R600_Reg128, 1, sel_y>;
1167 def : Extract_Element <i32, v4i32, R600_Reg128, 2, sel_z>;
1168 def : Extract_Element <i32, v4i32, R600_Reg128, 3, sel_w>;
1169
1170 def : Insert_Element <i32, v4i32, R600_Reg32, R600_Reg128, 4, sel_x>;
1171 def : Insert_Element <i32, v4i32, R600_Reg32, R600_Reg128, 5, sel_y>;
1172 def : Insert_Element <i32, v4i32, R600_Reg32, R600_Reg128, 6, sel_z>;
1173 def : Insert_Element <i32, v4i32, R600_Reg32, R600_Reg128, 7, sel_w>;
1174
1175 } // End isR600toCayman Predicate