src/glsl/glsl_parser.yy

   1 %{
   2 /*
   3  * Copyright © 2008, 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <string.h>
  27 #ifndef _MSC_VER
  28 #include <strings.h>
  29 #endif
  30 #include <assert.h>
  31
  32 #include "ast.h"
  33 #include "glsl_parser_extras.h"
  34 #include "glsl_types.h"
  35 #include "main/context.h"
  36
  37 #ifdef _MSC_VER
  38 #pragma warning( disable : 4065 ) // switch statement contains 'default' but no 'case' labels
  39 #endif
  40
  41 #undef yyerror
  42
  43 static void yyerror(YYLTYPE *loc, _mesa_glsl_parse_state *st, const char *msg)
  44 {
  45    _mesa_glsl_error(loc, st, "%s", msg);
  46 }
  47
  48 static int
  49 _mesa_glsl_lex(YYSTYPE *val, YYLTYPE *loc, _mesa_glsl_parse_state *state)
  50 {
  51    return _mesa_glsl_lexer_lex(val, loc, state->scanner);
  52 }
  53
  54 static bool match_layout_qualifier(const char *s1, const char *s2,
  55                                    _mesa_glsl_parse_state *state)
  56 {
  57    /* From the GLSL 1.50 spec, section 4.3.8 (Layout Qualifiers):
  58     *
  59     *     "The tokens in any layout-qualifier-id-list ... are not case
  60     *     sensitive, unless explicitly noted otherwise."
  61     *
  62     * The text "unless explicitly noted otherwise" appears to be
  63     * vacuous--no desktop GLSL spec (up through GLSL 4.40) notes
  64     * otherwise.
  65     *
  66     * However, the GLSL ES 3.00 spec says, in section 4.3.8 (Layout
  67     * Qualifiers):
  68     *
  69     *     "As for other identifiers, they are case sensitive."
  70     *
  71     * So we need to do a case-sensitive or a case-insensitive match,
  72     * depending on whether we are compiling for GLSL ES.
  73     */
  74    if (state->es_shader)
  75       return strcmp(s1, s2);
  76    else
  77       return strcasecmp(s1, s2);
  78 }
  79 %}
  80
  81 %expect 0
  82
  83 %pure-parser
  84 %error-verbose
  85
  86 %locations
  87 %initial-action {
  88    @$.first_line = 1;
  89    @$.first_column = 1;
  90    @$.last_line = 1;
  91    @$.last_column = 1;
  92    @$.source = 0;
  93 }
  94
  95 %lex-param   {struct _mesa_glsl_parse_state *state}
  96 %parse-param {struct _mesa_glsl_parse_state *state}
  97
  98 %union {
  99    int n;
 100    float real;
 101    double dreal;
 102    const char *identifier;
 103
 104    struct ast_type_qualifier type_qualifier;
 105
 106    ast_node *node;
 107    ast_type_specifier *type_specifier;
 108    ast_array_specifier *array_specifier;
 109    ast_fully_specified_type *fully_specified_type;
 110    ast_function *function;
 111    ast_parameter_declarator *parameter_declarator;
 112    ast_function_definition *function_definition;
 113    ast_compound_statement *compound_statement;
 114    ast_expression *expression;
 115    ast_declarator_list *declarator_list;
 116    ast_struct_specifier *struct_specifier;
 117    ast_declaration *declaration;
 118    ast_switch_body *switch_body;
 119    ast_case_label *case_label;
 120    ast_case_label_list *case_label_list;
 121    ast_case_statement *case_statement;
 122    ast_case_statement_list *case_statement_list;
 123    ast_interface_block *interface_block;
 124    ast_subroutine_list *subroutine_list;
 125    struct {
 126       ast_node *cond;
 127       ast_expression *rest;
 128    } for_rest_statement;
 129
 130    struct {
 131       ast_node *then_statement;
 132       ast_node *else_statement;
 133    } selection_rest_statement;
 134 }
 135
 136 %token ATTRIBUTE CONST_TOK BOOL_TOK FLOAT_TOK INT_TOK UINT_TOK DOUBLE_TOK
 137 %token BREAK BUFFER CONTINUE DO ELSE FOR IF DISCARD RETURN SWITCH CASE DEFAULT
 138 %token BVEC2 BVEC3 BVEC4 IVEC2 IVEC3 IVEC4 UVEC2 UVEC3 UVEC4 VEC2 VEC3 VEC4 DVEC2 DVEC3 DVEC4
 139 %token CENTROID IN_TOK OUT_TOK INOUT_TOK UNIFORM VARYING SAMPLE
 140 %token NOPERSPECTIVE FLAT SMOOTH
 141 %token MAT2X2 MAT2X3 MAT2X4
 142 %token MAT3X2 MAT3X3 MAT3X4
 143 %token MAT4X2 MAT4X3 MAT4X4
 144 %token DMAT2X2 DMAT2X3 DMAT2X4
 145 %token DMAT3X2 DMAT3X3 DMAT3X4
 146 %token DMAT4X2 DMAT4X3 DMAT4X4
 147 %token SAMPLER1D SAMPLER2D SAMPLER3D SAMPLERCUBE SAMPLER1DSHADOW SAMPLER2DSHADOW
 148 %token SAMPLERCUBESHADOW SAMPLER1DARRAY SAMPLER2DARRAY SAMPLER1DARRAYSHADOW
 149 %token SAMPLER2DARRAYSHADOW SAMPLERCUBEARRAY SAMPLERCUBEARRAYSHADOW
 150 %token ISAMPLER1D ISAMPLER2D ISAMPLER3D ISAMPLERCUBE
 151 %token ISAMPLER1DARRAY ISAMPLER2DARRAY ISAMPLERCUBEARRAY
 152 %token USAMPLER1D USAMPLER2D USAMPLER3D USAMPLERCUBE USAMPLER1DARRAY
 153 %token USAMPLER2DARRAY USAMPLERCUBEARRAY
 154 %token SAMPLER2DRECT ISAMPLER2DRECT USAMPLER2DRECT SAMPLER2DRECTSHADOW
 155 %token SAMPLERBUFFER ISAMPLERBUFFER USAMPLERBUFFER
 156 %token SAMPLER2DMS ISAMPLER2DMS USAMPLER2DMS
 157 %token SAMPLER2DMSARRAY ISAMPLER2DMSARRAY USAMPLER2DMSARRAY
 158 %token SAMPLEREXTERNALOES
 159 %token IMAGE1D IMAGE2D IMAGE3D IMAGE2DRECT IMAGECUBE IMAGEBUFFER
 160 %token IMAGE1DARRAY IMAGE2DARRAY IMAGECUBEARRAY IMAGE2DMS IMAGE2DMSARRAY
 161 %token IIMAGE1D IIMAGE2D IIMAGE3D IIMAGE2DRECT IIMAGECUBE IIMAGEBUFFER
 162 %token IIMAGE1DARRAY IIMAGE2DARRAY IIMAGECUBEARRAY IIMAGE2DMS IIMAGE2DMSARRAY
 163 %token UIMAGE1D UIMAGE2D UIMAGE3D UIMAGE2DRECT UIMAGECUBE UIMAGEBUFFER
 164 %token UIMAGE1DARRAY UIMAGE2DARRAY UIMAGECUBEARRAY UIMAGE2DMS UIMAGE2DMSARRAY
 165 %token IMAGE1DSHADOW IMAGE2DSHADOW IMAGE1DARRAYSHADOW IMAGE2DARRAYSHADOW
 166 %token COHERENT VOLATILE RESTRICT READONLY WRITEONLY
 167 %token ATOMIC_UINT
 168 %token STRUCT VOID_TOK WHILE
 169 %token <identifier> IDENTIFIER TYPE_IDENTIFIER NEW_IDENTIFIER
 170 %type <identifier> any_identifier
 171 %type <interface_block> instance_name_opt
 172 %token <real> FLOATCONSTANT
 173 %token <dreal> DOUBLECONSTANT
 174 %token <n> INTCONSTANT UINTCONSTANT BOOLCONSTANT
 175 %token <identifier> FIELD_SELECTION
 176 %token LEFT_OP RIGHT_OP
 177 %token INC_OP DEC_OP LE_OP GE_OP EQ_OP NE_OP
 178 %token AND_OP OR_OP XOR_OP MUL_ASSIGN DIV_ASSIGN ADD_ASSIGN
 179 %token MOD_ASSIGN LEFT_ASSIGN RIGHT_ASSIGN AND_ASSIGN XOR_ASSIGN OR_ASSIGN
 180 %token SUB_ASSIGN
 181 %token INVARIANT PRECISE
 182 %token LOWP MEDIUMP HIGHP SUPERP PRECISION
 183
 184 %token VERSION_TOK EXTENSION LINE COLON EOL INTERFACE OUTPUT
 185 %token PRAGMA_DEBUG_ON PRAGMA_DEBUG_OFF
 186 %token PRAGMA_OPTIMIZE_ON PRAGMA_OPTIMIZE_OFF
 187 %token PRAGMA_INVARIANT_ALL
 188 %token LAYOUT_TOK
 189 %token DOT_TOK
 190    /* Reserved words that are not actually used in the grammar.
 191     */
 192 %token ASM CLASS UNION ENUM TYPEDEF TEMPLATE THIS PACKED_TOK GOTO
 193 %token INLINE_TOK NOINLINE PUBLIC_TOK STATIC EXTERN EXTERNAL
 194 %token LONG_TOK SHORT_TOK HALF FIXED_TOK UNSIGNED INPUT_TOK
 195 %token HVEC2 HVEC3 HVEC4 FVEC2 FVEC3 FVEC4
 196 %token SAMPLER3DRECT
 197 %token SIZEOF CAST NAMESPACE USING
 198 %token RESOURCE PATCH
 199 %token SUBROUTINE
 200
 201 %token ERROR_TOK
 202
 203 %token COMMON PARTITION ACTIVE FILTER ROW_MAJOR
 204
 205 %type <identifier> variable_identifier
 206 %type <node> statement
 207 %type <node> statement_list
 208 %type <node> simple_statement
 209 %type <n> precision_qualifier
 210 %type <type_qualifier> type_qualifier
 211 %type <type_qualifier> auxiliary_storage_qualifier
 212 %type <type_qualifier> storage_qualifier
 213 %type <type_qualifier> interpolation_qualifier
 214 %type <type_qualifier> layout_qualifier
 215 %type <type_qualifier> layout_qualifier_id_list layout_qualifier_id
 216 %type <type_qualifier> interface_block_layout_qualifier
 217 %type <type_qualifier> memory_qualifier
 218 %type <type_qualifier> subroutine_qualifier
 219 %type <subroutine_list> subroutine_type_list
 220 %type <type_qualifier> interface_qualifier
 221 %type <type_specifier> type_specifier
 222 %type <type_specifier> type_specifier_nonarray
 223 %type <array_specifier> array_specifier
 224 %type <identifier> basic_type_specifier_nonarray
 225 %type <fully_specified_type> fully_specified_type
 226 %type <function> function_prototype
 227 %type <function> function_header
 228 %type <function> function_header_with_parameters
 229 %type <function> function_declarator
 230 %type <parameter_declarator> parameter_declarator
 231 %type <parameter_declarator> parameter_declaration
 232 %type <type_qualifier> parameter_qualifier
 233 %type <type_qualifier> parameter_direction_qualifier
 234 %type <type_specifier> parameter_type_specifier
 235 %type <function_definition> function_definition
 236 %type <compound_statement> compound_statement_no_new_scope
 237 %type <compound_statement> compound_statement
 238 %type <node> statement_no_new_scope
 239 %type <node> expression_statement
 240 %type <expression> expression
 241 %type <expression> primary_expression
 242 %type <expression> assignment_expression
 243 %type <expression> conditional_expression
 244 %type <expression> logical_or_expression
 245 %type <expression> logical_xor_expression
 246 %type <expression> logical_and_expression
 247 %type <expression> inclusive_or_expression
 248 %type <expression> exclusive_or_expression
 249 %type <expression> and_expression
 250 %type <expression> equality_expression
 251 %type <expression> relational_expression
 252 %type <expression> shift_expression
 253 %type <expression> additive_expression
 254 %type <expression> multiplicative_expression
 255 %type <expression> unary_expression
 256 %type <expression> constant_expression
 257 %type <expression> integer_expression
 258 %type <expression> postfix_expression
 259 %type <expression> function_call_header_with_parameters
 260 %type <expression> function_call_header_no_parameters
 261 %type <expression> function_call_header
 262 %type <expression> function_call_generic
 263 %type <expression> function_call_or_method
 264 %type <expression> function_call
 265 %type <n> assignment_operator
 266 %type <n> unary_operator
 267 %type <expression> function_identifier
 268 %type <node> external_declaration
 269 %type <declarator_list> init_declarator_list
 270 %type <declarator_list> single_declaration
 271 %type <expression> initializer
 272 %type <expression> initializer_list
 273 %type <node> declaration
 274 %type <node> declaration_statement
 275 %type <node> jump_statement
 276 %type <node> interface_block
 277 %type <interface_block> basic_interface_block
 278 %type <struct_specifier> struct_specifier
 279 %type <declarator_list> struct_declaration_list
 280 %type <declarator_list> struct_declaration
 281 %type <declaration> struct_declarator
 282 %type <declaration> struct_declarator_list
 283 %type <declarator_list> member_list
 284 %type <declarator_list> member_declaration
 285 %type <node> selection_statement
 286 %type <selection_rest_statement> selection_rest_statement
 287 %type <node> switch_statement
 288 %type <switch_body> switch_body
 289 %type <case_label_list> case_label_list
 290 %type <case_label> case_label
 291 %type <case_statement> case_statement
 292 %type <case_statement_list> case_statement_list
 293 %type <node> iteration_statement
 294 %type <node> condition
 295 %type <node> conditionopt
 296 %type <node> for_init_statement
 297 %type <for_rest_statement> for_rest_statement
 298 %type <n> integer_constant
 299 %type <node> layout_defaults
 300
 301 %right THEN ELSE
 302 %%
 303
 304 translation_unit:
 305    version_statement extension_statement_list
 306    {
 307       _mesa_glsl_initialize_types(state);
 308    }
 309    external_declaration_list
 310    {
 311       delete state->symbols;
 312       state->symbols = new(ralloc_parent(state)) glsl_symbol_table;
 313       _mesa_glsl_initialize_types(state);
 314    }
 315    ;
 316
 317 version_statement:
 318    /* blank - no #version specified: defaults are already set */
 319    | VERSION_TOK INTCONSTANT EOL
 320    {
 321       state->process_version_directive(&@2, $2, NULL);
 322       if (state->error) {
 323          YYERROR;
 324       }
 325    }
 326    | VERSION_TOK INTCONSTANT any_identifier EOL
 327    {
 328       state->process_version_directive(&@2, $2, $3);
 329       if (state->error) {
 330          YYERROR;
 331       }
 332    }
 333    ;
 334
 335 pragma_statement:
 336    PRAGMA_DEBUG_ON EOL
 337    | PRAGMA_DEBUG_OFF EOL
 338    | PRAGMA_OPTIMIZE_ON EOL
 339    | PRAGMA_OPTIMIZE_OFF EOL
 340    | PRAGMA_INVARIANT_ALL EOL
 341    {
 342       /* Pragma invariant(all) cannot be used in a fragment shader.
 343        *
 344        * Page 27 of the GLSL 1.20 spec, Page 53 of the GLSL ES 3.00 spec:
 345        *
 346        *     "It is an error to use this pragma in a fragment shader."
 347        */
 348       if (state->is_version(120, 300) &&
 349           state->stage == MESA_SHADER_FRAGMENT) {
 350          _mesa_glsl_error(& @1, state,
 351                           "pragma `invariant(all)' cannot be used "
 352                           "in a fragment shader.");
 353       } else if (!state->is_version(120, 100)) {
 354          _mesa_glsl_warning(& @1, state,
 355                             "pragma `invariant(all)' not supported in %s "
 356                             "(GLSL ES 1.00 or GLSL 1.20 required)",
 357                             state->get_version_string());
 358       } else {
 359          state->all_invariant = true;
 360       }
 361    }
 362    ;
 363
 364 extension_statement_list:
 365
 366    | extension_statement_list extension_statement
 367    ;
 368
 369 any_identifier:
 370    IDENTIFIER
 371    | TYPE_IDENTIFIER
 372    | NEW_IDENTIFIER
 373    ;
 374
 375 extension_statement:
 376    EXTENSION any_identifier COLON any_identifier EOL
 377    {
 378       if (!_mesa_glsl_process_extension($2, & @2, $4, & @4, state)) {
 379          YYERROR;
 380       }
 381    }
 382    ;
 383
 384 external_declaration_list:
 385    external_declaration
 386    {
 387       /* FINISHME: The NULL test is required because pragmas are set to
 388        * FINISHME: NULL. (See production rule for external_declaration.)
 389        */
 390       if ($1 != NULL)
 391          state->translation_unit.push_tail(& $1->link);
 392    }
 393    | external_declaration_list external_declaration
 394    {
 395       /* FINISHME: The NULL test is required because pragmas are set to
 396        * FINISHME: NULL. (See production rule for external_declaration.)
 397        */
 398       if ($2 != NULL)
 399          state->translation_unit.push_tail(& $2->link);
 400    }
 401    | external_declaration_list extension_statement {
 402       if (!state->allow_extension_directive_midshader) {
 403          _mesa_glsl_error(& @2, state,
 404                           "#extension directive is not allowed "
 405                           "in the middle of a shader");
 406          YYERROR;
 407       }
 408    }
 409    ;
 410
 411 variable_identifier:
 412    IDENTIFIER
 413    | NEW_IDENTIFIER
 414    ;
 415
 416 primary_expression:
 417    variable_identifier
 418    {
 419       void *ctx = state;
 420       $$ = new(ctx) ast_expression(ast_identifier, NULL, NULL, NULL);
 421       $$->set_location(@1);
 422       $$->primary_expression.identifier = $1;
 423    }
 424    | INTCONSTANT
 425    {
 426       void *ctx = state;
 427       $$ = new(ctx) ast_expression(ast_int_constant, NULL, NULL, NULL);
 428       $$->set_location(@1);
 429       $$->primary_expression.int_constant = $1;
 430    }
 431    | UINTCONSTANT
 432    {
 433       void *ctx = state;
 434       $$ = new(ctx) ast_expression(ast_uint_constant, NULL, NULL, NULL);
 435       $$->set_location(@1);
 436       $$->primary_expression.uint_constant = $1;
 437    }
 438    | FLOATCONSTANT
 439    {
 440       void *ctx = state;
 441       $$ = new(ctx) ast_expression(ast_float_constant, NULL, NULL, NULL);
 442       $$->set_location(@1);
 443       $$->primary_expression.float_constant = $1;
 444    }
 445    | DOUBLECONSTANT
 446    {
 447       void *ctx = state;
 448       $$ = new(ctx) ast_expression(ast_double_constant, NULL, NULL, NULL);
 449       $$->set_location(@1);
 450       $$->primary_expression.double_constant = $1;
 451    }
 452    | BOOLCONSTANT
 453    {
 454       void *ctx = state;
 455       $$ = new(ctx) ast_expression(ast_bool_constant, NULL, NULL, NULL);
 456       $$->set_location(@1);
 457       $$->primary_expression.bool_constant = $1;
 458    }
 459    | '(' expression ')'
 460    {
 461       $$ = $2;
 462    }
 463    ;
 464
 465 postfix_expression:
 466    primary_expression
 467    | postfix_expression '[' integer_expression ']'
 468    {
 469       void *ctx = state;
 470       $$ = new(ctx) ast_expression(ast_array_index, $1, $3, NULL);
 471       $$->set_location_range(@1, @4);
 472    }
 473    | function_call
 474    {
 475       $$ = $1;
 476    }
 477    | postfix_expression DOT_TOK FIELD_SELECTION
 478    {
 479       void *ctx = state;
 480       $$ = new(ctx) ast_expression(ast_field_selection, $1, NULL, NULL);
 481       $$->set_location_range(@1, @3);
 482       $$->primary_expression.identifier = $3;
 483    }
 484    | postfix_expression INC_OP
 485    {
 486       void *ctx = state;
 487       $$ = new(ctx) ast_expression(ast_post_inc, $1, NULL, NULL);
 488       $$->set_location_range(@1, @2);
 489    }
 490    | postfix_expression DEC_OP
 491    {
 492       void *ctx = state;
 493       $$ = new(ctx) ast_expression(ast_post_dec, $1, NULL, NULL);
 494       $$->set_location_range(@1, @2);
 495    }
 496    ;
 497
 498 integer_expression:
 499    expression
 500    ;
 501
 502 function_call:
 503    function_call_or_method
 504    ;
 505
 506 function_call_or_method:
 507    function_call_generic
 508    ;
 509
 510 function_call_generic:
 511    function_call_header_with_parameters ')'
 512    | function_call_header_no_parameters ')'
 513    ;
 514
 515 function_call_header_no_parameters:
 516    function_call_header VOID_TOK
 517    | function_call_header
 518    ;
 519
 520 function_call_header_with_parameters:
 521    function_call_header assignment_expression
 522    {
 523       $$ = $1;
 524       $$->set_location(@1);
 525       $$->expressions.push_tail(& $2->link);
 526    }
 527    | function_call_header_with_parameters ',' assignment_expression
 528    {
 529       $$ = $1;
 530       $$->set_location(@1);
 531       $$->expressions.push_tail(& $3->link);
 532    }
 533    ;
 534
 535    // Grammar Note: Constructors look like functions, but lexical
 536    // analysis recognized most of them as keywords. They are now
 537    // recognized through "type_specifier".
 538 function_call_header:
 539    function_identifier '('
 540    ;
 541
 542 function_identifier:
 543    type_specifier
 544    {
 545       void *ctx = state;
 546       $$ = new(ctx) ast_function_expression($1);
 547       $$->set_location(@1);
 548       }
 549    | postfix_expression
 550    {
 551       void *ctx = state;
 552       $$ = new(ctx) ast_function_expression($1);
 553       $$->set_location(@1);
 554       }
 555    ;
 556
 557    // Grammar Note: Constructors look like methods, but lexical
 558    // analysis recognized most of them as keywords. They are now
 559    // recognized through "type_specifier".
 560
 561    // Grammar Note: No traditional style type casts.
 562 unary_expression:
 563    postfix_expression
 564    | INC_OP unary_expression
 565    {
 566       void *ctx = state;
 567       $$ = new(ctx) ast_expression(ast_pre_inc, $2, NULL, NULL);
 568       $$->set_location(@1);
 569    }
 570    | DEC_OP unary_expression
 571    {
 572       void *ctx = state;
 573       $$ = new(ctx) ast_expression(ast_pre_dec, $2, NULL, NULL);
 574       $$->set_location(@1);
 575    }
 576    | unary_operator unary_expression
 577    {
 578       void *ctx = state;
 579       $$ = new(ctx) ast_expression($1, $2, NULL, NULL);
 580       $$->set_location_range(@1, @2);
 581    }
 582    ;
 583
 584    // Grammar Note: No '*' or '&' unary ops. Pointers are not supported.
 585 unary_operator:
 586    '+'   { $$ = ast_plus; }
 587    | '-' { $$ = ast_neg; }
 588    | '!' { $$ = ast_logic_not; }
 589    | '~' { $$ = ast_bit_not; }
 590    ;
 591
 592 multiplicative_expression:
 593    unary_expression
 594    | multiplicative_expression '*' unary_expression
 595    {
 596       void *ctx = state;
 597       $$ = new(ctx) ast_expression_bin(ast_mul, $1, $3);
 598       $$->set_location_range(@1, @3);
 599    }
 600    | multiplicative_expression '/' unary_expression
 601    {
 602       void *ctx = state;
 603       $$ = new(ctx) ast_expression_bin(ast_div, $1, $3);
 604       $$->set_location_range(@1, @3);
 605    }
 606    | multiplicative_expression '%' unary_expression
 607    {
 608       void *ctx = state;
 609       $$ = new(ctx) ast_expression_bin(ast_mod, $1, $3);
 610       $$->set_location_range(@1, @3);
 611    }
 612    ;
 613
 614 additive_expression:
 615    multiplicative_expression
 616    | additive_expression '+' multiplicative_expression
 617    {
 618       void *ctx = state;
 619       $$ = new(ctx) ast_expression_bin(ast_add, $1, $3);
 620       $$->set_location_range(@1, @3);
 621    }
 622    | additive_expression '-' multiplicative_expression
 623    {
 624       void *ctx = state;
 625       $$ = new(ctx) ast_expression_bin(ast_sub, $1, $3);
 626       $$->set_location_range(@1, @3);
 627    }
 628    ;
 629
 630 shift_expression:
 631    additive_expression
 632    | shift_expression LEFT_OP additive_expression
 633    {
 634       void *ctx = state;
 635       $$ = new(ctx) ast_expression_bin(ast_lshift, $1, $3);
 636       $$->set_location_range(@1, @3);
 637    }
 638    | shift_expression RIGHT_OP additive_expression
 639    {
 640       void *ctx = state;
 641       $$ = new(ctx) ast_expression_bin(ast_rshift, $1, $3);
 642       $$->set_location_range(@1, @3);
 643    }
 644    ;
 645
 646 relational_expression:
 647    shift_expression
 648    | relational_expression '<' shift_expression
 649    {
 650       void *ctx = state;
 651       $$ = new(ctx) ast_expression_bin(ast_less, $1, $3);
 652       $$->set_location_range(@1, @3);
 653    }
 654    | relational_expression '>' shift_expression
 655    {
 656       void *ctx = state;
 657       $$ = new(ctx) ast_expression_bin(ast_greater, $1, $3);
 658       $$->set_location_range(@1, @3);
 659    }
 660    | relational_expression LE_OP shift_expression
 661    {
 662       void *ctx = state;
 663       $$ = new(ctx) ast_expression_bin(ast_lequal, $1, $3);
 664       $$->set_location_range(@1, @3);
 665    }
 666    | relational_expression GE_OP shift_expression
 667    {
 668       void *ctx = state;
 669       $$ = new(ctx) ast_expression_bin(ast_gequal, $1, $3);
 670       $$->set_location_range(@1, @3);
 671    }
 672    ;
 673
 674 equality_expression:
 675    relational_expression
 676    | equality_expression EQ_OP relational_expression
 677    {
 678       void *ctx = state;
 679       $$ = new(ctx) ast_expression_bin(ast_equal, $1, $3);
 680       $$->set_location_range(@1, @3);
 681    }
 682    | equality_expression NE_OP relational_expression
 683    {
 684       void *ctx = state;
 685       $$ = new(ctx) ast_expression_bin(ast_nequal, $1, $3);
 686       $$->set_location_range(@1, @3);
 687    }
 688    ;
 689
 690 and_expression:
 691    equality_expression
 692    | and_expression '&' equality_expression
 693    {
 694       void *ctx = state;
 695       $$ = new(ctx) ast_expression_bin(ast_bit_and, $1, $3);
 696       $$->set_location_range(@1, @3);
 697    }
 698    ;
 699
 700 exclusive_or_expression:
 701    and_expression
 702    | exclusive_or_expression '^' and_expression
 703    {
 704       void *ctx = state;
 705       $$ = new(ctx) ast_expression_bin(ast_bit_xor, $1, $3);
 706       $$->set_location_range(@1, @3);
 707    }
 708    ;
 709
 710 inclusive_or_expression:
 711    exclusive_or_expression
 712    | inclusive_or_expression '|' exclusive_or_expression
 713    {
 714       void *ctx = state;
 715       $$ = new(ctx) ast_expression_bin(ast_bit_or, $1, $3);
 716       $$->set_location_range(@1, @3);
 717    }
 718    ;
 719
 720 logical_and_expression:
 721    inclusive_or_expression
 722    | logical_and_expression AND_OP inclusive_or_expression
 723    {
 724       void *ctx = state;
 725       $$ = new(ctx) ast_expression_bin(ast_logic_and, $1, $3);
 726       $$->set_location_range(@1, @3);
 727    }
 728    ;
 729
 730 logical_xor_expression:
 731    logical_and_expression
 732    | logical_xor_expression XOR_OP logical_and_expression
 733    {
 734       void *ctx = state;
 735       $$ = new(ctx) ast_expression_bin(ast_logic_xor, $1, $3);
 736       $$->set_location_range(@1, @3);
 737    }
 738    ;
 739
 740 logical_or_expression:
 741    logical_xor_expression
 742    | logical_or_expression OR_OP logical_xor_expression
 743    {
 744       void *ctx = state;
 745       $$ = new(ctx) ast_expression_bin(ast_logic_or, $1, $3);
 746       $$->set_location_range(@1, @3);
 747    }
 748    ;
 749
 750 conditional_expression:
 751    logical_or_expression
 752    | logical_or_expression '?' expression ':' assignment_expression
 753    {
 754       void *ctx = state;
 755       $$ = new(ctx) ast_expression(ast_conditional, $1, $3, $5);
 756       $$->set_location_range(@1, @5);
 757    }
 758    ;
 759
 760 assignment_expression:
 761    conditional_expression
 762    | unary_expression assignment_operator assignment_expression
 763    {
 764       void *ctx = state;
 765       $$ = new(ctx) ast_expression($2, $1, $3, NULL);
 766       $$->set_location_range(@1, @3);
 767    }
 768    ;
 769
 770 assignment_operator:
 771    '='                { $$ = ast_assign; }
 772    | MUL_ASSIGN       { $$ = ast_mul_assign; }
 773    | DIV_ASSIGN       { $$ = ast_div_assign; }
 774    | MOD_ASSIGN       { $$ = ast_mod_assign; }
 775    | ADD_ASSIGN       { $$ = ast_add_assign; }
 776    | SUB_ASSIGN       { $$ = ast_sub_assign; }
 777    | LEFT_ASSIGN      { $$ = ast_ls_assign; }
 778    | RIGHT_ASSIGN     { $$ = ast_rs_assign; }
 779    | AND_ASSIGN       { $$ = ast_and_assign; }
 780    | XOR_ASSIGN       { $$ = ast_xor_assign; }
 781    | OR_ASSIGN        { $$ = ast_or_assign; }
 782    ;
 783
 784 expression:
 785    assignment_expression
 786    {
 787       $$ = $1;
 788    }
 789    | expression ',' assignment_expression
 790    {
 791       void *ctx = state;
 792       if ($1->oper != ast_sequence) {
 793          $$ = new(ctx) ast_expression(ast_sequence, NULL, NULL, NULL);
 794          $$->set_location_range(@1, @3);
 795          $$->expressions.push_tail(& $1->link);
 796       } else {
 797          $$ = $1;
 798       }
 799
 800       $$->expressions.push_tail(& $3->link);
 801    }
 802    ;
 803
 804 constant_expression:
 805    conditional_expression
 806    ;
 807
 808 declaration:
 809    function_prototype ';'
 810    {
 811       state->symbols->pop_scope();
 812       $$ = $1;
 813    }
 814    | init_declarator_list ';'
 815    {
 816       $$ = $1;
 817    }
 818    | PRECISION precision_qualifier type_specifier ';'
 819    {
 820       $3->default_precision = $2;
 821       $$ = $3;
 822    }
 823    | interface_block
 824    {
 825       $$ = $1;
 826    }
 827    ;
 828
 829 function_prototype:
 830    function_declarator ')'
 831    ;
 832
 833 function_declarator:
 834    function_header
 835    | function_header_with_parameters
 836    ;
 837
 838 function_header_with_parameters:
 839    function_header parameter_declaration
 840    {
 841       $$ = $1;
 842       $$->parameters.push_tail(& $2->link);
 843    }
 844    | function_header_with_parameters ',' parameter_declaration
 845    {
 846       $$ = $1;
 847       $$->parameters.push_tail(& $3->link);
 848    }
 849    ;
 850
 851 function_header:
 852    fully_specified_type variable_identifier '('
 853    {
 854       void *ctx = state;
 855       $$ = new(ctx) ast_function();
 856       $$->set_location(@2);
 857       $$->return_type = $1;
 858       $$->identifier = $2;
 859
 860       if ($1->qualifier.flags.q.subroutine) {
 861          /* add type for IDENTIFIER search */
 862          state->symbols->add_type($2, glsl_type::get_subroutine_instance($2));
 863       } else
 864          state->symbols->add_function(new(state) ir_function($2));
 865       state->symbols->push_scope();
 866    }
 867    ;
 868
 869 parameter_declarator:
 870    type_specifier any_identifier
 871    {
 872       void *ctx = state;
 873       $$ = new(ctx) ast_parameter_declarator();
 874       $$->set_location_range(@1, @2);
 875       $$->type = new(ctx) ast_fully_specified_type();
 876       $$->type->set_location(@1);
 877       $$->type->specifier = $1;
 878       $$->identifier = $2;
 879    }
 880    | type_specifier any_identifier array_specifier
 881    {
 882       void *ctx = state;
 883       $$ = new(ctx) ast_parameter_declarator();
 884       $$->set_location_range(@1, @3);
 885       $$->type = new(ctx) ast_fully_specified_type();
 886       $$->type->set_location(@1);
 887       $$->type->specifier = $1;
 888       $$->identifier = $2;
 889       $$->array_specifier = $3;
 890    }
 891    ;
 892
 893 parameter_declaration:
 894    parameter_qualifier parameter_declarator
 895    {
 896       $$ = $2;
 897       $$->type->qualifier = $1;
 898    }
 899    | parameter_qualifier parameter_type_specifier
 900    {
 901       void *ctx = state;
 902       $$ = new(ctx) ast_parameter_declarator();
 903       $$->set_location(@2);
 904       $$->type = new(ctx) ast_fully_specified_type();
 905       $$->type->set_location_range(@1, @2);
 906       $$->type->qualifier = $1;
 907       $$->type->specifier = $2;
 908    }
 909    ;
 910
 911 parameter_qualifier:
 912    /* empty */
 913    {
 914       memset(& $$, 0, sizeof($$));
 915    }
 916    | CONST_TOK parameter_qualifier
 917    {
 918       if ($2.flags.q.constant)
 919          _mesa_glsl_error(&@1, state, "duplicate const qualifier");
 920
 921       $$ = $2;
 922       $$.flags.q.constant = 1;
 923    }
 924    | PRECISE parameter_qualifier
 925    {
 926       if ($2.flags.q.precise)
 927          _mesa_glsl_error(&@1, state, "duplicate precise qualifier");
 928
 929       $$ = $2;
 930       $$.flags.q.precise = 1;
 931    }
 932    | parameter_direction_qualifier parameter_qualifier
 933    {
 934       if (($1.flags.q.in || $1.flags.q.out) && ($2.flags.q.in || $2.flags.q.out))
 935          _mesa_glsl_error(&@1, state, "duplicate in/out/inout qualifier");
 936
 937       if (!state->has_420pack() && $2.flags.q.constant)
 938          _mesa_glsl_error(&@1, state, "in/out/inout must come after const "
 939                                       "or precise");
 940
 941       $$ = $1;
 942       $$.merge_qualifier(&@1, state, $2);
 943    }
 944    | precision_qualifier parameter_qualifier
 945    {
 946       if ($2.precision != ast_precision_none)
 947          _mesa_glsl_error(&@1, state, "duplicate precision qualifier");
 948
 949       if (!state->has_420pack() && $2.flags.i != 0)
 950          _mesa_glsl_error(&@1, state, "precision qualifiers must come last");
 951
 952       $$ = $2;
 953       $$.precision = $1;
 954    }
 955    | memory_qualifier parameter_qualifier
 956    {
 957       $$ = $1;
 958       $$.merge_qualifier(&@1, state, $2);
 959    }
 960
 961 parameter_direction_qualifier:
 962    IN_TOK
 963    {
 964       memset(& $$, 0, sizeof($$));
 965       $$.flags.q.in = 1;
 966    }
 967    | OUT_TOK
 968    {
 969       memset(& $$, 0, sizeof($$));
 970       $$.flags.q.out = 1;
 971    }
 972    | INOUT_TOK
 973    {
 974       memset(& $$, 0, sizeof($$));
 975       $$.flags.q.in = 1;
 976       $$.flags.q.out = 1;
 977    }
 978    ;
 979
 980 parameter_type_specifier:
 981    type_specifier
 982    ;
 983
 984 init_declarator_list:
 985    single_declaration
 986    | init_declarator_list ',' any_identifier
 987    {
 988       void *ctx = state;
 989       ast_declaration *decl = new(ctx) ast_declaration($3, NULL, NULL);
 990       decl->set_location(@3);
 991
 992       $$ = $1;
 993       $$->declarations.push_tail(&decl->link);
 994       state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
 995    }
 996    | init_declarator_list ',' any_identifier array_specifier
 997    {
 998       void *ctx = state;
 999       ast_declaration *decl = new(ctx) ast_declaration($3, $4, NULL);
1000       decl->set_location_range(@3, @4);
1001
1002       $$ = $1;
1003       $$->declarations.push_tail(&decl->link);
1004       state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1005    }
1006    | init_declarator_list ',' any_identifier array_specifier '=' initializer
1007    {
1008       void *ctx = state;
1009       ast_declaration *decl = new(ctx) ast_declaration($3, $4, $6);
1010       decl->set_location_range(@3, @4);
1011
1012       $$ = $1;
1013       $$->declarations.push_tail(&decl->link);
1014       state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1015    }
1016    | init_declarator_list ',' any_identifier '=' initializer
1017    {
1018       void *ctx = state;
1019       ast_declaration *decl = new(ctx) ast_declaration($3, NULL, $5);
1020       decl->set_location(@3);
1021
1022       $$ = $1;
1023       $$->declarations.push_tail(&decl->link);
1024       state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
1025    }
1026    ;
1027
1028    // Grammar Note: No 'enum', or 'typedef'.
1029 single_declaration:
1030    fully_specified_type
1031    {
1032       void *ctx = state;
1033       /* Empty declaration list is valid. */
1034       $$ = new(ctx) ast_declarator_list($1);
1035       $$->set_location(@1);
1036    }
1037    | fully_specified_type any_identifier
1038    {
1039       void *ctx = state;
1040       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1041       decl->set_location(@2);
1042
1043       $$ = new(ctx) ast_declarator_list($1);
1044       $$->set_location_range(@1, @2);
1045       $$->declarations.push_tail(&decl->link);
1046    }
1047    | fully_specified_type any_identifier array_specifier
1048    {
1049       void *ctx = state;
1050       ast_declaration *decl = new(ctx) ast_declaration($2, $3, NULL);
1051       decl->set_location_range(@2, @3);
1052
1053       $$ = new(ctx) ast_declarator_list($1);
1054       $$->set_location_range(@1, @3);
1055       $$->declarations.push_tail(&decl->link);
1056    }
1057    | fully_specified_type any_identifier array_specifier '=' initializer
1058    {
1059       void *ctx = state;
1060       ast_declaration *decl = new(ctx) ast_declaration($2, $3, $5);
1061       decl->set_location_range(@2, @3);
1062
1063       $$ = new(ctx) ast_declarator_list($1);
1064       $$->set_location_range(@1, @3);
1065       $$->declarations.push_tail(&decl->link);
1066    }
1067    | fully_specified_type any_identifier '=' initializer
1068    {
1069       void *ctx = state;
1070       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, $4);
1071       decl->set_location(@2);
1072
1073       $$ = new(ctx) ast_declarator_list($1);
1074       $$->set_location_range(@1, @2);
1075       $$->declarations.push_tail(&decl->link);
1076    }
1077    | INVARIANT variable_identifier
1078    {
1079       void *ctx = state;
1080       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1081       decl->set_location(@2);
1082
1083       $$ = new(ctx) ast_declarator_list(NULL);
1084       $$->set_location_range(@1, @2);
1085       $$->invariant = true;
1086
1087       $$->declarations.push_tail(&decl->link);
1088    }
1089    | PRECISE variable_identifier
1090    {
1091       void *ctx = state;
1092       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, NULL);
1093       decl->set_location(@2);
1094
1095       $$ = new(ctx) ast_declarator_list(NULL);
1096       $$->set_location_range(@1, @2);
1097       $$->precise = true;
1098
1099       $$->declarations.push_tail(&decl->link);
1100    }
1101    ;
1102
1103 fully_specified_type:
1104    type_specifier
1105    {
1106       void *ctx = state;
1107       $$ = new(ctx) ast_fully_specified_type();
1108       $$->set_location(@1);
1109       $$->specifier = $1;
1110    }
1111    | type_qualifier type_specifier
1112    {
1113       void *ctx = state;
1114       $$ = new(ctx) ast_fully_specified_type();
1115       $$->set_location_range(@1, @2);
1116       $$->qualifier = $1;
1117       $$->specifier = $2;
1118    }
1119    ;
1120
1121 layout_qualifier:
1122    LAYOUT_TOK '(' layout_qualifier_id_list ')'
1123    {
1124       $$ = $3;
1125    }
1126    ;
1127
1128 layout_qualifier_id_list:
1129    layout_qualifier_id
1130    | layout_qualifier_id_list ',' layout_qualifier_id
1131    {
1132       $$ = $1;
1133       if (!$$.merge_qualifier(& @3, state, $3)) {
1134          YYERROR;
1135       }
1136    }
1137    ;
1138
1139 integer_constant:
1140    INTCONSTANT { $$ = $1; }
1141    | UINTCONSTANT { $$ = $1; }
1142    ;
1143
1144 layout_qualifier_id:
1145    any_identifier
1146    {
1147       memset(& $$, 0, sizeof($$));
1148
1149       /* Layout qualifiers for ARB_fragment_coord_conventions. */
1150       if (!$$.flags.i && (state->ARB_fragment_coord_conventions_enable ||
1151                           state->is_version(150, 0))) {
1152          if (match_layout_qualifier($1, "origin_upper_left", state) == 0) {
1153             $$.flags.q.origin_upper_left = 1;
1154          } else if (match_layout_qualifier($1, "pixel_center_integer",
1155                                            state) == 0) {
1156             $$.flags.q.pixel_center_integer = 1;
1157          }
1158
1159          if ($$.flags.i && state->ARB_fragment_coord_conventions_warn) {
1160             _mesa_glsl_warning(& @1, state,
1161                                "GL_ARB_fragment_coord_conventions layout "
1162                                "identifier `%s' used", $1);
1163          }
1164       }
1165
1166       /* Layout qualifiers for AMD/ARB_conservative_depth. */
1167       if (!$$.flags.i &&
1168           (state->AMD_conservative_depth_enable ||
1169            state->ARB_conservative_depth_enable ||
1170            state->is_version(420, 0))) {
1171          if (match_layout_qualifier($1, "depth_any", state) == 0) {
1172             $$.flags.q.depth_any = 1;
1173          } else if (match_layout_qualifier($1, "depth_greater", state) == 0) {
1174             $$.flags.q.depth_greater = 1;
1175          } else if (match_layout_qualifier($1, "depth_less", state) == 0) {
1176             $$.flags.q.depth_less = 1;
1177          } else if (match_layout_qualifier($1, "depth_unchanged",
1178                                            state) == 0) {
1179             $$.flags.q.depth_unchanged = 1;
1180          }
1181
1182          if ($$.flags.i && state->AMD_conservative_depth_warn) {
1183             _mesa_glsl_warning(& @1, state,
1184                                "GL_AMD_conservative_depth "
1185                                "layout qualifier `%s' is used", $1);
1186          }
1187          if ($$.flags.i && state->ARB_conservative_depth_warn) {
1188             _mesa_glsl_warning(& @1, state,
1189                                "GL_ARB_conservative_depth "
1190                                "layout qualifier `%s' is used", $1);
1191          }
1192       }
1193
1194       /* See also interface_block_layout_qualifier. */
1195       if (!$$.flags.i && state->has_uniform_buffer_objects()) {
1196          if (match_layout_qualifier($1, "std140", state) == 0) {
1197             $$.flags.q.std140 = 1;
1198          } else if (match_layout_qualifier($1, "shared", state) == 0) {
1199             $$.flags.q.shared = 1;
1200          } else if (match_layout_qualifier($1, "column_major", state) == 0) {
1201             $$.flags.q.column_major = 1;
1202          /* "row_major" is a reserved word in GLSL 1.30+. Its token is parsed
1203           * below in the interface_block_layout_qualifier rule.
1204           *
1205           * It is not a reserved word in GLSL ES 3.00, so it's handled here as
1206           * an identifier.
1207           *
1208           * Also, this takes care of alternate capitalizations of
1209           * "row_major" (which is necessary because layout qualifiers
1210           * are case-insensitive in desktop GLSL).
1211           */
1212          } else if (match_layout_qualifier($1, "row_major", state) == 0) {
1213             $$.flags.q.row_major = 1;
1214          /* "packed" is a reserved word in GLSL, and its token is
1215           * parsed below in the interface_block_layout_qualifier rule.
1216           * However, we must take care of alternate capitalizations of
1217           * "packed", because layout qualifiers are case-insensitive
1218           * in desktop GLSL.
1219           */
1220          } else if (match_layout_qualifier($1, "packed", state) == 0) {
1221            $$.flags.q.packed = 1;
1222          }
1223
1224          if ($$.flags.i && state->ARB_uniform_buffer_object_warn) {
1225             _mesa_glsl_warning(& @1, state,
1226                                "#version 140 / GL_ARB_uniform_buffer_object "
1227                                "layout qualifier `%s' is used", $1);
1228          }
1229       }
1230
1231       /* Layout qualifiers for GLSL 1.50 geometry shaders. */
1232       if (!$$.flags.i) {
1233          static const struct {
1234             const char *s;
1235             GLenum e;
1236          } map[] = {
1237                  { "points", GL_POINTS },
1238                  { "lines", GL_LINES },
1239                  { "lines_adjacency", GL_LINES_ADJACENCY },
1240                  { "line_strip", GL_LINE_STRIP },
1241                  { "triangles", GL_TRIANGLES },
1242                  { "triangles_adjacency", GL_TRIANGLES_ADJACENCY },
1243                  { "triangle_strip", GL_TRIANGLE_STRIP },
1244          };
1245          for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1246             if (match_layout_qualifier($1, map[i].s, state) == 0) {
1247                $$.flags.q.prim_type = 1;
1248                $$.prim_type = map[i].e;
1249                break;
1250             }
1251          }
1252
1253          if ($$.flags.i && !state->is_version(150, 0)) {
1254             _mesa_glsl_error(& @1, state, "#version 150 layout "
1255                              "qualifier `%s' used", $1);
1256          }
1257       }
1258
1259       /* Layout qualifiers for ARB_shader_image_load_store. */
1260       if (state->ARB_shader_image_load_store_enable ||
1261           state->is_version(420, 310)) {
1262          if (!$$.flags.i) {
1263             static const struct {
1264                const char *name;
1265                GLenum format;
1266                glsl_base_type base_type;
1267                /** Minimum desktop GLSL version required for the image
1268                 * format.  Use 130 if already present in the original
1269                 * ARB extension.
1270                 */
1271                unsigned required_glsl;
1272                /** Minimum GLSL ES version required for the image format. */
1273                unsigned required_essl;
1274             } map[] = {
1275                { "rgba32f", GL_RGBA32F, GLSL_TYPE_FLOAT, 130, 310 },
1276                { "rgba16f", GL_RGBA16F, GLSL_TYPE_FLOAT, 130, 310 },
1277                { "rg32f", GL_RG32F, GLSL_TYPE_FLOAT, 130, 0 },
1278                { "rg16f", GL_RG16F, GLSL_TYPE_FLOAT, 130, 0 },
1279                { "r11f_g11f_b10f", GL_R11F_G11F_B10F, GLSL_TYPE_FLOAT, 130, 0 },
1280                { "r32f", GL_R32F, GLSL_TYPE_FLOAT, 130, 310 },
1281                { "r16f", GL_R16F, GLSL_TYPE_FLOAT, 130, 0 },
1282                { "rgba32ui", GL_RGBA32UI, GLSL_TYPE_UINT, 130, 310 },
1283                { "rgba16ui", GL_RGBA16UI, GLSL_TYPE_UINT, 130, 310 },
1284                { "rgb10_a2ui", GL_RGB10_A2UI, GLSL_TYPE_UINT, 130, 0 },
1285                { "rgba8ui", GL_RGBA8UI, GLSL_TYPE_UINT, 130, 310 },
1286                { "rg32ui", GL_RG32UI, GLSL_TYPE_UINT, 130, 0 },
1287                { "rg16ui", GL_RG16UI, GLSL_TYPE_UINT, 130, 0 },
1288                { "rg8ui", GL_RG8UI, GLSL_TYPE_UINT, 130, 0 },
1289                { "r32ui", GL_R32UI, GLSL_TYPE_UINT, 130, 310 },
1290                { "r16ui", GL_R16UI, GLSL_TYPE_UINT, 130, 0 },
1291                { "r8ui", GL_R8UI, GLSL_TYPE_UINT, 130, 0 },
1292                { "rgba32i", GL_RGBA32I, GLSL_TYPE_INT, 130, 310 },
1293                { "rgba16i", GL_RGBA16I, GLSL_TYPE_INT, 130, 310 },
1294                { "rgba8i", GL_RGBA8I, GLSL_TYPE_INT, 130, 310 },
1295                { "rg32i", GL_RG32I, GLSL_TYPE_INT, 130, 0 },
1296                { "rg16i", GL_RG16I, GLSL_TYPE_INT, 130, 0 },
1297                { "rg8i", GL_RG8I, GLSL_TYPE_INT, 130, 0 },
1298                { "r32i", GL_R32I, GLSL_TYPE_INT, 130, 310 },
1299                { "r16i", GL_R16I, GLSL_TYPE_INT, 130, 0 },
1300                { "r8i", GL_R8I, GLSL_TYPE_INT, 130, 0 },
1301                { "rgba16", GL_RGBA16, GLSL_TYPE_FLOAT, 130, 0 },
1302                { "rgb10_a2", GL_RGB10_A2, GLSL_TYPE_FLOAT, 130, 0 },
1303                { "rgba8", GL_RGBA8, GLSL_TYPE_FLOAT, 130, 310 },
1304                { "rg16", GL_RG16, GLSL_TYPE_FLOAT, 130, 0 },
1305                { "rg8", GL_RG8, GLSL_TYPE_FLOAT, 130, 0 },
1306                { "r16", GL_R16, GLSL_TYPE_FLOAT, 130, 0 },
1307                { "r8", GL_R8, GLSL_TYPE_FLOAT, 130, 0 },
1308                { "rgba16_snorm", GL_RGBA16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1309                { "rgba8_snorm", GL_RGBA8_SNORM, GLSL_TYPE_FLOAT, 130, 310 },
1310                { "rg16_snorm", GL_RG16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1311                { "rg8_snorm", GL_RG8_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1312                { "r16_snorm", GL_R16_SNORM, GLSL_TYPE_FLOAT, 130, 0 },
1313                { "r8_snorm", GL_R8_SNORM, GLSL_TYPE_FLOAT, 130, 0 }
1314             };
1315
1316             for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1317                if (state->is_version(map[i].required_glsl,
1318                                      map[i].required_essl) &&
1319                    match_layout_qualifier($1, map[i].name, state) == 0) {
1320                   $$.flags.q.explicit_image_format = 1;
1321                   $$.image_format = map[i].format;
1322                   $$.image_base_type = map[i].base_type;
1323                   break;
1324                }
1325             }
1326          }
1327
1328          if (!$$.flags.i &&
1329              match_layout_qualifier($1, "early_fragment_tests", state) == 0) {
1330             /* From section 4.4.1.3 of the GLSL 4.50 specification
1331              * (Fragment Shader Inputs):
1332              *
1333              *  "Fragment shaders also allow the following layout
1334              *   qualifier on in only (not with variable declarations)
1335              *     layout-qualifier-id
1336              *        early_fragment_tests
1337              *   [...]"
1338              */
1339             if (state->stage != MESA_SHADER_FRAGMENT) {
1340                _mesa_glsl_error(& @1, state,
1341                                 "early_fragment_tests layout qualifier only "
1342                                 "valid in fragment shaders");
1343             }
1344
1345             $$.flags.q.early_fragment_tests = 1;
1346          }
1347       }
1348
1349       /* Layout qualifiers for tessellation evaluation shaders. */
1350       if (!$$.flags.i) {
1351          struct {
1352             const char *s;
1353             GLenum e;
1354          } map[] = {
1355                  /* triangles already parsed by gs-specific code */
1356                  { "quads", GL_QUADS },
1357                  { "isolines", GL_ISOLINES },
1358          };
1359          for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1360             if (match_layout_qualifier($1, map[i].s, state) == 0) {
1361                $$.flags.q.prim_type = 1;
1362                $$.prim_type = map[i].e;
1363                break;
1364             }
1365          }
1366
1367          if ($$.flags.i &&
1368              !state->ARB_tessellation_shader_enable &&
1369              !state->is_version(400, 0)) {
1370             _mesa_glsl_error(& @1, state,
1371                              "primitive mode qualifier `%s' requires "
1372                              "GLSL 4.00 or ARB_tessellation_shader", $1);
1373          }
1374       }
1375       if (!$$.flags.i) {
1376          struct {
1377             const char *s;
1378             GLenum e;
1379          } map[] = {
1380                  { "equal_spacing", GL_EQUAL },
1381                  { "fractional_odd_spacing", GL_FRACTIONAL_ODD },
1382                  { "fractional_even_spacing", GL_FRACTIONAL_EVEN },
1383          };
1384          for (unsigned i = 0; i < ARRAY_SIZE(map); i++) {
1385             if (match_layout_qualifier($1, map[i].s, state) == 0) {
1386                $$.flags.q.vertex_spacing = 1;
1387                $$.vertex_spacing = map[i].e;
1388                break;
1389             }
1390          }
1391
1392          if ($$.flags.i &&
1393              !state->ARB_tessellation_shader_enable &&
1394              !state->is_version(400, 0)) {
1395             _mesa_glsl_error(& @1, state,
1396                              "vertex spacing qualifier `%s' requires "
1397                              "GLSL 4.00 or ARB_tessellation_shader", $1);
1398          }
1399       }
1400       if (!$$.flags.i) {
1401          if (match_layout_qualifier($1, "cw", state) == 0) {
1402             $$.flags.q.ordering = 1;
1403             $$.ordering = GL_CW;
1404          } else if (match_layout_qualifier($1, "ccw", state) == 0) {
1405             $$.flags.q.ordering = 1;
1406             $$.ordering = GL_CCW;
1407          }
1408
1409          if ($$.flags.i &&
1410              !state->ARB_tessellation_shader_enable &&
1411              !state->is_version(400, 0)) {
1412             _mesa_glsl_error(& @1, state,
1413                              "ordering qualifier `%s' requires "
1414                              "GLSL 4.00 or ARB_tessellation_shader", $1);
1415          }
1416       }
1417       if (!$$.flags.i) {
1418          if (match_layout_qualifier($1, "point_mode", state) == 0) {
1419             $$.flags.q.point_mode = 1;
1420             $$.point_mode = true;
1421          }
1422
1423          if ($$.flags.i &&
1424              !state->ARB_tessellation_shader_enable &&
1425              !state->is_version(400, 0)) {
1426             _mesa_glsl_error(& @1, state,
1427                              "qualifier `point_mode' requires "
1428                              "GLSL 4.00 or ARB_tessellation_shader");
1429          }
1430       }
1431
1432       if (!$$.flags.i) {
1433          _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1434                           "`%s'", $1);
1435          YYERROR;
1436       }
1437    }
1438    | any_identifier '=' integer_constant
1439    {
1440       memset(& $$, 0, sizeof($$));
1441
1442       if (match_layout_qualifier("location", $1, state) == 0) {
1443          $$.flags.q.explicit_location = 1;
1444
1445          if ($$.flags.q.attribute == 1 &&
1446              state->ARB_explicit_attrib_location_warn) {
1447             _mesa_glsl_warning(& @1, state,
1448                                "GL_ARB_explicit_attrib_location layout "
1449                                "identifier `%s' used", $1);
1450          }
1451
1452          if ($3 >= 0) {
1453             $$.location = $3;
1454          } else {
1455              _mesa_glsl_error(& @3, state, "invalid location %d specified", $3);
1456              YYERROR;
1457          }
1458       }
1459
1460       if (match_layout_qualifier("index", $1, state) == 0) {
1461          $$.flags.q.explicit_index = 1;
1462
1463          if ($3 >= 0) {
1464             $$.index = $3;
1465          } else {
1466             _mesa_glsl_error(& @3, state, "invalid index %d specified", $3);
1467             YYERROR;
1468          }
1469       }
1470
1471       if ((state->has_420pack() ||
1472            state->has_atomic_counters() ||
1473            state->has_shader_storage_buffer_objects()) &&
1474           match_layout_qualifier("binding", $1, state) == 0) {
1475          $$.flags.q.explicit_binding = 1;
1476          $$.binding = $3;
1477       }
1478
1479       if (state->has_atomic_counters() &&
1480           match_layout_qualifier("offset", $1, state) == 0) {
1481          $$.flags.q.explicit_offset = 1;
1482          $$.offset = $3;
1483       }
1484
1485       if (match_layout_qualifier("max_vertices", $1, state) == 0) {
1486          $$.flags.q.max_vertices = 1;
1487
1488          if ($3 < 0) {
1489             _mesa_glsl_error(& @3, state,
1490                              "invalid max_vertices %d specified", $3);
1491             YYERROR;
1492          } else {
1493             $$.max_vertices = $3;
1494             if (!state->is_version(150, 0)) {
1495                _mesa_glsl_error(& @3, state,
1496                                 "#version 150 max_vertices qualifier "
1497                                 "specified", $3);
1498             }
1499          }
1500       }
1501
1502       if (state->stage == MESA_SHADER_GEOMETRY) {
1503          if (match_layout_qualifier("stream", $1, state) == 0 &&
1504              state->check_explicit_attrib_stream_allowed(& @3)) {
1505             $$.flags.q.stream = 1;
1506
1507             if ($3 < 0) {
1508                _mesa_glsl_error(& @3, state,
1509                                 "invalid stream %d specified", $3);
1510                YYERROR;
1511             } else {
1512                $$.flags.q.explicit_stream = 1;
1513                $$.stream = $3;
1514             }
1515          }
1516       }
1517
1518       static const char * const local_size_qualifiers[3] = {
1519          "local_size_x",
1520          "local_size_y",
1521          "local_size_z",
1522       };
1523       for (int i = 0; i < 3; i++) {
1524          if (match_layout_qualifier(local_size_qualifiers[i], $1,
1525                                     state) == 0) {
1526             if ($3 <= 0) {
1527                _mesa_glsl_error(& @3, state,
1528                                 "invalid %s of %d specified",
1529                                 local_size_qualifiers[i], $3);
1530                YYERROR;
1531             } else if (!state->has_compute_shader()) {
1532                _mesa_glsl_error(& @3, state,
1533                                 "%s qualifier requires GLSL 4.30 or "
1534                                 "GLSL ES 3.10 or ARB_compute_shader",
1535                                 local_size_qualifiers[i]);
1536                YYERROR;
1537             } else {
1538                $$.flags.q.local_size |= (1 << i);
1539                $$.local_size[i] = $3;
1540             }
1541             break;
1542          }
1543       }
1544
1545       if (match_layout_qualifier("invocations", $1, state) == 0) {
1546          $$.flags.q.invocations = 1;
1547
1548          if ($3 <= 0) {
1549             _mesa_glsl_error(& @3, state,
1550                              "invalid invocations %d specified", $3);
1551             YYERROR;
1552          } else if ($3 > MAX_GEOMETRY_SHADER_INVOCATIONS) {
1553             _mesa_glsl_error(& @3, state,
1554                              "invocations (%d) exceeds "
1555                              "GL_MAX_GEOMETRY_SHADER_INVOCATIONS", $3);
1556             YYERROR;
1557          } else {
1558             $$.invocations = $3;
1559             if (!state->is_version(400, 0) &&
1560                 !state->ARB_gpu_shader5_enable) {
1561                _mesa_glsl_error(& @3, state,
1562                                 "GL_ARB_gpu_shader5 invocations "
1563                                 "qualifier specified", $3);
1564             }
1565          }
1566       }
1567
1568       /* Layout qualifiers for tessellation control shaders. */
1569       if (match_layout_qualifier("vertices", $1, state) == 0) {
1570          $$.flags.q.vertices = 1;
1571
1572          if ($3 <= 0) {
1573             _mesa_glsl_error(& @3, state,
1574                              "invalid vertices (%d) specified", $3);
1575             YYERROR;
1576          } else if ($3 > (int)state->Const.MaxPatchVertices) {
1577             _mesa_glsl_error(& @3, state,
1578                              "vertices (%d) exceeds "
1579                              "GL_MAX_PATCH_VERTICES", $3);
1580             YYERROR;
1581          } else {
1582             $$.vertices = $3;
1583             if (!state->ARB_tessellation_shader_enable &&
1584                 !state->is_version(400, 0)) {
1585                _mesa_glsl_error(& @1, state,
1586                                 "vertices qualifier requires GLSL 4.00 or "
1587                                 "ARB_tessellation_shader");
1588             }
1589          }
1590       }
1591
1592       /* If the identifier didn't match any known layout identifiers,
1593        * emit an error.
1594        */
1595       if (!$$.flags.i) {
1596          _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1597                           "`%s'", $1);
1598          YYERROR;
1599       }
1600    }
1601    | interface_block_layout_qualifier
1602    {
1603       $$ = $1;
1604       /* Layout qualifiers for ARB_uniform_buffer_object. */
1605       if ($$.flags.q.uniform && !state->has_uniform_buffer_objects()) {
1606          _mesa_glsl_error(& @1, state,
1607                           "#version 140 / GL_ARB_uniform_buffer_object "
1608                           "layout qualifier `%s' is used", $1);
1609       } else if ($$.flags.q.uniform && state->ARB_uniform_buffer_object_warn) {
1610          _mesa_glsl_warning(& @1, state,
1611                             "#version 140 / GL_ARB_uniform_buffer_object "
1612                             "layout qualifier `%s' is used", $1);
1613       }
1614    }
1615    ;
1616
1617 /* This is a separate language rule because we parse these as tokens
1618  * (due to them being reserved keywords) instead of identifiers like
1619  * most qualifiers.  See the any_identifier path of
1620  * layout_qualifier_id for the others.
1621  *
1622  * Note that since layout qualifiers are case-insensitive in desktop
1623  * GLSL, all of these qualifiers need to be handled as identifiers as
1624  * well (by the any_identifier path of layout_qualifier_id).
1625  */
1626 interface_block_layout_qualifier:
1627    ROW_MAJOR
1628    {
1629       memset(& $$, 0, sizeof($$));
1630       $$.flags.q.row_major = 1;
1631    }
1632    | PACKED_TOK
1633    {
1634       memset(& $$, 0, sizeof($$));
1635       $$.flags.q.packed = 1;
1636    }
1637    ;
1638
1639 subroutine_qualifier:
1640    SUBROUTINE
1641    {
1642       memset(& $$, 0, sizeof($$));
1643       $$.flags.q.subroutine = 1;
1644    }
1645    | SUBROUTINE '(' subroutine_type_list ')'
1646    {
1647       memset(& $$, 0, sizeof($$));
1648       $$.flags.q.subroutine_def = 1;
1649       $$.subroutine_list = $3;
1650    }
1651    ;
1652
1653 subroutine_type_list:
1654    any_identifier
1655    {
1656         void *ctx = state;
1657         ast_declaration *decl = new(ctx)  ast_declaration($1, NULL, NULL);
1658         decl->set_location(@1);
1659
1660         $$ = new(ctx) ast_subroutine_list();
1661         $$->declarations.push_tail(&decl->link);
1662    }
1663    | subroutine_type_list ',' any_identifier
1664    {
1665         void *ctx = state;
1666         ast_declaration *decl = new(ctx)  ast_declaration($3, NULL, NULL);
1667         decl->set_location(@3);
1668
1669         $$ = $1;
1670         $$->declarations.push_tail(&decl->link);
1671    }
1672    ;
1673
1674 interpolation_qualifier:
1675    SMOOTH
1676    {
1677       memset(& $$, 0, sizeof($$));
1678       $$.flags.q.smooth = 1;
1679    }
1680    | FLAT
1681    {
1682       memset(& $$, 0, sizeof($$));
1683       $$.flags.q.flat = 1;
1684    }
1685    | NOPERSPECTIVE
1686    {
1687       memset(& $$, 0, sizeof($$));
1688       $$.flags.q.noperspective = 1;
1689    }
1690    ;
1691
1692 type_qualifier:
1693    /* Single qualifiers */
1694    INVARIANT
1695    {
1696       memset(& $$, 0, sizeof($$));
1697       $$.flags.q.invariant = 1;
1698    }
1699    | PRECISE
1700    {
1701       memset(& $$, 0, sizeof($$));
1702       $$.flags.q.precise = 1;
1703    }
1704    | auxiliary_storage_qualifier
1705    | storage_qualifier
1706    | interpolation_qualifier
1707    | layout_qualifier
1708    | memory_qualifier
1709    | subroutine_qualifier
1710    | precision_qualifier
1711    {
1712       memset(&$$, 0, sizeof($$));
1713       $$.precision = $1;
1714    }
1715
1716    /* Multiple qualifiers:
1717     * In GLSL 4.20, these can be specified in any order.  In earlier versions,
1718     * they appear in this order (see GLSL 1.50 section 4.7 & comments below):
1719     *
1720     *    invariant interpolation auxiliary storage precision  ...or...
1721     *    layout storage precision
1722     *
1723     * Each qualifier's rule ensures that the accumulated qualifiers on the right
1724     * side don't contain any that must appear on the left hand side.
1725     * For example, when processing a storage qualifier, we check that there are
1726     * no auxiliary, interpolation, layout, invariant, or precise qualifiers to the right.
1727     */
1728    | PRECISE type_qualifier
1729    {
1730       if ($2.flags.q.precise)
1731          _mesa_glsl_error(&@1, state, "duplicate \"precise\" qualifier");
1732
1733       $$ = $2;
1734       $$.flags.q.precise = 1;
1735    }
1736    | INVARIANT type_qualifier
1737    {
1738       if ($2.flags.q.invariant)
1739          _mesa_glsl_error(&@1, state, "duplicate \"invariant\" qualifier");
1740
1741       if (!state->has_420pack() && $2.flags.q.precise)
1742          _mesa_glsl_error(&@1, state,
1743                           "\"invariant\" must come after \"precise\"");
1744
1745       $$ = $2;
1746       $$.flags.q.invariant = 1;
1747
1748       /* GLSL ES 3.00 spec, section 4.6.1 "The Invariant Qualifier":
1749        *
1750        * "Only variables output from a shader can be candidates for invariance.
1751        * This includes user-defined output variables and the built-in output
1752        * variables. As only outputs can be declared as invariant, an invariant
1753        * output from one shader stage will still match an input of a subsequent
1754        * stage without the input being declared as invariant."
1755        */
1756       if (state->es_shader && state->language_version >= 300 && $$.flags.q.in)
1757          _mesa_glsl_error(&@1, state, "invariant qualifiers cannot be used with shader inputs");
1758    }
1759    | interpolation_qualifier type_qualifier
1760    {
1761       /* Section 4.3 of the GLSL 1.40 specification states:
1762        * "...qualified with one of these interpolation qualifiers"
1763        *
1764        * GLSL 1.30 claims to allow "one or more", but insists that:
1765        * "These interpolation qualifiers may only precede the qualifiers in,
1766        *  centroid in, out, or centroid out in a declaration."
1767        *
1768        * ...which means that e.g. smooth can't precede smooth, so there can be
1769        * only one after all, and the 1.40 text is a clarification, not a change.
1770        */
1771       if ($2.has_interpolation())
1772          _mesa_glsl_error(&@1, state, "duplicate interpolation qualifier");
1773
1774       if (!state->has_420pack() &&
1775           ($2.flags.q.precise || $2.flags.q.invariant)) {
1776          _mesa_glsl_error(&@1, state, "interpolation qualifiers must come "
1777                           "after \"precise\" or \"invariant\"");
1778       }
1779
1780       $$ = $1;
1781       $$.merge_qualifier(&@1, state, $2);
1782    }
1783    | layout_qualifier type_qualifier
1784    {
1785       /* In the absence of ARB_shading_language_420pack, layout qualifiers may
1786        * appear no later than auxiliary storage qualifiers. There is no
1787        * particularly clear spec language mandating this, but in all examples
1788        * the layout qualifier precedes the storage qualifier.
1789        *
1790        * We allow combinations of layout with interpolation, invariant or
1791        * precise qualifiers since these are useful in ARB_separate_shader_objects.
1792        * There is no clear spec guidance on this either.
1793        */
1794       if (!state->has_420pack() && $2.has_layout())
1795          _mesa_glsl_error(&@1, state, "duplicate layout(...) qualifiers");
1796
1797       $$ = $1;
1798       $$.merge_qualifier(&@1, state, $2);
1799    }
1800    | subroutine_qualifier type_qualifier
1801    {
1802       $$ = $1;
1803       $$.merge_qualifier(&@1, state, $2);
1804    }
1805    | auxiliary_storage_qualifier type_qualifier
1806    {
1807       if ($2.has_auxiliary_storage()) {
1808          _mesa_glsl_error(&@1, state,
1809                           "duplicate auxiliary storage qualifier (centroid or sample)");
1810       }
1811
1812       if (!state->has_420pack() &&
1813           ($2.flags.q.precise || $2.flags.q.invariant ||
1814            $2.has_interpolation() || $2.has_layout())) {
1815          _mesa_glsl_error(&@1, state, "auxiliary storage qualifiers must come "
1816                           "just before storage qualifiers");
1817       }
1818       $$ = $1;
1819       $$.merge_qualifier(&@1, state, $2);
1820    }
1821    | storage_qualifier type_qualifier
1822    {
1823       /* Section 4.3 of the GLSL 1.20 specification states:
1824        * "Variable declarations may have a storage qualifier specified..."
1825        *  1.30 clarifies this to "may have one storage qualifier".
1826        */
1827       if ($2.has_storage())
1828          _mesa_glsl_error(&@1, state, "duplicate storage qualifier");
1829
1830       if (!state->has_420pack() &&
1831           ($2.flags.q.precise || $2.flags.q.invariant || $2.has_interpolation() ||
1832            $2.has_layout() || $2.has_auxiliary_storage())) {
1833          _mesa_glsl_error(&@1, state, "storage qualifiers must come after "
1834                           "precise, invariant, interpolation, layout and auxiliary "
1835                           "storage qualifiers");
1836       }
1837
1838       $$ = $1;
1839       $$.merge_qualifier(&@1, state, $2);
1840    }
1841    | precision_qualifier type_qualifier
1842    {
1843       if ($2.precision != ast_precision_none)
1844          _mesa_glsl_error(&@1, state, "duplicate precision qualifier");
1845
1846       if (!state->has_420pack() && $2.flags.i != 0)
1847          _mesa_glsl_error(&@1, state, "precision qualifiers must come last");
1848
1849       $$ = $2;
1850       $$.precision = $1;
1851    }
1852    | memory_qualifier type_qualifier
1853    {
1854       $$ = $1;
1855       $$.merge_qualifier(&@1, state, $2);
1856    }
1857    ;
1858
1859 auxiliary_storage_qualifier:
1860    CENTROID
1861    {
1862       memset(& $$, 0, sizeof($$));
1863       $$.flags.q.centroid = 1;
1864    }
1865    | SAMPLE
1866    {
1867       memset(& $$, 0, sizeof($$));
1868       $$.flags.q.sample = 1;
1869    }
1870    | PATCH
1871    {
1872       memset(& $$, 0, sizeof($$));
1873       $$.flags.q.patch = 1;
1874    }
1875
1876 storage_qualifier:
1877    CONST_TOK
1878    {
1879       memset(& $$, 0, sizeof($$));
1880       $$.flags.q.constant = 1;
1881    }
1882    | ATTRIBUTE
1883    {
1884       memset(& $$, 0, sizeof($$));
1885       $$.flags.q.attribute = 1;
1886    }
1887    | VARYING
1888    {
1889       memset(& $$, 0, sizeof($$));
1890       $$.flags.q.varying = 1;
1891    }
1892    | IN_TOK
1893    {
1894       memset(& $$, 0, sizeof($$));
1895       $$.flags.q.in = 1;
1896    }
1897    | OUT_TOK
1898    {
1899       memset(& $$, 0, sizeof($$));
1900       $$.flags.q.out = 1;
1901
1902       if (state->stage == MESA_SHADER_GEOMETRY &&
1903           state->has_explicit_attrib_stream()) {
1904          /* Section 4.3.8.2 (Output Layout Qualifiers) of the GLSL 4.00
1905           * spec says:
1906           *
1907           *     "If the block or variable is declared with the stream
1908           *     identifier, it is associated with the specified stream;
1909           *     otherwise, it is associated with the current default stream."
1910           */
1911           $$.flags.q.stream = 1;
1912           $$.flags.q.explicit_stream = 0;
1913           $$.stream = state->out_qualifier->stream;
1914       }
1915    }
1916    | UNIFORM
1917    {
1918       memset(& $$, 0, sizeof($$));
1919       $$.flags.q.uniform = 1;
1920    }
1921    | BUFFER
1922    {
1923       memset(& $$, 0, sizeof($$));
1924       $$.flags.q.buffer = 1;
1925    }
1926    ;
1927
1928 memory_qualifier:
1929    COHERENT
1930    {
1931       memset(& $$, 0, sizeof($$));
1932       $$.flags.q.coherent = 1;
1933    }
1934    | VOLATILE
1935    {
1936       memset(& $$, 0, sizeof($$));
1937       $$.flags.q._volatile = 1;
1938    }
1939    | RESTRICT
1940    {
1941       STATIC_ASSERT(sizeof($$.flags.q) <= sizeof($$.flags.i));
1942       memset(& $$, 0, sizeof($$));
1943       $$.flags.q.restrict_flag = 1;
1944    }
1945    | READONLY
1946    {
1947       memset(& $$, 0, sizeof($$));
1948       $$.flags.q.read_only = 1;
1949    }
1950    | WRITEONLY
1951    {
1952       memset(& $$, 0, sizeof($$));
1953       $$.flags.q.write_only = 1;
1954    }
1955    ;
1956
1957 array_specifier:
1958    '[' ']'
1959    {
1960       void *ctx = state;
1961       $$ = new(ctx) ast_array_specifier(@1);
1962       $$->set_location_range(@1, @2);
1963    }
1964    | '[' constant_expression ']'
1965    {
1966       void *ctx = state;
1967       $$ = new(ctx) ast_array_specifier(@1, $2);
1968       $$->set_location_range(@1, @3);
1969    }
1970    | array_specifier '[' ']'
1971    {
1972       $$ = $1;
1973
1974       if (!state->ARB_arrays_of_arrays_enable) {
1975          _mesa_glsl_error(& @1, state,
1976                           "GL_ARB_arrays_of_arrays "
1977                           "required for defining arrays of arrays");
1978       } else {
1979          _mesa_glsl_error(& @1, state,
1980                           "only the outermost array dimension can "
1981                           "be unsized");
1982       }
1983    }
1984    | array_specifier '[' constant_expression ']'
1985    {
1986       $$ = $1;
1987
1988       if (!state->ARB_arrays_of_arrays_enable) {
1989          _mesa_glsl_error(& @1, state,
1990                           "GL_ARB_arrays_of_arrays "
1991                           "required for defining arrays of arrays");
1992       }
1993
1994       $$->add_dimension($3);
1995    }
1996    ;
1997
1998 type_specifier:
1999    type_specifier_nonarray
2000    | type_specifier_nonarray array_specifier
2001    {
2002       $$ = $1;
2003       $$->array_specifier = $2;
2004    }
2005    ;
2006
2007 type_specifier_nonarray:
2008    basic_type_specifier_nonarray
2009    {
2010       void *ctx = state;
2011       $$ = new(ctx) ast_type_specifier($1);
2012       $$->set_location(@1);
2013    }
2014    | struct_specifier
2015    {
2016       void *ctx = state;
2017       $$ = new(ctx) ast_type_specifier($1);
2018       $$->set_location(@1);
2019    }
2020    | TYPE_IDENTIFIER
2021    {
2022       void *ctx = state;
2023       $$ = new(ctx) ast_type_specifier($1);
2024       $$->set_location(@1);
2025    }
2026    ;
2027
2028 basic_type_specifier_nonarray:
2029    VOID_TOK                 { $$ = "void"; }
2030    | FLOAT_TOK              { $$ = "float"; }
2031    | DOUBLE_TOK             { $$ = "double"; }
2032    | INT_TOK                { $$ = "int"; }
2033    | UINT_TOK               { $$ = "uint"; }
2034    | BOOL_TOK               { $$ = "bool"; }
2035    | VEC2                   { $$ = "vec2"; }
2036    | VEC3                   { $$ = "vec3"; }
2037    | VEC4                   { $$ = "vec4"; }
2038    | BVEC2                  { $$ = "bvec2"; }
2039    | BVEC3                  { $$ = "bvec3"; }
2040    | BVEC4                  { $$ = "bvec4"; }
2041    | IVEC2                  { $$ = "ivec2"; }
2042    | IVEC3                  { $$ = "ivec3"; }
2043    | IVEC4                  { $$ = "ivec4"; }
2044    | UVEC2                  { $$ = "uvec2"; }
2045    | UVEC3                  { $$ = "uvec3"; }
2046    | UVEC4                  { $$ = "uvec4"; }
2047    | DVEC2                  { $$ = "dvec2"; }
2048    | DVEC3                  { $$ = "dvec3"; }
2049    | DVEC4                  { $$ = "dvec4"; }
2050    | MAT2X2                 { $$ = "mat2"; }
2051    | MAT2X3                 { $$ = "mat2x3"; }
2052    | MAT2X4                 { $$ = "mat2x4"; }
2053    | MAT3X2                 { $$ = "mat3x2"; }
2054    | MAT3X3                 { $$ = "mat3"; }
2055    | MAT3X4                 { $$ = "mat3x4"; }
2056    | MAT4X2                 { $$ = "mat4x2"; }
2057    | MAT4X3                 { $$ = "mat4x3"; }
2058    | MAT4X4                 { $$ = "mat4"; }
2059    | DMAT2X2                { $$ = "dmat2"; }
2060    | DMAT2X3                { $$ = "dmat2x3"; }
2061    | DMAT2X4                { $$ = "dmat2x4"; }
2062    | DMAT3X2                { $$ = "dmat3x2"; }
2063    | DMAT3X3                { $$ = "dmat3"; }
2064    | DMAT3X4                { $$ = "dmat3x4"; }
2065    | DMAT4X2                { $$ = "dmat4x2"; }
2066    | DMAT4X3                { $$ = "dmat4x3"; }
2067    | DMAT4X4                { $$ = "dmat4"; }
2068    | SAMPLER1D              { $$ = "sampler1D"; }
2069    | SAMPLER2D              { $$ = "sampler2D"; }
2070    | SAMPLER2DRECT          { $$ = "sampler2DRect"; }
2071    | SAMPLER3D              { $$ = "sampler3D"; }
2072    | SAMPLERCUBE            { $$ = "samplerCube"; }
2073    | SAMPLEREXTERNALOES     { $$ = "samplerExternalOES"; }
2074    | SAMPLER1DSHADOW        { $$ = "sampler1DShadow"; }
2075    | SAMPLER2DSHADOW        { $$ = "sampler2DShadow"; }
2076    | SAMPLER2DRECTSHADOW    { $$ = "sampler2DRectShadow"; }
2077    | SAMPLERCUBESHADOW      { $$ = "samplerCubeShadow"; }
2078    | SAMPLER1DARRAY         { $$ = "sampler1DArray"; }
2079    | SAMPLER2DARRAY         { $$ = "sampler2DArray"; }
2080    | SAMPLER1DARRAYSHADOW   { $$ = "sampler1DArrayShadow"; }
2081    | SAMPLER2DARRAYSHADOW   { $$ = "sampler2DArrayShadow"; }
2082    | SAMPLERBUFFER          { $$ = "samplerBuffer"; }
2083    | SAMPLERCUBEARRAY       { $$ = "samplerCubeArray"; }
2084    | SAMPLERCUBEARRAYSHADOW { $$ = "samplerCubeArrayShadow"; }
2085    | ISAMPLER1D             { $$ = "isampler1D"; }
2086    | ISAMPLER2D             { $$ = "isampler2D"; }
2087    | ISAMPLER2DRECT         { $$ = "isampler2DRect"; }
2088    | ISAMPLER3D             { $$ = "isampler3D"; }
2089    | ISAMPLERCUBE           { $$ = "isamplerCube"; }
2090    | ISAMPLER1DARRAY        { $$ = "isampler1DArray"; }
2091    | ISAMPLER2DARRAY        { $$ = "isampler2DArray"; }
2092    | ISAMPLERBUFFER         { $$ = "isamplerBuffer"; }
2093    | ISAMPLERCUBEARRAY      { $$ = "isamplerCubeArray"; }
2094    | USAMPLER1D             { $$ = "usampler1D"; }
2095    | USAMPLER2D             { $$ = "usampler2D"; }
2096    | USAMPLER2DRECT         { $$ = "usampler2DRect"; }
2097    | USAMPLER3D             { $$ = "usampler3D"; }
2098    | USAMPLERCUBE           { $$ = "usamplerCube"; }
2099    | USAMPLER1DARRAY        { $$ = "usampler1DArray"; }
2100    | USAMPLER2DARRAY        { $$ = "usampler2DArray"; }
2101    | USAMPLERBUFFER         { $$ = "usamplerBuffer"; }
2102    | USAMPLERCUBEARRAY      { $$ = "usamplerCubeArray"; }
2103    | SAMPLER2DMS            { $$ = "sampler2DMS"; }
2104    | ISAMPLER2DMS           { $$ = "isampler2DMS"; }
2105    | USAMPLER2DMS           { $$ = "usampler2DMS"; }
2106    | SAMPLER2DMSARRAY       { $$ = "sampler2DMSArray"; }
2107    | ISAMPLER2DMSARRAY      { $$ = "isampler2DMSArray"; }
2108    | USAMPLER2DMSARRAY      { $$ = "usampler2DMSArray"; }
2109    | IMAGE1D                { $$ = "image1D"; }
2110    | IMAGE2D                { $$ = "image2D"; }
2111    | IMAGE3D                { $$ = "image3D"; }
2112    | IMAGE2DRECT            { $$ = "image2DRect"; }
2113    | IMAGECUBE              { $$ = "imageCube"; }
2114    | IMAGEBUFFER            { $$ = "imageBuffer"; }
2115    | IMAGE1DARRAY           { $$ = "image1DArray"; }
2116    | IMAGE2DARRAY           { $$ = "image2DArray"; }
2117    | IMAGECUBEARRAY         { $$ = "imageCubeArray"; }
2118    | IMAGE2DMS              { $$ = "image2DMS"; }
2119    | IMAGE2DMSARRAY         { $$ = "image2DMSArray"; }
2120    | IIMAGE1D               { $$ = "iimage1D"; }
2121    | IIMAGE2D               { $$ = "iimage2D"; }
2122    | IIMAGE3D               { $$ = "iimage3D"; }
2123    | IIMAGE2DRECT           { $$ = "iimage2DRect"; }
2124    | IIMAGECUBE             { $$ = "iimageCube"; }
2125    | IIMAGEBUFFER           { $$ = "iimageBuffer"; }
2126    | IIMAGE1DARRAY          { $$ = "iimage1DArray"; }
2127    | IIMAGE2DARRAY          { $$ = "iimage2DArray"; }
2128    | IIMAGECUBEARRAY        { $$ = "iimageCubeArray"; }
2129    | IIMAGE2DMS             { $$ = "iimage2DMS"; }
2130    | IIMAGE2DMSARRAY        { $$ = "iimage2DMSArray"; }
2131    | UIMAGE1D               { $$ = "uimage1D"; }
2132    | UIMAGE2D               { $$ = "uimage2D"; }
2133    | UIMAGE3D               { $$ = "uimage3D"; }
2134    | UIMAGE2DRECT           { $$ = "uimage2DRect"; }
2135    | UIMAGECUBE             { $$ = "uimageCube"; }
2136    | UIMAGEBUFFER           { $$ = "uimageBuffer"; }
2137    | UIMAGE1DARRAY          { $$ = "uimage1DArray"; }
2138    | UIMAGE2DARRAY          { $$ = "uimage2DArray"; }
2139    | UIMAGECUBEARRAY        { $$ = "uimageCubeArray"; }
2140    | UIMAGE2DMS             { $$ = "uimage2DMS"; }
2141    | UIMAGE2DMSARRAY        { $$ = "uimage2DMSArray"; }
2142    | ATOMIC_UINT            { $$ = "atomic_uint"; }
2143    ;
2144
2145 precision_qualifier:
2146    HIGHP
2147    {
2148       state->check_precision_qualifiers_allowed(&@1);
2149       $$ = ast_precision_high;
2150    }
2151    | MEDIUMP
2152    {
2153       state->check_precision_qualifiers_allowed(&@1);
2154       $$ = ast_precision_medium;
2155    }
2156    | LOWP
2157    {
2158       state->check_precision_qualifiers_allowed(&@1);
2159       $$ = ast_precision_low;
2160    }
2161    ;
2162
2163 struct_specifier:
2164    STRUCT any_identifier '{' struct_declaration_list '}'
2165    {
2166       void *ctx = state;
2167       $$ = new(ctx) ast_struct_specifier($2, $4);
2168       $$->set_location_range(@2, @5);
2169       state->symbols->add_type($2, glsl_type::void_type);
2170    }
2171    | STRUCT '{' struct_declaration_list '}'
2172    {
2173       void *ctx = state;
2174       $$ = new(ctx) ast_struct_specifier(NULL, $3);
2175       $$->set_location_range(@2, @4);
2176    }
2177    ;
2178
2179 struct_declaration_list:
2180    struct_declaration
2181    {
2182       $$ = $1;
2183       $1->link.self_link();
2184    }
2185    | struct_declaration_list struct_declaration
2186    {
2187       $$ = $1;
2188       $$->link.insert_before(& $2->link);
2189    }
2190    ;
2191
2192 struct_declaration:
2193    fully_specified_type struct_declarator_list ';'
2194    {
2195       void *ctx = state;
2196       ast_fully_specified_type *const type = $1;
2197       type->set_location(@1);
2198
2199       if (type->qualifier.flags.i != 0)
2200          _mesa_glsl_error(&@1, state,
2201                           "only precision qualifiers may be applied to "
2202                           "structure members");
2203
2204       $$ = new(ctx) ast_declarator_list(type);
2205       $$->set_location(@2);
2206
2207       $$->declarations.push_degenerate_list_at_head(& $2->link);
2208    }
2209    ;
2210
2211 struct_declarator_list:
2212    struct_declarator
2213    {
2214       $$ = $1;
2215       $1->link.self_link();
2216    }
2217    | struct_declarator_list ',' struct_declarator
2218    {
2219       $$ = $1;
2220       $$->link.insert_before(& $3->link);
2221    }
2222    ;
2223
2224 struct_declarator:
2225    any_identifier
2226    {
2227       void *ctx = state;
2228       $$ = new(ctx) ast_declaration($1, NULL, NULL);
2229       $$->set_location(@1);
2230    }
2231    | any_identifier array_specifier
2232    {
2233       void *ctx = state;
2234       $$ = new(ctx) ast_declaration($1, $2, NULL);
2235       $$->set_location_range(@1, @2);
2236    }
2237    ;
2238
2239 initializer:
2240    assignment_expression
2241    | '{' initializer_list '}'
2242    {
2243       $$ = $2;
2244    }
2245    | '{' initializer_list ',' '}'
2246    {
2247       $$ = $2;
2248    }
2249    ;
2250
2251 initializer_list:
2252    initializer
2253    {
2254       void *ctx = state;
2255       $$ = new(ctx) ast_aggregate_initializer();
2256       $$->set_location(@1);
2257       $$->expressions.push_tail(& $1->link);
2258    }
2259    | initializer_list ',' initializer
2260    {
2261       $1->expressions.push_tail(& $3->link);
2262    }
2263    ;
2264
2265 declaration_statement:
2266    declaration
2267    ;
2268
2269    // Grammar Note: labeled statements for SWITCH only; 'goto' is not
2270    // supported.
2271 statement:
2272    compound_statement        { $$ = (ast_node *) $1; }
2273    | simple_statement
2274    ;
2275
2276 simple_statement:
2277    declaration_statement
2278    | expression_statement
2279    | selection_statement
2280    | switch_statement
2281    | iteration_statement
2282    | jump_statement
2283    ;
2284
2285 compound_statement:
2286    '{' '}'
2287    {
2288       void *ctx = state;
2289       $$ = new(ctx) ast_compound_statement(true, NULL);
2290       $$->set_location_range(@1, @2);
2291    }
2292    | '{'
2293    {
2294       state->symbols->push_scope();
2295    }
2296    statement_list '}'
2297    {
2298       void *ctx = state;
2299       $$ = new(ctx) ast_compound_statement(true, $3);
2300       $$->set_location_range(@1, @4);
2301       state->symbols->pop_scope();
2302    }
2303    ;
2304
2305 statement_no_new_scope:
2306    compound_statement_no_new_scope { $$ = (ast_node *) $1; }
2307    | simple_statement
2308    ;
2309
2310 compound_statement_no_new_scope:
2311    '{' '}'
2312    {
2313       void *ctx = state;
2314       $$ = new(ctx) ast_compound_statement(false, NULL);
2315       $$->set_location_range(@1, @2);
2316    }
2317    | '{' statement_list '}'
2318    {
2319       void *ctx = state;
2320       $$ = new(ctx) ast_compound_statement(false, $2);
2321       $$->set_location_range(@1, @3);
2322    }
2323    ;
2324
2325 statement_list:
2326    statement
2327    {
2328       if ($1 == NULL) {
2329          _mesa_glsl_error(& @1, state, "<nil> statement");
2330          assert($1 != NULL);
2331       }
2332
2333       $$ = $1;
2334       $$->link.self_link();
2335    }
2336    | statement_list statement
2337    {
2338       if ($2 == NULL) {
2339          _mesa_glsl_error(& @2, state, "<nil> statement");
2340          assert($2 != NULL);
2341       }
2342       $$ = $1;
2343       $$->link.insert_before(& $2->link);
2344    }
2345    ;
2346
2347 expression_statement:
2348    ';'
2349    {
2350       void *ctx = state;
2351       $$ = new(ctx) ast_expression_statement(NULL);
2352       $$->set_location(@1);
2353    }
2354    | expression ';'
2355    {
2356       void *ctx = state;
2357       $$ = new(ctx) ast_expression_statement($1);
2358       $$->set_location(@1);
2359    }
2360    ;
2361
2362 selection_statement:
2363    IF '(' expression ')' selection_rest_statement
2364    {
2365       $$ = new(state) ast_selection_statement($3, $5.then_statement,
2366                                               $5.else_statement);
2367       $$->set_location_range(@1, @5);
2368    }
2369    ;
2370
2371 selection_rest_statement:
2372    statement ELSE statement
2373    {
2374       $$.then_statement = $1;
2375       $$.else_statement = $3;
2376    }
2377    | statement %prec THEN
2378    {
2379       $$.then_statement = $1;
2380       $$.else_statement = NULL;
2381    }
2382    ;
2383
2384 condition:
2385    expression
2386    {
2387       $$ = (ast_node *) $1;
2388    }
2389    | fully_specified_type any_identifier '=' initializer
2390    {
2391       void *ctx = state;
2392       ast_declaration *decl = new(ctx) ast_declaration($2, NULL, $4);
2393       ast_declarator_list *declarator = new(ctx) ast_declarator_list($1);
2394       decl->set_location_range(@2, @4);
2395       declarator->set_location(@1);
2396
2397       declarator->declarations.push_tail(&decl->link);
2398       $$ = declarator;
2399    }
2400    ;
2401
2402 /*
2403  * switch_statement grammar is based on the syntax described in the body
2404  * of the GLSL spec, not in it's appendix!!!
2405  */
2406 switch_statement:
2407    SWITCH '(' expression ')' switch_body
2408    {
2409       $$ = new(state) ast_switch_statement($3, $5);
2410       $$->set_location_range(@1, @5);
2411    }
2412    ;
2413
2414 switch_body:
2415    '{' '}'
2416    {
2417       $$ = new(state) ast_switch_body(NULL);
2418       $$->set_location_range(@1, @2);
2419    }
2420    | '{' case_statement_list '}'
2421    {
2422       $$ = new(state) ast_switch_body($2);
2423       $$->set_location_range(@1, @3);
2424    }
2425    ;
2426
2427 case_label:
2428    CASE expression ':'
2429    {
2430       $$ = new(state) ast_case_label($2);
2431       $$->set_location(@2);
2432    }
2433    | DEFAULT ':'
2434    {
2435       $$ = new(state) ast_case_label(NULL);
2436       $$->set_location(@2);
2437    }
2438    ;
2439
2440 case_label_list:
2441    case_label
2442    {
2443       ast_case_label_list *labels = new(state) ast_case_label_list();
2444
2445       labels->labels.push_tail(& $1->link);
2446       $$ = labels;
2447       $$->set_location(@1);
2448    }
2449    | case_label_list case_label
2450    {
2451       $$ = $1;
2452       $$->labels.push_tail(& $2->link);
2453    }
2454    ;
2455
2456 case_statement:
2457    case_label_list statement
2458    {
2459       ast_case_statement *stmts = new(state) ast_case_statement($1);
2460       stmts->set_location(@2);
2461
2462       stmts->stmts.push_tail(& $2->link);
2463       $$ = stmts;
2464    }
2465    | case_statement statement
2466    {
2467       $$ = $1;
2468       $$->stmts.push_tail(& $2->link);
2469    }
2470    ;
2471
2472 case_statement_list:
2473    case_statement
2474    {
2475       ast_case_statement_list *cases= new(state) ast_case_statement_list();
2476       cases->set_location(@1);
2477
2478       cases->cases.push_tail(& $1->link);
2479       $$ = cases;
2480    }
2481    | case_statement_list case_statement
2482    {
2483       $$ = $1;
2484       $$->cases.push_tail(& $2->link);
2485    }
2486    ;
2487
2488 iteration_statement:
2489    WHILE '(' condition ')' statement_no_new_scope
2490    {
2491       void *ctx = state;
2492       $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_while,
2493                                             NULL, $3, NULL, $5);
2494       $$->set_location_range(@1, @4);
2495    }
2496    | DO statement WHILE '(' expression ')' ';'
2497    {
2498       void *ctx = state;
2499       $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_do_while,
2500                                             NULL, $5, NULL, $2);
2501       $$->set_location_range(@1, @6);
2502    }
2503    | FOR '(' for_init_statement for_rest_statement ')' statement_no_new_scope
2504    {
2505       void *ctx = state;
2506       $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_for,
2507                                             $3, $4.cond, $4.rest, $6);
2508       $$->set_location_range(@1, @6);
2509    }
2510    ;
2511
2512 for_init_statement:
2513    expression_statement
2514    | declaration_statement
2515    ;
2516
2517 conditionopt:
2518    condition
2519    | /* empty */
2520    {
2521       $$ = NULL;
2522    }
2523    ;
2524
2525 for_rest_statement:
2526    conditionopt ';'
2527    {
2528       $$.cond = $1;
2529       $$.rest = NULL;
2530    }
2531    | conditionopt ';' expression
2532    {
2533       $$.cond = $1;
2534       $$.rest = $3;
2535    }
2536    ;
2537
2538    // Grammar Note: No 'goto'. Gotos are not supported.
2539 jump_statement:
2540    CONTINUE ';'
2541    {
2542       void *ctx = state;
2543       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_continue, NULL);
2544       $$->set_location(@1);
2545    }
2546    | BREAK ';'
2547    {
2548       void *ctx = state;
2549       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_break, NULL);
2550       $$->set_location(@1);
2551    }
2552    | RETURN ';'
2553    {
2554       void *ctx = state;
2555       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, NULL);
2556       $$->set_location(@1);
2557    }
2558    | RETURN expression ';'
2559    {
2560       void *ctx = state;
2561       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, $2);
2562       $$->set_location_range(@1, @2);
2563    }
2564    | DISCARD ';' // Fragment shader only.
2565    {
2566       void *ctx = state;
2567       $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_discard, NULL);
2568       $$->set_location(@1);
2569    }
2570    ;
2571
2572 external_declaration:
2573    function_definition      { $$ = $1; }
2574    | declaration            { $$ = $1; }
2575    | pragma_statement       { $$ = NULL; }
2576    | layout_defaults        { $$ = $1; }
2577    ;
2578
2579 function_definition:
2580    function_prototype compound_statement_no_new_scope
2581    {
2582       void *ctx = state;
2583       $$ = new(ctx) ast_function_definition();
2584       $$->set_location_range(@1, @2);
2585       $$->prototype = $1;
2586       $$->body = $2;
2587
2588       state->symbols->pop_scope();
2589    }
2590    ;
2591
2592 /* layout_qualifieropt is packed into this rule */
2593 interface_block:
2594    basic_interface_block
2595    {
2596       $$ = $1;
2597    }
2598    | layout_qualifier basic_interface_block
2599    {
2600       ast_interface_block *block = $2;
2601       if (!block->layout.merge_qualifier(& @1, state, $1)) {
2602          YYERROR;
2603       }
2604
2605       foreach_list_typed (ast_declarator_list, member, link, &block->declarations) {
2606          ast_type_qualifier& qualifier = member->type->qualifier;
2607          if (qualifier.flags.q.stream && qualifier.stream != block->layout.stream) {
2608                _mesa_glsl_error(& @1, state,
2609                              "stream layout qualifier on "
2610                              "interface block member does not match "
2611                              "the interface block (%d vs %d)",
2612                              qualifier.stream, block->layout.stream);
2613                YYERROR;
2614          }
2615       }
2616       $$ = block;
2617    }
2618    ;
2619
2620 basic_interface_block:
2621    interface_qualifier NEW_IDENTIFIER '{' member_list '}' instance_name_opt ';'
2622    {
2623       ast_interface_block *const block = $6;
2624
2625       block->block_name = $2;
2626       block->declarations.push_degenerate_list_at_head(& $4->link);
2627
2628       if ($1.flags.q.buffer) {
2629          if (!state->has_shader_storage_buffer_objects()) {
2630             _mesa_glsl_error(& @1, state,
2631                              "#version 430 / GL_ARB_shader_storage_buffer_object "
2632                              "required for defining shader storage blocks");
2633          } else if (state->ARB_shader_storage_buffer_object_warn) {
2634             _mesa_glsl_warning(& @1, state,
2635                                "#version 430 / GL_ARB_shader_storage_buffer_object "
2636                                "required for defining shader storage blocks");
2637          }
2638       } else if ($1.flags.q.uniform) {
2639          if (!state->has_uniform_buffer_objects()) {
2640             _mesa_glsl_error(& @1, state,
2641                              "#version 140 / GL_ARB_uniform_buffer_object "
2642                              "required for defining uniform blocks");
2643          } else if (state->ARB_uniform_buffer_object_warn) {
2644             _mesa_glsl_warning(& @1, state,
2645                                "#version 140 / GL_ARB_uniform_buffer_object "
2646                                "required for defining uniform blocks");
2647          }
2648       } else {
2649          if (state->es_shader || state->language_version < 150) {
2650             _mesa_glsl_error(& @1, state,
2651                              "#version 150 required for using "
2652                              "interface blocks");
2653          }
2654       }
2655
2656       /* From the GLSL 1.50.11 spec, section 4.3.7 ("Interface Blocks"):
2657        * "It is illegal to have an input block in a vertex shader
2658        *  or an output block in a fragment shader"
2659        */
2660       if ((state->stage == MESA_SHADER_VERTEX) && $1.flags.q.in) {
2661          _mesa_glsl_error(& @1, state,
2662                           "`in' interface block is not allowed for "
2663                           "a vertex shader");
2664       } else if ((state->stage == MESA_SHADER_FRAGMENT) && $1.flags.q.out) {
2665          _mesa_glsl_error(& @1, state,
2666                           "`out' interface block is not allowed for "
2667                           "a fragment shader");
2668       }
2669
2670       /* Since block arrays require names, and both features are added in
2671        * the same language versions, we don't have to explicitly
2672        * version-check both things.
2673        */
2674       if (block->instance_name != NULL) {
2675          state->check_version(150, 300, & @1, "interface blocks with "
2676                                "an instance name are not allowed");
2677       }
2678
2679       uint64_t interface_type_mask;
2680       struct ast_type_qualifier temp_type_qualifier;
2681
2682       /* Get a bitmask containing only the in/out/uniform/buffer
2683        * flags, allowing us to ignore other irrelevant flags like
2684        * interpolation qualifiers.
2685        */
2686       temp_type_qualifier.flags.i = 0;
2687       temp_type_qualifier.flags.q.uniform = true;
2688       temp_type_qualifier.flags.q.buffer = true;
2689       temp_type_qualifier.flags.q.in = true;
2690       temp_type_qualifier.flags.q.out = true;
2691       interface_type_mask = temp_type_qualifier.flags.i;
2692
2693       /* Get the block's interface qualifier.  The interface_qualifier
2694        * production rule guarantees that only one bit will be set (and
2695        * it will be in/out/uniform).
2696        */
2697       uint64_t block_interface_qualifier = $1.flags.i;
2698
2699       block->layout.flags.i |= block_interface_qualifier;
2700
2701       if (state->stage == MESA_SHADER_GEOMETRY &&
2702           state->has_explicit_attrib_stream()) {
2703          /* Assign global layout's stream value. */
2704          block->layout.flags.q.stream = 1;
2705          block->layout.flags.q.explicit_stream = 0;
2706          block->layout.stream = state->out_qualifier->stream;
2707       }
2708
2709       foreach_list_typed (ast_declarator_list, member, link, &block->declarations) {
2710          ast_type_qualifier& qualifier = member->type->qualifier;
2711          if ((qualifier.flags.i & interface_type_mask) == 0) {
2712             /* GLSLangSpec.1.50.11, 4.3.7 (Interface Blocks):
2713              * "If no optional qualifier is used in a member declaration, the
2714              *  qualifier of the variable is just in, out, or uniform as declared
2715              *  by interface-qualifier."
2716              */
2717             qualifier.flags.i |= block_interface_qualifier;
2718          } else if ((qualifier.flags.i & interface_type_mask) !=
2719                     block_interface_qualifier) {
2720             /* GLSLangSpec.1.50.11, 4.3.7 (Interface Blocks):
2721              * "If optional qualifiers are used, they can include interpolation
2722              *  and storage qualifiers and they must declare an input, output,
2723              *  or uniform variable consistent with the interface qualifier of
2724              *  the block."
2725              */
2726             _mesa_glsl_error(& @1, state,
2727                              "uniform/in/out qualifier on "
2728                              "interface block member does not match "
2729                              "the interface block");
2730          }
2731
2732          /* From GLSL ES 3.0, chapter 4.3.7 "Interface Blocks":
2733           *
2734           * "GLSL ES 3.0 does not support interface blocks for shader inputs or
2735           * outputs."
2736           *
2737           * And from GLSL ES 3.0, chapter 4.6.1 "The invariant qualifier":.
2738           *
2739           * "Only variables output from a shader can be candidates for
2740           * invariance."
2741           *
2742           * From GLSL 4.40 and GLSL 1.50, section "Interface Blocks":
2743           *
2744           * "If optional qualifiers are used, they can include interpolation
2745           * qualifiers, auxiliary storage qualifiers, and storage qualifiers
2746           * and they must declare an input, output, or uniform member
2747           * consistent with the interface qualifier of the block"
2748           */
2749          if (qualifier.flags.q.invariant)
2750             _mesa_glsl_error(&@1, state,
2751                              "invariant qualifiers cannot be used "
2752                              "with interface blocks members");
2753       }
2754
2755       $$ = block;
2756    }
2757    ;
2758
2759 interface_qualifier:
2760    IN_TOK
2761    {
2762       memset(& $$, 0, sizeof($$));
2763       $$.flags.q.in = 1;
2764    }
2765    | OUT_TOK
2766    {
2767       memset(& $$, 0, sizeof($$));
2768       $$.flags.q.out = 1;
2769    }
2770    | UNIFORM
2771    {
2772       memset(& $$, 0, sizeof($$));
2773       $$.flags.q.uniform = 1;
2774    }
2775    | BUFFER
2776    {
2777       memset(& $$, 0, sizeof($$));
2778       $$.flags.q.buffer = 1;
2779    }
2780    ;
2781
2782 instance_name_opt:
2783    /* empty */
2784    {
2785       $$ = new(state) ast_interface_block(*state->default_uniform_qualifier,
2786                                           NULL, NULL);
2787    }
2788    | NEW_IDENTIFIER
2789    {
2790       $$ = new(state) ast_interface_block(*state->default_uniform_qualifier,
2791                                           $1, NULL);
2792       $$->set_location(@1);
2793    }
2794    | NEW_IDENTIFIER array_specifier
2795    {
2796       $$ = new(state) ast_interface_block(*state->default_uniform_qualifier,
2797                                           $1, $2);
2798       $$->set_location_range(@1, @2);
2799    }
2800    ;
2801
2802 member_list:
2803    member_declaration
2804    {
2805       $$ = $1;
2806       $1->link.self_link();
2807    }
2808    | member_declaration member_list
2809    {
2810       $$ = $1;
2811       $2->link.insert_before(& $$->link);
2812    }
2813    ;
2814
2815 member_declaration:
2816    fully_specified_type struct_declarator_list ';'
2817    {
2818       void *ctx = state;
2819       ast_fully_specified_type *type = $1;
2820       type->set_location(@1);
2821
2822       if (type->qualifier.flags.q.attribute) {
2823          _mesa_glsl_error(& @1, state,
2824                           "keyword 'attribute' cannot be used with "
2825                           "interface block member");
2826       } else if (type->qualifier.flags.q.varying) {
2827          _mesa_glsl_error(& @1, state,
2828                           "keyword 'varying' cannot be used with "
2829                           "interface block member");
2830       }
2831
2832       $$ = new(ctx) ast_declarator_list(type);
2833       $$->set_location(@2);
2834
2835       $$->declarations.push_degenerate_list_at_head(& $2->link);
2836    }
2837    ;
2838
2839 layout_defaults:
2840    layout_qualifier UNIFORM ';'
2841    {
2842       if (!state->default_uniform_qualifier->merge_qualifier(& @1, state, $1)) {
2843          YYERROR;
2844       }
2845       $$ = NULL;
2846    }
2847
2848    | layout_qualifier IN_TOK ';'
2849    {
2850       $$ = NULL;
2851       if (!state->in_qualifier->merge_in_qualifier(& @1, state, $1, $$)) {
2852          YYERROR;
2853       }
2854    }
2855
2856    | layout_qualifier OUT_TOK ';'
2857    {
2858       $$ = NULL;
2859       if (state->stage == MESA_SHADER_GEOMETRY) {
2860          if ($1.flags.q.prim_type) {
2861             /* Make sure this is a valid output primitive type. */
2862             switch ($1.prim_type) {
2863             case GL_POINTS:
2864             case GL_LINE_STRIP:
2865             case GL_TRIANGLE_STRIP:
2866                break;
2867             default:
2868                _mesa_glsl_error(&@1, state, "invalid geometry shader output "
2869                                 "primitive type");
2870                break;
2871             }
2872          }
2873          if (!state->out_qualifier->merge_qualifier(& @1, state, $1))
2874             YYERROR;
2875
2876          /* Allow future assigments of global out's stream id value */
2877          state->out_qualifier->flags.q.explicit_stream = 0;
2878       } else if (state->stage == MESA_SHADER_TESS_CTRL) {
2879          if (!state->out_qualifier->merge_out_qualifier(& @1, state, $1, $$))
2880             YYERROR;
2881       } else {
2882          _mesa_glsl_error(& @1, state,
2883                           "out layout qualifiers only valid in "
2884                           "tessellation control or geometry shaders");
2885       }
2886    }