src/glsl/glsl_lexer.ll

   1 %{
   2 /*
   3  * Copyright © 2008, 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include <ctype.h>
  25 #include <limits.h>
  26 #include "strtod.h"
  27 #include "ast.h"
  28 #include "glsl_parser_extras.h"
  29 #include "glsl_parser.h"
  30
  31 static int classify_identifier(struct _mesa_glsl_parse_state *, const char *);
  32
  33 #ifdef _MSC_VER
  34 #define YY_NO_UNISTD_H
  35 #endif
  36
  37 #define YY_USER_ACTION                                          \
  38    do {                                                         \
  39       yylloc->source = 0;                                       \
  40       yylloc->first_column = yycolumn + 1;                      \
  41       yylloc->first_line = yylineno + 1;                        \
  42       yycolumn += yyleng;                                       \
  43    } while(0);
  44
  45 #define YY_USER_INIT yylineno = 0; yycolumn = 0;
  46
  47 /* A macro for handling reserved words and keywords across language versions.
  48  *
  49  * Certain words start out as identifiers, become reserved words in
  50  * later language revisions, and finally become language keywords.
  51  *
  52  * For example, consider the following lexer rule:
  53  * samplerBuffer       KEYWORD(130, 140, SAMPLERBUFFER)
  54  *
  55  * This means that "samplerBuffer" will be treated as:
  56  * - a keyword (SAMPLERBUFFER token)         ...in GLSL >= 1.40
  57  * - a reserved word - error                 ...in GLSL >= 1.30
  58  * - an identifier                           ...in GLSL <  1.30
  59  */
  60 #define KEYWORD(reserved_version, allowed_version, token)               \
  61    do {                                                                 \
  62       if (yyextra->language_version >= allowed_version) {               \
  63          return token;                                                  \
  64       } else if (yyextra->language_version >= reserved_version) {       \
  65          _mesa_glsl_error(yylloc, yyextra,                              \
  66                           "Illegal use of reserved word `%s'", yytext); \
  67          return ERROR_TOK;                                              \
  68       } else {                                                          \
  69          yylval->identifier = strdup(yytext);                           \
  70          return classify_identifier(yyextra, yytext);                   \
  71       }                                                                 \
  72    } while (0)
  73
  74 /* The ES macro can be used in KEYWORD checks:
  75  *
  76  *    word      KEYWORD(110 || ES, 400, TOKEN)
  77  * ...means the word is reserved in GLSL ES 1.00, while
  78  *
  79  *    word      KEYWORD(110, 130 || ES, TOKEN)
  80  * ...means the word is a legal keyword in GLSL ES 1.00.
  81  */
  82 #define ES yyextra->es_shader
  83
  84 static int
  85 literal_integer(char *text, int len, struct _mesa_glsl_parse_state *state,
  86                 YYSTYPE *lval, YYLTYPE *lloc, int base)
  87 {
  88    bool is_uint = (text[len - 1] == 'u' ||
  89                    text[len - 1] == 'U');
  90    const char *digits = text;
  91
  92    /* Skip "0x" */
  93    if (base == 16)
  94       digits += 2;
  95
  96    unsigned long long value = strtoull(digits, NULL, base);
  97
  98    lval->n = (int)value;
  99
 100    if (value > UINT_MAX) {
 101       /* Note that signed 0xffffffff is valid, not out of range! */
 102       if (state->language_version >= 130) {
 103          _mesa_glsl_error(lloc, state,
 104                           "Literal value `%s' out of range", text);
 105       } else {
 106          _mesa_glsl_warning(lloc, state,
 107                             "Literal value `%s' out of range", text);
 108       }
 109    } else if (base == 10 && !is_uint && (unsigned)value > (unsigned)INT_MAX + 1) {
 110       /* Tries to catch unintentionally providing a negative value.
 111        * Note that -2147483648 is parsed as -(2147483648), so we don't
 112        * want to warn for INT_MAX.
 113        */
 114       _mesa_glsl_warning(lloc, state,
 115                          "Signed literal value `%s' is interpreted as %d",
 116                          text, lval->n);
 117    }
 118    return is_uint ? UINTCONSTANT : INTCONSTANT;
 119 }
 120
 121 #define LITERAL_INTEGER(base) \
 122    literal_integer(yytext, yyleng, yyextra, yylval, yylloc, base)
 123
 124 %}
 125
 126 %option bison-bridge bison-locations reentrant noyywrap
 127 %option nounput noyy_top_state
 128 %option never-interactive
 129 %option prefix="_mesa_glsl_"
 130 %option extra-type="struct _mesa_glsl_parse_state *"
 131
 132 %x PP PRAGMA
 133
 134 DEC_INT         [1-9][0-9]*
 135 HEX_INT         0[xX][0-9a-fA-F]+
 136 OCT_INT         0[0-7]*
 137 INT             ({DEC_INT}|{HEX_INT}|{OCT_INT})
 138 SPC             [ \t]*
 139 SPCP            [ \t]+
 140 HASH            ^{SPC}#{SPC}
 141 %%
 142
 143 [ \r\t]+                ;
 144
 145     /* Preprocessor tokens. */
 146 ^[ \t]*#[ \t]*$                 ;
 147 ^[ \t]*#[ \t]*version           { BEGIN PP; return VERSION; }
 148 ^[ \t]*#[ \t]*extension         { BEGIN PP; return EXTENSION; }
 149 {HASH}line{SPCP}{INT}{SPCP}{INT}{SPC}$ {
 150                                    /* Eat characters until the first digit is
 151                                     * encountered
 152                                     */
 153                                    char *ptr = yytext;
 154                                    while (!isdigit(*ptr))
 155                                       ptr++;
 156
 157                                    /* Subtract one from the line number because
 158                                     * yylineno is zero-based instead of
 159                                     * one-based.
 160                                     */
 161                                    yylineno = strtol(ptr, &ptr, 0) - 1;
 162                                    yylloc->source = strtol(ptr, NULL, 0);
 163                                 }
 164 {HASH}line{SPCP}{INT}{SPC}$     {
 165                                    /* Eat characters until the first digit is
 166                                     * encountered
 167                                     */
 168                                    char *ptr = yytext;
 169                                    while (!isdigit(*ptr))
 170                                       ptr++;
 171
 172                                    /* Subtract one from the line number because
 173                                     * yylineno is zero-based instead of
 174                                     * one-based.
 175                                     */
 176                                    yylineno = strtol(ptr, &ptr, 0) - 1;
 177                                 }
 178 ^{SPC}#{SPC}pragma{SPCP}debug{SPC}\({SPC}on{SPC}\) {
 179                                   BEGIN PP;
 180                                   return PRAGMA_DEBUG_ON;
 181                                 }
 182 ^{SPC}#{SPC}pragma{SPCP}debug{SPC}\({SPC}off{SPC}\) {
 183                                   BEGIN PP;
 184                                   return PRAGMA_DEBUG_OFF;
 185                                 }
 186 ^{SPC}#{SPC}pragma{SPCP}optimize{SPC}\({SPC}on{SPC}\) {
 187                                   BEGIN PP;
 188                                   return PRAGMA_OPTIMIZE_ON;
 189                                 }
 190 ^{SPC}#{SPC}pragma{SPCP}optimize{SPC}\({SPC}off{SPC}\) {
 191                                   BEGIN PP;
 192                                   return PRAGMA_OPTIMIZE_OFF;
 193                                 }
 194 ^{SPC}#{SPC}pragma{SPCP}STDGL{SPCP}invariant{SPC}\({SPC}all{SPC}\) {
 195                                   BEGIN PP;
 196                                   return PRAGMA_INVARIANT_ALL;
 197                                 }
 198 ^{SPC}#{SPC}pragma{SPCP}        { BEGIN PRAGMA; }
 199
 200 <PRAGMA>\n                      { BEGIN 0; yylineno++; yycolumn = 0; }
 201 <PRAGMA>.                       { }
 202
 203 <PP>\/\/[^\n]*                  { }
 204 <PP>[ \t\r]*                    { }
 205 <PP>:                           return COLON;
 206 <PP>[_a-zA-Z][_a-zA-Z0-9]*      {
 207                                    yylval->identifier = strdup(yytext);
 208                                    return IDENTIFIER;
 209                                 }
 210 <PP>[1-9][0-9]*                 {
 211                                     yylval->n = strtol(yytext, NULL, 10);
 212                                     return INTCONSTANT;
 213                                 }
 214 <PP>\n                          { BEGIN 0; yylineno++; yycolumn = 0; return EOL; }
 215
 216 \n              { yylineno++; yycolumn = 0; }
 217
 218 attribute       return ATTRIBUTE;
 219 const           return CONST_TOK;
 220 bool            return BOOL_TOK;
 221 float           return FLOAT_TOK;
 222 int             return INT_TOK;
 223 uint            KEYWORD(130, 130, UINT_TOK);
 224
 225 break           return BREAK;
 226 continue        return CONTINUE;
 227 do              return DO;
 228 while           return WHILE;
 229 else            return ELSE;
 230 for             return FOR;
 231 if              return IF;
 232 discard         return DISCARD;
 233 return          return RETURN;
 234
 235 bvec2           return BVEC2;
 236 bvec3           return BVEC3;
 237 bvec4           return BVEC4;
 238 ivec2           return IVEC2;
 239 ivec3           return IVEC3;
 240 ivec4           return IVEC4;
 241 uvec2           KEYWORD(130, 130, UVEC2);
 242 uvec3           KEYWORD(130, 130, UVEC3);
 243 uvec4           KEYWORD(130, 130, UVEC4);
 244 vec2            return VEC2;
 245 vec3            return VEC3;
 246 vec4            return VEC4;
 247 mat2            return MAT2X2;
 248 mat3            return MAT3X3;
 249 mat4            return MAT4X4;
 250 mat2x2          KEYWORD(120, 120, MAT2X2);
 251 mat2x3          KEYWORD(120, 120, MAT2X3);
 252 mat2x4          KEYWORD(120, 120, MAT2X4);
 253 mat3x2          KEYWORD(120, 120, MAT3X2);
 254 mat3x3          KEYWORD(120, 120, MAT3X3);
 255 mat3x4          KEYWORD(120, 120, MAT3X4);
 256 mat4x2          KEYWORD(120, 120, MAT4X2);
 257 mat4x3          KEYWORD(120, 120, MAT4X3);
 258 mat4x4          KEYWORD(120, 120, MAT4X4);
 259
 260 in              return IN_TOK;
 261 out             return OUT_TOK;
 262 inout           return INOUT_TOK;
 263 uniform         return UNIFORM;
 264 varying         return VARYING;
 265 centroid        KEYWORD(120, 120, CENTROID);
 266 invariant       KEYWORD(120 || ES, 120 || ES, INVARIANT);
 267 flat            KEYWORD(130 || ES, 130, FLAT);
 268 smooth          KEYWORD(130, 130, SMOOTH);
 269 noperspective   KEYWORD(130, 130, NOPERSPECTIVE);
 270
 271 sampler1D       return SAMPLER1D;
 272 sampler2D       return SAMPLER2D;
 273 sampler3D       return SAMPLER3D;
 274 samplerCube     return SAMPLERCUBE;
 275 sampler1DArray  KEYWORD(130, 130, SAMPLER1DARRAY);
 276 sampler2DArray  KEYWORD(130, 130, SAMPLER2DARRAY);
 277 sampler1DShadow return SAMPLER1DSHADOW;
 278 sampler2DShadow return SAMPLER2DSHADOW;
 279 samplerCubeShadow       KEYWORD(130, 130, SAMPLERCUBESHADOW);
 280 sampler1DArrayShadow    KEYWORD(130, 130, SAMPLER1DARRAYSHADOW);
 281 sampler2DArrayShadow    KEYWORD(130, 130, SAMPLER2DARRAYSHADOW);
 282 isampler1D              KEYWORD(130, 130, ISAMPLER1D);
 283 isampler2D              KEYWORD(130, 130, ISAMPLER2D);
 284 isampler3D              KEYWORD(130, 130, ISAMPLER3D);
 285 isamplerCube            KEYWORD(130, 130, ISAMPLERCUBE);
 286 isampler1DArray         KEYWORD(130, 130, ISAMPLER1DARRAY);
 287 isampler2DArray         KEYWORD(130, 130, ISAMPLER2DARRAY);
 288 usampler1D              KEYWORD(130, 130, USAMPLER1D);
 289 usampler2D              KEYWORD(130, 130, USAMPLER2D);
 290 usampler3D              KEYWORD(130, 130, USAMPLER3D);
 291 usamplerCube            KEYWORD(130, 130, USAMPLERCUBE);
 292 usampler1DArray         KEYWORD(130, 130, USAMPLER1DARRAY);
 293 usampler2DArray         KEYWORD(130, 130, USAMPLER2DARRAY);
 294
 295
 296 struct          return STRUCT;
 297 void            return VOID_TOK;
 298
 299 layout          {
 300                   if ((yyextra->language_version >= 140)
 301                       || yyextra->AMD_conservative_depth_enable
 302                       || yyextra->ARB_explicit_attrib_location_enable
 303                       || yyextra->ARB_fragment_coord_conventions_enable) {
 304                       return LAYOUT_TOK;
 305                    } else {
 306                       yylval->identifier = strdup(yytext);
 307                       return IDENTIFIER;
 308                    }
 309                 }
 310
 311 \+\+            return INC_OP;
 312 --              return DEC_OP;
 313 \<=             return LE_OP;
 314 >=              return GE_OP;
 315 ==              return EQ_OP;
 316 !=              return NE_OP;
 317 &&              return AND_OP;
 318 \|\|            return OR_OP;
 319 "^^"            return XOR_OP;
 320 "<<"            return LEFT_OP;
 321 ">>"            return RIGHT_OP;
 322
 323 \*=             return MUL_ASSIGN;
 324 \/=             return DIV_ASSIGN;
 325 \+=             return ADD_ASSIGN;
 326 \%=             return MOD_ASSIGN;
 327 \<\<=           return LEFT_ASSIGN;
 328 >>=             return RIGHT_ASSIGN;
 329 &=              return AND_ASSIGN;
 330 "^="            return XOR_ASSIGN;
 331 \|=             return OR_ASSIGN;
 332 -=              return SUB_ASSIGN;
 333
 334 [1-9][0-9]*[uU]?        {
 335                             return LITERAL_INTEGER(10);
 336                         }
 337 0[xX][0-9a-fA-F]+[uU]?  {
 338                             return LITERAL_INTEGER(16);
 339                         }
 340 0[0-7]*[uU]?            {
 341                             return LITERAL_INTEGER(8);
 342                         }
 343
 344 [0-9]+\.[0-9]+([eE][+-]?[0-9]+)?[fF]?   {
 345                             yylval->real = glsl_strtod(yytext, NULL);
 346                             return FLOATCONSTANT;
 347                         }
 348 \.[0-9]+([eE][+-]?[0-9]+)?[fF]?         {
 349                             yylval->real = glsl_strtod(yytext, NULL);
 350                             return FLOATCONSTANT;
 351                         }
 352 [0-9]+\.([eE][+-]?[0-9]+)?[fF]?         {
 353                             yylval->real = glsl_strtod(yytext, NULL);
 354                             return FLOATCONSTANT;
 355                         }
 356 [0-9]+[eE][+-]?[0-9]+[fF]?              {
 357                             yylval->real = glsl_strtod(yytext, NULL);
 358                             return FLOATCONSTANT;
 359                         }
 360 [0-9]+[fF]              {
 361                             yylval->real = glsl_strtod(yytext, NULL);
 362                             return FLOATCONSTANT;
 363                         }
 364
 365 true                    {
 366                             yylval->n = 1;
 367                             return BOOLCONSTANT;
 368                         }
 369 false                   {
 370                             yylval->n = 0;
 371                             return BOOLCONSTANT;
 372                         }
 373
 374
 375     /* Reserved words in GLSL 1.10. */
 376 asm             KEYWORD(110 || ES, 999, ASM);
 377 class           KEYWORD(110 || ES, 999, CLASS);
 378 union           KEYWORD(110 || ES, 999, UNION);
 379 enum            KEYWORD(110 || ES, 999, ENUM);
 380 typedef         KEYWORD(110 || ES, 999, TYPEDEF);
 381 template        KEYWORD(110 || ES, 999, TEMPLATE);
 382 this            KEYWORD(110 || ES, 999, THIS);
 383 packed          KEYWORD(110 || ES, 999, PACKED_TOK);
 384 goto            KEYWORD(110 || ES, 999, GOTO);
 385 switch          KEYWORD(110 || ES, 130, SWITCH);
 386 default         KEYWORD(110 || ES, 130, DEFAULT);
 387 inline          KEYWORD(110 || ES, 999, INLINE_TOK);
 388 noinline        KEYWORD(110 || ES, 999, NOINLINE);
 389 volatile        KEYWORD(110 || ES, 999, VOLATILE);
 390 public          KEYWORD(110 || ES, 999, PUBLIC_TOK);
 391 static          KEYWORD(110 || ES, 999, STATIC);
 392 extern          KEYWORD(110 || ES, 999, EXTERN);
 393 external        KEYWORD(110 || ES, 999, EXTERNAL);
 394 interface       KEYWORD(110 || ES, 999, INTERFACE);
 395 long            KEYWORD(110 || ES, 999, LONG_TOK);
 396 short           KEYWORD(110 || ES, 999, SHORT_TOK);
 397 double          KEYWORD(110 || ES, 400, DOUBLE_TOK);
 398 half            KEYWORD(110 || ES, 999, HALF);
 399 fixed           KEYWORD(110 || ES, 999, FIXED_TOK);
 400 unsigned        KEYWORD(110 || ES, 999, UNSIGNED);
 401 input           KEYWORD(110 || ES, 999, INPUT_TOK);
 402 output          KEYWORD(110 || ES, 999, OUTPUT);
 403 hvec2           KEYWORD(110 || ES, 999, HVEC2);
 404 hvec3           KEYWORD(110 || ES, 999, HVEC3);
 405 hvec4           KEYWORD(110 || ES, 999, HVEC4);
 406 dvec2           KEYWORD(110 || ES, 400, DVEC2);
 407 dvec3           KEYWORD(110 || ES, 400, DVEC3);
 408 dvec4           KEYWORD(110 || ES, 400, DVEC4);
 409 fvec2           KEYWORD(110 || ES, 999, FVEC2);
 410 fvec3           KEYWORD(110 || ES, 999, FVEC3);
 411 fvec4           KEYWORD(110 || ES, 999, FVEC4);
 412 sampler2DRect           return SAMPLER2DRECT;
 413 sampler3DRect           KEYWORD(110 || ES, 999, SAMPLER3DRECT);
 414 sampler2DRectShadow     return SAMPLER2DRECTSHADOW;
 415 sizeof          KEYWORD(110 || ES, 999, SIZEOF);
 416 cast            KEYWORD(110 || ES, 999, CAST);
 417 namespace       KEYWORD(110 || ES, 999, NAMESPACE);
 418 using           KEYWORD(110 || ES, 999, USING);
 419
 420     /* Additional reserved words in GLSL 1.20. */
 421 lowp            KEYWORD(120, 130 || ES, LOWP);
 422 mediump         KEYWORD(120, 130 || ES, MEDIUMP);
 423 highp           KEYWORD(120, 130 || ES, HIGHP);
 424 precision       KEYWORD(120, 130 || ES, PRECISION);
 425
 426     /* Additional reserved words in GLSL 1.30. */
 427 case            KEYWORD(130, 130, CASE);
 428 common          KEYWORD(130, 999, COMMON);
 429 partition       KEYWORD(130, 999, PARTITION);
 430 active          KEYWORD(130, 999, ACTIVE);
 431 superp          KEYWORD(130 || ES, 999, SUPERP);
 432 samplerBuffer   KEYWORD(130, 140, SAMPLERBUFFER);
 433 filter          KEYWORD(130, 999, FILTER);
 434 image1D         KEYWORD(130, 999, IMAGE1D);
 435 image2D         KEYWORD(130, 999, IMAGE2D);
 436 image3D         KEYWORD(130, 999, IMAGE3D);
 437 imageCube       KEYWORD(130, 999, IMAGECUBE);
 438 iimage1D        KEYWORD(130, 999, IIMAGE1D);
 439 iimage2D        KEYWORD(130, 999, IIMAGE2D);
 440 iimage3D        KEYWORD(130, 999, IIMAGE3D);
 441 iimageCube      KEYWORD(130, 999, IIMAGECUBE);
 442 uimage1D        KEYWORD(130, 999, UIMAGE1D);
 443 uimage2D        KEYWORD(130, 999, UIMAGE2D);
 444 uimage3D        KEYWORD(130, 999, UIMAGE3D);
 445 uimageCube      KEYWORD(130, 999, UIMAGECUBE);
 446 image1DArray    KEYWORD(130, 999, IMAGE1DARRAY);
 447 image2DArray    KEYWORD(130, 999, IMAGE2DARRAY);
 448 iimage1DArray   KEYWORD(130, 999, IIMAGE1DARRAY);
 449 iimage2DArray   KEYWORD(130, 999, IIMAGE2DARRAY);
 450 uimage1DArray   KEYWORD(130, 999, UIMAGE1DARRAY);
 451 uimage2DArray   KEYWORD(130, 999, UIMAGE2DARRAY);
 452 image1DShadow   KEYWORD(130, 999, IMAGE1DSHADOW);
 453 image2DShadow   KEYWORD(130, 999, IMAGE2DSHADOW);
 454 image1DArrayShadow KEYWORD(130, 999, IMAGE1DARRAYSHADOW);
 455 image2DArrayShadow KEYWORD(130, 999, IMAGE2DARRAYSHADOW);
 456 imageBuffer     KEYWORD(130, 999, IMAGEBUFFER);
 457 iimageBuffer    KEYWORD(130, 999, IIMAGEBUFFER);
 458 uimageBuffer    KEYWORD(130, 999, UIMAGEBUFFER);
 459 row_major       KEYWORD(130, 999, ROW_MAJOR);
 460
 461 [_a-zA-Z][_a-zA-Z0-9]*  {
 462                             struct _mesa_glsl_parse_state *state = yyextra;
 463                             void *ctx = state;
 464                             yylval->identifier = ralloc_strdup(ctx, yytext);
 465                             return classify_identifier(state, yytext);
 466                         }
 467
 468 .                       { return yytext[0]; }
 469
 470 %%
 471
 472 int
 473 classify_identifier(struct _mesa_glsl_parse_state *state, const char *name)
 474 {
 475    if (state->symbols->get_variable(name) || state->symbols->get_function(name))
 476       return IDENTIFIER;
 477    else if (state->symbols->get_type(name))
 478       return TYPE_IDENTIFIER;
 479    else
 480       return NEW_IDENTIFIER;
 481 }
 482
 483 void
 484 _mesa_glsl_lexer_ctor(struct _mesa_glsl_parse_state *state, const char *string)
 485 {
 486    yylex_init_extra(state, & state->scanner);
 487    yy_scan_string(string, state->scanner);
 488 }
 489
 490 void
 491 _mesa_glsl_lexer_dtor(struct _mesa_glsl_parse_state *state)
 492 {
 493    yylex_destroy(state->scanner);
 494 }