src/glsl/glsl_parser.ypp

   1 %{
   2 /*
   3  * Copyright © 2008, 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <string.h>
  27 #include <assert.h>
  28
  29 #include "ast.h"
  30 #include "glsl_parser_extras.h"
  31 #include "glsl_types.h"
  32
  33 #define YYLEX_PARAM state->scanner
  34
  35 %}
  36
  37 %pure-parser
  38 %error-verbose
  39
  40 %locations
  41 %initial-action {
  42    @$.first_line = 1;
  43    @$.first_column = 1;
  44    @$.last_line = 1;
  45    @$.last_column = 1;
  46    @$.source = 0;
  47 }
  48
  49 %lex-param   {void *scanner}
  50 %parse-param {struct _mesa_glsl_parse_state *state}
  51
  52 %union {
  53    int n;
  54    float real;
  55    char *identifier;
  56
  57    struct ast_type_qualifier type_qualifier;
  58
  59    ast_node *node;
  60    ast_type_specifier *type_specifier;
  61    ast_fully_specified_type *fully_specified_type;
  62    ast_function *function;
  63    ast_parameter_declarator *parameter_declarator;
  64    ast_function_definition *function_definition;
  65    ast_compound_statement *compound_statement;
  66    ast_expression *expression;
  67    ast_declarator_list *declarator_list;
  68    ast_struct_specifier *struct_specifier;
  69    ast_declaration *declaration;
  70
  71    struct {
  72       ast_node *cond;
  73       ast_expression *rest;
  74    } for_rest_statement;
  75
  76    struct {
  77       ast_node *then_statement;
  78       ast_node *else_statement;
  79    } selection_rest_statement;
  80 }
  81
  82 %token ATTRIBUTE CONST_TOK BOOL_TOK FLOAT_TOK INT_TOK UINT_TOK
  83 %token BREAK CONTINUE DO ELSE FOR IF DISCARD RETURN SWITCH CASE DEFAULT
  84 %token BVEC2 BVEC3 BVEC4 IVEC2 IVEC3 IVEC4 UVEC2 UVEC3 UVEC4 VEC2 VEC3 VEC4
  85 %token CENTROID IN_TOK OUT_TOK INOUT_TOK UNIFORM VARYING
  86 %token NOPERSPECTIVE FLAT SMOOTH
  87 %token MAT2X2 MAT2X3 MAT2X4
  88 %token MAT3X2 MAT3X3 MAT3X4
  89 %token MAT4X2 MAT4X3 MAT4X4
  90 %token SAMPLER1D SAMPLER2D SAMPLER3D SAMPLERCUBE SAMPLER1DSHADOW SAMPLER2DSHADOW
  91 %token SAMPLERCUBESHADOW SAMPLER1DARRAY SAMPLER2DARRAY SAMPLER1DARRAYSHADOW
  92 %token SAMPLER2DARRAYSHADOW ISAMPLER1D ISAMPLER2D ISAMPLER3D ISAMPLERCUBE
  93 %token ISAMPLER1DARRAY ISAMPLER2DARRAY USAMPLER1D USAMPLER2D USAMPLER3D
  94 %token USAMPLERCUBE USAMPLER1DARRAY USAMPLER2DARRAY
  95 %token STRUCT VOID_TOK WHILE
  96 %token <identifier> IDENTIFIER
  97 %token <real> FLOATCONSTANT
  98 %token <n> INTCONSTANT UINTCONSTANT BOOLCONSTANT
  99 %token <identifier> FIELD_SELECTION
 100 %token LEFT_OP RIGHT_OP
 101 %token INC_OP DEC_OP LE_OP GE_OP EQ_OP NE_OP
 102 %token AND_OP OR_OP XOR_OP MUL_ASSIGN DIV_ASSIGN ADD_ASSIGN
 103 %token MOD_ASSIGN LEFT_ASSIGN RIGHT_ASSIGN AND_ASSIGN XOR_ASSIGN OR_ASSIGN
 104 %token SUB_ASSIGN
 105 %token INVARIANT
 106 %token LOWP MEDIUMP HIGHP SUPERP PRECISION
 107
 108 %token VERSION EXTENSION LINE COLON EOL INTERFACE OUTPUT
 109 %token PRAGMA_DEBUG_ON PRAGMA_DEBUG_OFF
 110 %token PRAGMA_OPTIMIZE_ON PRAGMA_OPTIMIZE_OFF
 111 %token PRAGMA_INVARIANT_ALL
 112 %token LAYOUT_TOK
 113
 114    /* Reserved words that are not actually used in the grammar.
 115     */
 116 %token ASM CLASS UNION ENUM TYPEDEF TEMPLATE THIS PACKED_TOK GOTO
 117 %token INLINE_TOK NOINLINE VOLATILE PUBLIC_TOK STATIC EXTERN EXTERNAL
 118 %token LONG_TOK SHORT_TOK DOUBLE_TOK HALF FIXED_TOK UNSIGNED INPUT_TOK OUPTUT
 119 %token HVEC2 HVEC3 HVEC4 DVEC2 DVEC3 DVEC4 FVEC2 FVEC3 FVEC4
 120 %token SAMPLER2DRECT SAMPLER3DRECT SAMPLER2DRECTSHADOW
 121 %token SIZEOF CAST NAMESPACE USING
 122
 123 %token ERROR_TOK
 124
 125 %token COMMON PARTITION ACTIVE SAMPLERBUFFER FILTER
 126 %token  IMAGE1D  IMAGE2D  IMAGE3D  IMAGECUBE  IMAGE1DARRAY  IMAGE2DARRAY
 127 %token IIMAGE1D IIMAGE2D IIMAGE3D IIMAGECUBE IIMAGE1DARRAY IIMAGE2DARRAY
 128 %token UIMAGE1D UIMAGE2D UIMAGE3D UIMAGECUBE UIMAGE1DARRAY UIMAGE2DARRAY
 129 %token IMAGE1DSHADOW IMAGE2DSHADOW IMAGEBUFFER IIMAGEBUFFER UIMAGEBUFFER
 130 %token IMAGE1DARRAYSHADOW IMAGE2DARRAYSHADOW
 131 %token ROW_MAJOR
 132
 133 %type <identifier> variable_identifier
 134 %type <node> statement
 135 %type <node> statement_list
 136 %type <node> simple_statement
 137 %type <n> precision_qualifier
 138 %type <type_qualifier> type_qualifier
 139 %type <type_qualifier> storage_qualifier
 140 %type <type_qualifier> interpolation_qualifier
 141 %type <type_qualifier> layout_qualifier
 142 %type <type_qualifier> layout_qualifier_id_list layout_qualifier_id
 143 %type <type_specifier> type_specifier
 144 %type <type_specifier> type_specifier_no_prec
 145 %type <type_specifier> type_specifier_nonarray
 146 %type <n> basic_type_specifier_nonarray
 147 %type <fully_specified_type> fully_specified_type
 148 %type <function> function_prototype
 149 %type <function> function_header
 150 %type <function> function_header_with_parameters
 151 %type <function> function_declarator
 152 %type <parameter_declarator> parameter_declarator
 153 %type <parameter_declarator> parameter_declaration
 154 %type <type_qualifier> parameter_qualifier
 155 %type <type_qualifier> parameter_type_qualifier
 156 %type <type_specifier> parameter_type_specifier
 157 %type <function_definition> function_definition
 158 %type <compound_statement> compound_statement_no_new_scope
 159 %type <compound_statement> compound_statement
 160 %type <node> statement_no_new_scope
 161 %type <node> expression_statement
 162 %type <expression> expression
 163 %type <expression> primary_expression
 164 %type <expression> assignment_expression
 165 %type <expression> conditional_expression
 166 %type <expression> logical_or_expression
 167 %type <expression> logical_xor_expression
 168 %type <expression> logical_and_expression
 169 %type <expression> inclusive_or_expression
 170 %type <expression> exclusive_or_expression
 171 %type <expression> and_expression
 172 %type <expression> equality_expression
 173 %type <expression> relational_expression
 174 %type <expression> shift_expression
 175 %type <expression> additive_expression
 176 %type <expression> multiplicative_expression
 177 %type <expression> unary_expression
 178 %type <expression> constant_expression
 179 %type <expression> integer_expression
 180 %type <expression> postfix_expression
 181 %type <expression> function_call_header_with_parameters
 182 %type <expression> function_call_header_no_parameters
 183 %type <expression> function_call_header
 184 %type <expression> function_call_generic
 185 %type <expression> function_call_or_method
 186 %type <expression> function_call
 187 %type <n> assignment_operator
 188 %type <n> unary_operator
 189 %type <expression> function_identifier
 190 %type <node> external_declaration
 191 %type <declarator_list> init_declarator_list
 192 %type <declarator_list> single_declaration
 193 %type <expression> initializer
 194 %type <node> declaration
 195 %type <node> declaration_statement
 196 %type <node> jump_statement
 197 %type <struct_specifier> struct_specifier
 198 %type <node> struct_declaration_list
 199 %type <declarator_list> struct_declaration
 200 %type <declaration> struct_declarator
 201 %type <declaration> struct_declarator_list
 202 %type <node> selection_statement
 203 %type <selection_rest_statement> selection_rest_statement
 204 %type <node> iteration_statement
 205 %type <node> condition
 206 %type <node> conditionopt
 207 %type <node> for_init_statement
 208 %type <for_rest_statement> for_rest_statement
 209 %%
 210
 211 translation_unit:
 212         version_statement extension_statement_list
 213         {
 214            _mesa_glsl_initialize_types(state);
 215         }
 216         external_declaration_list
 217         ;
 218
 219 version_statement:
 220         /* blank - no #version specified: defaults are already set */
 221         | VERSION INTCONSTANT EOL
 222         {
 223            switch ($2) {
 224            case 100:
 225               state->es_shader = true;
 226            case 110:
 227            case 120:
 228            case 130:
 229               /* FINISHME: Check against implementation support versions. */
 230               state->language_version = $2;
 231               state->version_string =
 232                  talloc_asprintf(state, "GLSL%s %d.%02d",
 233                                  state->es_shader ? " ES" : "",
 234                                  state->language_version / 100,
 235                                  state->language_version % 100);
 236               break;
 237            default:
 238               _mesa_glsl_error(& @2, state, "Shading language version"
 239                                "%u is not supported\n", $2);
 240               break;
 241            }
 242         }
 243         ;
 244
 245 pragma_statement:
 246         PRAGMA_DEBUG_ON EOL
 247         | PRAGMA_DEBUG_OFF EOL
 248         | PRAGMA_OPTIMIZE_ON EOL
 249         | PRAGMA_OPTIMIZE_OFF EOL
 250         | PRAGMA_INVARIANT_ALL EOL
 251         {
 252            if (state->language_version < 120) {
 253               _mesa_glsl_warning(& @1, state,
 254                                  "pragma `invariant(all)' not supported in %s",
 255                                  state->version_string);
 256            } else {
 257               state->all_invariant = true;
 258            }
 259         }
 260         ;
 261
 262 extension_statement_list:
 263
 264         | extension_statement_list extension_statement
 265         ;
 266
 267 extension_statement:
 268         EXTENSION IDENTIFIER COLON IDENTIFIER EOL
 269         {
 270            if (!_mesa_glsl_process_extension($2, & @2, $4, & @4, state)) {
 271               YYERROR;
 272            }
 273         }
 274         ;
 275
 276 external_declaration_list:
 277         external_declaration
 278         {
 279            /* FINISHME: The NULL test is required because pragmas are set to
 280             * FINISHME: NULL. (See production rule for external_declaration.)
 281             */
 282            if ($1 != NULL)
 283               state->translation_unit.push_tail(& $1->link);
 284         }
 285         | external_declaration_list external_declaration
 286         {
 287            /* FINISHME: The NULL test is required because pragmas are set to
 288             * FINISHME: NULL. (See production rule for external_declaration.)
 289             */
 290            if ($2 != NULL)
 291               state->translation_unit.push_tail(& $2->link);
 292         }
 293         ;
 294
 295 variable_identifier:
 296         IDENTIFIER
 297         ;
 298
 299 primary_expression:
 300         variable_identifier
 301         {
 302            void *ctx = state;
 303            $$ = new(ctx) ast_expression(ast_identifier, NULL, NULL, NULL);
 304            $$->set_location(yylloc);
 305            $$->primary_expression.identifier = $1;
 306         }
 307         | INTCONSTANT
 308         {
 309            void *ctx = state;
 310            $$ = new(ctx) ast_expression(ast_int_constant, NULL, NULL, NULL);
 311            $$->set_location(yylloc);
 312            $$->primary_expression.int_constant = $1;
 313         }
 314         | UINTCONSTANT
 315         {
 316            void *ctx = state;
 317            $$ = new(ctx) ast_expression(ast_uint_constant, NULL, NULL, NULL);
 318            $$->set_location(yylloc);
 319            $$->primary_expression.uint_constant = $1;
 320         }
 321         | FLOATCONSTANT
 322         {
 323            void *ctx = state;
 324            $$ = new(ctx) ast_expression(ast_float_constant, NULL, NULL, NULL);
 325            $$->set_location(yylloc);
 326            $$->primary_expression.float_constant = $1;
 327         }
 328         | BOOLCONSTANT
 329         {
 330            void *ctx = state;
 331            $$ = new(ctx) ast_expression(ast_bool_constant, NULL, NULL, NULL);
 332            $$->set_location(yylloc);
 333            $$->primary_expression.bool_constant = $1;
 334         }
 335         | '(' expression ')'
 336         {
 337            $$ = $2;
 338         }
 339         ;
 340
 341 postfix_expression:
 342         primary_expression
 343         | postfix_expression '[' integer_expression ']'
 344         {
 345            void *ctx = state;
 346            $$ = new(ctx) ast_expression(ast_array_index, $1, $3, NULL);
 347            $$->set_location(yylloc);
 348         }
 349         | function_call
 350         {
 351            $$ = $1;
 352         }
 353         | postfix_expression '.' IDENTIFIER
 354         {
 355            void *ctx = state;
 356            $$ = new(ctx) ast_expression(ast_field_selection, $1, NULL, NULL);
 357            $$->set_location(yylloc);
 358            $$->primary_expression.identifier = $3;
 359         }
 360         | postfix_expression INC_OP
 361         {
 362            void *ctx = state;
 363            $$ = new(ctx) ast_expression(ast_post_inc, $1, NULL, NULL);
 364            $$->set_location(yylloc);
 365         }
 366         | postfix_expression DEC_OP
 367         {
 368            void *ctx = state;
 369            $$ = new(ctx) ast_expression(ast_post_dec, $1, NULL, NULL);
 370            $$->set_location(yylloc);
 371         }
 372         ;
 373
 374 integer_expression:
 375         expression
 376         ;
 377
 378 function_call:
 379         function_call_or_method
 380         ;
 381
 382 function_call_or_method:
 383         function_call_generic
 384         | postfix_expression '.' function_call_generic
 385         {
 386            void *ctx = state;
 387            $$ = new(ctx) ast_expression(ast_field_selection, $1, $3, NULL);
 388            $$->set_location(yylloc);
 389         }
 390         ;
 391
 392 function_call_generic:
 393         function_call_header_with_parameters ')'
 394         | function_call_header_no_parameters ')'
 395         ;
 396
 397 function_call_header_no_parameters:
 398         function_call_header VOID_TOK
 399         | function_call_header
 400         ;
 401
 402 function_call_header_with_parameters:
 403         function_call_header assignment_expression
 404         {
 405            $$ = $1;
 406            $$->set_location(yylloc);
 407            $$->expressions.push_tail(& $2->link);
 408         }
 409         | function_call_header_with_parameters ',' assignment_expression
 410         {
 411            $$ = $1;
 412            $$->set_location(yylloc);
 413            $$->expressions.push_tail(& $3->link);
 414         }
 415         ;
 416
 417         // Grammar Note: Constructors look like functions, but lexical
 418         // analysis recognized most of them as keywords. They are now
 419         // recognized through "type_specifier".
 420 function_call_header:
 421         function_identifier '('
 422         ;
 423
 424 function_identifier:
 425         type_specifier
 426         {
 427            void *ctx = state;
 428            $$ = new(ctx) ast_function_expression($1);
 429            $$->set_location(yylloc);
 430         }
 431         | IDENTIFIER
 432         {
 433            void *ctx = state;
 434            ast_expression *callee = new(ctx) ast_expression($1);
 435            $$ = new(ctx) ast_function_expression(callee);
 436            $$->set_location(yylloc);
 437         }
 438         | FIELD_SELECTION
 439         {
 440            void *ctx = state;
 441            ast_expression *callee = new(ctx) ast_expression($1);
 442            $$ = new(ctx) ast_function_expression(callee);
 443            $$->set_location(yylloc);
 444         }
 445         ;
 446
 447         // Grammar Note: No traditional style type casts.
 448 unary_expression:
 449         postfix_expression
 450         | INC_OP unary_expression
 451         {
 452            void *ctx = state;
 453            $$ = new(ctx) ast_expression(ast_pre_inc, $2, NULL, NULL);
 454            $$->set_location(yylloc);
 455         }
 456         | DEC_OP unary_expression
 457         {
 458            void *ctx = state;
 459            $$ = new(ctx) ast_expression(ast_pre_dec, $2, NULL, NULL);
 460            $$->set_location(yylloc);
 461         }
 462         | unary_operator unary_expression
 463         {
 464            void *ctx = state;
 465            $$ = new(ctx) ast_expression($1, $2, NULL, NULL);
 466            $$->set_location(yylloc);
 467         }
 468         ;
 469
 470         // Grammar Note: No '*' or '&' unary ops. Pointers are not supported.
 471 unary_operator:
 472         '+'     { $$ = ast_plus; }
 473         | '-'   { $$ = ast_neg; }
 474         | '!'   { $$ = ast_logic_not; }
 475         | '~'   { $$ = ast_bit_not; }
 476         ;
 477
 478 multiplicative_expression:
 479         unary_expression
 480         | multiplicative_expression '*' unary_expression
 481         {
 482            void *ctx = state;
 483            $$ = new(ctx) ast_expression_bin(ast_mul, $1, $3);
 484            $$->set_location(yylloc);
 485         }
 486         | multiplicative_expression '/' unary_expression
 487         {
 488            void *ctx = state;
 489            $$ = new(ctx) ast_expression_bin(ast_div, $1, $3);
 490            $$->set_location(yylloc);
 491         }
 492         | multiplicative_expression '%' unary_expression
 493         {
 494            void *ctx = state;
 495            $$ = new(ctx) ast_expression_bin(ast_mod, $1, $3);
 496            $$->set_location(yylloc);
 497         }
 498         ;
 499
 500 additive_expression:
 501         multiplicative_expression
 502         | additive_expression '+' multiplicative_expression
 503         {
 504            void *ctx = state;
 505            $$ = new(ctx) ast_expression_bin(ast_add, $1, $3);
 506            $$->set_location(yylloc);
 507         }
 508         | additive_expression '-' multiplicative_expression
 509         {
 510            void *ctx = state;
 511            $$ = new(ctx) ast_expression_bin(ast_sub, $1, $3);
 512            $$->set_location(yylloc);
 513         }
 514         ;
 515
 516 shift_expression:
 517         additive_expression
 518         | shift_expression LEFT_OP additive_expression
 519         {
 520            void *ctx = state;
 521            $$ = new(ctx) ast_expression_bin(ast_lshift, $1, $3);
 522            $$->set_location(yylloc);
 523         }
 524         | shift_expression RIGHT_OP additive_expression
 525         {
 526            void *ctx = state;
 527            $$ = new(ctx) ast_expression_bin(ast_rshift, $1, $3);
 528            $$->set_location(yylloc);
 529         }
 530         ;
 531
 532 relational_expression:
 533         shift_expression
 534         | relational_expression '<' shift_expression
 535         {
 536            void *ctx = state;
 537            $$ = new(ctx) ast_expression_bin(ast_less, $1, $3);
 538            $$->set_location(yylloc);
 539         }
 540         | relational_expression '>' shift_expression
 541         {
 542            void *ctx = state;
 543            $$ = new(ctx) ast_expression_bin(ast_greater, $1, $3);
 544            $$->set_location(yylloc);
 545         }
 546         | relational_expression LE_OP shift_expression
 547         {
 548            void *ctx = state;
 549            $$ = new(ctx) ast_expression_bin(ast_lequal, $1, $3);
 550            $$->set_location(yylloc);
 551         }
 552         | relational_expression GE_OP shift_expression
 553         {
 554            void *ctx = state;
 555            $$ = new(ctx) ast_expression_bin(ast_gequal, $1, $3);
 556            $$->set_location(yylloc);
 557         }
 558         ;
 559
 560 equality_expression:
 561         relational_expression
 562         | equality_expression EQ_OP relational_expression
 563         {
 564            void *ctx = state;
 565            $$ = new(ctx) ast_expression_bin(ast_equal, $1, $3);
 566            $$->set_location(yylloc);
 567         }
 568         | equality_expression NE_OP relational_expression
 569         {
 570            void *ctx = state;
 571            $$ = new(ctx) ast_expression_bin(ast_nequal, $1, $3);
 572            $$->set_location(yylloc);
 573         }
 574         ;
 575
 576 and_expression:
 577         equality_expression
 578         | and_expression '&' equality_expression
 579         {
 580            void *ctx = state;
 581            $$ = new(ctx) ast_expression_bin(ast_bit_and, $1, $3);
 582            $$->set_location(yylloc);
 583         }
 584         ;
 585
 586 exclusive_or_expression:
 587         and_expression
 588         | exclusive_or_expression '^' and_expression
 589         {
 590            void *ctx = state;
 591            $$ = new(ctx) ast_expression_bin(ast_bit_xor, $1, $3);
 592            $$->set_location(yylloc);
 593         }
 594         ;
 595
 596 inclusive_or_expression:
 597         exclusive_or_expression
 598         | inclusive_or_expression '|' exclusive_or_expression
 599         {
 600            void *ctx = state;
 601            $$ = new(ctx) ast_expression_bin(ast_bit_or, $1, $3);
 602            $$->set_location(yylloc);
 603         }
 604         ;
 605
 606 logical_and_expression:
 607         inclusive_or_expression
 608         | logical_and_expression AND_OP inclusive_or_expression
 609         {
 610            void *ctx = state;
 611            $$ = new(ctx) ast_expression_bin(ast_logic_and, $1, $3);
 612            $$->set_location(yylloc);
 613         }
 614         ;
 615
 616 logical_xor_expression:
 617         logical_and_expression
 618         | logical_xor_expression XOR_OP logical_and_expression
 619         {
 620            void *ctx = state;
 621            $$ = new(ctx) ast_expression_bin(ast_logic_xor, $1, $3);
 622            $$->set_location(yylloc);
 623         }
 624         ;
 625
 626 logical_or_expression:
 627         logical_xor_expression
 628         | logical_or_expression OR_OP logical_xor_expression
 629         {
 630            void *ctx = state;
 631            $$ = new(ctx) ast_expression_bin(ast_logic_or, $1, $3);
 632            $$->set_location(yylloc);
 633         }
 634         ;
 635
 636 conditional_expression:
 637         logical_or_expression
 638         | logical_or_expression '?' expression ':' assignment_expression
 639         {
 640            void *ctx = state;
 641            $$ = new(ctx) ast_expression(ast_conditional, $1, $3, $5);
 642            $$->set_location(yylloc);
 643         }
 644         ;
 645
 646 assignment_expression:
 647         conditional_expression
 648         | unary_expression assignment_operator assignment_expression
 649         {
 650            void *ctx = state;
 651            $$ = new(ctx) ast_expression($2, $1, $3, NULL);
 652            $$->set_location(yylloc);
 653         }
 654         ;
 655
 656 assignment_operator:
 657         '='             { $$ = ast_assign; }
 658         | MUL_ASSIGN    { $$ = ast_mul_assign; }
 659         | DIV_ASSIGN    { $$ = ast_div_assign; }
 660         | MOD_ASSIGN    { $$ = ast_mod_assign; }
 661         | ADD_ASSIGN    { $$ = ast_add_assign; }
 662         | SUB_ASSIGN    { $$ = ast_sub_assign; }
 663         | LEFT_ASSIGN   { $$ = ast_ls_assign; }
 664         | RIGHT_ASSIGN  { $$ = ast_rs_assign; }
 665         | AND_ASSIGN    { $$ = ast_and_assign; }
 666         | XOR_ASSIGN    { $$ = ast_xor_assign; }
 667         | OR_ASSIGN     { $$ = ast_or_assign; }
 668         ;
 669
 670 expression:
 671         assignment_expression
 672         {
 673            $$ = $1;
 674         }
 675         | expression ',' assignment_expression
 676         {
 677            void *ctx = state;
 678            if ($1->oper != ast_sequence) {
 679               $$ = new(ctx) ast_expression(ast_sequence, NULL, NULL, NULL);
 680               $$->set_location(yylloc);
 681               $$->expressions.push_tail(& $1->link);
 682            } else {
 683               $$ = $1;
 684            }
 685
 686            $$->expressions.push_tail(& $3->link);
 687         }
 688         ;
 689
 690 constant_expression:
 691         conditional_expression
 692         ;
 693
 694 declaration:
 695         function_prototype ';'
 696         {
 697            $$ = $1;
 698         }
 699         | init_declarator_list ';'
 700         {
 701            $$ = $1;
 702         }
 703         | PRECISION precision_qualifier type_specifier_no_prec ';'
 704         {
 705            $3->precision = $2;
 706            $3->is_precision_statement = true;
 707            $$ = $3;
 708         }
 709         ;
 710
 711 function_prototype:
 712         function_declarator ')'
 713         ;
 714
 715 function_declarator:
 716         function_header
 717         | function_header_with_parameters
 718         ;
 719
 720 function_header_with_parameters:
 721         function_header parameter_declaration
 722         {
 723            $$ = $1;
 724            $$->parameters.push_tail(& $2->link);
 725         }
 726         | function_header_with_parameters ',' parameter_declaration
 727         {
 728            $$ = $1;
 729            $$->parameters.push_tail(& $3->link);
 730         }
 731         ;
 732
 733 function_header:
 734         fully_specified_type IDENTIFIER '('
 735         {
 736            void *ctx = state;
 737            $$ = new(ctx) ast_function();
 738            $$->set_location(yylloc);
 739            $$->return_type = $1;
 740            $$->identifier = $2;
 741         }
 742         ;
 743
 744 parameter_declarator:
 745         type_specifier IDENTIFIER
 746         {
 747            void *ctx = state;
 748            $$ = new(ctx) ast_parameter_declarator();
 749            $$->set_location(yylloc);
 750            $$->type = new(ctx) ast_fully_specified_type();
 751            $$->type->set_location(yylloc);
 752            $$->type->specifier = $1;
 753            $$->identifier = $2;
 754         }
 755         | type_specifier IDENTIFIER '[' constant_expression ']'
 756         {
 757            void *ctx = state;
 758            $$ = new(ctx) ast_parameter_declarator();
 759            $$->set_location(yylloc);
 760            $$->type = new(ctx) ast_fully_specified_type();
 761            $$->type->set_location(yylloc);
 762            $$->type->specifier = $1;
 763            $$->identifier = $2;
 764            $$->is_array = true;
 765            $$->array_size = $4;
 766         }
 767         ;
 768
 769 parameter_declaration:
 770         parameter_type_qualifier parameter_qualifier parameter_declarator
 771         {
 772            $1.flags.i |= $2.flags.i;
 773
 774            $$ = $3;
 775            $$->type->qualifier = $1;
 776         }
 777         | parameter_qualifier parameter_declarator
 778         {
 779            $$ = $2;
 780            $$->type->qualifier = $1;
 781         }
 782         | parameter_type_qualifier parameter_qualifier parameter_type_specifier
 783         {
 784            void *ctx = state;
 785            $1.flags.i |= $2.flags.i;
 786
 787            $$ = new(ctx) ast_parameter_declarator();
 788            $$->set_location(yylloc);
 789            $$->type = new(ctx) ast_fully_specified_type();
 790            $$->type->qualifier = $1;
 791            $$->type->specifier = $3;
 792         }
 793         | parameter_qualifier parameter_type_specifier
 794         {
 795            void *ctx = state;
 796            $$ = new(ctx) ast_parameter_declarator();
 797            $$->set_location(yylloc);
 798            $$->type = new(ctx) ast_fully_specified_type();
 799            $$->type->qualifier = $1;
 800            $$->type->specifier = $2;
 801         }
 802         ;
 803
 804 parameter_qualifier:
 805         /* empty */
 806         {
 807            memset(& $$, 0, sizeof($$));
 808         }
 809         | IN_TOK
 810         {
 811            memset(& $$, 0, sizeof($$));
 812            $$.flags.q.in = 1;
 813         }
 814         | OUT_TOK
 815         {
 816            memset(& $$, 0, sizeof($$));
 817            $$.flags.q.out = 1;
 818         }
 819         | INOUT_TOK
 820         {
 821            memset(& $$, 0, sizeof($$));
 822            $$.flags.q.in = 1;
 823            $$.flags.q.out = 1;
 824         }
 825         ;
 826
 827 parameter_type_specifier:
 828         type_specifier
 829         ;
 830
 831 init_declarator_list:
 832         single_declaration
 833         | init_declarator_list ',' IDENTIFIER
 834         {
 835            void *ctx = state;
 836            ast_declaration *decl = new(ctx) ast_declaration($3, false, NULL, NULL);
 837            decl->set_location(yylloc);
 838
 839            $$ = $1;
 840            $$->declarations.push_tail(&decl->link);
 841         }
 842         | init_declarator_list ',' IDENTIFIER '[' ']'
 843         {
 844            void *ctx = state;
 845            ast_declaration *decl = new(ctx) ast_declaration($3, true, NULL, NULL);
 846            decl->set_location(yylloc);
 847
 848            $$ = $1;
 849            $$->declarations.push_tail(&decl->link);
 850         }
 851         | init_declarator_list ',' IDENTIFIER '[' constant_expression ']'
 852         {
 853            void *ctx = state;
 854            ast_declaration *decl = new(ctx) ast_declaration($3, true, $5, NULL);
 855            decl->set_location(yylloc);
 856
 857            $$ = $1;
 858            $$->declarations.push_tail(&decl->link);
 859         }
 860         | init_declarator_list ',' IDENTIFIER '[' ']' '=' initializer
 861         {
 862            void *ctx = state;
 863            ast_declaration *decl = new(ctx) ast_declaration($3, true, NULL, $7);
 864            decl->set_location(yylloc);
 865
 866            $$ = $1;
 867            $$->declarations.push_tail(&decl->link);
 868         }
 869         | init_declarator_list ',' IDENTIFIER '[' constant_expression ']' '=' initializer
 870         {
 871            void *ctx = state;
 872            ast_declaration *decl = new(ctx) ast_declaration($3, true, $5, $8);
 873            decl->set_location(yylloc);
 874
 875            $$ = $1;
 876            $$->declarations.push_tail(&decl->link);
 877         }
 878         | init_declarator_list ',' IDENTIFIER '=' initializer
 879         {
 880            void *ctx = state;
 881            ast_declaration *decl = new(ctx) ast_declaration($3, false, NULL, $5);
 882            decl->set_location(yylloc);
 883
 884            $$ = $1;
 885            $$->declarations.push_tail(&decl->link);
 886         }
 887         ;
 888
 889         // Grammar Note: No 'enum', or 'typedef'.
 890 single_declaration:
 891         fully_specified_type
 892         {
 893            void *ctx = state;
 894            if ($1->specifier->type_specifier != ast_struct) {
 895               _mesa_glsl_error(& @1, state, "empty declaration list\n");
 896               YYERROR;
 897            } else {
 898               $$ = new(ctx) ast_declarator_list($1);
 899               $$->set_location(yylloc);
 900            }
 901         }
 902         | fully_specified_type IDENTIFIER
 903         {
 904            void *ctx = state;
 905            ast_declaration *decl = new(ctx) ast_declaration($2, false, NULL, NULL);
 906
 907            $$ = new(ctx) ast_declarator_list($1);
 908            $$->set_location(yylloc);
 909            $$->declarations.push_tail(&decl->link);
 910         }
 911         | fully_specified_type IDENTIFIER '[' ']'
 912         {
 913            void *ctx = state;
 914            ast_declaration *decl = new(ctx) ast_declaration($2, true, NULL, NULL);
 915
 916            $$ = new(ctx) ast_declarator_list($1);
 917            $$->set_location(yylloc);
 918            $$->declarations.push_tail(&decl->link);
 919         }
 920         | fully_specified_type IDENTIFIER '[' constant_expression ']'
 921         {
 922            void *ctx = state;
 923            ast_declaration *decl = new(ctx) ast_declaration($2, true, $4, NULL);
 924
 925            $$ = new(ctx) ast_declarator_list($1);
 926            $$->set_location(yylloc);
 927            $$->declarations.push_tail(&decl->link);
 928         }
 929         | fully_specified_type IDENTIFIER '[' ']' '=' initializer
 930         {
 931            void *ctx = state;
 932            ast_declaration *decl = new(ctx) ast_declaration($2, true, NULL, $6);
 933
 934            $$ = new(ctx) ast_declarator_list($1);
 935            $$->set_location(yylloc);
 936            $$->declarations.push_tail(&decl->link);
 937         }
 938         | fully_specified_type IDENTIFIER '[' constant_expression ']' '=' initializer
 939         {
 940            void *ctx = state;
 941            ast_declaration *decl = new(ctx) ast_declaration($2, true, $4, $7);
 942
 943            $$ = new(ctx) ast_declarator_list($1);
 944            $$->set_location(yylloc);
 945            $$->declarations.push_tail(&decl->link);
 946         }
 947         | fully_specified_type IDENTIFIER '=' initializer
 948         {
 949            void *ctx = state;
 950            ast_declaration *decl = new(ctx) ast_declaration($2, false, NULL, $4);
 951
 952            $$ = new(ctx) ast_declarator_list($1);
 953            $$->set_location(yylloc);
 954            $$->declarations.push_tail(&decl->link);
 955         }
 956         | INVARIANT IDENTIFIER // Vertex only.
 957         {
 958            void *ctx = state;
 959            ast_declaration *decl = new(ctx) ast_declaration($2, false, NULL, NULL);
 960
 961            $$ = new(ctx) ast_declarator_list(NULL);
 962            $$->set_location(yylloc);
 963            $$->invariant = true;
 964
 965            $$->declarations.push_tail(&decl->link);
 966         }
 967         ;
 968
 969 fully_specified_type:
 970         type_specifier
 971         {
 972            void *ctx = state;
 973            $$ = new(ctx) ast_fully_specified_type();
 974            $$->set_location(yylloc);
 975            $$->specifier = $1;
 976         }
 977         | type_qualifier type_specifier
 978         {
 979            void *ctx = state;
 980            $$ = new(ctx) ast_fully_specified_type();
 981            $$->set_location(yylloc);
 982            $$->qualifier = $1;
 983            $$->specifier = $2;
 984         }
 985         ;
 986
 987 layout_qualifier:
 988         LAYOUT_TOK '(' layout_qualifier_id_list ')'
 989         {
 990           $$ = $3;
 991         }
 992         ;
 993
 994 layout_qualifier_id_list:
 995         layout_qualifier_id
 996         | layout_qualifier_id_list ',' layout_qualifier_id
 997         {
 998            if (($1.flags.i & $3.flags.i) != 0) {
 999               _mesa_glsl_error(& @3, state,
1000                                "duplicate layout qualifiers used\n");
1001               YYERROR;
1002            }
1003
1004            $$.flags.i = $1.flags.i | $3.flags.i;
1005
1006            if ($1.flags.q.explicit_location)
1007               $$.location = $1.location;
1008
1009            if ($3.flags.q.explicit_location)
1010               $$.location = $3.location;
1011         }
1012         ;
1013
1014 layout_qualifier_id:
1015         IDENTIFIER
1016         {
1017            bool got_one = false;
1018
1019            memset(& $$, 0, sizeof($$));
1020
1021            if (state->ARB_fragment_coord_conventions_enable) {
1022               if (strcmp($1, "origin_upper_left") == 0) {
1023                  got_one = true;
1024                  $$.flags.q.origin_upper_left = 1;
1025               } else if (strcmp($1, "pixel_center_integer") == 0) {
1026                  got_one = true;
1027                  $$.flags.q.pixel_center_integer = 1;
1028               }
1029            }
1030
1031            /* If the identifier didn't match any known layout identifiers,
1032             * emit an error.
1033             */
1034            if (!got_one) {
1035               _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1036                                "`%s'\n", $1);
1037               YYERROR;
1038            } else if (state->ARB_fragment_coord_conventions_warn) {
1039               _mesa_glsl_warning(& @1, state,
1040                                  "GL_ARB_fragment_coord_conventions layout "
1041                                  "identifier `%s' used\n", $1);
1042            }
1043         }
1044         | IDENTIFIER '=' INTCONSTANT
1045         {
1046            bool got_one = false;
1047
1048            memset(& $$, 0, sizeof($$));
1049
1050            if (state->ARB_explicit_attrib_location_enable) {
1051               /* FINISHME: Handle 'index' once GL_ARB_blend_func_exteneded and
1052                * FINISHME: GLSL 1.30 (or later) are supported.
1053                */
1054               if (strcmp("location", $1) == 0) {
1055                  got_one = true;
1056
1057                  $$.flags.q.explicit_location = 1;
1058
1059                  if ($3 >= 0) {
1060                     $$.location = $3;
1061                  } else {
1062                     _mesa_glsl_error(& @3, state,
1063                                      "invalid location %d specified\n", $3);
1064                     YYERROR;
1065                  }
1066               }
1067            }
1068
1069            /* If the identifier didn't match any known layout identifiers,
1070             * emit an error.
1071             */
1072            if (!got_one) {
1073               _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1074                                "`%s'\n", $1);
1075               YYERROR;
1076            } else if (state->ARB_explicit_attrib_location_warn) {
1077               _mesa_glsl_warning(& @1, state,
1078                                  "GL_ARB_explicit_attrib_location layout "
1079                                  "identifier `%s' used\n", $1);
1080            }
1081         }
1082         ;
1083
1084 interpolation_qualifier:
1085         SMOOTH
1086         {
1087            memset(& $$, 0, sizeof($$));
1088            $$.flags.q.smooth = 1;
1089         }
1090         | FLAT
1091         {
1092            memset(& $$, 0, sizeof($$));
1093            $$.flags.q.flat = 1;
1094         }
1095         | NOPERSPECTIVE
1096         {
1097            memset(& $$, 0, sizeof($$));
1098            $$.flags.q.noperspective = 1;
1099         }
1100         ;
1101
1102 parameter_type_qualifier:
1103         CONST_TOK
1104         {
1105            memset(& $$, 0, sizeof($$));
1106            $$.flags.q.constant = 1;
1107         }
1108         ;
1109
1110 type_qualifier:
1111         storage_qualifier
1112         | layout_qualifier
1113         | layout_qualifier storage_qualifier
1114         {
1115            $$ = $1;
1116            $$.flags.i |= $2.flags.i;
1117         }
1118         | interpolation_qualifier
1119         | interpolation_qualifier storage_qualifier
1120         {
1121            $$ = $1;
1122            $$.flags.i |= $2.flags.i;
1123         }
1124         | INVARIANT storage_qualifier
1125         {
1126            $$ = $2;
1127            $$.flags.q.invariant = 1;
1128         }
1129         | INVARIANT interpolation_qualifier storage_qualifier
1130         {
1131            $$ = $2;
1132            $$.flags.i |= $3.flags.i;
1133            $$.flags.q.invariant = 1;
1134         }
1135         | INVARIANT
1136         {
1137            memset(& $$, 0, sizeof($$));
1138            $$.flags.q.invariant = 1;
1139         }
1140         ;
1141
1142 storage_qualifier:
1143         CONST_TOK
1144         {
1145            memset(& $$, 0, sizeof($$));
1146            $$.flags.q.constant = 1;
1147         }
1148         | ATTRIBUTE
1149         {
1150            memset(& $$, 0, sizeof($$));
1151            $$.flags.q.attribute = 1;
1152         }
1153         | VARYING
1154         {
1155            memset(& $$, 0, sizeof($$));
1156            $$.flags.q.varying = 1;
1157         }
1158         | CENTROID VARYING
1159         {
1160            memset(& $$, 0, sizeof($$));
1161            $$.flags.q.centroid = 1;
1162            $$.flags.q.varying = 1;
1163         }
1164         | IN_TOK
1165         {
1166            memset(& $$, 0, sizeof($$));
1167            $$.flags.q.in = 1;
1168         }
1169         | OUT_TOK
1170         {
1171            memset(& $$, 0, sizeof($$));
1172            $$.flags.q.out = 1;
1173         }
1174         | CENTROID IN_TOK
1175         {
1176            memset(& $$, 0, sizeof($$));
1177            $$.flags.q.centroid = 1; $$.flags.q.in = 1;
1178         }
1179         | CENTROID OUT_TOK
1180         {
1181            memset(& $$, 0, sizeof($$));
1182            $$.flags.q.centroid = 1; $$.flags.q.out = 1;
1183         }
1184         | UNIFORM
1185         {
1186            memset(& $$, 0, sizeof($$));
1187            $$.flags.q.uniform = 1;
1188         }
1189         ;
1190
1191 type_specifier:
1192         type_specifier_no_prec
1193         {
1194            $$ = $1;
1195         }
1196         | precision_qualifier type_specifier_no_prec
1197         {
1198            $$ = $2;
1199            $$->precision = $1;
1200         }
1201         ;
1202
1203 type_specifier_no_prec:
1204         type_specifier_nonarray
1205         | type_specifier_nonarray '[' ']'
1206         {
1207            $$ = $1;
1208            $$->is_array = true;
1209            $$->array_size = NULL;
1210         }
1211         | type_specifier_nonarray '[' constant_expression ']'
1212         {
1213            $$ = $1;
1214            $$->is_array = true;
1215            $$->array_size = $3;
1216         }
1217         ;
1218
1219 type_specifier_nonarray:
1220         basic_type_specifier_nonarray
1221         {
1222            void *ctx = state;
1223            $$ = new(ctx) ast_type_specifier($1);
1224            $$->set_location(yylloc);
1225         }
1226         | struct_specifier
1227         {
1228            void *ctx = state;
1229            $$ = new(ctx) ast_type_specifier($1);
1230            $$->set_location(yylloc);
1231         }
1232         | IDENTIFIER
1233         {
1234            void *ctx = state;
1235            $$ = new(ctx) ast_type_specifier($1);
1236            $$->set_location(yylloc);
1237         }
1238         ;
1239
1240 basic_type_specifier_nonarray:
1241         VOID_TOK                { $$ = ast_void; }
1242         | FLOAT_TOK             { $$ = ast_float; }
1243         | INT_TOK               { $$ = ast_int; }
1244         | UINT_TOK              { $$ = ast_uint; }
1245         | BOOL_TOK              { $$ = ast_bool; }
1246         | VEC2                  { $$ = ast_vec2; }
1247         | VEC3                  { $$ = ast_vec3; }
1248         | VEC4                  { $$ = ast_vec4; }
1249         | BVEC2                 { $$ = ast_bvec2; }
1250         | BVEC3                 { $$ = ast_bvec3; }
1251         | BVEC4                 { $$ = ast_bvec4; }
1252         | IVEC2                 { $$ = ast_ivec2; }
1253         | IVEC3                 { $$ = ast_ivec3; }
1254         | IVEC4                 { $$ = ast_ivec4; }
1255         | UVEC2                 { $$ = ast_uvec2; }
1256         | UVEC3                 { $$ = ast_uvec3; }
1257         | UVEC4                 { $$ = ast_uvec4; }
1258         | MAT2X2                { $$ = ast_mat2; }
1259         | MAT2X3                { $$ = ast_mat2x3; }
1260         | MAT2X4                { $$ = ast_mat2x4; }
1261         | MAT3X2                { $$ = ast_mat3x2; }
1262         | MAT3X3                { $$ = ast_mat3; }
1263         | MAT3X4                { $$ = ast_mat3x4; }
1264         | MAT4X2                { $$ = ast_mat4x2; }
1265         | MAT4X3                { $$ = ast_mat4x3; }
1266         | MAT4X4                { $$ = ast_mat4; }
1267         | SAMPLER1D             { $$ = ast_sampler1d; }
1268         | SAMPLER2D             { $$ = ast_sampler2d; }
1269         | SAMPLER2DRECT         { $$ = ast_sampler2drect; }
1270         | SAMPLER3D             { $$ = ast_sampler3d; }
1271         | SAMPLERCUBE           { $$ = ast_samplercube; }
1272         | SAMPLER1DSHADOW       { $$ = ast_sampler1dshadow; }
1273         | SAMPLER2DSHADOW       { $$ = ast_sampler2dshadow; }
1274         | SAMPLER2DRECTSHADOW   { $$ = ast_sampler2drectshadow; }
1275         | SAMPLERCUBESHADOW     { $$ = ast_samplercubeshadow; }
1276         | SAMPLER1DARRAY        { $$ = ast_sampler1darray; }
1277         | SAMPLER2DARRAY        { $$ = ast_sampler2darray; }
1278         | SAMPLER1DARRAYSHADOW  { $$ = ast_sampler1darrayshadow; }
1279         | SAMPLER2DARRAYSHADOW  { $$ = ast_sampler2darrayshadow; }
1280         | ISAMPLER1D            { $$ = ast_isampler1d; }
1281         | ISAMPLER2D            { $$ = ast_isampler2d; }
1282         | ISAMPLER3D            { $$ = ast_isampler3d; }
1283         | ISAMPLERCUBE          { $$ = ast_isamplercube; }
1284         | ISAMPLER1DARRAY       { $$ = ast_isampler1darray; }
1285         | ISAMPLER2DARRAY       { $$ = ast_isampler2darray; }
1286         | USAMPLER1D            { $$ = ast_usampler1d; }
1287         | USAMPLER2D            { $$ = ast_usampler2d; }
1288         | USAMPLER3D            { $$ = ast_usampler3d; }
1289         | USAMPLERCUBE          { $$ = ast_usamplercube; }
1290         | USAMPLER1DARRAY       { $$ = ast_usampler1darray; }
1291         | USAMPLER2DARRAY       { $$ = ast_usampler2darray; }
1292         ;
1293
1294 precision_qualifier:
1295         HIGHP     {
1296                      if (!state->es_shader && state->language_version < 130)
1297                         _mesa_glsl_error(& @1, state,
1298                                          "precision qualifier forbidden "
1299                                          "in %s (1.30 or later "
1300                                          "required)\n",
1301                                          state->version_string);
1302
1303                      $$ = ast_precision_high;
1304                   }
1305         | MEDIUMP {
1306                      if (!state->es_shader && state->language_version < 130)
1307                         _mesa_glsl_error(& @1, state,
1308                                          "precision qualifier forbidden "
1309                                          "in %s (1.30 or later "
1310                                          "required)\n",
1311                                          state->version_string);
1312
1313                      $$ = ast_precision_medium;
1314                   }
1315         | LOWP    {
1316                      if (!state->es_shader && state->language_version < 130)
1317                         _mesa_glsl_error(& @1, state,
1318                                          "precision qualifier forbidden "
1319                                          "in %s (1.30 or later "
1320                                          "required)\n",
1321                                          state->version_string);
1322
1323                      $$ = ast_precision_low;
1324                   }
1325         ;
1326
1327 struct_specifier:
1328         STRUCT IDENTIFIER '{' struct_declaration_list '}'
1329         {
1330            void *ctx = state;
1331            $$ = new(ctx) ast_struct_specifier($2, $4);
1332            $$->set_location(yylloc);
1333         }
1334         | STRUCT '{' struct_declaration_list '}'
1335         {
1336            void *ctx = state;
1337            $$ = new(ctx) ast_struct_specifier(NULL, $3);
1338            $$->set_location(yylloc);
1339         }
1340         ;
1341
1342 struct_declaration_list:
1343         struct_declaration
1344         {
1345            $$ = (ast_node *) $1;
1346            $1->link.self_link();
1347         }
1348         | struct_declaration_list struct_declaration
1349         {
1350            $$ = (ast_node *) $1;
1351            $$->link.insert_before(& $2->link);
1352         }
1353         ;
1354
1355 struct_declaration:
1356         type_specifier struct_declarator_list ';'
1357         {
1358            void *ctx = state;
1359            ast_fully_specified_type *type = new(ctx) ast_fully_specified_type();
1360            type->set_location(yylloc);
1361
1362            type->specifier = $1;
1363            $$ = new(ctx) ast_declarator_list(type);
1364            $$->set_location(yylloc);
1365
1366            $$->declarations.push_degenerate_list_at_head(& $2->link);
1367         }
1368         ;
1369
1370 struct_declarator_list:
1371         struct_declarator
1372         {
1373            $$ = $1;
1374            $1->link.self_link();
1375         }
1376         | struct_declarator_list ',' struct_declarator
1377         {
1378            $$ = $1;
1379            $$->link.insert_before(& $3->link);
1380         }
1381         ;
1382
1383 struct_declarator:
1384         IDENTIFIER
1385         {
1386            void *ctx = state;
1387            $$ = new(ctx) ast_declaration($1, false, NULL, NULL);
1388            $$->set_location(yylloc);
1389         }
1390         | IDENTIFIER '[' constant_expression ']'
1391         {
1392            void *ctx = state;
1393            $$ = new(ctx) ast_declaration($1, true, $3, NULL);
1394            $$->set_location(yylloc);
1395         }
1396         ;
1397
1398 initializer:
1399         assignment_expression
1400         ;
1401
1402 declaration_statement:
1403         declaration
1404         ;
1405
1406         // Grammar Note: labeled statements for SWITCH only; 'goto' is not
1407         // supported.
1408 statement:
1409         compound_statement      { $$ = (ast_node *) $1; }
1410         | simple_statement
1411         ;
1412
1413 simple_statement:
1414         declaration_statement
1415         | expression_statement
1416         | selection_statement
1417         | switch_statement              { $$ = NULL; }
1418         | case_label                    { $$ = NULL; }
1419         | iteration_statement
1420         | jump_statement
1421         ;
1422
1423 compound_statement:
1424         '{' '}'
1425         {
1426            void *ctx = state;
1427            $$ = new(ctx) ast_compound_statement(true, NULL);
1428            $$->set_location(yylloc);
1429         }
1430         | '{' statement_list '}'
1431         {
1432            void *ctx = state;
1433            $$ = new(ctx) ast_compound_statement(true, $2);
1434            $$->set_location(yylloc);
1435         }
1436         ;
1437
1438 statement_no_new_scope:
1439         compound_statement_no_new_scope { $$ = (ast_node *) $1; }
1440         | simple_statement
1441         ;
1442
1443 compound_statement_no_new_scope:
1444         '{' '}'
1445         {
1446            void *ctx = state;
1447            $$ = new(ctx) ast_compound_statement(false, NULL);
1448            $$->set_location(yylloc);
1449         }
1450         | '{' statement_list '}'
1451         {
1452            void *ctx = state;
1453            $$ = new(ctx) ast_compound_statement(false, $2);
1454            $$->set_location(yylloc);
1455         }
1456         ;
1457
1458 statement_list:
1459         statement
1460         {
1461            if ($1 == NULL) {
1462               _mesa_glsl_error(& @1, state, "<nil> statement\n");
1463               assert($1 != NULL);
1464            }
1465
1466            $$ = $1;
1467            $$->link.self_link();
1468         }
1469         | statement_list statement
1470         {
1471            if ($2 == NULL) {
1472               _mesa_glsl_error(& @2, state, "<nil> statement\n");
1473               assert($2 != NULL);
1474            }
1475            $$ = $1;
1476            $$->link.insert_before(& $2->link);
1477         }
1478         ;
1479
1480 expression_statement:
1481         ';'
1482         {
1483            void *ctx = state;
1484            $$ = new(ctx) ast_expression_statement(NULL);
1485            $$->set_location(yylloc);
1486         }
1487         | expression ';'
1488         {
1489            void *ctx = state;
1490            $$ = new(ctx) ast_expression_statement($1);
1491            $$->set_location(yylloc);
1492         }
1493         ;
1494
1495 selection_statement:
1496         IF '(' expression ')' selection_rest_statement
1497         {
1498            $$ = new(state) ast_selection_statement($3, $5.then_statement,
1499                                                    $5.else_statement);
1500            $$->set_location(yylloc);
1501         }
1502         ;
1503
1504 selection_rest_statement:
1505         statement ELSE statement
1506         {
1507            $$.then_statement = $1;
1508            $$.else_statement = $3;
1509         }
1510         | statement
1511         {
1512            $$.then_statement = $1;
1513            $$.else_statement = NULL;
1514         }
1515         ;
1516
1517 condition:
1518         expression
1519         {
1520            $$ = (ast_node *) $1;
1521         }
1522         | fully_specified_type IDENTIFIER '=' initializer
1523         {
1524            void *ctx = state;
1525            ast_declaration *decl = new(ctx) ast_declaration($2, false, NULL, $4);
1526            ast_declarator_list *declarator = new(ctx) ast_declarator_list($1);
1527            decl->set_location(yylloc);
1528            declarator->set_location(yylloc);
1529
1530            declarator->declarations.push_tail(&decl->link);
1531            $$ = declarator;
1532         }
1533         ;
1534
1535 switch_statement:
1536         SWITCH '(' expression ')' compound_statement
1537         ;
1538
1539 case_label:
1540         CASE expression ':'
1541         | DEFAULT ':'
1542         ;
1543
1544 iteration_statement:
1545         WHILE '(' condition ')' statement_no_new_scope
1546         {
1547            void *ctx = state;
1548            $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_while,
1549                                                     NULL, $3, NULL, $5);
1550            $$->set_location(yylloc);
1551         }
1552         | DO statement WHILE '(' expression ')' ';'
1553         {
1554            void *ctx = state;
1555            $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_do_while,
1556                                                     NULL, $5, NULL, $2);
1557            $$->set_location(yylloc);
1558         }
1559         | FOR '(' for_init_statement for_rest_statement ')' statement_no_new_scope
1560         {
1561            void *ctx = state;
1562            $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_for,
1563                                                     $3, $4.cond, $4.rest, $6);
1564            $$->set_location(yylloc);
1565         }
1566         ;
1567
1568 for_init_statement:
1569         expression_statement
1570         | declaration_statement
1571         ;
1572
1573 conditionopt:
1574         condition
1575         | /* empty */
1576         {
1577            $$ = NULL;
1578         }
1579         ;
1580
1581 for_rest_statement:
1582         conditionopt ';'
1583         {
1584            $$.cond = $1;
1585            $$.rest = NULL;
1586         }
1587         | conditionopt ';' expression
1588         {
1589            $$.cond = $1;
1590            $$.rest = $3;
1591         }
1592         ;
1593
1594         // Grammar Note: No 'goto'. Gotos are not supported.
1595 jump_statement:
1596         CONTINUE ';'
1597         {
1598            void *ctx = state;
1599            $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_continue, NULL);
1600            $$->set_location(yylloc);
1601         }
1602         | BREAK ';'
1603         {
1604            void *ctx = state;
1605            $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_break, NULL);
1606            $$->set_location(yylloc);
1607         }
1608         | RETURN ';'
1609         {
1610            void *ctx = state;
1611            $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, NULL);
1612            $$->set_location(yylloc);
1613         }
1614         | RETURN expression ';'
1615         {
1616            void *ctx = state;
1617            $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, $2);
1618            $$->set_location(yylloc);
1619         }
1620         | DISCARD ';' // Fragment shader only.
1621         {
1622            void *ctx = state;
1623            $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_discard, NULL);
1624            $$->set_location(yylloc);
1625         }
1626         ;
1627
1628 external_declaration:
1629         function_definition     { $$ = $1; }
1630         | declaration           { $$ = $1; }
1631         | pragma_statement      { $$ = NULL; }
1632         ;
1633
1634 function_definition:
1635         function_prototype compound_statement_no_new_scope
1636         {
1637            void *ctx = state;
1638            $$ = new(ctx) ast_function_definition();
1639            $$->set_location(yylloc);
1640            $$->prototype = $1;
1641            $$->body = $2;
1642         }
1643         ;