src/mesa/shader/program_lexer.l

   1 %{
   2 /*
   3  * Copyright © 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include "main/glheader.h"
  25 #include "main/imports.h"
  26 #include "prog_instruction.h"
  27 #include "prog_statevars.h"
  28
  29 #include "program_parser.h"
  30 #include "program_parse.tab.h"
  31
  32 #define require_ARB_vp (yyextra->mode == ARB_vertex)
  33 #define require_ARB_fp (yyextra->mode == ARB_fragment)
  34 #define require_shadow (yyextra->option.Shadow)
  35 #define require_rect   (yyextra->option.TexRect)
  36 #define require_texarray        (yyextra->option.TexArray)
  37
  38 #define return_token_or_IDENTIFIER(condition, token)    \
  39    do {                                                 \
  40       if (condition) {                                  \
  41          return token;                                  \
  42       } else {                                          \
  43          yylval->string = strdup(yytext);               \
  44          return IDENTIFIER;                             \
  45       }                                                 \
  46    } while (0)
  47
  48 #define return_token_or_DOT(condition, token)           \
  49    do {                                                 \
  50       if (condition) {                                  \
  51          return token;                                  \
  52       } else {                                          \
  53          yyless(1);                                     \
  54          return DOT;                                    \
  55       }                                                 \
  56    } while (0)
  57
  58
  59 #define return_opcode(condition, token, opcode, sat)    \
  60    do {                                                 \
  61       if (condition) {                                  \
  62          yylval->temp_inst.Opcode = OPCODE_ ## opcode;  \
  63          yylval->temp_inst.SaturateMode = SATURATE_ ## sat; \
  64          return token;                                  \
  65       } else {                                          \
  66          yylval->string = strdup(yytext);               \
  67          return IDENTIFIER;                             \
  68       }                                                 \
  69    } while (0)
  70
  71 #define SWIZZLE_INVAL  MAKE_SWIZZLE4(SWIZZLE_NIL, SWIZZLE_NIL, \
  72                                      SWIZZLE_NIL, SWIZZLE_NIL)
  73
  74 static unsigned
  75 mask_from_char(char c)
  76 {
  77    switch (c) {
  78    case 'x':
  79    case 'r':
  80       return WRITEMASK_X;
  81    case 'y':
  82    case 'g':
  83       return WRITEMASK_Y;
  84    case 'z':
  85    case 'b':
  86       return WRITEMASK_Z;
  87    case 'w':
  88    case 'a':
  89       return WRITEMASK_W;
  90    }
  91
  92    return 0;
  93 }
  94
  95 static unsigned
  96 swiz_from_char(char c)
  97 {
  98    switch (c) {
  99    case 'x':
 100    case 'r':
 101       return SWIZZLE_X;
 102    case 'y':
 103    case 'g':
 104       return SWIZZLE_Y;
 105    case 'z':
 106    case 'b':
 107       return SWIZZLE_Z;
 108    case 'w':
 109    case 'a':
 110       return SWIZZLE_W;
 111    }
 112
 113    return 0;
 114 }
 115
 116 #define YY_USER_ACTION                                                  \
 117    do {                                                                 \
 118       yylloc->first_column = yylloc->last_column;                       \
 119       yylloc->last_column += yyleng;                                    \
 120       if ((yylloc->first_line == 1)                                     \
 121           && (yylloc->first_column == 1)) {                             \
 122          yylloc->position = 1;                                          \
 123       } else {                                                          \
 124          yylloc->position += yylloc->last_column - yylloc->first_column; \
 125       }                                                                 \
 126    } while(0);
 127
 128 #define YY_EXTRA_TYPE struct asm_parser_state *
 129 %}
 130
 131 num    [0-9]+
 132 exp    [Ee][-+]?[0-9]+
 133 frac   "."[0-9]+
 134 dot    "."[ \t]*
 135
 136 %option bison-bridge bison-locations reentrant noyywrap
 137 %%
 138
 139 "!!ARBvp1.0"              { return ARBvp_10; }
 140 "!!ARBfp1.0"              { return ARBfp_10; }
 141 ADDRESS                   {
 142    yylval->integer = at_address;
 143    return_token_or_IDENTIFIER(require_ARB_vp, ADDRESS);
 144 }
 145 ALIAS                     { return ALIAS; }
 146 ATTRIB                    { return ATTRIB; }
 147 END                       { return END; }
 148 OPTION                    { return OPTION; }
 149 OUTPUT                    { return OUTPUT; }
 150 PARAM                     { return PARAM; }
 151 TEMP                      { yylval->integer = at_temp; return TEMP; }
 152
 153 ABS       { return_opcode(             1, VECTOR_OP, ABS, OFF); }
 154 ABS_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, ABS, ZERO_ONE); }
 155 ADD       { return_opcode(             1, BIN_OP, ADD, OFF); }
 156 ADD_SAT   { return_opcode(require_ARB_fp, BIN_OP, ADD, ZERO_ONE); }
 157 ARL       { return_opcode(require_ARB_vp, ARL, ARL, OFF); }
 158
 159 CMP       { return_opcode(require_ARB_fp, TRI_OP, CMP, OFF); }
 160 CMP_SAT   { return_opcode(require_ARB_fp, TRI_OP, CMP, ZERO_ONE); }
 161 COS       { return_opcode(require_ARB_fp, SCALAR_OP, COS, OFF); }
 162 COS_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, COS, ZERO_ONE); }
 163
 164 DP3       { return_opcode(             1, BIN_OP, DP3, OFF); }
 165 DP3_SAT   { return_opcode(require_ARB_fp, BIN_OP, DP3, ZERO_ONE); }
 166 DP4       { return_opcode(             1, BIN_OP, DP4, OFF); }
 167 DP4_SAT   { return_opcode(require_ARB_fp, BIN_OP, DP4, ZERO_ONE); }
 168 DPH       { return_opcode(             1, BIN_OP, DPH, OFF); }
 169 DPH_SAT   { return_opcode(require_ARB_fp, BIN_OP, DPH, ZERO_ONE); }
 170 DST       { return_opcode(             1, BIN_OP, DST, OFF); }
 171 DST_SAT   { return_opcode(require_ARB_fp, BIN_OP, DST, ZERO_ONE); }
 172
 173 EX2       { return_opcode(             1, SCALAR_OP, EX2, OFF); }
 174 EX2_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, EX2, ZERO_ONE); }
 175 EXP       { return_opcode(require_ARB_vp, SCALAR_OP, EXP, OFF); }
 176
 177 FLR       { return_opcode(             1, VECTOR_OP, FLR, OFF); }
 178 FLR_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, FLR, ZERO_ONE); }
 179 FRC       { return_opcode(             1, VECTOR_OP, FRC, OFF); }
 180 FRC_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, FRC, ZERO_ONE); }
 181
 182 KIL       { return_opcode(require_ARB_fp, KIL, KIL, OFF); }
 183
 184 LIT       { return_opcode(             1, VECTOR_OP, LIT, OFF); }
 185 LIT_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, LIT, ZERO_ONE); }
 186 LG2       { return_opcode(             1, SCALAR_OP, LG2, OFF); }
 187 LG2_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, LG2, ZERO_ONE); }
 188 LOG       { return_opcode(require_ARB_vp, SCALAR_OP, LOG, OFF); }
 189 LRP       { return_opcode(require_ARB_fp, TRI_OP, LRP, OFF); }
 190 LRP_SAT   { return_opcode(require_ARB_fp, TRI_OP, LRP, ZERO_ONE); }
 191
 192 MAD       { return_opcode(             1, TRI_OP, MAD, OFF); }
 193 MAD_SAT   { return_opcode(require_ARB_fp, TRI_OP, MAD, ZERO_ONE); }
 194 MAX       { return_opcode(             1, BIN_OP, MAX, OFF); }
 195 MAX_SAT   { return_opcode(require_ARB_fp, BIN_OP, MAX, ZERO_ONE); }
 196 MIN       { return_opcode(             1, BIN_OP, MIN, OFF); }
 197 MIN_SAT   { return_opcode(require_ARB_fp, BIN_OP, MIN, ZERO_ONE); }
 198 MOV       { return_opcode(             1, VECTOR_OP, MOV, OFF); }
 199 MOV_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, MOV, ZERO_ONE); }
 200 MUL       { return_opcode(             1, BIN_OP, MUL, OFF); }
 201 MUL_SAT   { return_opcode(require_ARB_fp, BIN_OP, MUL, ZERO_ONE); }
 202
 203 POW       { return_opcode(             1, BINSC_OP, POW, OFF); }
 204 POW_SAT   { return_opcode(require_ARB_fp, BINSC_OP, POW, ZERO_ONE); }
 205
 206 RCP       { return_opcode(             1, SCALAR_OP, RCP, OFF); }
 207 RCP_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, RCP, ZERO_ONE); }
 208 RSQ       { return_opcode(             1, SCALAR_OP, RSQ, OFF); }
 209 RSQ_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, RSQ, ZERO_ONE); }
 210
 211 SCS       { return_opcode(require_ARB_fp, SCALAR_OP, SCS, OFF); }
 212 SCS_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, SCS, ZERO_ONE); }
 213 SGE       { return_opcode(             1, BIN_OP, SGE, OFF); }
 214 SGE_SAT   { return_opcode(require_ARB_fp, BIN_OP, SGE, ZERO_ONE); }
 215 SIN       { return_opcode(require_ARB_fp, SCALAR_OP, SIN, OFF); }
 216 SIN_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, SIN, ZERO_ONE); }
 217 SLT       { return_opcode(             1, BIN_OP, SLT, OFF); }
 218 SLT_SAT   { return_opcode(require_ARB_fp, BIN_OP, SLT, ZERO_ONE); }
 219 SUB       { return_opcode(             1, BIN_OP, SUB, OFF); }
 220 SUB_SAT   { return_opcode(require_ARB_fp, BIN_OP, SUB, ZERO_ONE); }
 221 SWZ       { return_opcode(             1, SWZ, SWZ, OFF); }
 222 SWZ_SAT   { return_opcode(require_ARB_fp, SWZ, SWZ, ZERO_ONE); }
 223
 224 TEX       { return_opcode(require_ARB_fp, SAMPLE_OP, TEX, OFF); }
 225 TEX_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TEX, ZERO_ONE); }
 226 TXB       { return_opcode(require_ARB_fp, SAMPLE_OP, TXB, OFF); }
 227 TXB_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TXB, ZERO_ONE); }
 228 TXP       { return_opcode(require_ARB_fp, SAMPLE_OP, TXP, OFF); }
 229 TXP_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TXP, ZERO_ONE); }
 230
 231 XPD       { return_opcode(             1, BIN_OP, XPD, OFF); }
 232 XPD_SAT   { return_opcode(require_ARB_fp, BIN_OP, XPD, ZERO_ONE); }
 233
 234 vertex                    { return_token_or_IDENTIFIER(require_ARB_vp, VERTEX); }
 235 fragment                  { return_token_or_IDENTIFIER(require_ARB_fp, FRAGMENT); }
 236 program                   { return PROGRAM; }
 237 state                     { return STATE; }
 238 result                    { return RESULT; }
 239
 240 {dot}ambient              { return AMBIENT; }
 241 {dot}attenuation          { return ATTENUATION; }
 242 {dot}back                 { return BACK; }
 243 {dot}clip                 { return_token_or_DOT(require_ARB_vp, CLIP); }
 244 {dot}color                { return COLOR; }
 245 {dot}depth                { return_token_or_DOT(require_ARB_fp, DEPTH); }
 246 {dot}diffuse              { return DIFFUSE; }
 247 {dot}direction            { return DIRECTION; }
 248 {dot}emission             { return EMISSION; }
 249 {dot}env                  { return ENV; }
 250 {dot}eye                  { return EYE; }
 251 {dot}fogcoord             { return FOGCOORD; }
 252 {dot}fog                  { return FOG; }
 253 {dot}front                { return FRONT; }
 254 {dot}half                 { return HALF; }
 255 {dot}inverse              { return INVERSE; }
 256 {dot}invtrans             { return INVTRANS; }
 257 {dot}light                { return LIGHT; }
 258 {dot}lightmodel           { return LIGHTMODEL; }
 259 {dot}lightprod            { return LIGHTPROD; }
 260 {dot}local                { return LOCAL; }
 261 {dot}material             { return MATERIAL; }
 262 {dot}program              { return MAT_PROGRAM; }
 263 {dot}matrix               { return MATRIX; }
 264 {dot}matrixindex          { return_token_or_DOT(require_ARB_vp, MATRIXINDEX); }
 265 {dot}modelview            { return MODELVIEW; }
 266 {dot}mvp                  { return MVP; }
 267 {dot}normal               { return_token_or_DOT(require_ARB_vp, NORMAL); }
 268 {dot}object               { return OBJECT; }
 269 {dot}palette              { return PALETTE; }
 270 {dot}params               { return PARAMS; }
 271 {dot}plane                { return PLANE; }
 272 {dot}point                { return_token_or_DOT(require_ARB_vp, POINT_TOK); }
 273 {dot}pointsize            { return_token_or_DOT(require_ARB_vp, POINTSIZE); }
 274 {dot}position             { return POSITION; }
 275 {dot}primary              { return PRIMARY; }
 276 {dot}projection           { return PROJECTION; }
 277 {dot}range                { return_token_or_DOT(require_ARB_fp, RANGE); }
 278 {dot}row                  { return ROW; }
 279 {dot}scenecolor           { return SCENECOLOR; }
 280 {dot}secondary            { return SECONDARY; }
 281 {dot}shininess            { return SHININESS; }
 282 {dot}size                 { return_token_or_DOT(require_ARB_vp, SIZE_TOK); }
 283 {dot}specular             { return SPECULAR; }
 284 {dot}spot                 { return SPOT; }
 285 {dot}texcoord             { return TEXCOORD; }
 286 {dot}texenv               { return_token_or_DOT(require_ARB_fp, TEXENV); }
 287 {dot}texgen               { return_token_or_DOT(require_ARB_vp, TEXGEN); }
 288 {dot}q                    { return_token_or_DOT(require_ARB_vp, TEXGEN_Q); }
 289 {dot}s                    { return_token_or_DOT(require_ARB_vp, TEXGEN_S); }
 290 {dot}t                    { return_token_or_DOT(require_ARB_vp, TEXGEN_T); }
 291 {dot}texture              { return TEXTURE; }
 292 {dot}transpose            { return TRANSPOSE; }
 293 {dot}attrib               { return_token_or_DOT(require_ARB_vp, VTXATTRIB); }
 294 {dot}weight               { return_token_or_DOT(require_ARB_vp, WEIGHT); }
 295
 296 texture                   { return_token_or_IDENTIFIER(require_ARB_fp, TEXTURE_UNIT); }
 297 1D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_1D); }
 298 2D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_2D); }
 299 3D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_3D); }
 300 CUBE                      { return_token_or_IDENTIFIER(require_ARB_fp, TEX_CUBE); }
 301 RECT                      { return_token_or_IDENTIFIER(require_ARB_fp && require_rect, TEX_RECT); }
 302 SHADOW1D                  { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow, TEX_SHADOW1D); }
 303 SHADOW2D                  { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow, TEX_SHADOW2D); }
 304 SHADOWRECT                { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_rect, TEX_SHADOWRECT); }
 305 ARRAY1D                   { return_token_or_IDENTIFIER(require_ARB_fp && require_texarray, TEX_ARRAY1D); }
 306 ARRAY2D                   { return_token_or_IDENTIFIER(require_ARB_fp && require_texarray, TEX_ARRAY2D); }
 307 ARRAYSHADOW1D             { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_texarray, TEX_ARRAYSHADOW1D); }
 308 ARRAYSHADOW2D             { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_texarray, TEX_ARRAYSHADOW2D); }
 309
 310 [_a-zA-Z$][_a-zA-Z0-9$]*  {
 311    yylval->string = strdup(yytext);
 312    return IDENTIFIER;
 313 }
 314
 315 ".."                      { return DOT_DOT; }
 316
 317 {num}                     {
 318    yylval->integer = strtol(yytext, NULL, 10);
 319    return INTEGER;
 320 }
 321 {num}?{frac}{exp}?        {
 322    yylval->real = _mesa_strtod(yytext, NULL);
 323    return REAL;
 324 }
 325 {num}"."/[^.]             {
 326    yylval->real = _mesa_strtod(yytext, NULL);
 327    return REAL;
 328 }
 329 {num}{exp}                {
 330    yylval->real = _mesa_strtod(yytext, NULL);
 331    return REAL;
 332 }
 333 {num}"."{exp}             {
 334    yylval->real = _mesa_strtod(yytext, NULL);
 335    return REAL;
 336 }
 337
 338 ".xyzw"                   {
 339    yylval->swiz_mask.swizzle = SWIZZLE_NOOP;
 340    yylval->swiz_mask.mask = WRITEMASK_XYZW;
 341    return MASK4;
 342 }
 343
 344 ".xy"[zw]                 {
 345    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 346    yylval->swiz_mask.mask = WRITEMASK_XY
 347       | mask_from_char(yytext[3]);
 348    return MASK3;
 349 }
 350 ".xzw"                    {
 351    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 352    yylval->swiz_mask.mask = WRITEMASK_XZW;
 353    return MASK3;
 354 }
 355 ".yzw"                    {
 356    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 357    yylval->swiz_mask.mask = WRITEMASK_YZW;
 358    return MASK3;
 359 }
 360
 361 ".x"[yzw]                 {
 362    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 363    yylval->swiz_mask.mask = WRITEMASK_X
 364       | mask_from_char(yytext[2]);
 365    return MASK2;
 366 }
 367 ".y"[zw]                  {
 368    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 369    yylval->swiz_mask.mask = WRITEMASK_Y
 370       | mask_from_char(yytext[2]);
 371    return MASK2;
 372 }
 373 ".zw"                     {
 374    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 375    yylval->swiz_mask.mask = WRITEMASK_ZW;
 376    return MASK2;
 377 }
 378
 379 "."[xyzw]                 {
 380    const unsigned s = swiz_from_char(yytext[1]);
 381    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(s, s, s, s);
 382    yylval->swiz_mask.mask = mask_from_char(yytext[1]);
 383    return MASK1;
 384 }
 385
 386 "."[xyzw]{4}              {
 387    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(swiz_from_char(yytext[1]),
 388                                             swiz_from_char(yytext[2]),
 389                                             swiz_from_char(yytext[3]),
 390                                             swiz_from_char(yytext[4]));
 391    yylval->swiz_mask.mask = 0;
 392    return SWIZZLE;
 393 }
 394
 395 ".rgba"                   {
 396    yylval->swiz_mask.swizzle = SWIZZLE_NOOP;
 397    yylval->swiz_mask.mask = WRITEMASK_XYZW;
 398    return_token_or_DOT(require_ARB_fp, MASK4);
 399 }
 400
 401 ".rg"[ba]                 {
 402    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 403    yylval->swiz_mask.mask = WRITEMASK_XY
 404       | mask_from_char(yytext[3]);
 405    return_token_or_DOT(require_ARB_fp, MASK3);
 406 }
 407 ".rba"                    {
 408    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 409    yylval->swiz_mask.mask = WRITEMASK_XZW;
 410    return_token_or_DOT(require_ARB_fp, MASK3);
 411 }
 412 ".gba"                    {
 413    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 414    yylval->swiz_mask.mask = WRITEMASK_YZW;
 415    return_token_or_DOT(require_ARB_fp, MASK3);
 416 }
 417
 418 ".r"[gba]                 {
 419    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 420    yylval->swiz_mask.mask = WRITEMASK_X
 421       | mask_from_char(yytext[2]);
 422    return_token_or_DOT(require_ARB_fp, MASK2);
 423 }
 424 ".g"[ba]                  {
 425    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 426    yylval->swiz_mask.mask = WRITEMASK_Y
 427       | mask_from_char(yytext[2]);
 428    return_token_or_DOT(require_ARB_fp, MASK2);
 429 }
 430 ".ba"                     {
 431    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 432    yylval->swiz_mask.mask = WRITEMASK_ZW;
 433    return_token_or_DOT(require_ARB_fp, MASK2);
 434 }
 435
 436 "."[gba]                  {
 437    const unsigned s = swiz_from_char(yytext[1]);
 438    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(s, s, s, s);
 439    yylval->swiz_mask.mask = mask_from_char(yytext[1]);
 440    return_token_or_DOT(require_ARB_fp, MASK1);
 441 }
 442
 443
 444 ".r"                      {
 445    if (require_ARB_vp) {
 446       return TEXGEN_R;
 447    } else {
 448       yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(SWIZZLE_X, SWIZZLE_X,
 449                                                 SWIZZLE_X, SWIZZLE_X);
 450       yylval->swiz_mask.mask = WRITEMASK_X;
 451       return MASK1;
 452    }
 453 }
 454
 455 "."[rgba]{4}              {
 456    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(swiz_from_char(yytext[1]),
 457                                             swiz_from_char(yytext[2]),
 458                                             swiz_from_char(yytext[3]),
 459                                             swiz_from_char(yytext[4]));
 460    yylval->swiz_mask.mask = 0;
 461    return_token_or_DOT(require_ARB_fp, SWIZZLE);
 462 }
 463
 464 "."                       { return DOT; }
 465
 466 \n                        {
 467    yylloc->first_line++;
 468    yylloc->first_column = 1;
 469    yylloc->last_line++;
 470    yylloc->last_column = 1;
 471    yylloc->position++;
 472 }
 473 [ \t\r]+                  /* eat whitespace */ ;
 474 #.*$                      /* eat comments */ ;
 475 .                         { return yytext[0]; }
 476 %%
 477
 478 void
 479 _mesa_program_lexer_ctor(void **scanner, struct asm_parser_state *state,
 480                          const char *string, size_t len)
 481 {
 482    yylex_init_extra(state, scanner);
 483    yy_scan_bytes(string, len, *scanner);
 484 }
 485
 486 void
 487 _mesa_program_lexer_dtor(void *scanner)
 488 {
 489    yylex_destroy(scanner);
 490 }