src/mesa/shader/program_lexer.l

   1 %{
   2 /*
   3  * Copyright © 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include "main/glheader.h"
  25 #include "prog_instruction.h"
  26 #include "prog_statevars.h"
  27
  28 #include "program_parser.h"
  29 #include "program_parse.tab.h"
  30
  31 #define require_ARB_vp (yyextra->mode == ARB_vertex)
  32 #define require_ARB_fp (yyextra->mode == ARB_fragment)
  33 #define require_shadow (yyextra->option.Shadow)
  34 #define require_rect   (yyextra->option.TexRect)
  35 #define require_texarray        (yyextra->option.TexArray)
  36
  37 #define return_token_or_IDENTIFIER(condition, token)    \
  38    do {                                                 \
  39       if (condition) {                                  \
  40          return token;                                  \
  41       } else {                                          \
  42          yylval->string = strdup(yytext);               \
  43          return IDENTIFIER;                             \
  44       }                                                 \
  45    } while (0)
  46
  47 #define return_token_or_DOT(condition, token)           \
  48    do {                                                 \
  49       if (condition) {                                  \
  50          return token;                                  \
  51       } else {                                          \
  52          yyless(1);                                     \
  53          return DOT;                                    \
  54       }                                                 \
  55    } while (0)
  56
  57
  58 #define return_opcode(condition, token, opcode, sat)    \
  59    do {                                                 \
  60       if (condition) {                                  \
  61          yylval->temp_inst.Opcode = OPCODE_ ## opcode;  \
  62          yylval->temp_inst.SaturateMode = SATURATE_ ## sat; \
  63          return token;                                  \
  64       } else {                                          \
  65          yylval->string = strdup(yytext);               \
  66          return IDENTIFIER;                             \
  67       }                                                 \
  68    } while (0)
  69
  70 #define SWIZZLE_INVAL  MAKE_SWIZZLE4(SWIZZLE_NIL, SWIZZLE_NIL, \
  71                                      SWIZZLE_NIL, SWIZZLE_NIL)
  72
  73 static unsigned
  74 mask_from_char(char c)
  75 {
  76    switch (c) {
  77    case 'x':
  78    case 'r':
  79       return WRITEMASK_X;
  80    case 'y':
  81    case 'g':
  82       return WRITEMASK_Y;
  83    case 'z':
  84    case 'b':
  85       return WRITEMASK_Z;
  86    case 'w':
  87    case 'a':
  88       return WRITEMASK_W;
  89    }
  90
  91    return 0;
  92 }
  93
  94 static unsigned
  95 swiz_from_char(char c)
  96 {
  97    switch (c) {
  98    case 'x':
  99    case 'r':
 100       return SWIZZLE_X;
 101    case 'y':
 102    case 'g':
 103       return SWIZZLE_Y;
 104    case 'z':
 105    case 'b':
 106       return SWIZZLE_Z;
 107    case 'w':
 108    case 'a':
 109       return SWIZZLE_W;
 110    }
 111
 112    return 0;
 113 }
 114
 115 #define YY_USER_ACTION                                                  \
 116    do {                                                                 \
 117       yylloc->first_column = yylloc->last_column;                       \
 118       yylloc->last_column += yyleng;                                    \
 119       if ((yylloc->first_line == 1)                                     \
 120           && (yylloc->first_column == 1)) {                             \
 121          yylloc->position = 1;                                          \
 122       } else {                                                          \
 123          yylloc->position += yylloc->last_column - yylloc->first_column; \
 124       }                                                                 \
 125    } while(0);
 126
 127 #define YY_EXTRA_TYPE struct asm_parser_state *
 128 %}
 129
 130 num    [0-9]+
 131 exp    [Ee][-+]?[0-9]+
 132 frac   "."[0-9]+
 133 dot    "."[ \t]*
 134
 135 %option bison-bridge bison-locations reentrant noyywrap
 136 %%
 137
 138 "!!ARBvp1.0"              { return ARBvp_10; }
 139 "!!ARBfp1.0"              { return ARBfp_10; }
 140 ADDRESS                   {
 141    yylval->integer = at_address;
 142    return_token_or_IDENTIFIER(require_ARB_vp, ADDRESS);
 143 }
 144 ALIAS                     { return ALIAS; }
 145 ATTRIB                    { return ATTRIB; }
 146 END                       { return END; }
 147 OPTION                    { return OPTION; }
 148 OUTPUT                    { return OUTPUT; }
 149 PARAM                     { return PARAM; }
 150 TEMP                      { yylval->integer = at_temp; return TEMP; }
 151
 152 ABS       { return_opcode(             1, VECTOR_OP, ABS, OFF); }
 153 ABS_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, ABS, ZERO_ONE); }
 154 ADD       { return_opcode(             1, BIN_OP, ADD, OFF); }
 155 ADD_SAT   { return_opcode(require_ARB_fp, BIN_OP, ADD, ZERO_ONE); }
 156 ARL       { return_opcode(require_ARB_vp, ARL, ARL, OFF); }
 157
 158 CMP       { return_opcode(require_ARB_fp, TRI_OP, CMP, OFF); }
 159 CMP_SAT   { return_opcode(require_ARB_fp, TRI_OP, CMP, ZERO_ONE); }
 160 COS       { return_opcode(require_ARB_fp, SCALAR_OP, COS, OFF); }
 161 COS_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, COS, ZERO_ONE); }
 162
 163 DP3       { return_opcode(             1, BIN_OP, DP3, OFF); }
 164 DP3_SAT   { return_opcode(require_ARB_fp, BIN_OP, DP3, ZERO_ONE); }
 165 DP4       { return_opcode(             1, BIN_OP, DP4, OFF); }
 166 DP4_SAT   { return_opcode(require_ARB_fp, BIN_OP, DP4, ZERO_ONE); }
 167 DPH       { return_opcode(             1, BIN_OP, DPH, OFF); }
 168 DPH_SAT   { return_opcode(require_ARB_fp, BIN_OP, DPH, ZERO_ONE); }
 169 DST       { return_opcode(             1, BIN_OP, DST, OFF); }
 170 DST_SAT   { return_opcode(require_ARB_fp, BIN_OP, DST, ZERO_ONE); }
 171
 172 EX2       { return_opcode(             1, SCALAR_OP, EX2, OFF); }
 173 EX2_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, EX2, ZERO_ONE); }
 174 EXP       { return_opcode(require_ARB_vp, SCALAR_OP, EXP, OFF); }
 175
 176 FLR       { return_opcode(             1, VECTOR_OP, FLR, OFF); }
 177 FLR_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, FLR, ZERO_ONE); }
 178 FRC       { return_opcode(             1, VECTOR_OP, FRC, OFF); }
 179 FRC_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, FRC, ZERO_ONE); }
 180
 181 KIL       { return_opcode(require_ARB_fp, KIL, KIL, OFF); }
 182
 183 LIT       { return_opcode(             1, VECTOR_OP, LIT, OFF); }
 184 LIT_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, LIT, ZERO_ONE); }
 185 LG2       { return_opcode(             1, SCALAR_OP, LG2, OFF); }
 186 LG2_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, LG2, ZERO_ONE); }
 187 LOG       { return_opcode(require_ARB_vp, SCALAR_OP, LOG, OFF); }
 188 LRP       { return_opcode(require_ARB_fp, TRI_OP, LRP, OFF); }
 189 LRP_SAT   { return_opcode(require_ARB_fp, TRI_OP, LRP, ZERO_ONE); }
 190
 191 MAD       { return_opcode(             1, TRI_OP, MAD, OFF); }
 192 MAD_SAT   { return_opcode(require_ARB_fp, TRI_OP, MAD, ZERO_ONE); }
 193 MAX       { return_opcode(             1, BIN_OP, MAX, OFF); }
 194 MAX_SAT   { return_opcode(require_ARB_fp, BIN_OP, MAX, ZERO_ONE); }
 195 MIN       { return_opcode(             1, BIN_OP, MIN, OFF); }
 196 MIN_SAT   { return_opcode(require_ARB_fp, BIN_OP, MIN, ZERO_ONE); }
 197 MOV       { return_opcode(             1, VECTOR_OP, MOV, OFF); }
 198 MOV_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, MOV, ZERO_ONE); }
 199 MUL       { return_opcode(             1, BIN_OP, MUL, OFF); }
 200 MUL_SAT   { return_opcode(require_ARB_fp, BIN_OP, MUL, ZERO_ONE); }
 201
 202 POW       { return_opcode(             1, BINSC_OP, POW, OFF); }
 203 POW_SAT   { return_opcode(require_ARB_fp, BINSC_OP, POW, ZERO_ONE); }
 204
 205 RCP       { return_opcode(             1, SCALAR_OP, RCP, OFF); }
 206 RCP_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, RCP, ZERO_ONE); }
 207 RSQ       { return_opcode(             1, SCALAR_OP, RSQ, OFF); }
 208 RSQ_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, RSQ, ZERO_ONE); }
 209
 210 SCS       { return_opcode(require_ARB_fp, SCALAR_OP, SCS, OFF); }
 211 SCS_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, SCS, ZERO_ONE); }
 212 SGE       { return_opcode(             1, BIN_OP, SGE, OFF); }
 213 SGE_SAT   { return_opcode(require_ARB_fp, BIN_OP, SGE, ZERO_ONE); }
 214 SIN       { return_opcode(require_ARB_fp, SCALAR_OP, SIN, OFF); }
 215 SIN_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, SIN, ZERO_ONE); }
 216 SLT       { return_opcode(             1, BIN_OP, SLT, OFF); }
 217 SLT_SAT   { return_opcode(require_ARB_fp, BIN_OP, SLT, ZERO_ONE); }
 218 SUB       { return_opcode(             1, BIN_OP, SUB, OFF); }
 219 SUB_SAT   { return_opcode(require_ARB_fp, BIN_OP, SUB, ZERO_ONE); }
 220 SWZ       { return_opcode(             1, SWZ, SWZ, OFF); }
 221 SWZ_SAT   { return_opcode(require_ARB_fp, SWZ, SWZ, ZERO_ONE); }
 222
 223 TEX       { return_opcode(require_ARB_fp, SAMPLE_OP, TEX, OFF); }
 224 TEX_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TEX, ZERO_ONE); }
 225 TXB       { return_opcode(require_ARB_fp, SAMPLE_OP, TXB, OFF); }
 226 TXB_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TXB, ZERO_ONE); }
 227 TXP       { return_opcode(require_ARB_fp, SAMPLE_OP, TXP, OFF); }
 228 TXP_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TXP, ZERO_ONE); }
 229
 230 XPD       { return_opcode(             1, BIN_OP, XPD, OFF); }
 231 XPD_SAT   { return_opcode(require_ARB_fp, BIN_OP, XPD, ZERO_ONE); }
 232
 233 vertex                    { return_token_or_IDENTIFIER(require_ARB_vp, VERTEX); }
 234 fragment                  { return_token_or_IDENTIFIER(require_ARB_fp, FRAGMENT); }
 235 program                   { return PROGRAM; }
 236 state                     { return STATE; }
 237 result                    { return RESULT; }
 238
 239 {dot}ambient              { return AMBIENT; }
 240 {dot}attenuation          { return ATTENUATION; }
 241 {dot}back                 { return BACK; }
 242 {dot}clip                 { return_token_or_DOT(require_ARB_vp, CLIP); }
 243 {dot}color                { return COLOR; }
 244 {dot}depth                { return_token_or_DOT(require_ARB_fp, DEPTH); }
 245 {dot}diffuse              { return DIFFUSE; }
 246 {dot}direction            { return DIRECTION; }
 247 {dot}emission             { return EMISSION; }
 248 {dot}env                  { return ENV; }
 249 {dot}eye                  { return EYE; }
 250 {dot}fogcoord             { return FOGCOORD; }
 251 {dot}fog                  { return FOG; }
 252 {dot}front                { return FRONT; }
 253 {dot}half                 { return HALF; }
 254 {dot}inverse              { return INVERSE; }
 255 {dot}invtrans             { return INVTRANS; }
 256 {dot}light                { return LIGHT; }
 257 {dot}lightmodel           { return LIGHTMODEL; }
 258 {dot}lightprod            { return LIGHTPROD; }
 259 {dot}local                { return LOCAL; }
 260 {dot}material             { return MATERIAL; }
 261 {dot}program              { return MAT_PROGRAM; }
 262 {dot}matrix               { return MATRIX; }
 263 {dot}matrixindex          { return_token_or_DOT(require_ARB_vp, MATRIXINDEX); }
 264 {dot}modelview            { return MODELVIEW; }
 265 {dot}mvp                  { return MVP; }
 266 {dot}normal               { return_token_or_DOT(require_ARB_vp, NORMAL); }
 267 {dot}object               { return OBJECT; }
 268 {dot}palette              { return PALETTE; }
 269 {dot}params               { return PARAMS; }
 270 {dot}plane                { return PLANE; }
 271 {dot}point                { return_token_or_DOT(require_ARB_vp, POINT_TOK); }
 272 {dot}pointsize            { return_token_or_DOT(require_ARB_vp, POINTSIZE); }
 273 {dot}position             { return POSITION; }
 274 {dot}primary              { return PRIMARY; }
 275 {dot}projection           { return PROJECTION; }
 276 {dot}range                { return_token_or_DOT(require_ARB_fp, RANGE); }
 277 {dot}row                  { return ROW; }
 278 {dot}scenecolor           { return SCENECOLOR; }
 279 {dot}secondary            { return SECONDARY; }
 280 {dot}shininess            { return SHININESS; }
 281 {dot}size                 { return_token_or_DOT(require_ARB_vp, SIZE_TOK); }
 282 {dot}specular             { return SPECULAR; }
 283 {dot}spot                 { return SPOT; }
 284 {dot}texcoord             { return TEXCOORD; }
 285 {dot}texenv               { return_token_or_DOT(require_ARB_fp, TEXENV); }
 286 {dot}texgen               { return_token_or_DOT(require_ARB_vp, TEXGEN); }
 287 {dot}q                    { return_token_or_DOT(require_ARB_vp, TEXGEN_Q); }
 288 {dot}s                    { return_token_or_DOT(require_ARB_vp, TEXGEN_S); }
 289 {dot}t                    { return_token_or_DOT(require_ARB_vp, TEXGEN_T); }
 290 {dot}texture              { return TEXTURE; }
 291 {dot}transpose            { return TRANSPOSE; }
 292 {dot}attrib               { return_token_or_DOT(require_ARB_vp, VTXATTRIB); }
 293 {dot}weight               { return_token_or_DOT(require_ARB_vp, WEIGHT); }
 294
 295 texture                   { return_token_or_IDENTIFIER(require_ARB_fp, TEXTURE_UNIT); }
 296 1D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_1D); }
 297 2D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_2D); }
 298 3D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_3D); }
 299 CUBE                      { return_token_or_IDENTIFIER(require_ARB_fp, TEX_CUBE); }
 300 RECT                      { return_token_or_IDENTIFIER(require_ARB_fp && require_rect, TEX_RECT); }
 301 SHADOW1D                  { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow, TEX_SHADOW1D); }
 302 SHADOW2D                  { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow, TEX_SHADOW2D); }
 303 SHADOWRECT                { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_rect, TEX_SHADOWRECT); }
 304 ARRAY1D                   { return_token_or_IDENTIFIER(require_ARB_fp && require_texarray, TEX_ARRAY1D); }
 305 ARRAY2D                   { return_token_or_IDENTIFIER(require_ARB_fp && require_texarray, TEX_ARRAY2D); }
 306 ARRAYSHADOW1D             { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_texarray, TEX_ARRAYSHADOW1D); }
 307 ARRAYSHADOW2D             { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_texarray, TEX_ARRAYSHADOW2D); }
 308
 309 [_a-zA-Z$][_a-zA-Z0-9$]*  {
 310    yylval->string = strdup(yytext);
 311    return IDENTIFIER;
 312 }
 313
 314 ".."                      { return DOT_DOT; }
 315
 316 {num}                     {
 317    yylval->integer = strtol(yytext, NULL, 10);
 318    return INTEGER;
 319 }
 320 {num}?{frac}{exp}?        {
 321    yylval->real = strtod(yytext, NULL);
 322    return REAL;
 323 }
 324 {num}"."/[^.]             {
 325    yylval->real = strtod(yytext, NULL);
 326    return REAL;
 327 }
 328 {num}{exp}                {
 329    yylval->real = strtod(yytext, NULL);
 330    return REAL;
 331 }
 332 {num}"."{exp}             {
 333    yylval->real = strtod(yytext, NULL);
 334    return REAL;
 335 }
 336
 337 ".xyzw"                   {
 338    yylval->swiz_mask.swizzle = SWIZZLE_NOOP;
 339    yylval->swiz_mask.mask = WRITEMASK_XYZW;
 340    return MASK4;
 341 }
 342
 343 ".xy"[zw]                 {
 344    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 345    yylval->swiz_mask.mask = WRITEMASK_XY
 346       | mask_from_char(yytext[3]);
 347    return MASK3;
 348 }
 349 ".xzw"                    {
 350    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 351    yylval->swiz_mask.mask = WRITEMASK_XZW;
 352    return MASK3;
 353 }
 354 ".yzw"                    {
 355    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 356    yylval->swiz_mask.mask = WRITEMASK_YZW;
 357    return MASK3;
 358 }
 359
 360 ".x"[yzw]                 {
 361    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 362    yylval->swiz_mask.mask = WRITEMASK_X
 363       | mask_from_char(yytext[2]);
 364    return MASK2;
 365 }
 366 ".y"[zw]                  {
 367    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 368    yylval->swiz_mask.mask = WRITEMASK_Y
 369       | mask_from_char(yytext[2]);
 370    return MASK2;
 371 }
 372 ".zw"                     {
 373    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 374    yylval->swiz_mask.mask = WRITEMASK_ZW;
 375    return MASK2;
 376 }
 377
 378 "."[xyzw]                 {
 379    const unsigned s = swiz_from_char(yytext[1]);
 380    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(s, s, s, s);
 381    yylval->swiz_mask.mask = mask_from_char(yytext[1]);
 382    return MASK1;
 383 }
 384
 385 "."[xyzw]{4}              {
 386    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(swiz_from_char(yytext[1]),
 387                                             swiz_from_char(yytext[2]),
 388                                             swiz_from_char(yytext[3]),
 389                                             swiz_from_char(yytext[4]));
 390    yylval->swiz_mask.mask = 0;
 391    return SWIZZLE;
 392 }
 393
 394 ".rgba"                   {
 395    yylval->swiz_mask.swizzle = SWIZZLE_NOOP;
 396    yylval->swiz_mask.mask = WRITEMASK_XYZW;
 397    return_token_or_DOT(require_ARB_fp, MASK4);
 398 }
 399
 400 ".rg"[ba]                 {
 401    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 402    yylval->swiz_mask.mask = WRITEMASK_XY
 403       | mask_from_char(yytext[3]);
 404    return_token_or_DOT(require_ARB_fp, MASK3);
 405 }
 406 ".rba"                    {
 407    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 408    yylval->swiz_mask.mask = WRITEMASK_XZW;
 409    return_token_or_DOT(require_ARB_fp, MASK3);
 410 }
 411 ".gba"                    {
 412    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 413    yylval->swiz_mask.mask = WRITEMASK_YZW;
 414    return_token_or_DOT(require_ARB_fp, MASK3);
 415 }
 416
 417 ".r"[gba]                 {
 418    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 419    yylval->swiz_mask.mask = WRITEMASK_X
 420       | mask_from_char(yytext[2]);
 421    return_token_or_DOT(require_ARB_fp, MASK2);
 422 }
 423 ".g"[ba]                  {
 424    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 425    yylval->swiz_mask.mask = WRITEMASK_Y
 426       | mask_from_char(yytext[2]);
 427    return_token_or_DOT(require_ARB_fp, MASK2);
 428 }
 429 ".ba"                     {
 430    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 431    yylval->swiz_mask.mask = WRITEMASK_ZW;
 432    return_token_or_DOT(require_ARB_fp, MASK2);
 433 }
 434
 435 "."[gba]                  {
 436    const unsigned s = swiz_from_char(yytext[1]);
 437    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(s, s, s, s);
 438    yylval->swiz_mask.mask = mask_from_char(yytext[1]);
 439    return_token_or_DOT(require_ARB_fp, MASK1);
 440 }
 441
 442
 443 ".r"                      {
 444    if (require_ARB_vp) {
 445       return TEXGEN_R;
 446    } else {
 447       yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(SWIZZLE_X, SWIZZLE_X,
 448                                                 SWIZZLE_X, SWIZZLE_X);
 449       yylval->swiz_mask.mask = WRITEMASK_X;
 450       return MASK1;
 451    }
 452 }
 453
 454 "."[rgba]{4}              {
 455    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(swiz_from_char(yytext[1]),
 456                                             swiz_from_char(yytext[2]),
 457                                             swiz_from_char(yytext[3]),
 458                                             swiz_from_char(yytext[4]));
 459    yylval->swiz_mask.mask = 0;
 460    return_token_or_DOT(require_ARB_fp, SWIZZLE);
 461 }
 462
 463 "."                       { return DOT; }
 464
 465 \n                        {
 466    yylloc->first_line++;
 467    yylloc->first_column = 1;
 468    yylloc->last_line++;
 469    yylloc->last_column = 1;
 470    yylloc->position++;
 471 }
 472 [ \t\r]+                  /* eat whitespace */ ;
 473 #.*$                      /* eat comments */ ;
 474 .                         { return yytext[0]; }
 475 %%
 476
 477 void
 478 _mesa_program_lexer_ctor(void **scanner, struct asm_parser_state *state,
 479                          const char *string, size_t len)
 480 {
 481    yylex_init_extra(state, scanner);
 482    yy_scan_bytes(string, len, *scanner);
 483 }
 484
 485 void
 486 _mesa_program_lexer_dtor(void *scanner)
 487 {
 488    yylex_destroy(scanner);
 489 }