projects / mesa.git / blob
? search:


72bf560f07e1b0029d0d0d5ca07827cbaab45836
[mesa.git] / src / glsl / glsl_parser.yy
1 %{
2 /*
3 * Copyright © 2008, 2009 Intel Corporation
4 *
5 * Permission is hereby granted, free of charge, to any person obtaining a
6 * copy of this software and associated documentation files (the "Software"),
7 * to deal in the Software without restriction, including without limitation
8 * the rights to use, copy, modify, merge, publish, distribute, sublicense,
9 * and/or sell copies of the Software, and to permit persons to whom the
10 * Software is furnished to do so, subject to the following conditions:
11 *
12 * The above copyright notice and this permission notice (including the next
13 * paragraph) shall be included in all copies or substantial portions of the
14 * Software.
15 *
16 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
17 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
18 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
19 * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
20 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
21 * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
22 * DEALINGS IN THE SOFTWARE.
23 */
24 #include <stdio.h>
25 #include <stdlib.h>
26 #include <string.h>
27 #include <assert.h>
28
29 #include "ast.h"
30 #include "glsl_parser_extras.h"
31 #include "glsl_types.h"
32 #include "main/context.h"
33
34 #define YYLEX_PARAM state->scanner
35
36 #undef yyerror
37
38 static void yyerror(YYLTYPE *loc, _mesa_glsl_parse_state *st, const char *msg)
39 {
40 _mesa_glsl_error(loc, st, "%s", msg);
41 }
42 %}
43
44 %expect 0
45
46 %pure-parser
47 %error-verbose
48
49 %locations
50 %initial-action {
51 @$.first_line = 1;
52 @$.first_column = 1;
53 @$.last_line = 1;
54 @$.last_column = 1;
55 @$.source = 0;
56 }
57
58 %lex-param {void *scanner}
59 %parse-param {struct _mesa_glsl_parse_state *state}
60
61 %union {
62 int n;
63 float real;
64 const char *identifier;
65
66 struct ast_type_qualifier type_qualifier;
67
68 ast_node *node;
69 ast_type_specifier *type_specifier;
70 ast_fully_specified_type *fully_specified_type;
71 ast_function *function;
72 ast_parameter_declarator *parameter_declarator;
73 ast_function_definition *function_definition;
74 ast_compound_statement *compound_statement;
75 ast_expression *expression;
76 ast_declarator_list *declarator_list;
77 ast_struct_specifier *struct_specifier;
78 ast_declaration *declaration;
79 ast_switch_body *switch_body;
80 ast_case_label *case_label;
81 ast_case_label_list *case_label_list;
82 ast_case_statement *case_statement;
83 ast_case_statement_list *case_statement_list;
84 ast_interface_block *interface_block;
85
86 struct {
87 ast_node *cond;
88 ast_expression *rest;
89 } for_rest_statement;
90
91 struct {
92 ast_node *then_statement;
93 ast_node *else_statement;
94 } selection_rest_statement;
95 }
96
97 %token ATTRIBUTE CONST_TOK BOOL_TOK FLOAT_TOK INT_TOK UINT_TOK
98 %token BREAK CONTINUE DO ELSE FOR IF DISCARD RETURN SWITCH CASE DEFAULT
99 %token BVEC2 BVEC3 BVEC4 IVEC2 IVEC3 IVEC4 UVEC2 UVEC3 UVEC4 VEC2 VEC3 VEC4
100 %token CENTROID IN_TOK OUT_TOK INOUT_TOK UNIFORM VARYING
101 %token NOPERSPECTIVE FLAT SMOOTH
102 %token MAT2X2 MAT2X3 MAT2X4
103 %token MAT3X2 MAT3X3 MAT3X4
104 %token MAT4X2 MAT4X3 MAT4X4
105 %token SAMPLER1D SAMPLER2D SAMPLER3D SAMPLERCUBE SAMPLER1DSHADOW SAMPLER2DSHADOW
106 %token SAMPLERCUBESHADOW SAMPLER1DARRAY SAMPLER2DARRAY SAMPLER1DARRAYSHADOW
107 %token SAMPLER2DARRAYSHADOW SAMPLERCUBEARRAY SAMPLERCUBEARRAYSHADOW
108 %token ISAMPLER1D ISAMPLER2D ISAMPLER3D ISAMPLERCUBE
109 %token ISAMPLER1DARRAY ISAMPLER2DARRAY ISAMPLERCUBEARRAY
110 %token USAMPLER1D USAMPLER2D USAMPLER3D USAMPLERCUBE USAMPLER1DARRAY
111 %token USAMPLER2DARRAY USAMPLERCUBEARRAY
112 %token SAMPLER2DRECT ISAMPLER2DRECT USAMPLER2DRECT SAMPLER2DRECTSHADOW
113 %token SAMPLERBUFFER ISAMPLERBUFFER USAMPLERBUFFER
114 %token SAMPLER2DMS ISAMPLER2DMS USAMPLER2DMS
115 %token SAMPLER2DMSARRAY ISAMPLER2DMSARRAY USAMPLER2DMSARRAY
116 %token SAMPLEREXTERNALOES
117 %token STRUCT VOID_TOK WHILE
118 %token <identifier> IDENTIFIER TYPE_IDENTIFIER NEW_IDENTIFIER
119 %type <identifier> any_identifier
120 %type <interface_block> instance_name_opt
121 %token <real> FLOATCONSTANT
122 %token <n> INTCONSTANT UINTCONSTANT BOOLCONSTANT
123 %token <identifier> FIELD_SELECTION
124 %token LEFT_OP RIGHT_OP
125 %token INC_OP DEC_OP LE_OP GE_OP EQ_OP NE_OP
126 %token AND_OP OR_OP XOR_OP MUL_ASSIGN DIV_ASSIGN ADD_ASSIGN
127 %token MOD_ASSIGN LEFT_ASSIGN RIGHT_ASSIGN AND_ASSIGN XOR_ASSIGN OR_ASSIGN
128 %token SUB_ASSIGN
129 %token INVARIANT
130 %token LOWP MEDIUMP HIGHP SUPERP PRECISION
131
132 %token VERSION_TOK EXTENSION LINE COLON EOL INTERFACE OUTPUT
133 %token PRAGMA_DEBUG_ON PRAGMA_DEBUG_OFF
134 %token PRAGMA_OPTIMIZE_ON PRAGMA_OPTIMIZE_OFF
135 %token PRAGMA_INVARIANT_ALL
136 %token LAYOUT_TOK
137
138 /* Reserved words that are not actually used in the grammar.
139 */
140 %token ASM CLASS UNION ENUM TYPEDEF TEMPLATE THIS PACKED_TOK GOTO
141 %token INLINE_TOK NOINLINE VOLATILE PUBLIC_TOK STATIC EXTERN EXTERNAL
142 %token LONG_TOK SHORT_TOK DOUBLE_TOK HALF FIXED_TOK UNSIGNED INPUT_TOK OUPTUT
143 %token HVEC2 HVEC3 HVEC4 DVEC2 DVEC3 DVEC4 FVEC2 FVEC3 FVEC4
144 %token SAMPLER3DRECT
145 %token SIZEOF CAST NAMESPACE USING
146 %token COHERENT RESTRICT READONLY WRITEONLY RESOURCE ATOMIC_UINT PATCH SAMPLE
147 %token SUBROUTINE
148
149 %token ERROR_TOK
150
151 %token COMMON PARTITION ACTIVE FILTER
152 %token IMAGE1D IMAGE2D IMAGE3D IMAGECUBE IMAGE1DARRAY IMAGE2DARRAY
153 %token IIMAGE1D IIMAGE2D IIMAGE3D IIMAGECUBE IIMAGE1DARRAY IIMAGE2DARRAY
154 %token UIMAGE1D UIMAGE2D UIMAGE3D UIMAGECUBE UIMAGE1DARRAY UIMAGE2DARRAY
155 %token IMAGE1DSHADOW IMAGE2DSHADOW IMAGEBUFFER IIMAGEBUFFER UIMAGEBUFFER
156 %token IMAGE1DARRAYSHADOW IMAGE2DARRAYSHADOW
157 %token ROW_MAJOR
158
159 %type <identifier> variable_identifier
160 %type <node> statement
161 %type <node> statement_list
162 %type <node> simple_statement
163 %type <n> precision_qualifier
164 %type <type_qualifier> type_qualifier
165 %type <type_qualifier> storage_qualifier
166 %type <type_qualifier> interpolation_qualifier
167 %type <type_qualifier> layout_qualifier
168 %type <type_qualifier> layout_qualifier_id_list layout_qualifier_id
169 %type <type_qualifier> interface_block_layout_qualifier
170 %type <type_qualifier> interface_qualifier
171 %type <type_specifier> type_specifier
172 %type <type_specifier> type_specifier_no_prec
173 %type <type_specifier> type_specifier_nonarray
174 %type <identifier> basic_type_specifier_nonarray
175 %type <fully_specified_type> fully_specified_type
176 %type <function> function_prototype
177 %type <function> function_header
178 %type <function> function_header_with_parameters
179 %type <function> function_declarator
180 %type <parameter_declarator> parameter_declarator
181 %type <parameter_declarator> parameter_declaration
182 %type <type_qualifier> parameter_qualifier
183 %type <type_qualifier> parameter_type_qualifier
184 %type <type_specifier> parameter_type_specifier
185 %type <function_definition> function_definition
186 %type <compound_statement> compound_statement_no_new_scope
187 %type <compound_statement> compound_statement
188 %type <node> statement_no_new_scope
189 %type <node> expression_statement
190 %type <expression> expression
191 %type <expression> primary_expression
192 %type <expression> assignment_expression
193 %type <expression> conditional_expression
194 %type <expression> logical_or_expression
195 %type <expression> logical_xor_expression
196 %type <expression> logical_and_expression
197 %type <expression> inclusive_or_expression
198 %type <expression> exclusive_or_expression
199 %type <expression> and_expression
200 %type <expression> equality_expression
201 %type <expression> relational_expression
202 %type <expression> shift_expression
203 %type <expression> additive_expression
204 %type <expression> multiplicative_expression
205 %type <expression> unary_expression
206 %type <expression> constant_expression
207 %type <expression> integer_expression
208 %type <expression> postfix_expression
209 %type <expression> function_call_header_with_parameters
210 %type <expression> function_call_header_no_parameters
211 %type <expression> function_call_header
212 %type <expression> function_call_generic
213 %type <expression> function_call_or_method
214 %type <expression> function_call
215 %type <expression> method_call_generic
216 %type <expression> method_call_header_with_parameters
217 %type <expression> method_call_header_no_parameters
218 %type <expression> method_call_header
219 %type <n> assignment_operator
220 %type <n> unary_operator
221 %type <expression> function_identifier
222 %type <node> external_declaration
223 %type <declarator_list> init_declarator_list
224 %type <declarator_list> single_declaration
225 %type <expression> initializer
226 %type <expression> initializer_list
227 %type <node> declaration
228 %type <node> declaration_statement
229 %type <node> jump_statement
230 %type <node> interface_block
231 %type <interface_block> basic_interface_block
232 %type <struct_specifier> struct_specifier
233 %type <declarator_list> struct_declaration_list
234 %type <declarator_list> struct_declaration
235 %type <declaration> struct_declarator
236 %type <declaration> struct_declarator_list
237 %type <declarator_list> member_list
238 %type <declarator_list> member_declaration
239 %type <node> selection_statement
240 %type <selection_rest_statement> selection_rest_statement
241 %type <node> switch_statement
242 %type <switch_body> switch_body
243 %type <case_label_list> case_label_list
244 %type <case_label> case_label
245 %type <case_statement> case_statement
246 %type <case_statement_list> case_statement_list
247 %type <node> iteration_statement
248 %type <node> condition
249 %type <node> conditionopt
250 %type <node> for_init_statement
251 %type <for_rest_statement> for_rest_statement
252 %type <n> integer_constant
253
254 %right THEN ELSE
255 %%
256
257 translation_unit:
258 version_statement extension_statement_list
259 {
260 _mesa_glsl_initialize_types(state);
261 }
262 external_declaration_list
263 {
264 delete state->symbols;
265 state->symbols = new(ralloc_parent(state)) glsl_symbol_table;
266 _mesa_glsl_initialize_types(state);
267 }
268 ;
269
270 version_statement:
271 /* blank - no #version specified: defaults are already set */
272 | VERSION_TOK INTCONSTANT EOL
273 {
274 state->process_version_directive(&@2, $2, NULL);
275 if (state->error) {
276 YYERROR;
277 }
278 }
279 | VERSION_TOK INTCONSTANT any_identifier EOL
280 {
281 state->process_version_directive(&@2, $2, $3);
282 if (state->error) {
283 YYERROR;
284 }
285 }
286 ;
287
288 pragma_statement:
289 PRAGMA_DEBUG_ON EOL
290 | PRAGMA_DEBUG_OFF EOL
291 | PRAGMA_OPTIMIZE_ON EOL
292 | PRAGMA_OPTIMIZE_OFF EOL
293 | PRAGMA_INVARIANT_ALL EOL
294 {
295 if (!state->is_version(120, 100)) {
296 _mesa_glsl_warning(& @1, state,
297 "pragma `invariant(all)' not supported in %s "
298 "(GLSL ES 1.00 or GLSL 1.20 required).",
299 state->get_version_string());
300 } else {
301 state->all_invariant = true;
302 }
303 }
304 ;
305
306 extension_statement_list:
307
308 | extension_statement_list extension_statement
309 ;
310
311 any_identifier:
312 IDENTIFIER
313 | TYPE_IDENTIFIER
314 | NEW_IDENTIFIER
315 ;
316
317 extension_statement:
318 EXTENSION any_identifier COLON any_identifier EOL
319 {
320 if (!_mesa_glsl_process_extension($2, & @2, $4, & @4, state)) {
321 YYERROR;
322 }
323 }
324 ;
325
326 external_declaration_list:
327 external_declaration
328 {
329 /* FINISHME: The NULL test is required because pragmas are set to
330 * FINISHME: NULL. (See production rule for external_declaration.)
331 */
332 if ($1 != NULL)
333 state->translation_unit.push_tail(& $1->link);
334 }
335 | external_declaration_list external_declaration
336 {
337 /* FINISHME: The NULL test is required because pragmas are set to
338 * FINISHME: NULL. (See production rule for external_declaration.)
339 */
340 if ($2 != NULL)
341 state->translation_unit.push_tail(& $2->link);
342 }
343 ;
344
345 variable_identifier:
346 IDENTIFIER
347 | NEW_IDENTIFIER
348 ;
349
350 primary_expression:
351 variable_identifier
352 {
353 void *ctx = state;
354 $$ = new(ctx) ast_expression(ast_identifier, NULL, NULL, NULL);
355 $$->set_location(yylloc);
356 $$->primary_expression.identifier = $1;
357 }
358 | INTCONSTANT
359 {
360 void *ctx = state;
361 $$ = new(ctx) ast_expression(ast_int_constant, NULL, NULL, NULL);
362 $$->set_location(yylloc);
363 $$->primary_expression.int_constant = $1;
364 }
365 | UINTCONSTANT
366 {
367 void *ctx = state;
368 $$ = new(ctx) ast_expression(ast_uint_constant, NULL, NULL, NULL);
369 $$->set_location(yylloc);
370 $$->primary_expression.uint_constant = $1;
371 }
372 | FLOATCONSTANT
373 {
374 void *ctx = state;
375 $$ = new(ctx) ast_expression(ast_float_constant, NULL, NULL, NULL);
376 $$->set_location(yylloc);
377 $$->primary_expression.float_constant = $1;
378 }
379 | BOOLCONSTANT
380 {
381 void *ctx = state;
382 $$ = new(ctx) ast_expression(ast_bool_constant, NULL, NULL, NULL);
383 $$->set_location(yylloc);
384 $$->primary_expression.bool_constant = $1;
385 }
386 | '(' expression ')'
387 {
388 $$ = $2;
389 }
390 ;
391
392 postfix_expression:
393 primary_expression
394 | postfix_expression '[' integer_expression ']'
395 {
396 void *ctx = state;
397 $$ = new(ctx) ast_expression(ast_array_index, $1, $3, NULL);
398 $$->set_location(yylloc);
399 }
400 | function_call
401 {
402 $$ = $1;
403 }
404 | postfix_expression '.' any_identifier
405 {
406 void *ctx = state;
407 $$ = new(ctx) ast_expression(ast_field_selection, $1, NULL, NULL);
408 $$->set_location(yylloc);
409 $$->primary_expression.identifier = $3;
410 }
411 | postfix_expression INC_OP
412 {
413 void *ctx = state;
414 $$ = new(ctx) ast_expression(ast_post_inc, $1, NULL, NULL);
415 $$->set_location(yylloc);
416 }
417 | postfix_expression DEC_OP
418 {
419 void *ctx = state;
420 $$ = new(ctx) ast_expression(ast_post_dec, $1, NULL, NULL);
421 $$->set_location(yylloc);
422 }
423 ;
424
425 integer_expression:
426 expression
427 ;
428
429 function_call:
430 function_call_or_method
431 ;
432
433 function_call_or_method:
434 function_call_generic
435 | postfix_expression '.' method_call_generic
436 {
437 void *ctx = state;
438 $$ = new(ctx) ast_expression(ast_field_selection, $1, $3, NULL);
439 $$->set_location(yylloc);
440 }
441 ;
442
443 function_call_generic:
444 function_call_header_with_parameters ')'
445 | function_call_header_no_parameters ')'
446 ;
447
448 function_call_header_no_parameters:
449 function_call_header VOID_TOK
450 | function_call_header
451 ;
452
453 function_call_header_with_parameters:
454 function_call_header assignment_expression
455 {
456 $$ = $1;
457 $$->set_location(yylloc);
458 $$->expressions.push_tail(& $2->link);
459 }
460 | function_call_header_with_parameters ',' assignment_expression
461 {
462 $$ = $1;
463 $$->set_location(yylloc);
464 $$->expressions.push_tail(& $3->link);
465 }
466 ;
467
468 // Grammar Note: Constructors look like functions, but lexical
469 // analysis recognized most of them as keywords. They are now
470 // recognized through "type_specifier".
471 function_call_header:
472 function_identifier '('
473 ;
474
475 function_identifier:
476 type_specifier
477 {
478 void *ctx = state;
479 $$ = new(ctx) ast_function_expression($1);
480 $$->set_location(yylloc);
481 }
482 | variable_identifier
483 {
484 void *ctx = state;
485 ast_expression *callee = new(ctx) ast_expression($1);
486 $$ = new(ctx) ast_function_expression(callee);
487 $$->set_location(yylloc);
488 }
489 | FIELD_SELECTION
490 {
491 void *ctx = state;
492 ast_expression *callee = new(ctx) ast_expression($1);
493 $$ = new(ctx) ast_function_expression(callee);
494 $$->set_location(yylloc);
495 }
496 ;
497
498 method_call_generic:
499 method_call_header_with_parameters ')'
500 | method_call_header_no_parameters ')'
501 ;
502
503 method_call_header_no_parameters:
504 method_call_header VOID_TOK
505 | method_call_header
506 ;
507
508 method_call_header_with_parameters:
509 method_call_header assignment_expression
510 {
511 $$ = $1;
512 $$->set_location(yylloc);
513 $$->expressions.push_tail(& $2->link);
514 }
515 | method_call_header_with_parameters ',' assignment_expression
516 {
517 $$ = $1;
518 $$->set_location(yylloc);
519 $$->expressions.push_tail(& $3->link);
520 }
521 ;
522
523 // Grammar Note: Constructors look like methods, but lexical
524 // analysis recognized most of them as keywords. They are now
525 // recognized through "type_specifier".
526 method_call_header:
527 variable_identifier '('
528 {
529 void *ctx = state;
530 ast_expression *callee = new(ctx) ast_expression($1);
531 $$ = new(ctx) ast_function_expression(callee);
532 $$->set_location(yylloc);
533 }
534 ;
535
536 // Grammar Note: No traditional style type casts.
537 unary_expression:
538 postfix_expression
539 | INC_OP unary_expression
540 {
541 void *ctx = state;
542 $$ = new(ctx) ast_expression(ast_pre_inc, $2, NULL, NULL);
543 $$->set_location(yylloc);
544 }
545 | DEC_OP unary_expression
546 {
547 void *ctx = state;
548 $$ = new(ctx) ast_expression(ast_pre_dec, $2, NULL, NULL);
549 $$->set_location(yylloc);
550 }
551 | unary_operator unary_expression
552 {
553 void *ctx = state;
554 $$ = new(ctx) ast_expression($1, $2, NULL, NULL);
555 $$->set_location(yylloc);
556 }
557 ;
558
559 // Grammar Note: No '*' or '&' unary ops. Pointers are not supported.
560 unary_operator:
561 '+' { $$ = ast_plus; }
562 | '-' { $$ = ast_neg; }
563 | '!' { $$ = ast_logic_not; }
564 | '~' { $$ = ast_bit_not; }
565 ;
566
567 multiplicative_expression:
568 unary_expression
569 | multiplicative_expression '*' unary_expression
570 {
571 void *ctx = state;
572 $$ = new(ctx) ast_expression_bin(ast_mul, $1, $3);
573 $$->set_location(yylloc);
574 }
575 | multiplicative_expression '/' unary_expression
576 {
577 void *ctx = state;
578 $$ = new(ctx) ast_expression_bin(ast_div, $1, $3);
579 $$->set_location(yylloc);
580 }
581 | multiplicative_expression '%' unary_expression
582 {
583 void *ctx = state;
584 $$ = new(ctx) ast_expression_bin(ast_mod, $1, $3);
585 $$->set_location(yylloc);
586 }
587 ;
588
589 additive_expression:
590 multiplicative_expression
591 | additive_expression '+' multiplicative_expression
592 {
593 void *ctx = state;
594 $$ = new(ctx) ast_expression_bin(ast_add, $1, $3);
595 $$->set_location(yylloc);
596 }
597 | additive_expression '-' multiplicative_expression
598 {
599 void *ctx = state;
600 $$ = new(ctx) ast_expression_bin(ast_sub, $1, $3);
601 $$->set_location(yylloc);
602 }
603 ;
604
605 shift_expression:
606 additive_expression
607 | shift_expression LEFT_OP additive_expression
608 {
609 void *ctx = state;
610 $$ = new(ctx) ast_expression_bin(ast_lshift, $1, $3);
611 $$->set_location(yylloc);
612 }
613 | shift_expression RIGHT_OP additive_expression
614 {
615 void *ctx = state;
616 $$ = new(ctx) ast_expression_bin(ast_rshift, $1, $3);
617 $$->set_location(yylloc);
618 }
619 ;
620
621 relational_expression:
622 shift_expression
623 | relational_expression '<' shift_expression
624 {
625 void *ctx = state;
626 $$ = new(ctx) ast_expression_bin(ast_less, $1, $3);
627 $$->set_location(yylloc);
628 }
629 | relational_expression '>' shift_expression
630 {
631 void *ctx = state;
632 $$ = new(ctx) ast_expression_bin(ast_greater, $1, $3);
633 $$->set_location(yylloc);
634 }
635 | relational_expression LE_OP shift_expression
636 {
637 void *ctx = state;
638 $$ = new(ctx) ast_expression_bin(ast_lequal, $1, $3);
639 $$->set_location(yylloc);
640 }
641 | relational_expression GE_OP shift_expression
642 {
643 void *ctx = state;
644 $$ = new(ctx) ast_expression_bin(ast_gequal, $1, $3);
645 $$->set_location(yylloc);
646 }
647 ;
648
649 equality_expression:
650 relational_expression
651 | equality_expression EQ_OP relational_expression
652 {
653 void *ctx = state;
654 $$ = new(ctx) ast_expression_bin(ast_equal, $1, $3);
655 $$->set_location(yylloc);
656 }
657 | equality_expression NE_OP relational_expression
658 {
659 void *ctx = state;
660 $$ = new(ctx) ast_expression_bin(ast_nequal, $1, $3);
661 $$->set_location(yylloc);
662 }
663 ;
664
665 and_expression:
666 equality_expression
667 | and_expression '&' equality_expression
668 {
669 void *ctx = state;
670 $$ = new(ctx) ast_expression_bin(ast_bit_and, $1, $3);
671 $$->set_location(yylloc);
672 }
673 ;
674
675 exclusive_or_expression:
676 and_expression
677 | exclusive_or_expression '^' and_expression
678 {
679 void *ctx = state;
680 $$ = new(ctx) ast_expression_bin(ast_bit_xor, $1, $3);
681 $$->set_location(yylloc);
682 }
683 ;
684
685 inclusive_or_expression:
686 exclusive_or_expression
687 | inclusive_or_expression '|' exclusive_or_expression
688 {
689 void *ctx = state;
690 $$ = new(ctx) ast_expression_bin(ast_bit_or, $1, $3);
691 $$->set_location(yylloc);
692 }
693 ;
694
695 logical_and_expression:
696 inclusive_or_expression
697 | logical_and_expression AND_OP inclusive_or_expression
698 {
699 void *ctx = state;
700 $$ = new(ctx) ast_expression_bin(ast_logic_and, $1, $3);
701 $$->set_location(yylloc);
702 }
703 ;
704
705 logical_xor_expression:
706 logical_and_expression
707 | logical_xor_expression XOR_OP logical_and_expression
708 {
709 void *ctx = state;
710 $$ = new(ctx) ast_expression_bin(ast_logic_xor, $1, $3);
711 $$->set_location(yylloc);
712 }
713 ;
714
715 logical_or_expression:
716 logical_xor_expression
717 | logical_or_expression OR_OP logical_xor_expression
718 {
719 void *ctx = state;
720 $$ = new(ctx) ast_expression_bin(ast_logic_or, $1, $3);
721 $$->set_location(yylloc);
722 }
723 ;
724
725 conditional_expression:
726 logical_or_expression
727 | logical_or_expression '?' expression ':' assignment_expression
728 {
729 void *ctx = state;
730 $$ = new(ctx) ast_expression(ast_conditional, $1, $3, $5);
731 $$->set_location(yylloc);
732 }
733 ;
734
735 assignment_expression:
736 conditional_expression
737 | unary_expression assignment_operator assignment_expression
738 {
739 void *ctx = state;
740 $$ = new(ctx) ast_expression($2, $1, $3, NULL);
741 $$->set_location(yylloc);
742 }
743 ;
744
745 assignment_operator:
746 '=' { $$ = ast_assign; }
747 | MUL_ASSIGN { $$ = ast_mul_assign; }
748 | DIV_ASSIGN { $$ = ast_div_assign; }
749 | MOD_ASSIGN { $$ = ast_mod_assign; }
750 | ADD_ASSIGN { $$ = ast_add_assign; }
751 | SUB_ASSIGN { $$ = ast_sub_assign; }
752 | LEFT_ASSIGN { $$ = ast_ls_assign; }
753 | RIGHT_ASSIGN { $$ = ast_rs_assign; }
754 | AND_ASSIGN { $$ = ast_and_assign; }
755 | XOR_ASSIGN { $$ = ast_xor_assign; }
756 | OR_ASSIGN { $$ = ast_or_assign; }
757 ;
758
759 expression:
760 assignment_expression
761 {
762 $$ = $1;
763 }
764 | expression ',' assignment_expression
765 {
766 void *ctx = state;
767 if ($1->oper != ast_sequence) {
768 $$ = new(ctx) ast_expression(ast_sequence, NULL, NULL, NULL);
769 $$->set_location(yylloc);
770 $$->expressions.push_tail(& $1->link);
771 } else {
772 $$ = $1;
773 }
774
775 $$->expressions.push_tail(& $3->link);
776 }
777 ;
778
779 constant_expression:
780 conditional_expression
781 ;
782
783 declaration:
784 function_prototype ';'
785 {
786 state->symbols->pop_scope();
787 $$ = $1;
788 }
789 | init_declarator_list ';'
790 {
791 $$ = $1;
792 }
793 | PRECISION precision_qualifier type_specifier_no_prec ';'
794 {
795 $3->precision = $2;
796 $3->is_precision_statement = true;
797 $$ = $3;
798 }
799 | interface_block
800 {
801 $$ = $1;
802 }
803 ;
804
805 function_prototype:
806 function_declarator ')'
807 ;
808
809 function_declarator:
810 function_header
811 | function_header_with_parameters
812 ;
813
814 function_header_with_parameters:
815 function_header parameter_declaration
816 {
817 $$ = $1;
818 $$->parameters.push_tail(& $2->link);
819 }
820 | function_header_with_parameters ',' parameter_declaration
821 {
822 $$ = $1;
823 $$->parameters.push_tail(& $3->link);
824 }
825 ;
826
827 function_header:
828 fully_specified_type variable_identifier '('
829 {
830 void *ctx = state;
831 $$ = new(ctx) ast_function();
832 $$->set_location(yylloc);
833 $$->return_type = $1;
834 $$->identifier = $2;
835
836 state->symbols->add_function(new(state) ir_function($2));
837 state->symbols->push_scope();
838 }
839 ;
840
841 parameter_declarator:
842 type_specifier any_identifier
843 {
844 void *ctx = state;
845 $$ = new(ctx) ast_parameter_declarator();
846 $$->set_location(yylloc);
847 $$->type = new(ctx) ast_fully_specified_type();
848 $$->type->set_location(yylloc);
849 $$->type->specifier = $1;
850 $$->identifier = $2;
851 }
852 | type_specifier any_identifier '[' constant_expression ']'
853 {
854 void *ctx = state;
855 $$ = new(ctx) ast_parameter_declarator();
856 $$->set_location(yylloc);
857 $$->type = new(ctx) ast_fully_specified_type();
858 $$->type->set_location(yylloc);
859 $$->type->specifier = $1;
860 $$->identifier = $2;
861 $$->is_array = true;
862 $$->array_size = $4;
863 }
864 ;
865
866 parameter_declaration:
867 parameter_type_qualifier parameter_qualifier parameter_declarator
868 {
869 $1.flags.i |= $2.flags.i;
870
871 $$ = $3;
872 $$->type->qualifier = $1;
873 }
874 | parameter_qualifier parameter_declarator
875 {
876 $$ = $2;
877 $$->type->qualifier = $1;
878 }
879 | parameter_type_qualifier parameter_qualifier parameter_type_specifier
880 {
881 void *ctx = state;
882 $1.flags.i |= $2.flags.i;
883
884 $$ = new(ctx) ast_parameter_declarator();
885 $$->set_location(yylloc);
886 $$->type = new(ctx) ast_fully_specified_type();
887 $$->type->qualifier = $1;
888 $$->type->specifier = $3;
889 }
890 | parameter_qualifier parameter_type_specifier
891 {
892 void *ctx = state;
893 $$ = new(ctx) ast_parameter_declarator();
894 $$->set_location(yylloc);
895 $$->type = new(ctx) ast_fully_specified_type();
896 $$->type->qualifier = $1;
897 $$->type->specifier = $2;
898 }
899 ;
900
901 parameter_qualifier:
902 /* empty */
903 {
904 memset(& $$, 0, sizeof($$));
905 }
906 | IN_TOK
907 {
908 memset(& $$, 0, sizeof($$));
909 $$.flags.q.in = 1;
910 }
911 | OUT_TOK
912 {
913 memset(& $$, 0, sizeof($$));
914 $$.flags.q.out = 1;
915 }
916 | INOUT_TOK
917 {
918 memset(& $$, 0, sizeof($$));
919 $$.flags.q.in = 1;
920 $$.flags.q.out = 1;
921 }
922 ;
923
924 parameter_type_specifier:
925 type_specifier
926 ;
927
928 init_declarator_list:
929 single_declaration
930 | init_declarator_list ',' any_identifier
931 {
932 void *ctx = state;
933 ast_declaration *decl = new(ctx) ast_declaration($3, false, NULL, NULL);
934 decl->set_location(yylloc);
935
936 $$ = $1;
937 $$->declarations.push_tail(&decl->link);
938 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
939 }
940 | init_declarator_list ',' any_identifier '[' ']'
941 {
942 void *ctx = state;
943 ast_declaration *decl = new(ctx) ast_declaration($3, true, NULL, NULL);
944 decl->set_location(yylloc);
945
946 $$ = $1;
947 $$->declarations.push_tail(&decl->link);
948 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
949 }
950 | init_declarator_list ',' any_identifier '[' constant_expression ']'
951 {
952 void *ctx = state;
953 ast_declaration *decl = new(ctx) ast_declaration($3, true, $5, NULL);
954 decl->set_location(yylloc);
955
956 $$ = $1;
957 $$->declarations.push_tail(&decl->link);
958 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
959 }
960 | init_declarator_list ',' any_identifier '[' ']' '=' initializer
961 {
962 void *ctx = state;
963 ast_declaration *decl = new(ctx) ast_declaration($3, true, NULL, $7);
964 decl->set_location(yylloc);
965
966 $$ = $1;
967 $$->declarations.push_tail(&decl->link);
968 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
969 if ($7->oper == ast_aggregate) {
970 ast_aggregate_initializer *ai = (ast_aggregate_initializer *)$7;
971 ast_type_specifier *type = new(ctx) ast_type_specifier($1->type->specifier, true, NULL);
972 _mesa_ast_set_aggregate_type(type, ai, state);
973 }
974 }
975 | init_declarator_list ',' any_identifier '[' constant_expression ']' '=' initializer
976 {
977 void *ctx = state;
978 ast_declaration *decl = new(ctx) ast_declaration($3, true, $5, $8);
979 decl->set_location(yylloc);
980
981 $$ = $1;
982 $$->declarations.push_tail(&decl->link);
983 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
984 if ($8->oper == ast_aggregate) {
985 ast_aggregate_initializer *ai = (ast_aggregate_initializer *)$8;
986 ast_type_specifier *type = new(ctx) ast_type_specifier($1->type->specifier, true, $5);
987 _mesa_ast_set_aggregate_type(type, ai, state);
988 }
989 }
990 | init_declarator_list ',' any_identifier '=' initializer
991 {
992 void *ctx = state;
993 ast_declaration *decl = new(ctx) ast_declaration($3, false, NULL, $5);
994 decl->set_location(yylloc);
995
996 $$ = $1;
997 $$->declarations.push_tail(&decl->link);
998 state->symbols->add_variable(new(state) ir_variable(NULL, $3, ir_var_auto));
999 if ($5->oper == ast_aggregate) {
1000 ast_aggregate_initializer *ai = (ast_aggregate_initializer *)$5;
1001 _mesa_ast_set_aggregate_type($1->type->specifier, ai, state);
1002 }
1003 }
1004 ;
1005
1006 // Grammar Note: No 'enum', or 'typedef'.
1007 single_declaration:
1008 fully_specified_type
1009 {
1010 void *ctx = state;
1011 /* Empty declaration list is valid. */
1012 $$ = new(ctx) ast_declarator_list($1);
1013 $$->set_location(yylloc);
1014 }
1015 | fully_specified_type any_identifier
1016 {
1017 void *ctx = state;
1018 ast_declaration *decl = new(ctx) ast_declaration($2, false, NULL, NULL);
1019
1020 $$ = new(ctx) ast_declarator_list($1);
1021 $$->set_location(yylloc);
1022 $$->declarations.push_tail(&decl->link);
1023 }
1024 | fully_specified_type any_identifier '[' ']'
1025 {
1026 void *ctx = state;
1027 ast_declaration *decl = new(ctx) ast_declaration($2, true, NULL, NULL);
1028
1029 $$ = new(ctx) ast_declarator_list($1);
1030 $$->set_location(yylloc);
1031 $$->declarations.push_tail(&decl->link);
1032 }
1033 | fully_specified_type any_identifier '[' constant_expression ']'
1034 {
1035 void *ctx = state;
1036 ast_declaration *decl = new(ctx) ast_declaration($2, true, $4, NULL);
1037
1038 $$ = new(ctx) ast_declarator_list($1);
1039 $$->set_location(yylloc);
1040 $$->declarations.push_tail(&decl->link);
1041 }
1042 | fully_specified_type any_identifier '[' ']' '=' initializer
1043 {
1044 void *ctx = state;
1045 ast_declaration *decl = new(ctx) ast_declaration($2, true, NULL, $6);
1046
1047 $$ = new(ctx) ast_declarator_list($1);
1048 $$->set_location(yylloc);
1049 $$->declarations.push_tail(&decl->link);
1050 if ($6->oper == ast_aggregate) {
1051 ast_aggregate_initializer *ai = (ast_aggregate_initializer *)$6;
1052 ast_type_specifier *type = new(ctx) ast_type_specifier($1->specifier, true, NULL);
1053 _mesa_ast_set_aggregate_type(type, ai, state);
1054 }
1055 }
1056 | fully_specified_type any_identifier '[' constant_expression ']' '=' initializer
1057 {
1058 void *ctx = state;
1059 ast_declaration *decl = new(ctx) ast_declaration($2, true, $4, $7);
1060
1061 $$ = new(ctx) ast_declarator_list($1);
1062 $$->set_location(yylloc);
1063 $$->declarations.push_tail(&decl->link);
1064 if ($7->oper == ast_aggregate) {
1065 ast_aggregate_initializer *ai = (ast_aggregate_initializer *)$7;
1066 ast_type_specifier *type = new(ctx) ast_type_specifier($1->specifier, true, $4);
1067 _mesa_ast_set_aggregate_type(type, ai, state);
1068 }
1069 }
1070 | fully_specified_type any_identifier '=' initializer
1071 {
1072 void *ctx = state;
1073 ast_declaration *decl = new(ctx) ast_declaration($2, false, NULL, $4);
1074
1075 $$ = new(ctx) ast_declarator_list($1);
1076 $$->set_location(yylloc);
1077 $$->declarations.push_tail(&decl->link);
1078 if ($4->oper == ast_aggregate) {
1079 _mesa_ast_set_aggregate_type($1->specifier, $4, state);
1080 }
1081 }
1082 | INVARIANT variable_identifier // Vertex only.
1083 {
1084 void *ctx = state;
1085 ast_declaration *decl = new(ctx) ast_declaration($2, false, NULL, NULL);
1086
1087 $$ = new(ctx) ast_declarator_list(NULL);
1088 $$->set_location(yylloc);
1089 $$->invariant = true;
1090
1091 $$->declarations.push_tail(&decl->link);
1092 }
1093 ;
1094
1095 fully_specified_type:
1096 type_specifier
1097 {
1098 void *ctx = state;
1099 $$ = new(ctx) ast_fully_specified_type();
1100 $$->set_location(yylloc);
1101 $$->specifier = $1;
1102 }
1103 | type_qualifier type_specifier
1104 {
1105 void *ctx = state;
1106 $$ = new(ctx) ast_fully_specified_type();
1107 $$->set_location(yylloc);
1108 $$->qualifier = $1;
1109 $$->specifier = $2;
1110 }
1111 ;
1112
1113 layout_qualifier:
1114 LAYOUT_TOK '(' layout_qualifier_id_list ')'
1115 {
1116 $$ = $3;
1117 }
1118 ;
1119
1120 layout_qualifier_id_list:
1121 layout_qualifier_id
1122 | layout_qualifier_id_list ',' layout_qualifier_id
1123 {
1124 $$ = $1;
1125 if (!$$.merge_qualifier(& @3, state, $3)) {
1126 YYERROR;
1127 }
1128 }
1129 ;
1130
1131 integer_constant:
1132 INTCONSTANT { $$ = $1; }
1133 | UINTCONSTANT { $$ = $1; }
1134 ;
1135
1136 layout_qualifier_id:
1137 any_identifier
1138 {
1139 memset(& $$, 0, sizeof($$));
1140
1141 /* Layout qualifiers for ARB_fragment_coord_conventions. */
1142 if (!$$.flags.i && state->ARB_fragment_coord_conventions_enable) {
1143 if (strcmp($1, "origin_upper_left") == 0) {
1144 $$.flags.q.origin_upper_left = 1;
1145 } else if (strcmp($1, "pixel_center_integer") == 0) {
1146 $$.flags.q.pixel_center_integer = 1;
1147 }
1148
1149 if ($$.flags.i && state->ARB_fragment_coord_conventions_warn) {
1150 _mesa_glsl_warning(& @1, state,
1151 "GL_ARB_fragment_coord_conventions layout "
1152 "identifier `%s' used\n", $1);
1153 }
1154 }
1155
1156 /* Layout qualifiers for AMD/ARB_conservative_depth. */
1157 if (!$$.flags.i &&
1158 (state->AMD_conservative_depth_enable ||
1159 state->ARB_conservative_depth_enable)) {
1160 if (strcmp($1, "depth_any") == 0) {
1161 $$.flags.q.depth_any = 1;
1162 } else if (strcmp($1, "depth_greater") == 0) {
1163 $$.flags.q.depth_greater = 1;
1164 } else if (strcmp($1, "depth_less") == 0) {
1165 $$.flags.q.depth_less = 1;
1166 } else if (strcmp($1, "depth_unchanged") == 0) {
1167 $$.flags.q.depth_unchanged = 1;
1168 }
1169
1170 if ($$.flags.i && state->AMD_conservative_depth_warn) {
1171 _mesa_glsl_warning(& @1, state,
1172 "GL_AMD_conservative_depth "
1173 "layout qualifier `%s' is used\n", $1);
1174 }
1175 if ($$.flags.i && state->ARB_conservative_depth_warn) {
1176 _mesa_glsl_warning(& @1, state,
1177 "GL_ARB_conservative_depth "
1178 "layout qualifier `%s' is used\n", $1);
1179 }
1180 }
1181
1182 /* See also interface_block_layout_qualifier. */
1183 if (!$$.flags.i && state->ARB_uniform_buffer_object_enable) {
1184 if (strcmp($1, "std140") == 0) {
1185 $$.flags.q.std140 = 1;
1186 } else if (strcmp($1, "shared") == 0) {
1187 $$.flags.q.shared = 1;
1188 } else if (strcmp($1, "column_major") == 0) {
1189 $$.flags.q.column_major = 1;
1190 /* "row_major" is a reserved word in GLSL 1.30+. Its token is parsed
1191 * below in the interface_block_layout_qualifier rule.
1192 *
1193 * It is not a reserved word in GLSL ES 3.00, so it's handled here as
1194 * an identifier.
1195 */
1196 } else if (strcmp($1, "row_major") == 0) {
1197 $$.flags.q.row_major = 1;
1198 }
1199
1200 if ($$.flags.i && state->ARB_uniform_buffer_object_warn) {
1201 _mesa_glsl_warning(& @1, state,
1202 "#version 140 / GL_ARB_uniform_buffer_object "
1203 "layout qualifier `%s' is used\n", $1);
1204 }
1205 }
1206
1207 if (!$$.flags.i) {
1208 _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1209 "`%s'\n", $1);
1210 YYERROR;
1211 }
1212 }
1213 | any_identifier '=' integer_constant
1214 {
1215 memset(& $$, 0, sizeof($$));
1216
1217 if (state->ARB_explicit_attrib_location_enable) {
1218 if (strcmp("location", $1) == 0) {
1219 $$.flags.q.explicit_location = 1;
1220
1221 if ($3 >= 0) {
1222 $$.location = $3;
1223 } else {
1224 _mesa_glsl_error(& @3, state,
1225 "invalid location %d specified\n", $3);
1226 YYERROR;
1227 }
1228 }
1229
1230 if (strcmp("index", $1) == 0) {
1231 $$.flags.q.explicit_index = 1;
1232
1233 if ($3 >= 0) {
1234 $$.index = $3;
1235 } else {
1236 _mesa_glsl_error(& @3, state,
1237 "invalid index %d specified\n", $3);
1238 YYERROR;
1239 }
1240 }
1241 }
1242
1243 /* If the identifier didn't match any known layout identifiers,
1244 * emit an error.
1245 */
1246 if (!$$.flags.i) {
1247 _mesa_glsl_error(& @1, state, "unrecognized layout identifier "
1248 "`%s'\n", $1);
1249 YYERROR;
1250 } else if (state->ARB_explicit_attrib_location_warn) {
1251 _mesa_glsl_warning(& @1, state,
1252 "GL_ARB_explicit_attrib_location layout "
1253 "identifier `%s' used\n", $1);
1254 }
1255 }
1256 | interface_block_layout_qualifier
1257 {
1258 $$ = $1;
1259 /* Layout qualifiers for ARB_uniform_buffer_object. */
1260 if ($$.flags.q.uniform && !state->ARB_uniform_buffer_object_enable) {
1261 _mesa_glsl_error(& @1, state,
1262 "#version 140 / GL_ARB_uniform_buffer_object "
1263 "layout qualifier `%s' is used\n", $1);
1264 } else if ($$.flags.q.uniform && state->ARB_uniform_buffer_object_warn) {
1265 _mesa_glsl_warning(& @1, state,
1266 "#version 140 / GL_ARB_uniform_buffer_object "
1267 "layout qualifier `%s' is used\n", $1);
1268 }
1269 }
1270 ;
1271
1272 /* This is a separate language rule because we parse these as tokens
1273 * (due to them being reserved keywords) instead of identifiers like
1274 * most qualifiers. See the any_identifier path of
1275 * layout_qualifier_id for the others.
1276 */
1277 interface_block_layout_qualifier:
1278 ROW_MAJOR
1279 {
1280 memset(& $$, 0, sizeof($$));
1281 $$.flags.q.row_major = 1;
1282 }
1283 | PACKED_TOK
1284 {
1285 memset(& $$, 0, sizeof($$));
1286 $$.flags.q.packed = 1;
1287 }
1288 ;
1289
1290 interpolation_qualifier:
1291 SMOOTH
1292 {
1293 memset(& $$, 0, sizeof($$));
1294 $$.flags.q.smooth = 1;
1295 }
1296 | FLAT
1297 {
1298 memset(& $$, 0, sizeof($$));
1299 $$.flags.q.flat = 1;
1300 }
1301 | NOPERSPECTIVE
1302 {
1303 memset(& $$, 0, sizeof($$));
1304 $$.flags.q.noperspective = 1;
1305 }
1306 ;
1307
1308 parameter_type_qualifier:
1309 CONST_TOK
1310 {
1311 memset(& $$, 0, sizeof($$));
1312 $$.flags.q.constant = 1;
1313 }
1314 ;
1315
1316 type_qualifier:
1317 /* Single qualifiers */
1318 INVARIANT
1319 {
1320 memset(& $$, 0, sizeof($$));
1321 $$.flags.q.invariant = 1;
1322 }
1323 | storage_qualifier
1324 | interpolation_qualifier
1325 | layout_qualifier
1326
1327 /* Multiple qualifiers:
1328 * In GLSL 4.20, these can be specified in any order. In earlier versions,
1329 * they appear in this order (see GLSL 1.50 section 4.7 & comments below):
1330 *
1331 * invariant interpolation storage precision ...or...
1332 * layout storage precision
1333 *
1334 * Each qualifier's rule ensures that the accumulated qualifiers on the right
1335 * side don't contain any that must appear on the left hand side.
1336 * For example, when processing a storage qualifier, we check that there are
1337 * no interpolation, layout, or invariant qualifiers to the right.
1338 */
1339 | INVARIANT type_qualifier
1340 {
1341 if ($2.flags.q.invariant)
1342 _mesa_glsl_error(&@1, state, "Duplicate \"invariant\" qualifier.\n");
1343
1344 if ($2.has_layout()) {
1345 _mesa_glsl_error(&@1, state,
1346 "\"invariant\" cannot be used with layout(...).\n");
1347 }
1348
1349 $$ = $2;
1350 $$.flags.q.invariant = 1;
1351 }
1352 | interpolation_qualifier type_qualifier
1353 {
1354 /* Section 4.3 of the GLSL 1.40 specification states:
1355 * "...qualified with one of these interpolation qualifiers"
1356 *
1357 * GLSL 1.30 claims to allow "one or more", but insists that:
1358 * "These interpolation qualifiers may only precede the qualifiers in,
1359 * centroid in, out, or centroid out in a declaration."
1360 *
1361 * ...which means that e.g. smooth can't precede smooth, so there can be
1362 * only one after all, and the 1.40 text is a clarification, not a change.
1363 */
1364 if ($2.has_interpolation())
1365 _mesa_glsl_error(&@1, state, "Duplicate interpolation qualifier.\n");
1366
1367 if ($2.has_layout()) {
1368 _mesa_glsl_error(&@1, state, "Interpolation qualifiers cannot be used "
1369 "with layout(...).\n");
1370 }
1371
1372 if ($2.flags.q.invariant) {
1373 _mesa_glsl_error(&@1, state, "Interpolation qualifiers must come "
1374 "after \"invariant\".\n");
1375 }
1376
1377 $$ = $1;
1378 $$.flags.i |= $2.flags.i;
1379 }
1380 | layout_qualifier type_qualifier
1381 {
1382 /* The GLSL 1.50 grammar indicates that a layout(...) declaration can be
1383 * used standalone or immediately before a storage qualifier. It cannot
1384 * be used with interpolation qualifiers or invariant. There does not
1385 * appear to be any text indicating that it must come before the storage
1386 * qualifier, but always seems to in examples.
1387 */
1388 if ($2.has_layout())
1389 _mesa_glsl_error(&@1, state, "Duplicate layout(...) qualifiers.\n");
1390
1391 if ($2.flags.q.invariant)
1392 _mesa_glsl_error(&@1, state, "layout(...) cannot be used with "
1393 "the \"invariant\" qualifier\n");
1394
1395 if ($2.has_interpolation()) {
1396 _mesa_glsl_error(&@1, state, "layout(...) cannot be used with "
1397 "interpolation qualifiers.\n");
1398 }
1399
1400 $$ = $1;
1401 $$.flags.i |= $2.flags.i;
1402 }
1403 | storage_qualifier type_qualifier
1404 {
1405 /* Section 4.3 of the GLSL 1.20 specification states:
1406 * "Variable declarations may have a storage qualifier specified..."
1407 * 1.30 clarifies this to "may have one storage qualifier".
1408 */
1409 if ($2.has_storage())
1410 _mesa_glsl_error(&@1, state, "Duplicate storage qualifier.\n");
1411
1412 if ($2.flags.q.invariant || $2.has_interpolation() || $2.has_layout()) {
1413 _mesa_glsl_error(&@1, state, "Storage qualifiers must come after "
1414 "invariant, interpolation, and layout qualifiers.\n");
1415 }
1416
1417 $$ = $1;
1418 $$.flags.i |= $2.flags.i;
1419 }
1420 ;
1421
1422 storage_qualifier:
1423 CONST_TOK
1424 {
1425 memset(& $$, 0, sizeof($$));
1426 $$.flags.q.constant = 1;
1427 }
1428 | ATTRIBUTE
1429 {
1430 memset(& $$, 0, sizeof($$));
1431 $$.flags.q.attribute = 1;
1432 }
1433 | VARYING
1434 {
1435 memset(& $$, 0, sizeof($$));
1436 $$.flags.q.varying = 1;
1437 }
1438 | CENTROID VARYING
1439 {
1440 memset(& $$, 0, sizeof($$));
1441 $$.flags.q.centroid = 1;
1442 $$.flags.q.varying = 1;
1443 }
1444 | IN_TOK
1445 {
1446 memset(& $$, 0, sizeof($$));
1447 $$.flags.q.in = 1;
1448 }
1449 | OUT_TOK
1450 {
1451 memset(& $$, 0, sizeof($$));
1452 $$.flags.q.out = 1;
1453 }
1454 | CENTROID IN_TOK
1455 {
1456 memset(& $$, 0, sizeof($$));
1457 $$.flags.q.centroid = 1; $$.flags.q.in = 1;
1458 }
1459 | CENTROID OUT_TOK
1460 {
1461 memset(& $$, 0, sizeof($$));
1462 $$.flags.q.centroid = 1; $$.flags.q.out = 1;
1463 }
1464 | UNIFORM
1465 {
1466 memset(& $$, 0, sizeof($$));
1467 $$.flags.q.uniform = 1;
1468 }
1469 ;
1470
1471 type_specifier:
1472 type_specifier_no_prec
1473 {
1474 $$ = $1;
1475 }
1476 | precision_qualifier type_specifier_no_prec
1477 {
1478 $$ = $2;
1479 $$->precision = $1;
1480 }
1481 ;
1482
1483 type_specifier_no_prec:
1484 type_specifier_nonarray
1485 | type_specifier_nonarray '[' ']'
1486 {
1487 $$ = $1;
1488 $$->is_array = true;
1489 $$->array_size = NULL;
1490 }
1491 | type_specifier_nonarray '[' constant_expression ']'
1492 {
1493 $$ = $1;
1494 $$->is_array = true;
1495 $$->array_size = $3;
1496 }
1497 ;
1498
1499 type_specifier_nonarray:
1500 basic_type_specifier_nonarray
1501 {
1502 void *ctx = state;
1503 $$ = new(ctx) ast_type_specifier($1);
1504 $$->set_location(yylloc);
1505 }
1506 | struct_specifier
1507 {
1508 void *ctx = state;
1509 $$ = new(ctx) ast_type_specifier($1);
1510 $$->set_location(yylloc);
1511 }
1512 | TYPE_IDENTIFIER
1513 {
1514 void *ctx = state;
1515 $$ = new(ctx) ast_type_specifier($1);
1516 $$->set_location(yylloc);
1517 }
1518 ;
1519
1520 basic_type_specifier_nonarray:
1521 VOID_TOK { $$ = "void"; }
1522 | FLOAT_TOK { $$ = "float"; }
1523 | INT_TOK { $$ = "int"; }
1524 | UINT_TOK { $$ = "uint"; }
1525 | BOOL_TOK { $$ = "bool"; }
1526 | VEC2 { $$ = "vec2"; }
1527 | VEC3 { $$ = "vec3"; }
1528 | VEC4 { $$ = "vec4"; }
1529 | BVEC2 { $$ = "bvec2"; }
1530 | BVEC3 { $$ = "bvec3"; }
1531 | BVEC4 { $$ = "bvec4"; }
1532 | IVEC2 { $$ = "ivec2"; }
1533 | IVEC3 { $$ = "ivec3"; }
1534 | IVEC4 { $$ = "ivec4"; }
1535 | UVEC2 { $$ = "uvec2"; }
1536 | UVEC3 { $$ = "uvec3"; }
1537 | UVEC4 { $$ = "uvec4"; }
1538 | MAT2X2 { $$ = "mat2"; }
1539 | MAT2X3 { $$ = "mat2x3"; }
1540 | MAT2X4 { $$ = "mat2x4"; }
1541 | MAT3X2 { $$ = "mat3x2"; }
1542 | MAT3X3 { $$ = "mat3"; }
1543 | MAT3X4 { $$ = "mat3x4"; }
1544 | MAT4X2 { $$ = "mat4x2"; }
1545 | MAT4X3 { $$ = "mat4x3"; }
1546 | MAT4X4 { $$ = "mat4"; }
1547 | SAMPLER1D { $$ = "sampler1D"; }
1548 | SAMPLER2D { $$ = "sampler2D"; }
1549 | SAMPLER2DRECT { $$ = "sampler2DRect"; }
1550 | SAMPLER3D { $$ = "sampler3D"; }
1551 | SAMPLERCUBE { $$ = "samplerCube"; }
1552 | SAMPLEREXTERNALOES { $$ = "samplerExternalOES"; }
1553 | SAMPLER1DSHADOW { $$ = "sampler1DShadow"; }
1554 | SAMPLER2DSHADOW { $$ = "sampler2DShadow"; }
1555 | SAMPLER2DRECTSHADOW { $$ = "sampler2DRectShadow"; }
1556 | SAMPLERCUBESHADOW { $$ = "samplerCubeShadow"; }
1557 | SAMPLER1DARRAY { $$ = "sampler1DArray"; }
1558 | SAMPLER2DARRAY { $$ = "sampler2DArray"; }
1559 | SAMPLER1DARRAYSHADOW { $$ = "sampler1DArrayShadow"; }
1560 | SAMPLER2DARRAYSHADOW { $$ = "sampler2DArrayShadow"; }
1561 | SAMPLERBUFFER { $$ = "samplerBuffer"; }
1562 | SAMPLERCUBEARRAY { $$ = "samplerCubeArray"; }
1563 | SAMPLERCUBEARRAYSHADOW { $$ = "samplerCubeArrayShadow"; }
1564 | ISAMPLER1D { $$ = "isampler1D"; }
1565 | ISAMPLER2D { $$ = "isampler2D"; }
1566 | ISAMPLER2DRECT { $$ = "isampler2DRect"; }
1567 | ISAMPLER3D { $$ = "isampler3D"; }
1568 | ISAMPLERCUBE { $$ = "isamplerCube"; }
1569 | ISAMPLER1DARRAY { $$ = "isampler1DArray"; }
1570 | ISAMPLER2DARRAY { $$ = "isampler2DArray"; }
1571 | ISAMPLERBUFFER { $$ = "isamplerBuffer"; }
1572 | ISAMPLERCUBEARRAY { $$ = "isamplerCubeArray"; }
1573 | USAMPLER1D { $$ = "usampler1D"; }
1574 | USAMPLER2D { $$ = "usampler2D"; }
1575 | USAMPLER2DRECT { $$ = "usampler2DRect"; }
1576 | USAMPLER3D { $$ = "usampler3D"; }
1577 | USAMPLERCUBE { $$ = "usamplerCube"; }
1578 | USAMPLER1DARRAY { $$ = "usampler1DArray"; }
1579 | USAMPLER2DARRAY { $$ = "usampler2DArray"; }
1580 | USAMPLERBUFFER { $$ = "usamplerBuffer"; }
1581 | USAMPLERCUBEARRAY { $$ = "usamplerCubeArray"; }
1582 | SAMPLER2DMS { $$ = "sampler2DMS"; }
1583 | ISAMPLER2DMS { $$ = "isampler2DMS"; }
1584 | USAMPLER2DMS { $$ = "usampler2DMS"; }
1585 | SAMPLER2DMSARRAY { $$ = "sampler2DMSArray"; }
1586 | ISAMPLER2DMSARRAY { $$ = "isampler2DMSArray"; }
1587 | USAMPLER2DMSARRAY { $$ = "usampler2DMSArray"; }
1588 ;
1589
1590 precision_qualifier:
1591 HIGHP
1592 {
1593 state->check_precision_qualifiers_allowed(&@1);
1594 $$ = ast_precision_high;
1595 }
1596 | MEDIUMP
1597 {
1598 state->check_precision_qualifiers_allowed(&@1);
1599 $$ = ast_precision_medium;
1600 }
1601 | LOWP
1602 {
1603 state->check_precision_qualifiers_allowed(&@1);
1604 $$ = ast_precision_low;
1605 }
1606 ;
1607
1608 struct_specifier:
1609 STRUCT any_identifier '{' struct_declaration_list '}'
1610 {
1611 void *ctx = state;
1612 $$ = new(ctx) ast_struct_specifier($2, $4);
1613 $$->set_location(yylloc);
1614 state->symbols->add_type($2, glsl_type::void_type);
1615 state->symbols->add_type_ast($2, new(ctx) ast_type_specifier($$));
1616 }
1617 | STRUCT '{' struct_declaration_list '}'
1618 {
1619 void *ctx = state;
1620 $$ = new(ctx) ast_struct_specifier(NULL, $3);
1621 $$->set_location(yylloc);
1622 }
1623 ;
1624
1625 struct_declaration_list:
1626 struct_declaration
1627 {
1628 $$ = $1;
1629 $1->link.self_link();
1630 }
1631 | struct_declaration_list struct_declaration
1632 {
1633 $$ = $1;
1634 $$->link.insert_before(& $2->link);
1635 }
1636 ;
1637
1638 struct_declaration:
1639 type_specifier struct_declarator_list ';'
1640 {
1641 void *ctx = state;
1642 ast_fully_specified_type *type = new(ctx) ast_fully_specified_type();
1643 type->set_location(yylloc);
1644
1645 type->specifier = $1;
1646 $$ = new(ctx) ast_declarator_list(type);
1647 $$->set_location(yylloc);
1648
1649 $$->declarations.push_degenerate_list_at_head(& $2->link);
1650 }
1651 ;
1652
1653 struct_declarator_list:
1654 struct_declarator
1655 {
1656 $$ = $1;
1657 $1->link.self_link();
1658 }
1659 | struct_declarator_list ',' struct_declarator
1660 {
1661 $$ = $1;
1662 $$->link.insert_before(& $3->link);
1663 }
1664 ;
1665
1666 struct_declarator:
1667 any_identifier
1668 {
1669 void *ctx = state;
1670 $$ = new(ctx) ast_declaration($1, false, NULL, NULL);
1671 $$->set_location(yylloc);
1672 }
1673 | any_identifier '[' constant_expression ']'
1674 {
1675 void *ctx = state;
1676 $$ = new(ctx) ast_declaration($1, true, $3, NULL);
1677 $$->set_location(yylloc);
1678 }
1679 ;
1680
1681 initializer:
1682 assignment_expression
1683 | '{' initializer_list '}'
1684 {
1685 $$ = $2;
1686 }
1687 | '{' initializer_list ',' '}'
1688 {
1689 $$ = $2;
1690 }
1691 ;
1692
1693 initializer_list:
1694 initializer
1695 {
1696 void *ctx = state;
1697 $$ = new(ctx) ast_aggregate_initializer();
1698 $$->set_location(yylloc);
1699 $$->expressions.push_tail(& $1->link);
1700 }
1701 | initializer_list ',' initializer
1702 {
1703 $1->expressions.push_tail(& $3->link);
1704 }
1705 ;
1706
1707 declaration_statement:
1708 declaration
1709 ;
1710
1711 // Grammar Note: labeled statements for SWITCH only; 'goto' is not
1712 // supported.
1713 statement:
1714 compound_statement { $$ = (ast_node *) $1; }
1715 | simple_statement
1716 ;
1717
1718 simple_statement:
1719 declaration_statement
1720 | expression_statement
1721 | selection_statement
1722 | switch_statement
1723 | iteration_statement
1724 | jump_statement
1725 ;
1726
1727 compound_statement:
1728 '{' '}'
1729 {
1730 void *ctx = state;
1731 $$ = new(ctx) ast_compound_statement(true, NULL);
1732 $$->set_location(yylloc);
1733 }
1734 | '{'
1735 {
1736 state->symbols->push_scope();
1737 }
1738 statement_list '}'
1739 {
1740 void *ctx = state;
1741 $$ = new(ctx) ast_compound_statement(true, $3);
1742 $$->set_location(yylloc);
1743 state->symbols->pop_scope();
1744 }
1745 ;
1746
1747 statement_no_new_scope:
1748 compound_statement_no_new_scope { $$ = (ast_node *) $1; }
1749 | simple_statement
1750 ;
1751
1752 compound_statement_no_new_scope:
1753 '{' '}'
1754 {
1755 void *ctx = state;
1756 $$ = new(ctx) ast_compound_statement(false, NULL);
1757 $$->set_location(yylloc);
1758 }
1759 | '{' statement_list '}'
1760 {
1761 void *ctx = state;
1762 $$ = new(ctx) ast_compound_statement(false, $2);
1763 $$->set_location(yylloc);
1764 }
1765 ;
1766
1767 statement_list:
1768 statement
1769 {
1770 if ($1 == NULL) {
1771 _mesa_glsl_error(& @1, state, "<nil> statement\n");
1772 assert($1 != NULL);
1773 }
1774
1775 $$ = $1;
1776 $$->link.self_link();
1777 }
1778 | statement_list statement
1779 {
1780 if ($2 == NULL) {
1781 _mesa_glsl_error(& @2, state, "<nil> statement\n");
1782 assert($2 != NULL);
1783 }
1784 $$ = $1;
1785 $$->link.insert_before(& $2->link);
1786 }
1787 ;
1788
1789 expression_statement:
1790 ';'
1791 {
1792 void *ctx = state;
1793 $$ = new(ctx) ast_expression_statement(NULL);
1794 $$->set_location(yylloc);
1795 }
1796 | expression ';'
1797 {
1798 void *ctx = state;
1799 $$ = new(ctx) ast_expression_statement($1);
1800 $$->set_location(yylloc);
1801 }
1802 ;
1803
1804 selection_statement:
1805 IF '(' expression ')' selection_rest_statement
1806 {
1807 $$ = new(state) ast_selection_statement($3, $5.then_statement,
1808 $5.else_statement);
1809 $$->set_location(yylloc);
1810 }
1811 ;
1812
1813 selection_rest_statement:
1814 statement ELSE statement
1815 {
1816 $$.then_statement = $1;
1817 $$.else_statement = $3;
1818 }
1819 | statement %prec THEN
1820 {
1821 $$.then_statement = $1;
1822 $$.else_statement = NULL;
1823 }
1824 ;
1825
1826 condition:
1827 expression
1828 {
1829 $$ = (ast_node *) $1;
1830 }
1831 | fully_specified_type any_identifier '=' initializer
1832 {
1833 void *ctx = state;
1834 ast_declaration *decl = new(ctx) ast_declaration($2, false, NULL, $4);
1835 ast_declarator_list *declarator = new(ctx) ast_declarator_list($1);
1836 decl->set_location(yylloc);
1837 declarator->set_location(yylloc);
1838
1839 declarator->declarations.push_tail(&decl->link);
1840 $$ = declarator;
1841 }
1842 ;
1843
1844 /*
1845 * siwtch_statement grammar is based on the syntax described in the body
1846 * of the GLSL spec, not in it's appendix!!!
1847 */
1848 switch_statement:
1849 SWITCH '(' expression ')' switch_body
1850 {
1851 $$ = new(state) ast_switch_statement($3, $5);
1852 $$->set_location(yylloc);
1853 }
1854 ;
1855
1856 switch_body:
1857 '{' '}'
1858 {
1859 $$ = new(state) ast_switch_body(NULL);
1860 $$->set_location(yylloc);
1861 }
1862 | '{' case_statement_list '}'
1863 {
1864 $$ = new(state) ast_switch_body($2);
1865 $$->set_location(yylloc);
1866 }
1867 ;
1868
1869 case_label:
1870 CASE expression ':'
1871 {
1872 $$ = new(state) ast_case_label($2);
1873 $$->set_location(yylloc);
1874 }
1875 | DEFAULT ':'
1876 {
1877 $$ = new(state) ast_case_label(NULL);
1878 $$->set_location(yylloc);
1879 }
1880 ;
1881
1882 case_label_list:
1883 case_label
1884 {
1885 ast_case_label_list *labels = new(state) ast_case_label_list();
1886
1887 labels->labels.push_tail(& $1->link);
1888 $$ = labels;
1889 $$->set_location(yylloc);
1890 }
1891 | case_label_list case_label
1892 {
1893 $$ = $1;
1894 $$->labels.push_tail(& $2->link);
1895 }
1896 ;
1897
1898 case_statement:
1899 case_label_list statement
1900 {
1901 ast_case_statement *stmts = new(state) ast_case_statement($1);
1902 stmts->set_location(yylloc);
1903
1904 stmts->stmts.push_tail(& $2->link);
1905 $$ = stmts;
1906 }
1907 | case_statement statement
1908 {
1909 $$ = $1;
1910 $$->stmts.push_tail(& $2->link);
1911 }
1912 ;
1913
1914 case_statement_list:
1915 case_statement
1916 {
1917 ast_case_statement_list *cases= new(state) ast_case_statement_list();
1918 cases->set_location(yylloc);
1919
1920 cases->cases.push_tail(& $1->link);
1921 $$ = cases;
1922 }
1923 | case_statement_list case_statement
1924 {
1925 $$ = $1;
1926 $$->cases.push_tail(& $2->link);
1927 }
1928 ;
1929
1930 iteration_statement:
1931 WHILE '(' condition ')' statement_no_new_scope
1932 {
1933 void *ctx = state;
1934 $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_while,
1935 NULL, $3, NULL, $5);
1936 $$->set_location(yylloc);
1937 }
1938 | DO statement WHILE '(' expression ')' ';'
1939 {
1940 void *ctx = state;
1941 $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_do_while,
1942 NULL, $5, NULL, $2);
1943 $$->set_location(yylloc);
1944 }
1945 | FOR '(' for_init_statement for_rest_statement ')' statement_no_new_scope
1946 {
1947 void *ctx = state;
1948 $$ = new(ctx) ast_iteration_statement(ast_iteration_statement::ast_for,
1949 $3, $4.cond, $4.rest, $6);
1950 $$->set_location(yylloc);
1951 }
1952 ;
1953
1954 for_init_statement:
1955 expression_statement
1956 | declaration_statement
1957 ;
1958
1959 conditionopt:
1960 condition
1961 | /* empty */
1962 {
1963 $$ = NULL;
1964 }
1965 ;
1966
1967 for_rest_statement:
1968 conditionopt ';'
1969 {
1970 $$.cond = $1;
1971 $$.rest = NULL;
1972 }
1973 | conditionopt ';' expression
1974 {
1975 $$.cond = $1;
1976 $$.rest = $3;
1977 }
1978 ;
1979
1980 // Grammar Note: No 'goto'. Gotos are not supported.
1981 jump_statement:
1982 CONTINUE ';'
1983 {
1984 void *ctx = state;
1985 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_continue, NULL);
1986 $$->set_location(yylloc);
1987 }
1988 | BREAK ';'
1989 {
1990 void *ctx = state;
1991 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_break, NULL);
1992 $$->set_location(yylloc);
1993 }
1994 | RETURN ';'
1995 {
1996 void *ctx = state;
1997 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, NULL);
1998 $$->set_location(yylloc);
1999 }
2000 | RETURN expression ';'
2001 {
2002 void *ctx = state;
2003 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_return, $2);
2004 $$->set_location(yylloc);
2005 }
2006 | DISCARD ';' // Fragment shader only.
2007 {
2008 void *ctx = state;
2009 $$ = new(ctx) ast_jump_statement(ast_jump_statement::ast_discard, NULL);
2010 $$->set_location(yylloc);
2011 }
2012 ;
2013
2014 external_declaration:
2015 function_definition { $$ = $1; }
2016 | declaration { $$ = $1; }
2017 | pragma_statement { $$ = NULL; }
2018 | layout_defaults { $$ = NULL; }
2019 ;
2020
2021 function_definition:
2022 function_prototype compound_statement_no_new_scope
2023 {
2024 void *ctx = state;
2025 $$ = new(ctx) ast_function_definition();
2026 $$->set_location(yylloc);
2027 $$->prototype = $1;
2028 $$->body = $2;
2029
2030 state->symbols->pop_scope();
2031 }
2032 ;
2033
2034 /* layout_qualifieropt is packed into this rule */
2035 interface_block:
2036 basic_interface_block
2037 {
2038 $$ = $1;
2039 }
2040 | layout_qualifier basic_interface_block
2041 {
2042 ast_interface_block *block = $2;
2043 if (!block->layout.merge_qualifier(& @1, state, $1)) {
2044 YYERROR;
2045 }
2046 $$ = block;
2047 }
2048 ;
2049
2050 basic_interface_block:
2051 interface_qualifier NEW_IDENTIFIER '{' member_list '}' instance_name_opt ';'
2052 {
2053 ast_interface_block *const block = $6;
2054
2055 block->block_name = $2;
2056 block->declarations.push_degenerate_list_at_head(& $4->link);
2057
2058 if ($1.flags.q.uniform) {
2059 if (!state->ARB_uniform_buffer_object_enable) {
2060 _mesa_glsl_error(& @1, state,
2061 "#version 140 / GL_ARB_uniform_buffer_object "
2062 "required for defining uniform blocks\n");
2063 } else if (state->ARB_uniform_buffer_object_warn) {
2064 _mesa_glsl_warning(& @1, state,
2065 "#version 140 / GL_ARB_uniform_buffer_object "
2066 "required for defining uniform blocks\n");
2067 }
2068 } else {
2069 if (state->es_shader || state->language_version < 150) {
2070 _mesa_glsl_error(& @1, state,
2071 "#version 150 required for using "
2072 "interface blocks.\n");
2073 }
2074 }
2075
2076 /* From the GLSL 1.50.11 spec, section 4.3.7 ("Interface Blocks"):
2077 * "It is illegal to have an input block in a vertex shader
2078 * or an output block in a fragment shader"
2079 */
2080 if ((state->target == vertex_shader) && $1.flags.q.in) {
2081 _mesa_glsl_error(& @1, state,
2082 "`in' interface block is not allowed for "
2083 "a vertex shader\n");
2084 } else if ((state->target == fragment_shader) && $1.flags.q.out) {
2085 _mesa_glsl_error(& @1, state,
2086 "`out' interface block is not allowed for "
2087 "a fragment shader\n");
2088 }
2089
2090 /* Since block arrays require names, and both features are added in
2091 * the same language versions, we don't have to explicitly
2092 * version-check both things.
2093 */
2094 if (block->instance_name != NULL) {
2095 state->check_version(150, 300, & @1, "interface blocks with "
2096 "an instance name are not allowed");
2097 }
2098
2099 unsigned interface_type_mask;
2100 struct ast_type_qualifier temp_type_qualifier;
2101
2102 /* Get a bitmask containing only the in/out/uniform flags, allowing us
2103 * to ignore other irrelevant flags like interpolation qualifiers.
2104 */
2105 temp_type_qualifier.flags.i = 0;
2106 temp_type_qualifier.flags.q.uniform = true;
2107 temp_type_qualifier.flags.q.in = true;
2108 temp_type_qualifier.flags.q.out = true;
2109 interface_type_mask = temp_type_qualifier.flags.i;
2110
2111 /* Get the block's interface qualifier. The interface_qualifier
2112 * production rule guarantees that only one bit will be set (and
2113 * it will be in/out/uniform).
2114 */
2115 unsigned block_interface_qualifier = $1.flags.i;
2116
2117 block->layout.flags.i |= block_interface_qualifier;
2118
2119 foreach_list_typed (ast_declarator_list, member, link, &block->declarations) {
2120 ast_type_qualifier& qualifier = member->type->qualifier;
2121 if ((qualifier.flags.i & interface_type_mask) == 0) {
2122 /* GLSLangSpec.1.50.11, 4.3.7 (Interface Blocks):
2123 * "If no optional qualifier is used in a member declaration, the
2124 * qualifier of the variable is just in, out, or uniform as declared
2125 * by interface-qualifier."
2126 */
2127 qualifier.flags.i |= block_interface_qualifier;
2128 } else if ((qualifier.flags.i & interface_type_mask) !=
2129 block_interface_qualifier) {
2130 /* GLSLangSpec.1.50.11, 4.3.7 (Interface Blocks):
2131 * "If optional qualifiers are used, they can include interpolation
2132 * and storage qualifiers and they must declare an input, output,
2133 * or uniform variable consistent with the interface qualifier of
2134 * the block."
2135 */
2136 _mesa_glsl_error(& @1, state,
2137 "uniform/in/out qualifier on "
2138 "interface block member does not match "
2139 "the interface block\n");
2140 }
2141 }
2142
2143 $$ = block;
2144 }
2145 ;
2146
2147 interface_qualifier:
2148 IN_TOK
2149 {
2150 memset(& $$, 0, sizeof($$));
2151 $$.flags.q.in = 1;
2152 }
2153 | OUT_TOK
2154 {
2155 memset(& $$, 0, sizeof($$));
2156 $$.flags.q.out = 1;
2157 }
2158 | UNIFORM
2159 {
2160 memset(& $$, 0, sizeof($$));
2161 $$.flags.q.uniform = 1;
2162 }
2163 ;
2164
2165 instance_name_opt:
2166 /* empty */
2167 {
2168 $$ = new(state) ast_interface_block(*state->default_uniform_qualifier,
2169 NULL, NULL);
2170 }
2171 | NEW_IDENTIFIER
2172 {
2173 $$ = new(state) ast_interface_block(*state->default_uniform_qualifier,
2174 $1, NULL);
2175 }
2176 | NEW_IDENTIFIER '[' constant_expression ']'
2177 {
2178 $$ = new(state) ast_interface_block(*state->default_uniform_qualifier,
2179 $1, $3);
2180 }
2181 | NEW_IDENTIFIER '[' ']'
2182 {
2183 _mesa_glsl_error(& @1, state,
2184 "instance block arrays must be explicitly sized\n");
2185
2186 $$ = new(state) ast_interface_block(*state->default_uniform_qualifier,
2187 $1, NULL);
2188 }
2189 ;
2190
2191 member_list:
2192 member_declaration
2193 {
2194 $$ = $1;
2195 $1->link.self_link();
2196 }
2197 | member_declaration member_list
2198 {
2199 $$ = $1;
2200 $2->link.insert_before(& $$->link);
2201 }
2202 ;
2203
2204 member_declaration:
2205 fully_specified_type struct_declarator_list ';'
2206 {
2207 void *ctx = state;
2208 ast_fully_specified_type *type = $1;
2209 type->set_location(yylloc);
2210
2211 if (type->qualifier.flags.q.attribute) {
2212 _mesa_glsl_error(& @1, state,
2213 "keyword 'attribute' cannot be used with "
2214 "interface block member\n");
2215 } else if (type->qualifier.flags.q.varying) {
2216 _mesa_glsl_error(& @1, state,
2217 "keyword 'varying' cannot be used with "
2218 "interface block member\n");
2219 }
2220
2221 $$ = new(ctx) ast_declarator_list(type);
2222 $$->set_location(yylloc);
2223 $$->ubo_qualifiers_valid = true;
2224
2225 $$->declarations.push_degenerate_list_at_head(& $2->link);
2226 }
2227 ;
2228
2229 layout_defaults:
2230 layout_qualifier UNIFORM ';'
2231 {
2232 if (!state->default_uniform_qualifier->merge_qualifier(& @1, state, $1)) {
2233 YYERROR;
2234 }
2235 }