src/glsl/glsl_lexer.lpp

   1 %{
   2 /*
   3  * Copyright © 2008, 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include <ctype.h>
  25 #include "ast.h"
  26 #include "glsl_parser_extras.h"
  27 #include "glsl_parser.h"
  28
  29 #define YY_USER_ACTION                                          \
  30    do {                                                         \
  31       yylloc->source = 0;                                       \
  32       yylloc->first_column = yycolumn + 1;                      \
  33       yylloc->first_line = yylineno + 1;                        \
  34       yycolumn += yyleng;                                       \
  35    } while(0);
  36
  37 #define YY_USER_INIT yylineno = 0; yycolumn = 0;
  38
  39 #define IS_UINT (yytext[yyleng - 1] == 'u' || yytext[yyleng - 1] == 'U')
  40
  41 /* A macro for handling reserved words and keywords across language versions.
  42  *
  43  * Certain words start out as identifiers, become reserved words in
  44  * later language revisions, and finally become language keywords.
  45  *
  46  * For example, consider the following lexer rule:
  47  * samplerBuffer       KEYWORD(130, 140, SAMPLERBUFFER)
  48  *
  49  * This means that "samplerBuffer" will be treated as:
  50  * - a keyword (SAMPLERBUFFER token)         ...in GLSL >= 1.40
  51  * - a reserved word - error                 ...in GLSL >= 1.30
  52  * - an identifier                           ...in GLSL <  1.30
  53  */
  54 #define KEYWORD(reserved_version, allowed_version, token)               \
  55    do {                                                                 \
  56       if (yyextra->language_version >= allowed_version) {               \
  57          return token;                                                  \
  58       } else if (yyextra->language_version >= reserved_version) {       \
  59          _mesa_glsl_error(yylloc, yyextra,                              \
  60                           "Illegal use of reserved word `%s'", yytext); \
  61          return ERROR_TOK;                                              \
  62       } else {                                                          \
  63          yylval->identifier = strdup(yytext);                           \
  64          return IDENTIFIER;                                             \
  65       }                                                                 \
  66    } while (0)
  67
  68 /* The ES macro can be used in KEYWORD checks:
  69  *
  70  *    word      KEYWORD(110 || ES, 400, TOKEN)
  71  * ...means the word is reserved in GLSL ES 1.00, while
  72  *
  73  *    word      KEYWORD(110, 130 || ES, TOKEN)
  74  * ...means the word is a legal keyword in GLSL ES 1.00.
  75  */
  76 #define ES yyextra->es_shader
  77 %}
  78
  79 %option bison-bridge bison-locations reentrant noyywrap
  80 %option nounput noyy_top_state
  81 %option never-interactive
  82 %option prefix="_mesa_glsl_"
  83 %option extra-type="struct _mesa_glsl_parse_state *"
  84
  85 %x PP PRAGMA
  86
  87 DEC_INT         [1-9][0-9]*
  88 HEX_INT         0[xX][0-9a-fA-F]+
  89 OCT_INT         0[0-7]*
  90 INT             ({DEC_INT}|{HEX_INT}|{OCT_INT})
  91 SPC             [ \t]*
  92 SPCP            [ \t]+
  93 HASH            ^{SPC}#{SPC}
  94 %%
  95
  96 [ \r\t]+                ;
  97
  98     /* Preprocessor tokens. */
  99 ^[ \t]*#[ \t]*$                 ;
 100 ^[ \t]*#[ \t]*version           { BEGIN PP; return VERSION; }
 101 ^[ \t]*#[ \t]*extension         { BEGIN PP; return EXTENSION; }
 102 {HASH}line{SPCP}{INT}{SPCP}{INT}{SPC}$ {
 103                                    /* Eat characters until the first digit is
 104                                     * encountered
 105                                     */
 106                                    char *ptr = yytext;
 107                                    while (!isdigit(*ptr))
 108                                       ptr++;
 109
 110                                    /* Subtract one from the line number because
 111                                     * yylineno is zero-based instead of
 112                                     * one-based.
 113                                     */
 114                                    yylineno = strtol(ptr, &ptr, 0) - 1;
 115                                    yylloc->source = strtol(ptr, NULL, 0);
 116                                 }
 117 {HASH}line{SPCP}{INT}{SPC}$     {
 118                                    /* Eat characters until the first digit is
 119                                     * encountered
 120                                     */
 121                                    char *ptr = yytext;
 122                                    while (!isdigit(*ptr))
 123                                       ptr++;
 124
 125                                    /* Subtract one from the line number because
 126                                     * yylineno is zero-based instead of
 127                                     * one-based.
 128                                     */
 129                                    yylineno = strtol(ptr, &ptr, 0) - 1;
 130                                 }
 131 ^{SPC}#{SPC}pragma{SPCP}debug{SPC}\({SPC}on{SPC}\) {
 132                                   BEGIN PP;
 133                                   return PRAGMA_DEBUG_ON;
 134                                 }
 135 ^{SPC}#{SPC}pragma{SPCP}debug{SPC}\({SPC}off{SPC}\) {
 136                                   BEGIN PP;
 137                                   return PRAGMA_DEBUG_OFF;
 138                                 }
 139 ^{SPC}#{SPC}pragma{SPCP}optimize{SPC}\({SPC}on{SPC}\) {
 140                                   BEGIN PP;
 141                                   return PRAGMA_OPTIMIZE_ON;
 142                                 }
 143 ^{SPC}#{SPC}pragma{SPCP}optimize{SPC}\({SPC}off{SPC}\) {
 144                                   BEGIN PP;
 145                                   return PRAGMA_OPTIMIZE_OFF;
 146                                 }
 147 ^{SPC}#{SPC}pragma{SPCP}        { BEGIN PRAGMA; }
 148
 149 <PRAGMA>\n                      { BEGIN 0; yylineno++; yycolumn = 0; }
 150 <PRAGMA>.                       { }
 151
 152 <PP>\/\/[^\n]*                  { }
 153 <PP>[ \t\r]*                    { }
 154 <PP>:                           return COLON;
 155 <PP>[_a-zA-Z][_a-zA-Z0-9]*      {
 156                                    yylval->identifier = strdup(yytext);
 157                                    return IDENTIFIER;
 158                                 }
 159 <PP>[1-9][0-9]*                 {
 160                                     yylval->n = strtol(yytext, NULL, 10);
 161                                     return INTCONSTANT;
 162                                 }
 163 <PP>\n                          { BEGIN 0; yylineno++; yycolumn = 0; return EOL; }
 164
 165 \n              { yylineno++; yycolumn = 0; }
 166
 167 attribute       return ATTRIBUTE;
 168 const           return CONST_TOK;
 169 bool            return BOOL_TOK;
 170 float           return FLOAT_TOK;
 171 int             return INT_TOK;
 172 uint            KEYWORD(130, 130, UINT_TOK);
 173
 174 break           return BREAK;
 175 continue        return CONTINUE;
 176 do              return DO;
 177 while           return WHILE;
 178 else            return ELSE;
 179 for             return FOR;
 180 if              return IF;
 181 discard         return DISCARD;
 182 return          return RETURN;
 183
 184 bvec2           return BVEC2;
 185 bvec3           return BVEC3;
 186 bvec4           return BVEC4;
 187 ivec2           return IVEC2;
 188 ivec3           return IVEC3;
 189 ivec4           return IVEC4;
 190 uvec2           KEYWORD(130, 130, UVEC2);
 191 uvec3           KEYWORD(130, 130, UVEC3);
 192 uvec4           KEYWORD(130, 130, UVEC4);
 193 vec2            return VEC2;
 194 vec3            return VEC3;
 195 vec4            return VEC4;
 196 mat2            return MAT2X2;
 197 mat3            return MAT3X3;
 198 mat4            return MAT4X4;
 199 mat2x2          KEYWORD(120, 120, MAT2X2);
 200 mat2x3          KEYWORD(120, 120, MAT2X3);
 201 mat2x4          KEYWORD(120, 120, MAT2X4);
 202 mat3x2          KEYWORD(120, 120, MAT3X2);
 203 mat3x3          KEYWORD(120, 120, MAT3X3);
 204 mat3x4          KEYWORD(120, 120, MAT3X4);
 205 mat4x2          KEYWORD(120, 120, MAT4X2);
 206 mat4x3          KEYWORD(120, 120, MAT4X3);
 207 mat4x4          KEYWORD(120, 120, MAT4X4);
 208
 209 in              return IN_TOK;
 210 out             return OUT_TOK;
 211 inout           return INOUT_TOK;
 212 uniform         return UNIFORM;
 213 varying         return VARYING;
 214 centroid        KEYWORD(120, 120, CENTROID);
 215 invariant       KEYWORD(120 || ES, 120 || ES, INVARIANT);
 216 flat            KEYWORD(130 || ES, 130, FLAT);
 217 smooth          KEYWORD(130, 130, SMOOTH);
 218 noperspective   KEYWORD(130, 130, NOPERSPECTIVE);
 219
 220 sampler1D       return SAMPLER1D;
 221 sampler2D       return SAMPLER2D;
 222 sampler3D       return SAMPLER3D;
 223 samplerCube     return SAMPLERCUBE;
 224 sampler1DArray  KEYWORD(130, 130, SAMPLER1DARRAY);
 225 sampler2DArray  KEYWORD(130, 130, SAMPLER2DARRAY);
 226 sampler1DShadow return SAMPLER1DSHADOW;
 227 sampler2DShadow return SAMPLER2DSHADOW;
 228 samplerCubeShadow       KEYWORD(130, 130, SAMPLERCUBESHADOW);
 229 sampler1DArrayShadow    KEYWORD(130, 130, SAMPLER1DARRAYSHADOW);
 230 sampler2DArrayShadow    KEYWORD(130, 130, SAMPLER2DARRAYSHADOW);
 231 isampler1D              KEYWORD(130, 130, ISAMPLER1D);
 232 isampler2D              KEYWORD(130, 130, ISAMPLER2D);
 233 isampler3D              KEYWORD(130, 130, ISAMPLER3D);
 234 isamplerCube            KEYWORD(130, 130, ISAMPLERCUBE);
 235 isampler1DArray         KEYWORD(130, 130, ISAMPLER1DARRAY);
 236 isampler2DArray         KEYWORD(130, 130, ISAMPLER2DARRAY);
 237 usampler1D              KEYWORD(130, 130, USAMPLER1D);
 238 usampler2D              KEYWORD(130, 130, USAMPLER2D);
 239 usampler3D              KEYWORD(130, 130, USAMPLER3D);
 240 usamplerCube            KEYWORD(130, 130, USAMPLERCUBE);
 241 usampler1DArray         KEYWORD(130, 130, USAMPLER1DARRAY);
 242 usampler2DArray         KEYWORD(130, 130, USAMPLER2DARRAY);
 243
 244
 245 struct          return STRUCT;
 246 void            return VOID_TOK;
 247
 248 layout          {
 249                   if ((yyextra->language_version >= 140)
 250                       || yyextra->ARB_explicit_attrib_location_enable
 251                       || (yyextra->ARB_fragment_coord_conventions_enable)){
 252                       return LAYOUT_TOK;
 253                    } else {
 254                       yylval->identifier = strdup(yytext);
 255                       return IDENTIFIER;
 256                    }
 257                 }
 258
 259 \+\+            return INC_OP;
 260 --              return DEC_OP;
 261 \<=             return LE_OP;
 262 >=              return GE_OP;
 263 ==              return EQ_OP;
 264 !=              return NE_OP;
 265 &&              return AND_OP;
 266 \|\|            return OR_OP;
 267 "^^"            return XOR_OP;
 268 "<<"            return LEFT_OP;
 269 ">>"            return RIGHT_OP;
 270
 271 \*=             return MUL_ASSIGN;
 272 \/=             return DIV_ASSIGN;
 273 \+=             return ADD_ASSIGN;
 274 \%=             return MOD_ASSIGN;
 275 \<\<=           return LEFT_ASSIGN;
 276 >>=             return RIGHT_ASSIGN;
 277 &=              return AND_ASSIGN;
 278 "^="            return XOR_ASSIGN;
 279 \|=             return OR_ASSIGN;
 280 -=              return SUB_ASSIGN;
 281
 282 [1-9][0-9]*[uU]?        {
 283                             yylval->n = strtol(yytext, NULL, 10);
 284                             return IS_UINT ? UINTCONSTANT : INTCONSTANT;
 285                         }
 286 0[xX][0-9a-fA-F]+[uU]?  {
 287                             yylval->n = strtol(yytext + 2, NULL, 16);
 288                             return IS_UINT ? UINTCONSTANT : INTCONSTANT;
 289                         }
 290 0[0-7]*[uU]?            {
 291                             yylval->n = strtol(yytext, NULL, 8);
 292                             return IS_UINT ? UINTCONSTANT : INTCONSTANT;
 293                         }
 294
 295 [0-9]+\.[0-9]+([eE][+-]?[0-9]+)?[fF]?   {
 296                             yylval->real = strtod(yytext, NULL);
 297                             return FLOATCONSTANT;
 298                         }
 299 \.[0-9]+([eE][+-]?[0-9]+)?[fF]?         {
 300                             yylval->real = strtod(yytext, NULL);
 301                             return FLOATCONSTANT;
 302                         }
 303 [0-9]+\.([eE][+-]?[0-9]+)?[fF]?         {
 304                             yylval->real = strtod(yytext, NULL);
 305                             return FLOATCONSTANT;
 306                         }
 307 [0-9]+[eE][+-]?[0-9]+[fF]?              {
 308                             yylval->real = strtod(yytext, NULL);
 309                             return FLOATCONSTANT;
 310                         }
 311 [0-9]+[fF]              {
 312                             yylval->real = strtod(yytext, NULL);
 313                             return FLOATCONSTANT;
 314                         }
 315
 316 true                    {
 317                             yylval->n = 1;
 318                             return BOOLCONSTANT;
 319                         }
 320 false                   {
 321                             yylval->n = 0;
 322                             return BOOLCONSTANT;
 323                         }
 324
 325
 326     /* Reserved words in GLSL 1.10. */
 327 asm             KEYWORD(110 || ES, 999, ASM);
 328 class           KEYWORD(110 || ES, 999, CLASS);
 329 union           KEYWORD(110 || ES, 999, UNION);
 330 enum            KEYWORD(110 || ES, 999, ENUM);
 331 typedef         KEYWORD(110 || ES, 999, TYPEDEF);
 332 template        KEYWORD(110 || ES, 999, TEMPLATE);
 333 this            KEYWORD(110 || ES, 999, THIS);
 334 packed          KEYWORD(110 || ES, 999, PACKED_TOK);
 335 goto            KEYWORD(110 || ES, 999, GOTO);
 336 switch          KEYWORD(110 || ES, 130, SWITCH);
 337 default         KEYWORD(110 || ES, 130, DEFAULT);
 338 inline          KEYWORD(110 || ES, 999, INLINE_TOK);
 339 noinline        KEYWORD(110 || ES, 999, NOINLINE);
 340 volatile        KEYWORD(110 || ES, 999, VOLATILE);
 341 public          KEYWORD(110 || ES, 999, PUBLIC_TOK);
 342 static          KEYWORD(110 || ES, 999, STATIC);
 343 extern          KEYWORD(110 || ES, 999, EXTERN);
 344 external        KEYWORD(110 || ES, 999, EXTERNAL);
 345 interface       KEYWORD(110 || ES, 999, INTERFACE);
 346 long            KEYWORD(110 || ES, 999, LONG_TOK);
 347 short           KEYWORD(110 || ES, 999, SHORT_TOK);
 348 double          KEYWORD(110 || ES, 400, DOUBLE_TOK);
 349 half            KEYWORD(110 || ES, 999, HALF);
 350 fixed           KEYWORD(110 || ES, 999, FIXED_TOK);
 351 unsigned        KEYWORD(110 || ES, 999, UNSIGNED);
 352 input           KEYWORD(110 || ES, 999, INPUT_TOK);
 353 output          KEYWORD(110 || ES, 999, OUTPUT);
 354 hvec2           KEYWORD(110 || ES, 999, HVEC2);
 355 hvec3           KEYWORD(110 || ES, 999, HVEC3);
 356 hvec4           KEYWORD(110 || ES, 999, HVEC4);
 357 dvec2           KEYWORD(110 || ES, 400, DVEC2);
 358 dvec3           KEYWORD(110 || ES, 400, DVEC3);
 359 dvec4           KEYWORD(110 || ES, 400, DVEC4);
 360 fvec2           KEYWORD(110 || ES, 999, FVEC2);
 361 fvec3           KEYWORD(110 || ES, 999, FVEC3);
 362 fvec4           KEYWORD(110 || ES, 999, FVEC4);
 363 sampler2DRect           return SAMPLER2DRECT;
 364 sampler3DRect           KEYWORD(110 || ES, 999, SAMPLER3DRECT);
 365 sampler2DRectShadow     return SAMPLER2DRECTSHADOW;
 366 sizeof          KEYWORD(110 || ES, 999, SIZEOF);
 367 cast            KEYWORD(110 || ES, 999, CAST);
 368 namespace       KEYWORD(110 || ES, 999, NAMESPACE);
 369 using           KEYWORD(110 || ES, 999, USING);
 370
 371     /* Additional reserved words in GLSL 1.20. */
 372 lowp            KEYWORD(120, 130 || ES, LOWP);
 373 mediump         KEYWORD(120, 130 || ES, MEDIUMP);
 374 highp           KEYWORD(120, 130 || ES, HIGHP);
 375 precision       KEYWORD(120, 130 || ES, PRECISION);
 376
 377     /* Additional reserved words in GLSL 1.30. */
 378 case            KEYWORD(130, 130, CASE);
 379 common          KEYWORD(130, 999, COMMON);
 380 partition       KEYWORD(130, 999, PARTITION);
 381 active          KEYWORD(130, 999, ACTIVE);
 382 superp          KEYWORD(130 || ES, 999, SUPERP);
 383 samplerBuffer   KEYWORD(130, 140, SAMPLERBUFFER);
 384 filter          KEYWORD(130, 999, FILTER);
 385 image1D         KEYWORD(130, 999, IMAGE1D);
 386 image2D         KEYWORD(130, 999, IMAGE2D);
 387 image3D         KEYWORD(130, 999, IMAGE3D);
 388 imageCube       KEYWORD(130, 999, IMAGECUBE);
 389 iimage1D        KEYWORD(130, 999, IIMAGE1D);
 390 iimage2D        KEYWORD(130, 999, IIMAGE2D);
 391 iimage3D        KEYWORD(130, 999, IIMAGE3D);
 392 iimageCube      KEYWORD(130, 999, IIMAGECUBE);
 393 uimage1D        KEYWORD(130, 999, UIMAGE1D);
 394 uimage2D        KEYWORD(130, 999, UIMAGE2D);
 395 uimage3D        KEYWORD(130, 999, UIMAGE3D);
 396 uimageCube      KEYWORD(130, 999, UIMAGECUBE);
 397 image1DArray    KEYWORD(130, 999, IMAGE1DARRAY);
 398 image2DArray    KEYWORD(130, 999, IMAGE2DARRAY);
 399 iimage1DArray   KEYWORD(130, 999, IIMAGE1DARRAY);
 400 iimage2DArray   KEYWORD(130, 999, IIMAGE2DARRAY);
 401 uimage1DArray   KEYWORD(130, 999, UIMAGE1DARRAY);
 402 uimage2DArray   KEYWORD(130, 999, UIMAGE2DARRAY);
 403 image1DShadow   KEYWORD(130, 999, IMAGE1DSHADOW);
 404 image2DShadow   KEYWORD(130, 999, IMAGE2DSHADOW);
 405 image1DArrayShadow KEYWORD(130, 999, IMAGE1DARRAYSHADOW);
 406 image2DArrayShadow KEYWORD(130, 999, IMAGE2DARRAYSHADOW);
 407 imageBuffer     KEYWORD(130, 999, IMAGEBUFFER);
 408 iimageBuffer    KEYWORD(130, 999, IIMAGEBUFFER);
 409 uimageBuffer    KEYWORD(130, 999, UIMAGEBUFFER);
 410 row_major       KEYWORD(130, 999, ROW_MAJOR);
 411
 412 [_a-zA-Z][_a-zA-Z0-9]*  {
 413                             struct _mesa_glsl_parse_state *state = yyextra;
 414                             void *ctx = state;
 415                             yylval->identifier = talloc_strdup(ctx, yytext);
 416                             return IDENTIFIER;
 417                         }
 418
 419 .                       { return yytext[0]; }
 420
 421 %%
 422
 423 void
 424 _mesa_glsl_lexer_ctor(struct _mesa_glsl_parse_state *state, const char *string)
 425 {
 426    yylex_init_extra(state, & state->scanner);
 427    yy_scan_string(string, state->scanner);
 428 }
 429
 430 void
 431 _mesa_glsl_lexer_dtor(struct _mesa_glsl_parse_state *state)
 432 {
 433    yylex_destroy(state->scanner);
 434 }