src/mesa/shader/program_lexer.l

   1 %{
   2 /*
   3  * Copyright © 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include "main/glheader.h"
  25 #include "prog_instruction.h"
  26
  27 #include "program_parser.h"
  28 #include "program_parse.tab.h"
  29
  30 #define require_ARB_vp (yyextra->mode == ARB_vertex)
  31 #define require_ARB_fp (yyextra->mode == ARB_fragment)
  32 #define require_shadow (yyextra->option.Shadow)
  33 #define require_rect   (yyextra->option.TexRect)
  34 #define require_texarray        (yyextra->option.TexArray)
  35
  36 #define return_token_or_IDENTIFIER(condition, token)    \
  37    do {                                                 \
  38       if (condition) {                                  \
  39          return token;                                  \
  40       } else {                                          \
  41          yylval->string = strdup(yytext);               \
  42          return IDENTIFIER;                             \
  43       }                                                 \
  44    } while (0)
  45
  46 #define return_token_or_DOT(condition, token)           \
  47    do {                                                 \
  48       if (condition) {                                  \
  49          return token;                                  \
  50       } else {                                          \
  51          yyless(1);                                     \
  52          return DOT;                                    \
  53       }                                                 \
  54    } while (0)
  55
  56
  57 #define return_opcode(condition, token, opcode, sat)    \
  58    do {                                                 \
  59       if (condition) {                                  \
  60          yylval->temp_inst.Opcode = OPCODE_ ## opcode;  \
  61          yylval->temp_inst.SaturateMode = SATURATE_ ## sat; \
  62          return token;                                  \
  63       } else {                                          \
  64          yylval->string = strdup(yytext);               \
  65          return IDENTIFIER;                             \
  66       }                                                 \
  67    } while (0)
  68
  69 #define SWIZZLE_INVAL  MAKE_SWIZZLE4(SWIZZLE_NIL, SWIZZLE_NIL, \
  70                                      SWIZZLE_NIL, SWIZZLE_NIL)
  71
  72 static unsigned
  73 mask_from_char(char c)
  74 {
  75    switch (c) {
  76    case 'x':
  77    case 'r':
  78       return WRITEMASK_X;
  79    case 'y':
  80    case 'g':
  81       return WRITEMASK_Y;
  82    case 'z':
  83    case 'b':
  84       return WRITEMASK_Z;
  85    case 'w':
  86    case 'a':
  87       return WRITEMASK_W;
  88    }
  89
  90    return 0;
  91 }
  92
  93 static unsigned
  94 swiz_from_char(char c)
  95 {
  96    switch (c) {
  97    case 'x':
  98    case 'r':
  99       return SWIZZLE_X;
 100    case 'y':
 101    case 'g':
 102       return SWIZZLE_Y;
 103    case 'z':
 104    case 'b':
 105       return SWIZZLE_Z;
 106    case 'w':
 107    case 'a':
 108       return SWIZZLE_W;
 109    }
 110
 111    return 0;
 112 }
 113
 114 #define YY_USER_ACTION                                                  \
 115    do {                                                                 \
 116       yylloc->first_column = yylloc->last_column;                       \
 117       yylloc->last_column += yyleng;                                    \
 118       if ((yylloc->first_line == 1)                                     \
 119           && (yylloc->first_column == 1)) {                             \
 120          yylloc->position = 1;                                          \
 121       } else {                                                          \
 122          yylloc->position += yylloc->last_column - yylloc->first_column; \
 123       }                                                                 \
 124    } while(0);
 125
 126 #define YY_EXTRA_TYPE struct asm_parser_state *
 127 %}
 128
 129 num    [0-9]+
 130 exp    [Ee][-+]?[0-9]+
 131 frac   "."[0-9]+
 132 dot    "."[ \t]*
 133
 134 %option bison-bridge bison-locations reentrant noyywrap
 135 %%
 136
 137 "!!ARBvp1.0"              { return ARBvp_10; }
 138 "!!ARBfp1.0"              { return ARBfp_10; }
 139 ADDRESS                   {
 140    yylval->integer = at_address;
 141    return_token_or_IDENTIFIER(require_ARB_vp, ADDRESS);
 142 }
 143 ALIAS                     { return ALIAS; }
 144 ATTRIB                    { return ATTRIB; }
 145 END                       { return END; }
 146 OPTION                    { return OPTION; }
 147 OUTPUT                    { return OUTPUT; }
 148 PARAM                     { return PARAM; }
 149 TEMP                      { yylval->integer = at_temp; return TEMP; }
 150
 151 ABS       { return_opcode(             1, VECTOR_OP, ABS, OFF); }
 152 ABS_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, ABS, ZERO_ONE); }
 153 ADD       { return_opcode(             1, BIN_OP, ADD, OFF); }
 154 ADD_SAT   { return_opcode(require_ARB_fp, BIN_OP, ADD, ZERO_ONE); }
 155 ARL       { return_opcode(require_ARB_vp, ARL, ARL, OFF); }
 156
 157 CMP       { return_opcode(require_ARB_fp, TRI_OP, CMP, OFF); }
 158 CMP_SAT   { return_opcode(require_ARB_fp, TRI_OP, CMP, ZERO_ONE); }
 159 COS       { return_opcode(require_ARB_fp, SCALAR_OP, COS, OFF); }
 160 COS_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, COS, ZERO_ONE); }
 161
 162 DP3       { return_opcode(             1, BIN_OP, DP3, OFF); }
 163 DP3_SAT   { return_opcode(require_ARB_fp, BIN_OP, DP3, ZERO_ONE); }
 164 DP4       { return_opcode(             1, BIN_OP, DP4, OFF); }
 165 DP4_SAT   { return_opcode(require_ARB_fp, BIN_OP, DP4, ZERO_ONE); }
 166 DPH       { return_opcode(             1, BIN_OP, DPH, OFF); }
 167 DPH_SAT   { return_opcode(require_ARB_fp, BIN_OP, DPH, ZERO_ONE); }
 168 DST       { return_opcode(             1, BIN_OP, DST, OFF); }
 169 DST_SAT   { return_opcode(require_ARB_fp, BIN_OP, DST, ZERO_ONE); }
 170
 171 EX2       { return_opcode(             1, SCALAR_OP, EX2, OFF); }
 172 EX2_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, EX2, ZERO_ONE); }
 173 EXP       { return_opcode(require_ARB_vp, SCALAR_OP, EXP, OFF); }
 174
 175 FLR       { return_opcode(             1, VECTOR_OP, FLR, OFF); }
 176 FLR_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, FLR, ZERO_ONE); }
 177 FRC       { return_opcode(             1, VECTOR_OP, FRC, OFF); }
 178 FRC_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, FRC, ZERO_ONE); }
 179
 180 KIL       { return_opcode(require_ARB_fp, KIL, KIL, OFF); }
 181
 182 LIT       { return_opcode(             1, VECTOR_OP, LIT, OFF); }
 183 LIT_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, LIT, ZERO_ONE); }
 184 LG2       { return_opcode(             1, SCALAR_OP, LG2, OFF); }
 185 LG2_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, LG2, ZERO_ONE); }
 186 LOG       { return_opcode(require_ARB_vp, SCALAR_OP, LOG, OFF); }
 187 LRP       { return_opcode(require_ARB_fp, TRI_OP, LRP, OFF); }
 188 LRP_SAT   { return_opcode(require_ARB_fp, TRI_OP, LRP, ZERO_ONE); }
 189
 190 MAD       { return_opcode(             1, TRI_OP, MAD, OFF); }
 191 MAD_SAT   { return_opcode(require_ARB_fp, TRI_OP, MAD, ZERO_ONE); }
 192 MAX       { return_opcode(             1, BIN_OP, MAX, OFF); }
 193 MAX_SAT   { return_opcode(require_ARB_fp, BIN_OP, MAX, ZERO_ONE); }
 194 MIN       { return_opcode(             1, BIN_OP, MIN, OFF); }
 195 MIN_SAT   { return_opcode(require_ARB_fp, BIN_OP, MIN, ZERO_ONE); }
 196 MOV       { return_opcode(             1, VECTOR_OP, MOV, OFF); }
 197 MOV_SAT   { return_opcode(require_ARB_fp, VECTOR_OP, MOV, ZERO_ONE); }
 198 MUL       { return_opcode(             1, BIN_OP, MUL, OFF); }
 199 MUL_SAT   { return_opcode(require_ARB_fp, BIN_OP, MUL, ZERO_ONE); }
 200
 201 POW       { return_opcode(             1, BINSC_OP, POW, OFF); }
 202 POW_SAT   { return_opcode(require_ARB_fp, BINSC_OP, POW, ZERO_ONE); }
 203
 204 RCP       { return_opcode(             1, SCALAR_OP, RCP, OFF); }
 205 RCP_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, RCP, ZERO_ONE); }
 206 RSQ       { return_opcode(             1, SCALAR_OP, RSQ, OFF); }
 207 RSQ_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, RSQ, ZERO_ONE); }
 208
 209 SCS       { return_opcode(require_ARB_fp, SCALAR_OP, SCS, OFF); }
 210 SCS_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, SCS, ZERO_ONE); }
 211 SGE       { return_opcode(             1, BIN_OP, SGE, OFF); }
 212 SGE_SAT   { return_opcode(require_ARB_fp, BIN_OP, SGE, ZERO_ONE); }
 213 SIN       { return_opcode(require_ARB_fp, SCALAR_OP, SIN, OFF); }
 214 SIN_SAT   { return_opcode(require_ARB_fp, SCALAR_OP, SIN, ZERO_ONE); }
 215 SLT       { return_opcode(             1, BIN_OP, SLT, OFF); }
 216 SLT_SAT   { return_opcode(require_ARB_fp, BIN_OP, SLT, ZERO_ONE); }
 217 SUB       { return_opcode(             1, BIN_OP, SUB, OFF); }
 218 SUB_SAT   { return_opcode(require_ARB_fp, BIN_OP, SUB, ZERO_ONE); }
 219 SWZ       { return_opcode(             1, SWZ, SWZ, OFF); }
 220 SWZ_SAT   { return_opcode(require_ARB_fp, SWZ, SWZ, ZERO_ONE); }
 221
 222 TEX       { return_opcode(require_ARB_fp, SAMPLE_OP, TEX, OFF); }
 223 TEX_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TEX, ZERO_ONE); }
 224 TXB       { return_opcode(require_ARB_fp, SAMPLE_OP, TXB, OFF); }
 225 TXB_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TXB, ZERO_ONE); }
 226 TXP       { return_opcode(require_ARB_fp, SAMPLE_OP, TXP, OFF); }
 227 TXP_SAT   { return_opcode(require_ARB_fp, SAMPLE_OP, TXP, ZERO_ONE); }
 228
 229 XPD       { return_opcode(             1, BIN_OP, XPD, OFF); }
 230 XPD_SAT   { return_opcode(require_ARB_fp, BIN_OP, XPD, ZERO_ONE); }
 231
 232 vertex                    { return_token_or_IDENTIFIER(require_ARB_vp, VERTEX); }
 233 fragment                  { return_token_or_IDENTIFIER(require_ARB_fp, FRAGMENT); }
 234 program                   { return PROGRAM; }
 235 state                     { return STATE; }
 236 result                    { return RESULT; }
 237
 238 {dot}ambient              { return AMBIENT; }
 239 {dot}attenuation          { return ATTENUATION; }
 240 {dot}back                 { return BACK; }
 241 {dot}clip                 { return_token_or_DOT(require_ARB_vp, CLIP); }
 242 {dot}color                { return COLOR; }
 243 {dot}depth                { return_token_or_DOT(require_ARB_fp, DEPTH); }
 244 {dot}diffuse              { return DIFFUSE; }
 245 {dot}direction            { return DIRECTION; }
 246 {dot}emission             { return EMISSION; }
 247 {dot}env                  { return ENV; }
 248 {dot}eye                  { return EYE; }
 249 {dot}fogcoord             { return FOGCOORD; }
 250 {dot}fog                  { return FOG; }
 251 {dot}front                { return FRONT; }
 252 {dot}half                 { return HALF; }
 253 {dot}inverse              { return INVERSE; }
 254 {dot}invtrans             { return INVTRANS; }
 255 {dot}light                { return LIGHT; }
 256 {dot}lightmodel           { return LIGHTMODEL; }
 257 {dot}lightprod            { return LIGHTPROD; }
 258 {dot}local                { return LOCAL; }
 259 {dot}material             { return MATERIAL; }
 260 {dot}program              { return MAT_PROGRAM; }
 261 {dot}matrix               { return MATRIX; }
 262 {dot}matrixindex          { return_token_or_DOT(require_ARB_vp, MATRIXINDEX); }
 263 {dot}modelview            { return MODELVIEW; }
 264 {dot}mvp                  { return MVP; }
 265 {dot}normal               { return_token_or_DOT(require_ARB_vp, NORMAL); }
 266 {dot}object               { return OBJECT; }
 267 {dot}palette              { return PALETTE; }
 268 {dot}params               { return PARAMS; }
 269 {dot}plane                { return PLANE; }
 270 {dot}point                { return_token_or_DOT(require_ARB_vp, POINT); }
 271 {dot}pointsize            { return_token_or_DOT(require_ARB_vp, POINTSIZE); }
 272 {dot}position             { return POSITION; }
 273 {dot}primary              { return PRIMARY; }
 274 {dot}projection           { return PROJECTION; }
 275 {dot}range                { return_token_or_DOT(require_ARB_fp, RANGE); }
 276 {dot}row                  { return ROW; }
 277 {dot}scenecolor           { return SCENECOLOR; }
 278 {dot}secondary            { return SECONDARY; }
 279 {dot}shininess            { return SHININESS; }
 280 {dot}size                 { return_token_or_DOT(require_ARB_vp, SIZE); }
 281 {dot}specular             { return SPECULAR; }
 282 {dot}spot                 { return SPOT; }
 283 {dot}texcoord             { return TEXCOORD; }
 284 {dot}texenv               { return_token_or_DOT(require_ARB_fp, TEXENV); }
 285 {dot}texgen               { return_token_or_DOT(require_ARB_vp, TEXGEN); }
 286 {dot}q                    { return_token_or_DOT(require_ARB_vp, TEXGEN_Q); }
 287 {dot}s                    { return_token_or_DOT(require_ARB_vp, TEXGEN_S); }
 288 {dot}t                    { return_token_or_DOT(require_ARB_vp, TEXGEN_T); }
 289 {dot}texture              { return TEXTURE; }
 290 {dot}transpose            { return TRANSPOSE; }
 291 {dot}attrib               { return_token_or_DOT(require_ARB_vp, VTXATTRIB); }
 292 {dot}weight               { return_token_or_DOT(require_ARB_vp, WEIGHT); }
 293
 294 texture                   { return_token_or_IDENTIFIER(require_ARB_fp, TEXTURE_UNIT); }
 295 1D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_1D); }
 296 2D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_2D); }
 297 3D                        { return_token_or_IDENTIFIER(require_ARB_fp, TEX_3D); }
 298 CUBE                      { return_token_or_IDENTIFIER(require_ARB_fp, TEX_CUBE); }
 299 RECT                      { return_token_or_IDENTIFIER(require_ARB_fp && require_rect, TEX_RECT); }
 300 SHADOW1D                  { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow, TEX_SHADOW1D); }
 301 SHADOW2D                  { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow, TEX_SHADOW2D); }
 302 SHADOWRECT                { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_rect, TEX_SHADOWRECT); }
 303 ARRAY1D                   { return_token_or_IDENTIFIER(require_ARB_fp && require_texarray, TEX_ARRAY1D); }
 304 ARRAY2D                   { return_token_or_IDENTIFIER(require_ARB_fp && require_texarray, TEX_ARRAY2D); }
 305 ARRAYSHADOW1D             { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_texarray, TEX_ARRAYSHADOW1D); }
 306 ARRAYSHADOW2D             { return_token_or_IDENTIFIER(require_ARB_fp && require_shadow && require_texarray, TEX_ARRAYSHADOW2D); }
 307
 308 [_a-zA-Z$][_a-zA-Z0-9$]*  {
 309    yylval->string = strdup(yytext);
 310    return IDENTIFIER;
 311 }
 312
 313 ".."                      { return DOT_DOT; }
 314
 315 {num}                     {
 316    yylval->integer = strtol(yytext, NULL, 10);
 317    return INTEGER;
 318 }
 319 {num}?{frac}{exp}?        {
 320    yylval->real = strtod(yytext, NULL);
 321    return REAL;
 322 }
 323 {num}"."/[^.]             {
 324    yylval->real = strtod(yytext, NULL);
 325    return REAL;
 326 }
 327 {num}{exp}                {
 328    yylval->real = strtod(yytext, NULL);
 329    return REAL;
 330 }
 331 {num}"."{exp}             {
 332    yylval->real = strtod(yytext, NULL);
 333    return REAL;
 334 }
 335
 336 ".xyzw"                   {
 337    yylval->swiz_mask.swizzle = SWIZZLE_NOOP;
 338    yylval->swiz_mask.mask = WRITEMASK_XYZW;
 339    return MASK4;
 340 }
 341
 342 ".xy"[zw]                 {
 343    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 344    yylval->swiz_mask.mask = WRITEMASK_XY
 345       | mask_from_char(yytext[3]);
 346    return MASK3;
 347 }
 348 ".xzw"                    {
 349    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 350    yylval->swiz_mask.mask = WRITEMASK_XZW;
 351    return MASK3;
 352 }
 353 ".yzw"                    {
 354    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 355    yylval->swiz_mask.mask = WRITEMASK_YZW;
 356    return MASK3;
 357 }
 358
 359 ".x"[yzw]                 {
 360    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 361    yylval->swiz_mask.mask = WRITEMASK_X
 362       | mask_from_char(yytext[2]);
 363    return MASK2;
 364 }
 365 ".y"[zw]                  {
 366    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 367    yylval->swiz_mask.mask = WRITEMASK_Y
 368       | mask_from_char(yytext[2]);
 369    return MASK2;
 370 }
 371 ".zw"                     {
 372    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 373    yylval->swiz_mask.mask = WRITEMASK_ZW;
 374    return MASK2;
 375 }
 376
 377 "."[xyzw]                 {
 378    const unsigned s = swiz_from_char(yytext[1]);
 379    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(s, s, s, s);
 380    yylval->swiz_mask.mask = mask_from_char(yytext[1]);
 381    return MASK1;
 382 }
 383
 384 "."[xyzw]{4}              {
 385    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(swiz_from_char(yytext[1]),
 386                                             swiz_from_char(yytext[2]),
 387                                             swiz_from_char(yytext[3]),
 388                                             swiz_from_char(yytext[4]));
 389    yylval->swiz_mask.mask = 0;
 390    return SWIZZLE;
 391 }
 392
 393 ".rgba"                   {
 394    yylval->swiz_mask.swizzle = SWIZZLE_NOOP;
 395    yylval->swiz_mask.mask = WRITEMASK_XYZW;
 396    return_token_or_DOT(require_ARB_fp, MASK4);
 397 }
 398
 399 ".rg"[ba]                 {
 400    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 401    yylval->swiz_mask.mask = WRITEMASK_XY
 402       | mask_from_char(yytext[3]);
 403    return_token_or_DOT(require_ARB_fp, MASK3);
 404 }
 405 ".rba"                    {
 406    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 407    yylval->swiz_mask.mask = WRITEMASK_XZW;
 408    return_token_or_DOT(require_ARB_fp, MASK3);
 409 }
 410 ".gba"                    {
 411    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 412    yylval->swiz_mask.mask = WRITEMASK_YZW;
 413    return_token_or_DOT(require_ARB_fp, MASK3);
 414 }
 415
 416 ".r"[gba]                 {
 417    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 418    yylval->swiz_mask.mask = WRITEMASK_X
 419       | mask_from_char(yytext[2]);
 420    return_token_or_DOT(require_ARB_fp, MASK2);
 421 }
 422 ".g"[ba]                  {
 423    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 424    yylval->swiz_mask.mask = WRITEMASK_Y
 425       | mask_from_char(yytext[2]);
 426    return_token_or_DOT(require_ARB_fp, MASK2);
 427 }
 428 ".ba"                     {
 429    yylval->swiz_mask.swizzle = SWIZZLE_INVAL;
 430    yylval->swiz_mask.mask = WRITEMASK_ZW;
 431    return_token_or_DOT(require_ARB_fp, MASK2);
 432 }
 433
 434 "."[gba]                  {
 435    const unsigned s = swiz_from_char(yytext[1]);
 436    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(s, s, s, s);
 437    yylval->swiz_mask.mask = mask_from_char(yytext[1]);
 438    return_token_or_DOT(require_ARB_fp, MASK1);
 439 }
 440
 441
 442 ".r"                      {
 443    if (require_ARB_vp) {
 444       return TEXGEN_R;
 445    } else {
 446       yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(SWIZZLE_X, SWIZZLE_X,
 447                                                 SWIZZLE_X, SWIZZLE_X);
 448       yylval->swiz_mask.mask = WRITEMASK_X;
 449       return MASK1;
 450    }
 451 }
 452
 453 "."[rgba]{4}              {
 454    yylval->swiz_mask.swizzle = MAKE_SWIZZLE4(swiz_from_char(yytext[1]),
 455                                             swiz_from_char(yytext[2]),
 456                                             swiz_from_char(yytext[3]),
 457                                             swiz_from_char(yytext[4]));
 458    yylval->swiz_mask.mask = 0;
 459    return_token_or_DOT(require_ARB_fp, SWIZZLE);
 460 }
 461
 462 "."                       { return DOT; }
 463
 464 \n                        {
 465    yylloc->first_line++;
 466    yylloc->first_column = 1;
 467    yylloc->last_line++;
 468    yylloc->last_column = 1;
 469    yylloc->position++;
 470 }
 471 [ \t\r]+                  /* eat whitespace */ ;
 472 #.*$                      /* eat comments */ ;
 473 .                         { return yytext[0]; }
 474 %%
 475
 476 void
 477 _mesa_program_lexer_ctor(void **scanner, struct asm_parser_state *state,
 478                          const char *string, size_t len)
 479 {
 480    yylex_init_extra(state, scanner);
 481    yy_scan_bytes(string, len, *scanner);
 482 }
 483
 484 void
 485 _mesa_program_lexer_dtor(void *scanner)
 486 {
 487    yylex_destroy(scanner);
 488 }