src/gallium/drivers/radeon/R600Instructions.td

   1 //===-- R600Instructions.td - R600 Instruction defs  -------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // R600 Tablegen instruction definitions
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "R600Intrinsics.td"
  15
  16 class InstR600 <bits<32> inst, dag outs, dag ins, string asm, list<dag> pattern,
  17                 InstrItinClass itin>
  18     : AMDGPUInst <outs, ins, asm, pattern> {
  19
  20   field bits<32> Inst;
  21         bit Trig = 0;
  22   bit Op3 = 0;
  23
  24   let Inst = inst;
  25   let Namespace = "AMDIL";
  26   let OutOperandList = outs;
  27   let InOperandList = ins;
  28   let AsmString = asm;
  29   let Pattern = pattern;
  30   let Itinerary = itin;
  31
  32   let TSFlags{4} = Trig;
  33   let TSFlags{5} = Op3;
  34 }
  35
  36 class InstR600ISA <dag outs, dag ins, string asm, list<dag> pattern> :
  37     AMDGPUInst <outs, ins, asm, pattern>
  38 {
  39   field bits<64> Inst;
  40
  41   let Namespace = "AMDIL";
  42 }
  43
  44 def MEMri : Operand<iPTRAny> {
  45   let MIOperandInfo = (ops R600_Reg32:$ptr, R600_Reg32:$index);
  46 }
  47
  48 def ADDRParam : ComplexPattern<i32, 2, "SelectADDRParam", [], []>;
  49
  50 class R600_ALU {
  51
  52   bits<7> DST_GPR = 0;
  53   bits<9> SRC0_SEL = 0;
  54   bits<1> SRC0_NEG = 0;
  55   bits<9> SRC1_SEL = 0;
  56   bits<1> SRC1_NEG = 0;
  57   bits<1> CLAMP = 0;
  58
  59 }
  60
  61
  62 class R600_1OP <bits<32> inst, string opName, list<dag> pattern,
  63                 InstrItinClass itin = AnyALU> :
  64   InstR600 <inst,
  65           (outs R600_Reg32:$dst),
  66           (ins R600_Reg32:$src, variable_ops),
  67           !strconcat(opName, " $dst, $src"),
  68           pattern,
  69           itin
  70   >;
  71
  72 class R600_2OP <bits<32> inst, string opName, list<dag> pattern,
  73                 InstrItinClass itin = AnyALU> :
  74   InstR600 <inst,
  75           (outs R600_Reg32:$dst),
  76           (ins R600_Reg32:$src0, R600_Reg32:$src1, variable_ops),
  77           !strconcat(opName, " $dst, $src0, $src1"),
  78           pattern,
  79           itin
  80   >;
  81
  82 class R600_3OP <bits<32> inst, string opName, list<dag> pattern,
  83                 InstrItinClass itin = AnyALU> :
  84   InstR600 <inst,
  85           (outs R600_Reg32:$dst),
  86           (ins R600_Reg32:$src0, R600_Reg32:$src1, R600_Reg32:$src2, variable_ops),
  87           !strconcat(opName, " $dst, $src0, $src1, $src2"),
  88           pattern,
  89           itin>{
  90
  91     let Op3 = 1;
  92   }
  93
  94 class R600_REDUCTION <bits<32> inst, dag ins, string asm, list<dag> pattern,
  95                       InstrItinClass itin = VecALU> :
  96   InstR600 <inst,
  97           (outs R600_Reg32:$dst),
  98           ins,
  99           asm,
 100           pattern,
 101           itin
 102
 103   >;
 104
 105 class R600_TEX <bits<32> inst, string opName, list<dag> pattern,
 106                 InstrItinClass itin = AnyALU> :
 107   InstR600 <inst,
 108           (outs R600_Reg128:$dst),
 109           (ins R600_Reg128:$src0, i32imm:$src1, i32imm:$src2),
 110           !strconcat(opName, "$dst, $src0, $src1, $src2"),
 111           pattern,
 112           itin
 113   >;
 114
 115 def TEX_SHADOW : PatLeaf<
 116   (imm),
 117   [{uint32_t TType = (uint32_t)N->getZExtValue();
 118     return (TType >= 6 && TType <= 8) || TType == 11 || TType == 12;
 119   }]
 120 >;
 121
 122 def COND_EQ : PatLeaf <
 123   (cond),
 124   [{switch(N->get()){{default: return false;
 125                      case ISD::SETOEQ: case ISD::SETUEQ:
 126                      case ISD::SETEQ: return true;}}}]
 127 >;
 128
 129 def COND_NE : PatLeaf <
 130   (cond),
 131   [{switch(N->get()){{default: return false;
 132                      case ISD::SETONE: case ISD::SETUNE:
 133                      case ISD::SETNE: return true;}}}]
 134 >;
 135 def COND_GT : PatLeaf <
 136   (cond),
 137   [{switch(N->get()){{default: return false;
 138                      case ISD::SETOGT: case ISD::SETUGT:
 139                      case ISD::SETGT: return true;}}}]
 140 >;
 141
 142 def COND_GE : PatLeaf <
 143   (cond),
 144   [{switch(N->get()){{default: return false;
 145                      case ISD::SETOGE: case ISD::SETUGE:
 146                      case ISD::SETGE: return true;}}}]
 147 >;
 148
 149 def COND_LT : PatLeaf <
 150   (cond),
 151   [{switch(N->get()){{default: return false;
 152                      case ISD::SETOLT: case ISD::SETULT:
 153                      case ISD::SETLT: return true;}}}]
 154 >;
 155
 156 def COND_LE : PatLeaf <
 157   (cond),
 158   [{switch(N->get()){{default: return false;
 159                      case ISD::SETOLE: case ISD::SETULE:
 160                      case ISD::SETLE: return true;}}}]
 161 >;
 162
 163 class EG_CF_RAT <bits <8> cf_inst, bits <6> rat_inst, dag outs, dag ins,
 164                  string asm> :
 165     InstR600ISA <outs, ins, asm, []>
 166 {
 167   bits<7>  RW_GPR;
 168   bits<7>  INDEX_GPR;
 169   bits<4>  RAT_ID;
 170
 171   bits<2>  RIM;
 172   bits<2>  TYPE;
 173   bits<1>  RW_REL;
 174   bits<2>  ELEM_SIZE;
 175
 176   bits<12> ARRAY_SIZE;
 177   bits<4>  COMP_MASK;
 178   bits<4>  BURST_COUNT;
 179   bits<1>  VPM;
 180   bits<1>  EOP;
 181   bits<1>  MARK;
 182   bits<1>  BARRIER;
 183
 184   /* CF_ALLOC_EXPORT_WORD0_RAT */
 185   let Inst{3-0}   = RAT_ID;
 186   let Inst{9-4}   = rat_inst;
 187   let Inst{10}    = 0; /* Reserved */
 188   let Inst{12-11} = RIM;
 189   let Inst{14-13} = TYPE;
 190   let Inst{21-15} = RW_GPR;
 191   let Inst{22}    = RW_REL;
 192   let Inst{29-23} = INDEX_GPR;
 193   let Inst{31-30} = ELEM_SIZE;
 194
 195   /* CF_ALLOC_EXPORT_WORD1_BUF */
 196   let Inst{43-32} = ARRAY_SIZE;
 197   let Inst{47-44} = COMP_MASK;
 198   let Inst{51-48} = BURST_COUNT;
 199   let Inst{52}    = VPM;
 200   let Inst{53}    = EOP;
 201   let Inst{61-54} = cf_inst;
 202   let Inst{62}    = MARK;
 203   let Inst{63}    = BARRIER;
 204 }
 205
 206 /*
 207 def store_global : PatFrag<(ops node:$value, node:$ptr),
 208                            (store node:$value, node:$ptr),
 209                            [{
 210                             const Value *Src;
 211                             const PointerType *Type;
 212                             if ((src = cast<StoreSDNode>(N)->getSrcValue() &&
 213                                  PT = dyn_cast<PointerType>(Src->getType()))) {
 214                               return PT->getAddressSpace() == 1;
 215                             }
 216                             return false;
 217                            }]>;
 218
 219 */
 220
 221 def load_param : PatFrag<(ops node:$ptr),
 222                          (load node:$ptr),
 223                           [{
 224                            return true;
 225                            const Value *Src = cast<LoadSDNode>(N)->getSrcValue();
 226                            if (Src) {
 227                                 PointerType * PT = dyn_cast<PointerType>(Src->getType());
 228                                 return PT && PT->getAddressSpace() == AMDILAS::PARAM_I_ADDRESS;
 229                            }
 230                            return false;
 231                           }]>;
 232
 233 //class EG_CF <bits<32> inst, string asm> :
 234 //    InstR600 <inst, (outs), (ins), asm, []>;
 235
 236 /* XXX: We will use this when we emit the real ISA.
 237   bits<24> ADDR = 0;
 238   bits<3> JTS = 0;
 239
 240   bits<3> PC = 0;
 241   bits<5> CF_CONS = 0;
 242   bits<2> COND = 0;
 243   bits<6> COUNT = 0;
 244   bits<1> VPM = 0;
 245   bits<1> EOP = 0;
 246   bits<8> CF_INST = 0;
 247   bits<1> WQM = 0;
 248   bits<1> B = 0;
 249
 250   let Inst{23-0} = ADDR;
 251   let Inst{26-24} = JTS;
 252   let Inst{34-32} = PC;
 253   let Inst{39-35} = CF_CONST;
 254   let Inst{41-40} = COND;
 255   let Inst{47-42} = COUNT;
 256   let Inst{52} = VPM;
 257   let Inst{53} = EOP;
 258   let Inst{61-54} = CF_INST;
 259   let Inst{62} = WQM;
 260   let Inst{63} = B;
 261 //}
 262 */
 263 def isR600 : Predicate<"Subtarget.device()"
 264                             "->getGeneration() == AMDILDeviceInfo::HD4XXX">;
 265 def isEG : Predicate<"Subtarget.device()"
 266                             "->getGeneration() >= AMDILDeviceInfo::HD5XXX && "
 267                             "Subtarget.device()->getDeviceFlag() != OCL_DEVICE_CAYMAN">;
 268 def isCayman : Predicate<"Subtarget.device()"
 269                             "->getDeviceFlag() == OCL_DEVICE_CAYMAN">;
 270 def isEGorCayman : Predicate<"Subtarget.device()"
 271                             "->getGeneration() == AMDILDeviceInfo::HD5XXX"
 272                             "|| Subtarget.device()->getGeneration() =="
 273                             "AMDILDeviceInfo::HD6XXX">;
 274
 275 def isR600toCayman : Predicate<
 276                      "Subtarget.device()->getGeneration() <= AMDILDeviceInfo::HD6XXX">;
 277
 278
 279 let Predicates = [isR600toCayman] in {
 280
 281 /* ------------------------------------------- */
 282 /* Common Instructions R600, R700, Evergreen, Cayman */
 283 /* ------------------------------------------- */
 284 def ADD : R600_2OP <
 285   0x0, "ADD",
 286   [(set R600_Reg32:$dst, (fadd R600_Reg32:$src0, R600_Reg32:$src1))]
 287 >;
 288
 289 // Non-IEEE MUL: 0 * anything = 0
 290 def MUL : R600_2OP <
 291   0x1, "MUL NON-IEEE",
 292   [(set R600_Reg32:$dst, (int_AMDGPU_mul R600_Reg32:$src0, R600_Reg32:$src1))]
 293 >;
 294
 295 def MUL_IEEE : R600_2OP <
 296   0x2, "MUL_IEEE",
 297   [(set R600_Reg32:$dst, (fmul R600_Reg32:$src0, R600_Reg32:$src1))]
 298 >;
 299
 300 def MAX : R600_2OP <
 301   0x3, "MAX",
 302   [(set R600_Reg32:$dst, (AMDGPUfmax R600_Reg32:$src0, R600_Reg32:$src1))]
 303 >;
 304
 305 def MIN : R600_2OP <
 306   0x4, "MIN",
 307   [(set R600_Reg32:$dst, (AMDGPUfmin R600_Reg32:$src0, R600_Reg32:$src1))]
 308 >;
 309
 310 /* For the SET* instructions there is a naming conflict in TargetSelectionDAG.td,
 311  * so some of the instruction names don't match the asm string.
 312  * XXX: Use the defs in TargetSelectionDAG.td instead of intrinsics.
 313  */
 314
 315 def SETE : R600_2OP <
 316   0x08, "SETE",
 317   [(set R600_Reg32:$dst,
 318    (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO,
 319              COND_EQ))]
 320 >;
 321
 322 def SGT : R600_2OP <
 323   0x09, "SETGT",
 324   [(set R600_Reg32:$dst,
 325    (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO,
 326               COND_GT))]
 327 >;
 328
 329 def SGE : R600_2OP <
 330   0xA, "SETGE",
 331   [(set R600_Reg32:$dst,
 332    (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO,
 333               COND_GE))]
 334 >;
 335
 336 def SNE : R600_2OP <
 337   0xB, "SETNE",
 338   [(set R600_Reg32:$dst,
 339    (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO,
 340     COND_NE))]
 341 >;
 342
 343 def FRACT : R600_1OP <
 344   0x10, "FRACT",
 345   [(set R600_Reg32:$dst, (AMDGPUfract R600_Reg32:$src))]
 346 >;
 347
 348 def TRUNC : R600_1OP <
 349   0x11, "TRUNC",
 350   [(set R600_Reg32:$dst, (int_AMDGPU_trunc R600_Reg32:$src))]
 351 >;
 352
 353 def CEIL : R600_1OP <
 354   0x12, "CEIL",
 355   [(set R600_Reg32:$dst, (fceil R600_Reg32:$src))]
 356 >;
 357
 358 def RNDNE : R600_1OP <
 359   0x13, "RNDNE",
 360   [(set R600_Reg32:$dst, (frint R600_Reg32:$src))]
 361 >;
 362
 363 def FLOOR : R600_1OP <
 364   0x14, "FLOOR",
 365   [(set R600_Reg32:$dst, (int_AMDGPU_floor R600_Reg32:$src))]
 366 >;
 367
 368 def MOV : R600_1OP <0x19, "MOV", []>;
 369
 370 def KILLGT : R600_2OP <
 371   0x2D, "KILLGT",
 372   []
 373 >;
 374
 375 def AND_INT : R600_2OP <
 376   0x30, "AND_INT",
 377   [(set R600_Reg32:$dst, (and R600_Reg32:$src0, R600_Reg32:$src1))]
 378 >;
 379
 380 def OR_INT : R600_2OP <
 381   0x31, "OR_INT",
 382   [(set R600_Reg32:$dst, (or R600_Reg32:$src0, R600_Reg32:$src1))]
 383 >;
 384
 385 def XOR_INT : R600_2OP <
 386   0x32, "XOR_INT",
 387   [(set R600_Reg32:$dst, (xor R600_Reg32:$src0, R600_Reg32:$src1))]
 388 >;
 389
 390 def NOT_INT : R600_1OP <
 391   0x33, "NOT_INT",
 392   [(set R600_Reg32:$dst, (not R600_Reg32:$src))]
 393 >;
 394
 395 def ADD_INT : R600_2OP <
 396   0x34, "ADD_INT",
 397   [(set R600_Reg32:$dst, (add R600_Reg32:$src0, R600_Reg32:$src1))]
 398 >;
 399
 400 def SUB_INT : R600_2OP <
 401         0x35, "SUB_INT",
 402         [(set R600_Reg32:$dst, (sub R600_Reg32:$src0, R600_Reg32:$src1))]
 403 >;
 404
 405 def MAX_INT : R600_2OP <
 406   0x36, "MAX_INT",
 407   [(set R600_Reg32:$dst, (AMDGPUsmax R600_Reg32:$src0, R600_Reg32:$src1))]>;
 408
 409 def MIN_INT : R600_2OP <
 410   0x37, "MIN_INT",
 411   [(set R600_Reg32:$dst, (AMDGPUsmin R600_Reg32:$src0, R600_Reg32:$src1))]>;
 412
 413 def MAX_UINT : R600_2OP <
 414   0x38, "MAX_UINT",
 415   [(set R600_Reg32:$dst, (AMDGPUsmax R600_Reg32:$src0, R600_Reg32:$src1))]
 416 >;
 417
 418 def MIN_UINT : R600_2OP <
 419   0x39, "MIN_UINT",
 420   [(set R600_Reg32:$dst, (AMDGPUumin R600_Reg32:$src0, R600_Reg32:$src1))]
 421 >;
 422
 423 def SETE_INT : R600_2OP <
 424   0x3A, "SETE_INT",
 425   [(set (i32 R600_Reg32:$dst),
 426    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETEQ))]
 427 >;
 428
 429 def SETGT_INT : R600_2OP <
 430   0x3B, "SGT_INT",
 431   [(set (i32 R600_Reg32:$dst),
 432    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETGT))]
 433 >;
 434
 435 def SETGE_INT : R600_2OP <
 436         0x3C, "SETGE_INT",
 437         [(set (i32 R600_Reg32:$dst),
 438    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETGE))]
 439 >;
 440
 441 def SETNE_INT : R600_2OP <
 442   0x3D, "SETNE_INT",
 443   [(set (i32 R600_Reg32:$dst),
 444    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETNE))]
 445 >;
 446
 447 def SETGT_UINT : R600_2OP <
 448   0x3E, "SETGT_UINT",
 449   [(set (i32 R600_Reg32:$dst),
 450    (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETUGT))]
 451 >;
 452
 453 def SETGE_UINT : R600_2OP <
 454   0x3F, "SETGE_UINT",
 455   [(set (i32 R600_Reg32:$dst),
 456     (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETUGE))]
 457 >;
 458
 459 def CNDE_INT : R600_3OP <
 460         0x1C, "CNDE_INT",
 461   [(set (i32 R600_Reg32:$dst),
 462    (IL_cmov_logical R600_Reg32:$src0, R600_Reg32:$src2, R600_Reg32:$src1))]
 463 >;
 464
 465 /* Texture instructions */
 466
 467
 468 def TEX_LD : R600_TEX <
 469   0x03, "TEX_LD",
 470   [(set R600_Reg128:$dst, (int_AMDGPU_txf R600_Reg128:$src0, imm:$src1, imm:$src2, imm:$src3, imm:$src4, imm:$src5))]
 471 > {
 472 let AsmString = "TEX_LD $dst, $src0, $src1, $src2, $src3, $src4, $src5";
 473 let InOperandList = (ins R600_Reg128:$src0, i32imm:$src1, i32imm:$src2, i32imm:$src3, i32imm:$src4, i32imm:$src5);
 474 }
 475
 476 def TEX_GET_TEXTURE_RESINFO : R600_TEX <
 477   0x04, "TEX_GET_TEXTURE_RESINFO",
 478   [(set R600_Reg128:$dst, (int_AMDGPU_txq R600_Reg128:$src0, imm:$src1, imm:$src2))]
 479 >;
 480
 481 def TEX_GET_GRADIENTS_H : R600_TEX <
 482   0x07, "TEX_GET_GRADIENTS_H",
 483   [(set R600_Reg128:$dst, (int_AMDGPU_ddx R600_Reg128:$src0, imm:$src1, imm:$src2))]
 484 >;
 485
 486 def TEX_GET_GRADIENTS_V : R600_TEX <
 487   0x08, "TEX_GET_GRADIENTS_V",
 488   [(set R600_Reg128:$dst, (int_AMDGPU_ddy R600_Reg128:$src0, imm:$src1, imm:$src2))]
 489 >;
 490
 491 def TEX_SET_GRADIENTS_H : R600_TEX <
 492   0x0B, "TEX_SET_GRADIENTS_H",
 493   []
 494 >;
 495
 496 def TEX_SET_GRADIENTS_V : R600_TEX <
 497   0x0C, "TEX_SET_GRADIENTS_V",
 498   []
 499 >;
 500
 501 def TEX_SAMPLE : R600_TEX <
 502   0x10, "TEX_SAMPLE",
 503   [(set R600_Reg128:$dst, (int_AMDGPU_tex R600_Reg128:$src0, imm:$src1, imm:$src2))]
 504 >;
 505
 506 def TEX_SAMPLE_C : R600_TEX <
 507   0x18, "TEX_SAMPLE_C",
 508   [(set R600_Reg128:$dst, (int_AMDGPU_tex R600_Reg128:$src0, imm:$src1, TEX_SHADOW:$src2))]
 509 >;
 510
 511 def TEX_SAMPLE_L : R600_TEX <
 512   0x11, "TEX_SAMPLE_L",
 513   [(set R600_Reg128:$dst, (int_AMDGPU_txl R600_Reg128:$src0, imm:$src1, imm:$src2))]
 514 >;
 515
 516 def TEX_SAMPLE_C_L : R600_TEX <
 517   0x19, "TEX_SAMPLE_C_L",
 518   [(set R600_Reg128:$dst, (int_AMDGPU_txl R600_Reg128:$src0, imm:$src1, TEX_SHADOW:$src2))]
 519 >;
 520
 521 def TEX_SAMPLE_LB : R600_TEX <
 522   0x12, "TEX_SAMPLE_LB",
 523   [(set R600_Reg128:$dst, (int_AMDGPU_txb R600_Reg128:$src0, imm:$src1, imm:$src2))]
 524 >;
 525
 526 def TEX_SAMPLE_C_LB : R600_TEX <
 527   0x1A, "TEX_SAMPLE_C_LB",
 528   [(set R600_Reg128:$dst, (int_AMDGPU_txb R600_Reg128:$src0, imm:$src1, TEX_SHADOW:$src2))]
 529 >;
 530
 531 def TEX_SAMPLE_G : R600_TEX <
 532   0x14, "TEX_SAMPLE_G",
 533   []
 534 >;
 535
 536 def TEX_SAMPLE_C_G : R600_TEX <
 537   0x1C, "TEX_SAMPLE_C_G",
 538   []
 539 >;
 540
 541 def KILP : Pat <
 542   (int_AMDGPU_kilp),
 543   (MASK_WRITE (KILLGT (f32 ONE), (f32 ZERO)))
 544 >;
 545
 546 def KIL : Pat <
 547   (int_AMDGPU_kill R600_Reg32:$src0),
 548   (MASK_WRITE (KILLGT (f32 ZERO), (f32 R600_Reg32:$src0)))
 549 >;
 550
 551 /* Helper classes for common instructions */
 552
 553 class MUL_LIT_Common <bits<32> inst> : R600_3OP <
 554   inst, "MUL_LIT",
 555   []
 556 >;
 557
 558 class MULADD_Common <bits<32> inst> : R600_3OP <
 559   inst, "MULADD",
 560   [(set (f32 R600_Reg32:$dst),
 561    (IL_mad R600_Reg32:$src0, R600_Reg32:$src1, R600_Reg32:$src2))]
 562 >;
 563
 564 class CNDE_Common <bits<32> inst> : R600_3OP <
 565   inst, "CNDE",
 566   [(set (f32 R600_Reg32:$dst),
 567    (IL_cmov_logical R600_Reg32:$src0, R600_Reg32:$src2, R600_Reg32:$src1))]
 568 >;
 569
 570 class CNDGT_Common <bits<32> inst> : R600_3OP <
 571   inst, "CNDGT",
 572   []
 573 >;
 574
 575 class CNDGE_Common <bits<32> inst> : R600_3OP <
 576   inst, "CNDGE",
 577   [(set R600_Reg32:$dst, (int_AMDGPU_cndlt R600_Reg32:$src0, R600_Reg32:$src2, R600_Reg32:$src1))]
 578 >;
 579
 580 class DOT4_Common <bits<32> inst> : R600_REDUCTION <
 581   inst,
 582   (ins R600_Reg128:$src0, R600_Reg128:$src1),
 583   "DOT4 $dst $src0, $src1",
 584   [(set R600_Reg32:$dst, (int_AMDGPU_dp4 R600_Reg128:$src0, R600_Reg128:$src1))]
 585 >;
 586
 587 class CUBE_Common <bits<32> inst> : InstR600 <
 588   inst,
 589   (outs R600_Reg128:$dst),
 590   (ins R600_Reg128:$src),
 591   "CUBE $dst $src",
 592   [(set R600_Reg128:$dst, (int_AMDGPU_cube R600_Reg128:$src))],
 593   VecALU
 594 >;
 595
 596 class EXP_IEEE_Common <bits<32> inst> : R600_1OP <
 597   inst, "EXP_IEEE",
 598   [(set R600_Reg32:$dst, (fexp2 R600_Reg32:$src))]
 599 >;
 600
 601 class FLT_TO_INT_Common <bits<32> inst> : R600_1OP <
 602   inst, "FLT_TO_INT",
 603   [(set R600_Reg32:$dst, (fp_to_sint R600_Reg32:$src))]
 604 >;
 605
 606 class INT_TO_FLT_Common <bits<32> inst> : R600_1OP <
 607   inst, "INT_TO_FLT",
 608   [(set R600_Reg32:$dst, (sint_to_fp R600_Reg32:$src))]
 609 >;
 610
 611 class FLT_TO_UINT_Common <bits<32> inst> : R600_1OP <
 612   inst, "FLT_TO_UINT",
 613   [(set R600_Reg32:$dst, (fp_to_uint R600_Reg32:$src))]
 614 >;
 615
 616 class UINT_TO_FLT_Common <bits<32> inst> : R600_1OP <
 617   inst, "UINT_TO_FLT",
 618   [(set R600_Reg32:$dst, (uint_to_fp R600_Reg32:$src))]
 619 >;
 620
 621 class LOG_CLAMPED_Common <bits<32> inst> : R600_1OP <
 622   inst, "LOG_CLAMPED",
 623   []
 624 >;
 625
 626 class LOG_IEEE_Common <bits<32> inst> : R600_1OP <
 627   inst, "LOG_IEEE",
 628   [(set R600_Reg32:$dst, (int_AMDIL_log R600_Reg32:$src))]
 629 >;
 630
 631 class LSHL_Common <bits<32> inst> : R600_2OP <
 632   inst, "LSHL $dst, $src0, $src1",
 633   [(set R600_Reg32:$dst, (shl R600_Reg32:$src0, R600_Reg32:$src1))]
 634 >;
 635
 636 class LSHR_Common <bits<32> inst> : R600_2OP <
 637   inst, "LSHR $dst, $src0, $src1",
 638   [(set R600_Reg32:$dst, (srl R600_Reg32:$src0, R600_Reg32:$src1))]
 639 >;
 640
 641 class ASHR_Common <bits<32> inst> : R600_2OP <
 642   inst, "ASHR $dst, $src0, $src1",
 643   [(set R600_Reg32:$dst, (sra R600_Reg32:$src0, R600_Reg32:$src1))]
 644 >;
 645
 646 class MULHI_INT_Common <bits<32> inst> : R600_2OP <
 647   inst, "MULHI_INT $dst, $src0, $src1",
 648   [(set R600_Reg32:$dst, (mulhs R600_Reg32:$src0, R600_Reg32:$src1))]
 649 >;
 650
 651 class MULHI_UINT_Common <bits<32> inst> : R600_2OP <
 652   inst, "MULHI $dst, $src0, $src1",
 653   [(set R600_Reg32:$dst, (mulhu R600_Reg32:$src0, R600_Reg32:$src1))]
 654 >;
 655
 656 class MULLO_INT_Common <bits<32> inst> : R600_2OP <
 657   inst, "MULLO_INT $dst, $src0, $src1",
 658   [(set R600_Reg32:$dst, (mul R600_Reg32:$src0, R600_Reg32:$src1))]
 659 >;
 660
 661 class MULLO_UINT_Common <bits<32> inst> : R600_2OP <
 662   inst, "MULLO_UINT $dst, $src0, $src1",
 663   []
 664 >;
 665
 666 class RECIP_CLAMPED_Common <bits<32> inst> : R600_1OP <
 667   inst, "RECIP_CLAMPED",
 668   []
 669 >;
 670
 671 class RECIP_IEEE_Common <bits<32> inst> : R600_1OP <
 672   inst, "RECIP_IEEE",
 673   [(set R600_Reg32:$dst, (int_AMDGPU_rcp R600_Reg32:$src))]
 674 >;
 675
 676 class RECIP_UINT_Common <bits<32> inst> : R600_1OP <
 677   inst, "RECIP_INT $dst, $src",
 678   [(set R600_Reg32:$dst, (AMDGPUurecip R600_Reg32:$src))]
 679 >;
 680
 681 class RECIPSQRT_CLAMPED_Common <bits<32> inst> : R600_1OP <
 682   inst, "RECIPSQRT_CLAMPED",
 683   [(set R600_Reg32:$dst, (int_AMDGPU_rsq R600_Reg32:$src))]
 684 >;
 685
 686 class RECIPSQRT_IEEE_Common <bits<32> inst> : R600_1OP <
 687   inst, "RECIPSQRT_IEEE",
 688   []
 689 >;
 690
 691 class SIN_Common <bits<32> inst> : R600_1OP <
 692   inst, "SIN",
 693   [(set R600_Reg32:$dst, (int_AMDIL_sin R600_Reg32:$src))]>{
 694   let Trig = 1;
 695 }
 696
 697 class COS_Common <bits<32> inst> : R600_1OP <
 698   inst, "COS",
 699   [(set R600_Reg32:$dst, (int_AMDIL_cos R600_Reg32:$src))]> {
 700   let Trig = 1;
 701 }
 702
 703 /* Helper patterns for complex intrinsics */
 704 /* -------------------------------------- */
 705
 706 class DIV_Common <InstR600 recip_ieee> : Pat<
 707   (int_AMDGPU_div R600_Reg32:$src0, R600_Reg32:$src1),
 708   (MUL R600_Reg32:$src0, (recip_ieee R600_Reg32:$src1))
 709 >;
 710
 711 class SSG_Common <InstR600 cndgt, InstR600 cndge> : Pat <
 712   (int_AMDGPU_ssg R600_Reg32:$src),
 713   (cndgt R600_Reg32:$src, (f32 ONE), (cndge R600_Reg32:$src, (f32 ZERO), (f32 NEG_ONE)))
 714 >;
 715
 716 class TGSI_LIT_Z_Common <InstR600 mul_lit, InstR600 log_clamped, InstR600 exp_ieee> : Pat <
 717   (int_TGSI_lit_z R600_Reg32:$src_x, R600_Reg32:$src_y, R600_Reg32:$src_w),
 718   (exp_ieee (mul_lit (log_clamped (MAX R600_Reg32:$src_y, (f32 ZERO))), R600_Reg32:$src_w, R600_Reg32:$src_x))
 719 >;
 720
 721 /* ---------------------- */
 722 /* R600 / R700 Only Instructions */
 723 /* ---------------------- */
 724
 725 let Predicates = [isR600] in {
 726
 727   def MUL_LIT_r600 : MUL_LIT_Common<0x0C>;
 728   def MULADD_r600 : MULADD_Common<0x10>;
 729   def CNDE_r600 : CNDE_Common<0x18>;
 730   def CNDGT_r600 : CNDGT_Common<0x19>;
 731   def CNDGE_r600 : CNDGE_Common<0x1A>;
 732   def DOT4_r600 : DOT4_Common<0x50>;
 733   def CUBE_r600 : CUBE_Common<0x52>;
 734   def EXP_IEEE_r600 : EXP_IEEE_Common<0x61>;
 735   def LOG_CLAMPED_r600 : LOG_CLAMPED_Common<0x62>;
 736   def LOG_IEEE_r600 : LOG_IEEE_Common<0x63>;
 737   def RECIP_CLAMPED_r600 : RECIP_CLAMPED_Common<0x64>;
 738   def RECIP_IEEE_r600 : RECIP_IEEE_Common<0x66>;
 739   def RECIPSQRT_CLAMPED_r600 : RECIPSQRT_CLAMPED_Common<0x67>;
 740   def RECIPSQRT_IEEE_r600 : RECIPSQRT_IEEE_Common<0x69>;
 741   def FLT_TO_INT_r600 : FLT_TO_INT_Common<0x6b>;
 742   def INT_TO_FLT_r600 : INT_TO_FLT_Common<0x6c>;
 743   def FLT_TO_UINT_r600 : FLT_TO_UINT_Common<0x79>;
 744   def UINT_TO_FLT_r600 : UINT_TO_FLT_Common<0x6d>;
 745   def SIN_r600 : SIN_Common<0x6E>;
 746   def COS_r600 : COS_Common<0x6F>;
 747   def ASHR_r600 : ASHR_Common<0x70>;
 748   def LSHR_r600 : LSHR_Common<0x71>;
 749   def LSHL_r600 : LSHL_Common<0x72>;
 750   def MULLO_INT_r600 : MULLO_INT_Common<0x73>;
 751   def MULHI_INT_r600 : MULHI_INT_Common<0x74>;
 752   def MULLO_UINT_r600 : MULLO_UINT_Common<0x75>;
 753   def MULHI_UINT_r600 : MULHI_UINT_Common<0x76>;
 754   def RECIP_UINT_r600 : RECIP_UINT_Common <0x78>;
 755
 756   def DIV_r600 : DIV_Common<RECIP_IEEE_r600>;
 757   def POW_r600 : POW_Common<LOG_IEEE_r600, EXP_IEEE_r600, MUL, GPRF32>;
 758   def SSG_r600 : SSG_Common<CNDGT_r600, CNDGE_r600>;
 759   def TGSI_LIT_Z_r600 : TGSI_LIT_Z_Common<MUL_LIT_r600, LOG_CLAMPED_r600, EXP_IEEE_r600>;
 760
 761 }
 762
 763 /* ----------------- */
 764 /* R700+ Trig helper */
 765 /* ----------------- */
 766
 767 /*
 768 class TRIG_HELPER_r700 <InstR600 trig_inst>: Pat <
 769   (trig_inst R600_Reg32:$src),
 770   (trig_inst (fmul R600_Reg32:$src, (PI))))
 771 >;
 772 */
 773
 774 /* ---------------------- */
 775 /* Evergreen Instructions */
 776 /* ---------------------- */
 777
 778
 779 let Predicates = [isEG] in {
 780
 781 def RAT_WRITE_CACHELESS_eg :
 782     EG_CF_RAT <0x57, 0x2, (outs), (ins R600_TReg32_X:$rw_gpr,
 783                                    R600_TReg32_X:$index_gpr, i32imm:$rat_id), "">
 784 {
 785   let RIM         = 0;
 786   /* XXX: Have a separate instruction for non-indexed writes. */
 787   let TYPE        = 1;
 788   let RW_REL      = 0;
 789   let ELEM_SIZE   = 0;
 790
 791   let ARRAY_SIZE  = 0;
 792   let COMP_MASK   = 1;
 793   let BURST_COUNT = 0;
 794   let VPM         = 0;
 795   let EOP         = 0;
 796   let MARK        = 0;
 797   let BARRIER     = 1;
 798 }
 799
 800 def VTX_READ_eg : InstR600ISA < (outs R600_TReg32_X:$dst),
 801                                 (ins R600_TReg32_X:$src, i32imm:$buffer_id),
 802                                 "VTX_READ_eg $dst, $src", []>
 803 {
 804 /*
 805   bits<7> DST_GPR;
 806   bits<7> SRC_GPR;
 807   bits<8> BUFFER_ID;
 808 */
 809   /* If any of these field below need to be calculated at compile time, and
 810    * a ins operand for them and move them to the list of operands above. */
 811
 812   /* XXX: This instruction is manual encoded, so none of these values are used.
 813    */
 814 /*
 815   bits<5> VC_INST          = 0; //VC_INST_FETCH
 816   bits<2> FETCH_TYPE       = 2;
 817   bits<1> FETCH_WHOLE_QUAD = 1;
 818   bits<1> SRC_REL          = 0;
 819   bits<2> SRC_SEL_X        = 0;
 820   bits<6> MEGA_FETCH_COUNT = 4;
 821 */
 822 /*
 823
 824   bits<1> DST_REL          = 0;
 825   bits<3> DST_SEL_X        = 0;
 826   bits<3> DST_SEL_Y        = 7; //Masked
 827   bits<3> DST_SEL_Z        = 7; //Masked
 828   bits<3> DST_SEL_W        = 7; //Masked
 829   bits<1> USE_CONST_FIELDS = 1; //Masked
 830   bits<6> DATA_FORMAT      = 0;
 831   bits<2> NUM_FORMAT_ALL   = 0;
 832   bits<1> FORMAT_COMP_ALL  = 0;
 833   bits<1> SRF_MODE_ALL     = 0;
 834 */
 835
 836 /*
 837   let Inst{4-0}   = VC_INST;
 838   let Inst{6-5}   = FETCH_TYPE;
 839   let Inst{7}     = FETCH_WHOLE_QUAD;
 840   let Inst{15-8}  = BUFFER_ID;
 841   let Inst{22-16} = SRC_GPR;
 842   let Inst{23}    = SRC_REL;
 843   let Inst{25-24} = SRC_SEL_X;
 844   let Inst{31-26} = MEGA_FETCH_COUNT;
 845 */
 846   /* DST_GPR is OK to leave uncommented, because LLVM 3.0 only prevents you
 847    * from statically setting bits > 31.  This field will be set by
 848    * getMachineValueOp which can set bits > 31.
 849    */
 850 //  let Inst{32-38} = DST_GPR;
 851
 852   /* XXX: Uncomment for LLVM 3.1 which supports 64-bit instructions */
 853
 854 /*
 855   let Inst{39}    = DST_REL;
 856   let Inst{40}    = 0; //Reserved
 857   let Inst{43-41} = DST_SEL_X;
 858   let Inst{46-44} = DST_SEL_Y;
 859   let Inst{49-47} = DST_SEL_Z;
 860   let Inst{52-50} = DST_SEL_W;
 861   let Inst{53}    = USE_CONST_FIELDS;
 862   let Inst{59-54} = DATA_FORMAT;
 863   let Inst{61-60} = NUM_FORMAT_ALL;
 864   let Inst{62}    = FORMAT_COMP_ALL;
 865   let Inst{63}    = SRF_MODE_ALL;
 866 */
 867 }
 868
 869 /* XXX: Need to convert PTR to rat_id */
 870 /*
 871 def : Pat <(store_global (f32 R600_Reg32:$value), node:$ptr),
 872            (RAT_WRITE_CACHELESS_eg (INSERT_SUBREG (v4f32 (IMPLICIT_DEF)),
 873                                                   (f32 R600_Reg32:$value),
 874                                                    sel_x),
 875                                     (f32 ZERO), 0, R600_Reg32:$ptr)>;
 876 */
 877
 878 class VTX_Param_Read_Pattern <ValueType vt> : Pat <
 879     (vt (load_param ADDRParam:$mem)),
 880     (VTX_READ_eg (i32 R600_Reg32:$mem), 0)>;
 881
 882 def : VTX_Param_Read_Pattern <f32>;
 883 def : VTX_Param_Read_Pattern <i32>;
 884
 885 } // End isEG Predicate
 886
 887 /* ------------------------------- */
 888 /* Evergreen / Cayman Instructions */
 889 /* ------------------------------- */
 890
 891 let Predicates = [isEGorCayman] in {
 892
 893 class TRIG_eg <InstR600 trig, Intrinsic intr> : Pat<
 894   (intr R600_Reg32:$src),
 895   (trig (MUL (MOV (LOADCONST_i32 CONST.TWO_PI_INV)), R600_Reg32:$src))
 896 >;
 897
 898   def MULADD_eg : MULADD_Common<0x14>;
 899   def ASHR_eg : ASHR_Common<0x15>;
 900   def LSHR_eg : LSHR_Common<0x16>;
 901   def LSHL_eg : LSHL_Common<0x17>;
 902   def CNDE_eg : CNDE_Common<0x19>;
 903   def CNDGT_eg : CNDGT_Common<0x1A>;
 904   def CNDGE_eg : CNDGE_Common<0x1B>;
 905   def MUL_LIT_eg : MUL_LIT_Common<0x1F>;
 906   def EXP_IEEE_eg : EXP_IEEE_Common<0x81>;
 907   def LOG_CLAMPED_eg : LOG_CLAMPED_Common<0x82>;
 908   def LOG_IEEE_eg : LOG_IEEE_Common<0x83>;
 909   def RECIP_CLAMPED_eg : RECIP_CLAMPED_Common<0x84>;
 910   def RECIP_IEEE_eg : RECIP_IEEE_Common<0x86>;
 911   def RECIPSQRT_CLAMPED_eg : RECIPSQRT_CLAMPED_Common<0x87>;
 912   def RECIPSQRT_IEEE_eg : RECIPSQRT_IEEE_Common<0x89>;
 913   def SIN_eg : SIN_Common<0x8D>;
 914   def COS_eg : COS_Common<0x8E>;
 915   def MULLO_INT_eg : MULLO_INT_Common<0x8F>;
 916   def MULHI_INT_eg : MULHI_INT_Common<0x90>;
 917   def MULLO_UINT_eg : MULLO_UINT_Common<0x91>;
 918   def MULHI_UINT_eg : MULHI_UINT_Common<0x92>;
 919   def RECIP_UINT_eg : RECIP_UINT_Common<0x94>;
 920   def DOT4_eg : DOT4_Common<0xBE>;
 921   def CUBE_eg : CUBE_Common<0xC0>;
 922
 923   def DIV_eg : DIV_Common<RECIP_IEEE_eg>;
 924   def POW_eg : POW_Common<LOG_IEEE_eg, EXP_IEEE_eg, MUL, GPRF32>;
 925   def SSG_eg : SSG_Common<CNDGT_eg, CNDGE_eg>;
 926   def TGSI_LIT_Z_eg : TGSI_LIT_Z_Common<MUL_LIT_eg, LOG_CLAMPED_eg, EXP_IEEE_eg>;
 927
 928   def : TRIG_eg <SIN_eg, int_AMDGPU_sin>;
 929   def : TRIG_eg <COS_eg, int_AMDGPU_cos>;
 930
 931   def FLT_TO_INT_eg : FLT_TO_INT_Common<0x50> {
 932     let Pattern = [];
 933   }
 934
 935   def INT_TO_FLT_eg : INT_TO_FLT_Common<0x9B>;
 936
 937   def FLT_TO_UINT_eg : FLT_TO_UINT_Common<0x9A> {
 938     let Pattern = [];
 939   }
 940
 941   def UINT_TO_FLT_eg : UINT_TO_FLT_Common<0x9C>;
 942
 943   def : Pat<(fp_to_sint R600_Reg32:$src),
 944     (FLT_TO_INT_eg (TRUNC R600_Reg32:$src))>;
 945
 946   def : Pat<(fp_to_uint R600_Reg32:$src),
 947     (FLT_TO_UINT_eg (TRUNC R600_Reg32:$src))>;
 948 }
 949
 950 let Predicates = [isCayman] in {
 951
 952   /* XXX: I'm not sure if this opcode is correct. */
 953   def RECIP_UINT_cm : RECIP_UINT_Common<0x77>;
 954
 955 } // End isCayman
 956
 957 /* Other Instructions */
 958
 959 let isCodeGenOnly = 1 in {
 960 /*
 961   def SWIZZLE : AMDGPUShaderInst <
 962     (outs GPRV4F32:$dst),
 963     (ins GPRV4F32:$src0, i32imm:$src1),
 964     "SWIZZLE $dst, $src0, $src1",
 965     [(set GPRV4F32:$dst, (int_AMDGPU_swizzle GPRV4F32:$src0, imm:$src1))]
 966   >;
 967 */
 968
 969   def LAST : AMDGPUShaderInst <
 970     (outs),
 971     (ins),
 972     "LAST",
 973     []
 974   >;
 975
 976   def GET_CHAN : AMDGPUShaderInst <
 977     (outs R600_Reg32:$dst),
 978     (ins R600_Reg128:$src0, i32imm:$src1),
 979     "GET_CHAN $dst, $src0, $src1",
 980     []
 981   >;
 982
 983   def MULLIT : AMDGPUShaderInst <
 984     (outs R600_Reg128:$dst),
 985     (ins R600_Reg32:$src0, R600_Reg32:$src1, R600_Reg32:$src2),
 986     "MULLIT $dst, $src0, $src1",
 987     [(set R600_Reg128:$dst, (int_AMDGPU_mullit R600_Reg32:$src0, R600_Reg32:$src1, R600_Reg32:$src2))]
 988   >;
 989
 990 let usesCustomInserter = 1, isPseudo = 1 in {
 991
 992 class R600PreloadInst <string asm, Intrinsic intr> : AMDGPUInst <
 993   (outs R600_TReg32:$dst),
 994   (ins),
 995   asm,
 996   [(set R600_TReg32:$dst, (intr))]
 997 >;
 998
 999 def TGID_X : R600PreloadInst <"TGID_X", int_r600_read_tgid_x>;
1000 def TGID_Y : R600PreloadInst <"TGID_Y", int_r600_read_tgid_y>;
1001 def TGID_Z : R600PreloadInst <"TGID_Z", int_r600_read_tgid_z>;
1002
1003 def TIDIG_X : R600PreloadInst <"TIDIG_X", int_r600_read_tidig_x>;
1004 def TIDIG_Y : R600PreloadInst <"TIDIG_Y", int_r600_read_tidig_y>;
1005 def TIDIG_Z : R600PreloadInst <"TIDIG_Z", int_r600_read_tidig_z>;
1006
1007 def NGROUPS_X : R600PreloadInst <"NGROUPS_X", int_r600_read_ngroups_x>;
1008 def NGROUPS_Y : R600PreloadInst <"NGROUPS_Y", int_r600_read_ngroups_y>;
1009 def NGROUPS_Z : R600PreloadInst <"NGROUPS_Z", int_r600_read_ngroups_z>;
1010
1011 def GLOBAL_SIZE_X : R600PreloadInst <"GLOBAL_SIZE_X",
1012                                      int_r600_read_global_size_x>;
1013 def GLOBAL_SIZE_Y : R600PreloadInst <"GLOBAL_SIZE_Y",
1014                                      int_r600_read_global_size_y>;
1015 def GLOBAL_SIZE_Z : R600PreloadInst <"GLOBAL_SIZE_Z",
1016                                      int_r600_read_global_size_z>;
1017
1018 def LOCAL_SIZE_X : R600PreloadInst <"LOCAL_SIZE_X",
1019                                     int_r600_read_local_size_x>;
1020 def LOCAL_SIZE_Y : R600PreloadInst <"LOCAL_SIZE_Y",
1021                                     int_r600_read_local_size_y>;
1022 def LOCAL_SIZE_Z : R600PreloadInst <"LOCAL_SIZE_Z",
1023                                     int_r600_read_local_size_z>;
1024
1025 def R600_LOAD_CONST : AMDGPUShaderInst <
1026   (outs R600_Reg32:$dst),
1027   (ins i32imm:$src0),
1028   "R600_LOAD_CONST $dst, $src0",
1029   [(set R600_Reg32:$dst, (int_AMDGPU_load_const imm:$src0))]
1030 >;
1031
1032 def LOAD_INPUT : AMDGPUShaderInst <
1033   (outs R600_Reg32:$dst),
1034   (ins i32imm:$src),
1035   "LOAD_INPUT $dst, $src",
1036   [(set R600_Reg32:$dst, (int_R600_load_input imm:$src))]
1037 >;
1038
1039 def RESERVE_REG : AMDGPUShaderInst <
1040   (outs),
1041   (ins i32imm:$src),
1042   "RESERVE_REG $src",
1043   [(int_AMDGPU_reserve_reg imm:$src)]
1044 >;
1045
1046 def STORE_OUTPUT: AMDGPUShaderInst <
1047   (outs),
1048   (ins R600_Reg32:$src0, i32imm:$src1),
1049   "STORE_OUTPUT $src0, $src1",
1050   [(int_AMDGPU_store_output R600_Reg32:$src0, imm:$src1)]
1051 >;
1052
1053 def TXD: AMDGPUShaderInst <
1054   (outs R600_Reg128:$dst),
1055   (ins R600_Reg128:$src0, R600_Reg128:$src1, R600_Reg128:$src2, i32imm:$src3, i32imm:$src4),
1056   "TXD $dst, $src0, $src1, $src2, $src3, $src4",
1057   [(set R600_Reg128:$dst, (int_AMDGPU_txd R600_Reg128:$src0, R600_Reg128:$src1, R600_Reg128:$src2, imm:$src3, imm:$src4))]
1058 >;
1059
1060 def TXD_SHADOW: AMDGPUShaderInst <
1061   (outs R600_Reg128:$dst),
1062   (ins R600_Reg128:$src0, R600_Reg128:$src1, R600_Reg128:$src2, i32imm:$src3, i32imm:$src4),
1063   "TXD_SHADOW $dst, $src0, $src1, $src2, $src3, $src4",
1064   [(set R600_Reg128:$dst, (int_AMDGPU_txd R600_Reg128:$src0, R600_Reg128:$src1, R600_Reg128:$src2, imm:$src3, TEX_SHADOW:$src4))]
1065 >;
1066
1067 } // End usesCustomInserter = 1, isPseudo = 1
1068
1069 } // End isCodeGenOnly = 1
1070
1071 def CLAMP_R600 :  CLAMP <R600_Reg32>;
1072 def FABS_R600 : FABS<R600_Reg32>;
1073 def FNEG_R600 : FNEG<R600_Reg32>;
1074
1075 let isPseudo = 1 in {
1076
1077 def LOAD_VTX : AMDGPUShaderInst <
1078     (outs R600_Reg32:$dst),
1079     (ins MEMri:$mem),
1080     "LOAD_VTX",
1081     [(set (i32 R600_Reg32:$dst), (load_param ADDRParam:$mem))]
1082 >;
1083
1084
1085 } //End isPseudo
1086
1087 //===----------------------------------------------------------------------===//
1088 // ISel Patterns
1089 //===----------------------------------------------------------------------===//
1090
1091 // SGT Reverse args
1092 def : Pat <
1093   (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO, COND_LT),
1094   (SGT R600_Reg32:$src1, R600_Reg32:$src0)
1095 >;
1096
1097 // SGE Reverse args
1098 def : Pat <
1099   (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO, COND_LE),
1100   (SGE R600_Reg32:$src1, R600_Reg32:$src0)
1101 >;
1102
1103 // SETGT_INT reverse args
1104 def : Pat <
1105   (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETLT),
1106   (SETGT_INT R600_Reg32:$src1, R600_Reg32:$src0)
1107 >;
1108
1109 // SETGE_INT reverse args
1110 def : Pat <
1111   (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETLE),
1112   (SETGE_INT R600_Reg32:$src1, R600_Reg32:$src0)
1113 >;
1114
1115 // SETGT_UINT reverse args
1116 def : Pat <
1117   (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETULT),
1118   (SETGT_UINT R600_Reg32:$src1, R600_Reg32:$src0)
1119 >;
1120
1121 // SETGE_UINT reverse args
1122 def : Pat <
1123   (selectcc (i32 R600_Reg32:$src0), R600_Reg32:$src1, -1, 0, SETULE),
1124   (SETGE_UINT R600_Reg32:$src0, R600_Reg32:$src1)
1125 >;
1126
1127 // The next two patterns are special cases for handling 'true if ordered' and
1128 // 'true if unordered' conditionals.  The assumption here is that the behavior of
1129 // SETE and SNE conforms to the Direct3D 10 rules for floating point values
1130 // described here:
1131 // http://msdn.microsoft.com/en-us/library/windows/desktop/cc308050.aspx#alpha_32_bit
1132 // We assume that  SETE returns false when one of the operands is NAN and
1133 // SNE returns true when on of the operands is NAN
1134
1135 //SETE - 'true if ordered'
1136 def : Pat <
1137   (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO, SETO),
1138   (SETE R600_Reg32:$src0, R600_Reg32:$src1)
1139 >;
1140
1141 //SNE - 'true if unordered'
1142 def : Pat <
1143   (selectcc (f32 R600_Reg32:$src0), R600_Reg32:$src1, FP_ONE, FP_ZERO, SETUO),
1144   (SNE R600_Reg32:$src0, R600_Reg32:$src1)
1145 >;
1146
1147 def : Extract_Element <f32, v4f32, R600_Reg128, 0, sel_x>;
1148 def : Extract_Element <f32, v4f32, R600_Reg128, 1, sel_y>;
1149 def : Extract_Element <f32, v4f32, R600_Reg128, 2, sel_z>;
1150 def : Extract_Element <f32, v4f32, R600_Reg128, 3, sel_w>;
1151
1152 def : Insert_Element <f32, v4f32, R600_Reg32, R600_Reg128, 4, sel_x>;
1153 def : Insert_Element <f32, v4f32, R600_Reg32, R600_Reg128, 5, sel_y>;
1154 def : Insert_Element <f32, v4f32, R600_Reg32, R600_Reg128, 6, sel_z>;
1155 def : Insert_Element <f32, v4f32, R600_Reg32, R600_Reg128, 7, sel_w>;
1156
1157 def : Extract_Element <i32, v4i32, R600_Reg128, 0, sel_x>;
1158 def : Extract_Element <i32, v4i32, R600_Reg128, 1, sel_y>;
1159 def : Extract_Element <i32, v4i32, R600_Reg128, 2, sel_z>;
1160 def : Extract_Element <i32, v4i32, R600_Reg128, 3, sel_w>;
1161
1162 def : Insert_Element <i32, v4i32, R600_Reg32, R600_Reg128, 4, sel_x>;
1163 def : Insert_Element <i32, v4i32, R600_Reg32, R600_Reg128, 5, sel_y>;
1164 def : Insert_Element <i32, v4i32, R600_Reg32, R600_Reg128, 6, sel_z>;
1165 def : Insert_Element <i32, v4i32, R600_Reg32, R600_Reg128, 7, sel_w>;
1166
1167 // bitconvert patterns
1168
1169 def : BitConvert <i32, f32, R600_Reg32>;
1170 def : BitConvert <f32, i32, R600_Reg32>;
1171
1172 } // End isR600toCayman Predicate