src/mesa/shader/program_lexer.l

   1 %{
   2 /*
   3  * Copyright © 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include "main/glheader.h"
  25 #include "prog_instruction.h"
  26 #include "prog_statevars.h"
  27
  28 #include "symbol_table.h"
  29 #include "program_parser.h"
  30 #include "program_parse.tab.h"
  31
  32 #define require_ARB_vp (yyextra->mode == ARB_vertex)
  33 #define require_ARB_fp (yyextra->mode == ARB_fragment)
  34 #define require_NV_fp  (yyextra->option.NV_fragment)
  35 #define require_shadow (yyextra->option.Shadow)
  36 #define require_rect   (yyextra->option.TexRect)
  37 #define require_texarray        (yyextra->option.TexArray)
  38
  39 #ifndef HAVE_UNISTD_H
  40 #define YY_NO_UNISTD_H
  41 #endif
  42
  43 #define return_token_or_IDENTIFIER(condition, token)    \
  44    do {                                                 \
  45       if (condition) {                                  \
  46          return token;                                  \
  47       } else {                                          \
  48          return handle_ident(yyextra, yytext, yylval);  \
  49       }                                                 \
  50    } while (0)
  51
  52 #define return_token_or_DOT(condition, token)           \
  53    do {                                                 \
  54       if (condition) {                                  \
  55          return token;                                  \
  56       } else {                                          \
  57          yyless(1);                                     \
  58          return DOT;                                    \
  59       }                                                 \
  60    } while (0)
  61
  62
  63 #define return_opcode(condition, token, opcode, len)    \
  64    do {                                                 \
  65       if (condition &&                                  \
  66           _mesa_parse_instruction_suffix(yyextra,       \
  67                                          yytext + len,  \
  68                                          & yylval->temp_inst)) {        \
  69          yylval->temp_inst.Opcode = OPCODE_ ## opcode;  \
  70          return token;                                  \
  71       } else {                                          \
  72          return handle_ident(yyextra, yytext, yylval);  \
  73       }                                                 \
  74    } while (0)
  75
  76 #define SWIZZLE_INVAL  MAKE_SWIZZLE4(SWIZZLE_NIL, SWIZZLE_NIL, \
  77                                      SWIZZLE_NIL, SWIZZLE_NIL)
  78
  79 static unsigned
  80 mask_from_char(char c)
  81 {
  82    switch (c) {
  83    case 'x':
  84    case 'r':
  85       return WRITEMASK_X;
  86    case 'y':
  87    case 'g':
  88       return WRITEMASK_Y;
  89    case 'z':
  90    case 'b':
  91       return WRITEMASK_Z;
  92    case 'w':
  93    case 'a':
  94       return WRITEMASK_W;
  95    }
  96
  97    return 0;
  98 }
  99
 100 static unsigned
 101 swiz_from_char(char c)
 102 {
 103    switch (c) {
 104    case 'x':
 105    case 'r':
 106       return SWIZZLE_X;
 107    case 'y':
 108    case 'g':
 109       return SWIZZLE_Y;
 110    case 'z':
 111    case 'b':
 112       return SWIZZLE_Z;
 113    case 'w':
 114    case 'a':
 115       return SWIZZLE_W;
 116    }
 117
 118    return 0;
 119 }
 120
 121 static int
 122 handle_ident(struct asm_parser_state *state, const char *text, YYSTYPE *lval)
 123 {
 124    lval->string = strdup(text);
 125
 126    return (_mesa_symbol_table_find_symbol(state->st, 0, text) == NULL)
 127       ? IDENTIFIER : USED_IDENTIFIER;
 128 }
 129
 130 #define YY_USER_ACTION                                                  \
 131    do {                                                                 \
 132       yylloc->first_column = yylloc->last_column;                       \
 133       yylloc->last_column += yyleng;                                    \
 134       if ((yylloc->first_line == 1)                                     \
 135           && (yylloc->first_column == 1)) {                             \
 136          yylloc->position = 1;                                          \
 137       } else {                                                          \
 138          yylloc->position += yylloc->last_column - yylloc->first_column; \
 139       }                                                                 \
 140    } while(0);
 141
 142 #define YY_EXTRA_TYPE struct asm_parser_state *
 143 %}
 144
 145 num    [0-9]+
 146 exp    [Ee][-+]?[0-9]+
 147 frac   "."[0-9]+
 148 dot    "."[ \t]*
 149
 150 sz     [HRX]?
 151 szf    [HR]?
 152 cc     C?
 153 sat    (_SAT)?
 154
 155 %option bison-bridge bison-locations reentrant noyywrap
 156 %%
 157
 158 "!!ARBvp1.0"              { return ARBvp_10; }
 159 "!!ARBfp1.0"              { return ARBfp_10; }
 160 ADDRESS                   {
 161    yylval->integer = at_address;
 162    return_token_or_IDENTIFIER(require_ARB_vp, ADDRESS);
 163 }
 164 ALIAS                     { return ALIAS; }
 165 ATTRIB                    { return ATTRIB; }
 166 END                       { return END; }
 167 OPTION                    { return OPTION; }
 168 OUTPUT                    { return OUTPUT; }
 169 PARAM                     { return PARAM; }
 170 TEMP                      { yylval->integer = at_temp; return TEMP; }
 171
 172 ABS{sz}{cc}{sat}   { return_opcode(             1, VECTOR_OP, ABS, 3); }
 173 ADD{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, ADD, 3); }
 174 ARL                { return_opcode(require_ARB_vp, ARL, ARL, 3); }
 175
 176 CMP{sat}           { return_opcode(require_ARB_fp, TRI_OP, CMP, 3); }
 177 COS{szf}{cc}{sat}  { return_opcode(require_ARB_fp, SCALAR_OP, COS, 3); }
 178
 179 DDX{szf}{cc}{sat}  { return_opcode(require_NV_fp,  VECTOR_OP, DDX, 3); }
 180 DDY{szf}{cc}{sat}  { return_opcode(require_NV_fp,  VECTOR_OP, DDY, 3); }
 181 DP3{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, DP3, 3); }
 182 DP4{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, DP4, 3); }
 183 DPH{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, DPH, 3); }
 184 DST{szf}{cc}{sat}  { return_opcode(             1, BIN_OP, DST, 3); }
 185
 186 EX2{szf}{cc}{sat}  { return_opcode(             1, SCALAR_OP, EX2, 3); }
 187 EXP                { return_opcode(require_ARB_vp, SCALAR_OP, EXP, 3); }
 188
 189 FLR{sz}{cc}{sat}   { return_opcode(             1, VECTOR_OP, FLR, 3); }
 190 FRC{sz}{cc}{sat}   { return_opcode(             1, VECTOR_OP, FRC, 3); }
 191
 192 KIL                { return_opcode(require_ARB_fp, KIL, KIL, 3); }
 193
 194 LIT{szf}{cc}{sat}  { return_opcode(             1, VECTOR_OP, LIT, 3); }
 195 LG2{szf}{cc}{sat}  { return_opcode(             1, SCALAR_OP, LG2, 3); }
 196 LOG                { return_opcode(require_ARB_vp, SCALAR_OP, LOG, 3); }
 197 LRP{sz}{cc}{sat}   { return_opcode(require_ARB_fp, TRI_OP, LRP, 3); }
 198
 199 MAD{sz}{cc}{sat}   { return_opcode(             1, TRI_OP, MAD, 3); }
 200 MAX{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, MAX, 3); }
 201 MIN{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, MIN, 3); }
 202 MOV{sz}{cc}{sat}   { return_opcode(             1, VECTOR_OP, MOV, 3); }
 203 MUL{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, MUL, 3); }
 204
 205 PK2H               { return_opcode(require_NV_fp,  VECTOR_OP, PK2H, 4); }
 206 PK2US              { return_opcode(require_NV_fp,  VECTOR_OP, PK2US, 5); }
 207 PK4B               { return_opcode(require_NV_fp,  VECTOR_OP, PK4B, 4); }
 208 PK4UB              { return_opcode(require_NV_fp,  VECTOR_OP, PK4UB, 5); }
 209 POW{szf}{cc}{sat}  { return_opcode(             1, BINSC_OP, POW, 3); }
 210
 211 RCP{szf}{cc}{sat}  { return_opcode(             1, SCALAR_OP, RCP, 3); }
 212 RFL{szf}{cc}{sat}  { return_opcode(require_NV_fp,  BIN_OP,    RFL, 3); }
 213 RSQ{szf}{cc}{sat}  { return_opcode(             1, SCALAR_OP, RSQ, 3); }
 214
 215 SCS{sat}           { return_opcode(require_ARB_fp, SCALAR_OP, SCS, 3); }
 216 SEQ{sz}{cc}{sat}   { return_opcode(require_NV_fp,  BIN_OP, SEQ, 3); }
 217 SFL{sz}{cc}{sat}   { return_opcode(require_NV_fp,  BIN_OP, SFL, 3); }
 218 SGE{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, SGE, 3); }
 219 SGT{sz}{cc}{sat}   { return_opcode(require_NV_fp,  BIN_OP, SGT, 3); }
 220 SIN{szf}{cc}{sat}  { return_opcode(require_ARB_fp, SCALAR_OP, SIN, 3); }
 221 SLE{sz}{cc}{sat}   { return_opcode(require_NV_fp,  BIN_OP, SLE, 3); }
 222 SLT{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, SLT, 3); }
 223 SNE{sz}{cc}{sat}   { return_opcode(require_NV_fp,  BIN_OP, SNE, 3); }
 224 STR{sz}{cc}{sat}   { return_opcode(require_NV_fp,  BIN_OP, STR, 3); }
 225 SUB{sz}{cc}{sat}   { return_opcode(             1, BIN_OP, SUB, 3); }
 226 SWZ{sat}           { return_opcode(             1, SWZ, SWZ, 3); }
 227
 228 TEX{cc}{sat}       { return_opcode(require_ARB_fp, SAMPLE_OP, TEX, 3); }
 229 TXB{cc}{sat}       { return_opcode(require_ARB_fp, SAMPLE_OP, TXB, 3); }
 230 TXD{cc}{sat}       { return_opcode(require_NV_fp,  TXD_OP, TXD, 3); }
 231 TXP{cc}{sat}       { return_opcode(require_ARB_fp, SAMPLE_OP, TXP, 3); }
 232
 233 UP2H{cc}{sat}      { return_opcode(require_NV_fp,  SCALAR_OP, UP2H, 4); }
 234 UP2US{cc}{sat}     { return_opcode(require_NV_fp,  SCALAR_OP, UP2US, 5); }
 235 UP4B{cc}{sat}      { return_opcode(require_NV_fp,  SCALAR_OP, UP4B, 4); }
 236 UP4UB{cc}{sat}     { return_opcode(require_NV_fp,  SCALAR_OP, UP4UB, 5); }
 237
 238 X2D{szf}{cc}{sat}  { return_opcode(require_NV_fp,  TRI_OP, X2D, 3); }
 239 XPD{sat}           { return_opcode(             1, BIN_OP, XPD, 3); }
 240
 241 vertex                    { return_token_or_IDENTIFIER(require_ARB_vp, VERTEX); }
 242 fragment                  { return_token_or_IDENTIFIER(require_ARB_fp, FRAGMENT); }
 243 program                   { return PROGRAM; }
 244 state                     { return STATE; }
 245 result                    { return RESULT; }
 246
 247 {dot}ambient              { return AMBIENT; }
 248 {dot}attenuation          { return ATTENUATION; }
 249 {dot}back                 { return BACK; }
 250 {dot}clip                 { return_token_or_DOT(require_ARB_vp, CLIP); }
 251 {dot}color                { return COLOR; }
 252 {dot}depth                { return_token_or_DOT(require_ARB_fp, DEPTH); }
 253 {dot}diffuse              { return DIFFUSE; }
 254 {dot}direction            { return DIRECTION; }
 255 {dot}emission             { return EMISSION; }
 256 {dot}env                  { return ENV; }
 257 {dot}eye                  { return EYE; }
 258 {dot}fogcoord             { return FOGCOORD; }
 259 {dot}fog                  { return FOG; }
 260 {dot}front                { return FRONT; }
 261 {dot}half                 { return HALF; }
 262 {dot}inverse              { return INVERSE; }
 263 {dot}invtrans             { return INVTRANS; }
 264 {dot}light                { return LIGHT; }
 265 {dot}lightmodel           { return LIGHTMODEL; }
 266 {dot}lightprod            { return LIGHTPROD; }
 267 {dot}local                { return LOCAL; }
 268 {dot}material             { return MATERIAL; }
 269 {dot}program              { return MAT_PROGRAM; }
 270 {dot}matrix               { return MATRIX; }
 271 {dot}matrixindex          { return_token_or_DOT(require_ARB_vp, MATRIXINDEX); }
 272 {dot}modelview            { return MODELVIEW; }
 273 {dot}mvp                  { return MVP; }
 274 {dot}normal               { return_token_or_DOT(require_ARB_vp, NORMAL); }
 275 {dot}object               { return OBJECT; }
 276 {dot}palette              { return PALETTE; }
 277 {dot}params               { return PARAMS; }
 278 {dot}plane                { return PLANE; }
 279 {dot}point                { return_token_or_DOT(require_ARB_vp, POINT_TOK); }
 280 {dot}pointsize            { return_token_or_DOT(require_ARB_vp, POINTSIZE); }
 281 {dot}position             { return POSITION; }
 282 {dot}primary              { return PRIMARY; }
 283 {dot}projection           { return PROJECTION; }
 284 {dot}range                { return_token_or_DOT(require_ARB_fp, RANGE); }
 285 {dot}row                  { return ROW; }
 286 {dot}scenecolor           { return SCENECOLOR; }
 287 {dot}secondary            { return SECONDARY; }
 288 {dot}shininess            { return SHININESS; }
 289 {dot}size                 { return_token_or_DOT(require_ARB_vp, SIZE_TOK); }
 290 {dot}specular             { return SPECULAR; }
 291 {dot}spot                 { return SPOT; }
 292 {dot}texcoord             { return TEXCOORD; }
 293 {dot}texenv               { return_token_or_DOT(require_ARB_fp, TEXENV); }
 294 {dot}texgen               { return_token_or_DOT(require_ARB_vp, TEXGEN); }
 295 {dot}q                    { return_token_or_DOT(require_ARB_vp, TEXGEN_Q); }
 296 {dot}s                    { return_token_or_DOT(require_ARB_vp, TEXGEN_S); }
 297 {dot}t                    { return_token_or_DOT(require_ARB_vp, TEXGEN_T); }
 298 {dot}texture              { return TEXTURE; }
 299 {dot}transpose            { return TRANSPOSE; }
 300 {dot}attrib               { return_token_or_DOT(require_ARB_vp, VTXATTRIB); }
 301 {dot}weight               { return_token_or_DOT(require_ARB_vp, WEIGHT); }
 302
 303 texture                   { return_token_or_IDENTIFIER(require_ARB_fp, TEXTURE_UNIT); }
 304 1D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_1D); }
 305 2D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_2D); }
 306 3D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_3D); }
 307 CUBE                      { return_token_or_IDENTIFIER(require_ARB_fp, TEX_CUBE); }
 308 RECT                      { return_token_or_IDENTIFIER(require_ARB_fp && require_rect, TEX_RECT); }
 309 SHADOW1D                  { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow, TEX_SHADOW1D); }
 310 SHADOW2D                  { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow, TEX_SHADOW2D); }
 311 SHADOWRECT                { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_rect, TEX_SHADOWRECT); }
 312 ARRAY1D                   { return_token_or_IDENTIFIER(require_ARB_fp && require_texarray, TEX_ARRAY1D); }
 313 ARRAY2D                   { return_token_or_IDENTIFIER(require_ARB_fp && require_texarray, TEX_ARRAY2D); }
 314 ARRAYSHADOW1D             { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_texarray, TEX_ARRAYSHADOW1D); }
 315 ARRAYSHADOW2D             { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_texarray, TEX_ARRAYSHADOW2D); }
 316
 317 [_a-zA-Z$][_a-zA-Z0-9$]*  { return handle_ident(yyextra, yytext, yylval); }
 318
 319 ".."                      { return DOT_DOT; }
 320
 321 {num}                     {
 322    yylval->integer = strtol(yytext, NULL, 10);
 323    return INTEGER;
 324 }
 325 {num}?{frac}{exp}?        {
 326    yylval->real = strtod(yytext, NULL);
 327    return REAL;
 328 }
 329 {num}"."/[^.]             {
 330    yylval->real = strtod(yytext, NULL);
 331    return REAL;
 332 }
 333 {num}{exp}                {
 334    yylval->real = strtod(yytext, NULL);
 335    return REAL;
 336 }
 337 {num}"."{exp}             {
 338    yylval->real = strtod(yytext, NULL);
 339    return REAL;
 340 }
 341
 342 ".xyzw"                   {
 343    yylval->swiz_mask.swizzle = SWIZZLE_NOOP;
 344    yylval->swiz_mask.mask = WRITEMASK_XYZW;
 345    return MASK4;
 346 }
 347
 348 ".xy"[zw]                 {
 349    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 350    yylval->swiz_mask.mask = WRITEMASK_XY
 351       | mask_from_char(yytext[3]);
 352    return MASK3;
 353 }
 354 ".xzw"                    {
 355    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 356    yylval->swiz_mask.mask = WRITEMASK_XZW;
 357    return MASK3;
 358 }
 359 ".yzw"                    {
 360    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 361    yylval->swiz_mask.mask = WRITEMASK_YZW;
 362    return MASK3;
 363 }
 364
 365 ".x"[yzw]                 {
 366    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 367    yylval->swiz_mask.mask = WRITEMASK_X
 368       | mask_from_char(yytext[2]);
 369    return MASK2;
 370 }
 371 ".y"[zw]                  {
 372    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 373    yylval->swiz_mask.mask = WRITEMASK_Y
 374       | mask_from_char(yytext[2]);
 375    return MASK2;
 376 }
 377 ".zw"                     {
 378    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 379    yylval->swiz_mask.mask = WRITEMASK_ZW;
 380    return MASK2;
 381 }
 382
 383 "."[xyzw]                 {
 384    const unsigned s = swiz_from_char(yytext[1]);
 385    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(s, s, s, s);
 386    yylval->swiz_mask.mask = mask_from_char(yytext[1]);
 387    return MASK1;
 388 }
 389
 390 "."[xyzw]{4}              {
 391    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(swiz_from_char(yytext[1]),
 392                                             swiz_from_char(yytext[2]),
 393                                             swiz_from_char(yytext[3]),
 394                                             swiz_from_char(yytext[4]));
 395    yylval->swiz_mask.mask = 0;
 396    return SWIZZLE;
 397 }
 398
 399 ".rgba"                   {
 400    yylval->swiz_mask.swizzle = SWIZZLE_NOOP;
 401    yylval->swiz_mask.mask = WRITEMASK_XYZW;
 402    return_token_or_DOT(require_ARB_fp, MASK4);
 403 }
 404
 405 ".rg"[ba]                 {
 406    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 407    yylval->swiz_mask.mask = WRITEMASK_XY
 408       | mask_from_char(yytext[3]);
 409    return_token_or_DOT(require_ARB_fp, MASK3);
 410 }
 411 ".rba"                    {
 412    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 413    yylval->swiz_mask.mask = WRITEMASK_XZW;
 414    return_token_or_DOT(require_ARB_fp, MASK3);
 415 }
 416 ".gba"                    {
 417    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 418    yylval->swiz_mask.mask = WRITEMASK_YZW;
 419    return_token_or_DOT(require_ARB_fp, MASK3);
 420 }
 421
 422 ".r"[gba]                 {
 423    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 424    yylval->swiz_mask.mask = WRITEMASK_X
 425       | mask_from_char(yytext[2]);
 426    return_token_or_DOT(require_ARB_fp, MASK2);
 427 }
 428 ".g"[ba]                  {
 429    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 430    yylval->swiz_mask.mask = WRITEMASK_Y
 431       | mask_from_char(yytext[2]);
 432    return_token_or_DOT(require_ARB_fp, MASK2);
 433 }
 434 ".ba"                     {
 435    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 436    yylval->swiz_mask.mask = WRITEMASK_ZW;
 437    return_token_or_DOT(require_ARB_fp, MASK2);
 438 }
 439
 440 "."[gba]                  {
 441    const unsigned s = swiz_from_char(yytext[1]);
 442    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(s, s, s, s);
 443    yylval->swiz_mask.mask = mask_from_char(yytext[1]);
 444    return_token_or_DOT(require_ARB_fp, MASK1);
 445 }
 446
 447
 448 ".r"                      {
 449    if (require_ARB_vp) {
 450       return TEXGEN_R;
 451    } else {
 452       yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(SWIZZLE_X, SWIZZLE_X,
 453                                                 SWIZZLE_X, SWIZZLE_X);
 454       yylval->swiz_mask.mask = WRITEMASK_X;
 455       return MASK1;
 456    }
 457 }
 458
 459 "."[rgba]{4}              {
 460    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(swiz_from_char(yytext[1]),
 461                                             swiz_from_char(yytext[2]),
 462                                             swiz_from_char(yytext[3]),
 463                                             swiz_from_char(yytext[4]));
 464    yylval->swiz_mask.mask = 0;
 465    return_token_or_DOT(require_ARB_fp, SWIZZLE);
 466 }
 467
 468 "."                       { return DOT; }
 469
 470 \n                        {
 471    yylloc->first_line++;
 472    yylloc->first_column = 1;
 473    yylloc->last_line++;
 474    yylloc->last_column = 1;
 475    yylloc->position++;
 476 }
 477 [ \t\r]+                  /* eat whitespace */ ;
 478 #.*$                      /* eat comments */ ;
 479 .                         { return yytext[0]; }
 480 %%
 481
 482 void
 483 _mesa_program_lexer_ctor(void **scanner, struct asm_parser_state *state,
 484                          const char *string, size_t len)
 485 {
 486    yylex_init_extra(state, scanner);
 487    yy_scan_bytes(string, len, *scanner);
 488 }
 489
 490 void
 491 _mesa_program_lexer_dtor(void *scanner)
 492 {
 493    yylex_destroy(scanner);
 494 }