src/mesa/x86/3dnow_xform1.S

   1 /* $Id: 3dnow_xform1.S,v 1.1 2001/03/29 06:46:16 gareth Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #include "matypes.h"
  28 #include "xform_args.h"
  29
  30     SEG_TEXT
  31
  32 #define FRAME_OFFSET    4
  33
  34
  35 ALIGNTEXT16
  36 GLOBL GLNAME( _mesa_3dnow_transform_points1_general )
  37 GLNAME( _mesa_3dnow_transform_points1_general ):
  38
  39     PUSH_L    ( ESI )
  40
  41     MOV_L     ( ARG_DEST, ECX )
  42     MOV_L     ( ARG_MATRIX, ESI )
  43     MOV_L     ( ARG_SOURCE, EAX )
  44     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
  45     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
  46     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
  47     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
  48
  49     PUSH_L    ( EDI )
  50
  51     MOV_L     ( REGOFF(4, ECX), EDX )
  52     MOV_L     ( ESI, ECX )
  53     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
  54     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
  55     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
  56
  57     TEST_L    ( ESI, ESI )
  58     JZ        ( LLBL( G3TPGR_3 ) )
  59
  60     MOVQ      ( REGIND(ECX), MM0 )      /* m01             | m00             */
  61     MOVQ      ( REGOFF(8, ECX), MM1 )   /* m03             | m02             */
  62
  63     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
  64     MOVQ      ( REGOFF(56, ECX), MM3 )  /* m33             | m32             */
  65
  66 ALIGNTEXT16
  67 LLBL( G3TPGR_2 ):
  68
  69     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
  70     PUNPCKLDQ ( MM4, MM4 )              /* x0              | x0              */
  71
  72     MOVQ      ( MM4, MM5 )              /* x0              | x0              */
  73     PFMUL     ( MM0, MM4 )              /* x0*m01          | x0*m00          */
  74
  75     PFMUL     ( MM1, MM5 )              /* x0*m03          | x0*m02          */
  76     PFADD     ( MM2, MM4 )              /* x0*m01+m31      | x0*m00+m30      */
  77
  78     PFADD     ( MM3, MM5 )              /* x0*m03+m33      | x0*m02+m32      */
  79     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
  80
  81     MOVQ      ( MM5, REGOFF(8, EDX) )   /* write r3, r2                      */
  82     ADD_L     ( EDI, EAX )              /* next vertex                       */
  83
  84     ADD_L     ( CONST(16), EDX )        /* next r                            */
  85     DEC_L     ( ESI )                   /* decrement vertex counter          */
  86
  87     JNZ       ( LLBL( G3TPGR_2 ) )      /* cnt > 0 ? -> process next vertex  */
  88
  89 LLBL( G3TPGR_3 ):
  90
  91     FEMMS
  92     POP_L     ( EDI )
  93     POP_L     ( ESI )
  94     RET
  95
  96
  97
  98
  99 ALIGNTEXT16
 100 GLOBL GLNAME( _mesa_3dnow_transform_points1_identity )
 101 GLNAME( _mesa_3dnow_transform_points1_identity ):
 102
 103     PUSH_L    ( ESI )
 104
 105     MOV_L     ( ARG_DEST, ECX )
 106     MOV_L     ( ARG_MATRIX, ESI )
 107     MOV_L     ( ARG_SOURCE, EAX )
 108     MOV_L     ( CONST(1), REGOFF(V4F_SIZE, ECX) )
 109     OR_B      ( CONST(VEC_SIZE_1), REGOFF(V4F_FLAGS, ECX) )
 110     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 111     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 112
 113     PUSH_L    ( EDI )
 114
 115     MOV_L     ( REGOFF(4, ECX), EDX )
 116     MOV_L     ( ESI, ECX )
 117     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 118     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 119     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 120
 121     TEST_L    ( ESI, ESI )
 122     JZ        ( LLBL( G3TPIR_4) )
 123
 124 ALIGNTEXT16
 125 LLBL( G3TPIR_3 ):
 126
 127     MOVD      ( REGIND(EAX), MM0 )      /*                 | x0              */
 128     ADD_L     ( EDI, EAX )              /* next vertex                       */
 129
 130     MOVD      ( MM0, REGIND(EDX) )      /*                 | r0              */
 131     ADD_L     ( CONST(16), EDX )        /* next r                            */
 132
 133     DEC_L     ( ESI )                   /* decrement vertex counter          */
 134     JNZ       ( LLBL( G3TPIR_3 ) )      /* cnt > 0 ? -> process next vertex  */
 135
 136 LLBL( G3TPIR_4 ):
 137
 138     FEMMS
 139     POP_L     ( EDI )
 140     POP_L     ( ESI )
 141     RET
 142
 143
 144
 145
 146 ALIGNTEXT16
 147 GLOBL GLNAME( _mesa_3dnow_transform_points1_3d_no_rot )
 148 GLNAME( _mesa_3dnow_transform_points1_3d_no_rot ):
 149
 150     PUSH_L    ( ESI )
 151
 152     MOV_L     ( ARG_DEST, ECX )
 153     MOV_L     ( ARG_MATRIX, ESI )
 154     MOV_L     ( ARG_SOURCE, EAX )
 155     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 156     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 157     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 158     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 159
 160     PUSH_L    ( EDI )
 161
 162     MOV_L     ( REGOFF(4, ECX), EDX )
 163     MOV_L     ( ESI, ECX )
 164     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 165     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 166     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 167
 168     TEST_L    ( ESI, ESI )
 169     JZ        ( LLBL( G3TP3NRR_3 ) )
 170
 171     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 172     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 173
 174     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 175
 176 ALIGNTEXT16
 177 LLBL( G3TP3NRR_2 ):
 178
 179     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 180     PFMUL     ( MM0, MM4 )              /*                 | x0*m00          */
 181
 182     PFADD     ( MM2, MM4 )              /* m31             | x0*m00+m30      */
 183     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 184
 185     MOVD      ( MM3, REGOFF(8, EDX) )   /* write r2                          */
 186     ADD_L     ( EDI, EAX )              /* next vertex                       */
 187
 188     ADD_L     ( CONST(16), EDX )        /* next r                            */
 189     DEC_L     ( ESI )                   /* decrement vertex counter          */
 190
 191     JNZ       ( LLBL( G3TP3NRR_2 ) )    /* cnt > 0 ? -> process next vertex  */
 192
 193 LLBL( G3TP3NRR_3 ):
 194
 195     FEMMS
 196     POP_L     ( EDI )
 197     POP_L     ( ESI )
 198     RET
 199
 200
 201
 202
 203 ALIGNTEXT16
 204 GLOBL GLNAME( _mesa_3dnow_transform_points1_perspective )
 205 GLNAME( _mesa_3dnow_transform_points1_perspective ):
 206
 207     PUSH_L    ( ESI )
 208
 209     MOV_L     ( ARG_DEST, ECX )
 210     MOV_L     ( ARG_MATRIX, ESI )
 211     MOV_L     ( ARG_SOURCE, EAX )
 212     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 213     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 214     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 215     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 216
 217     PUSH_L    ( EDI )
 218
 219     MOV_L     ( REGOFF(4, ECX), EDX )
 220     MOV_L     ( ESI, ECX )
 221     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 222     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 223     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 224
 225     TEST_L    ( ESI, ESI )
 226     JZ        ( LLBL( G3TPPR_3 ) )
 227
 228     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 229     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 230
 231 ALIGNTEXT16
 232 LLBL( G3TPPR_2 ):
 233
 234     MOVD      ( REGIND(EAX), MM4 )      /* 0               | x0              */
 235     PFMUL     ( MM0, MM4 )              /* 0               | x0*m00          */
 236
 237     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 238     MOVQ      ( MM3, REGOFF(8, EDX) )   /* write r2  (=m32), r3 (=0)         */
 239
 240     ADD_L     ( EDI, EAX )              /* next vertex                       */
 241     ADD_L     ( CONST(16), EDX )        /* next r                            */
 242
 243     DEC_L     ( ESI )                   /* decrement vertex counter          */
 244     JNZ       ( LLBL( G3TPPR_2 ) )      /* cnt > 0 ? -> process next vertex  */
 245
 246 LLBL( G3TPPR_3 ):
 247
 248     FEMMS
 249     POP_L     ( EDI )
 250     POP_L     ( ESI )
 251     RET
 252
 253
 254
 255
 256 ALIGNTEXT16
 257 GLOBL GLNAME( _mesa_3dnow_transform_points1_2d )
 258 GLNAME( _mesa_3dnow_transform_points1_2d ):
 259
 260     PUSH_L    ( ESI )
 261
 262     MOV_L     ( ARG_DEST, ECX )
 263     MOV_L     ( ARG_MATRIX, ESI )
 264     MOV_L     ( ARG_SOURCE, EAX )
 265     MOV_L     ( CONST(2), REGOFF(V4F_SIZE, ECX) )
 266     OR_B      ( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, ECX) )
 267     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 268     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 269
 270     PUSH_L    ( EDI )
 271
 272     MOV_L     ( REGOFF(4, ECX), EDX )
 273     MOV_L     ( ESI, ECX )
 274     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 275     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 276     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 277
 278     TEST_L    ( ESI, ESI )
 279     JZ        ( LLBL( G3TP2R_3 ) )
 280
 281     MOVQ      ( REGIND(ECX), MM0 )      /* m01             | m00             */
 282     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 283
 284 ALIGNTEXT16
 285 LLBL( G3TP2R_2 ):
 286
 287     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 288     PUNPCKLDQ ( MM4, MM4 )              /* x0              | x0              */
 289
 290     PFMUL     ( MM0, MM4 )              /* x0*m01          | x0*m00          */
 291     PFADD     ( MM2, MM4 )              /* x0*m01+m31      | x0*m00+m30      */
 292
 293     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 294     ADD_L     ( EDI, EAX )              /* next vertex                       */
 295
 296     ADD_L     ( CONST(16), EDX )        /* next r                            */
 297     DEC_L     ( ESI )                   /* decrement vertex counter          */
 298
 299     JNZ       ( LLBL( G3TP2R_2 ) )      /* cnt > 0 ? -> process next vertex  */
 300
 301 LLBL( G3TP2R_3 ):
 302
 303     FEMMS
 304     POP_L     ( EDI )
 305     POP_L     ( ESI )
 306     RET
 307
 308
 309
 310
 311 ALIGNTEXT16
 312 GLOBL GLNAME( _mesa_3dnow_transform_points1_2d_no_rot )
 313 GLNAME( _mesa_3dnow_transform_points1_2d_no_rot ):
 314
 315     PUSH_L    ( ESI )
 316
 317     MOV_L     ( ARG_DEST, ECX )
 318     MOV_L     ( ARG_MATRIX, ESI )
 319     MOV_L     ( ARG_SOURCE, EAX )
 320     MOV_L     ( CONST(2), REGOFF(V4F_SIZE, ECX) )
 321     OR_B      ( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, ECX) )
 322     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 323     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 324
 325     PUSH_L    ( EDI )
 326
 327     MOV_L     ( REGOFF(4, ECX), EDX )
 328     MOV_L     ( ESI, ECX )
 329     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 330     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 331     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 332
 333     TEST_L    ( ESI, ESI )
 334     JZ        ( LLBL( G3TP2NRR_3 ) )
 335
 336     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 337     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 338
 339 ALIGNTEXT16
 340 LLBL( G3TP2NRR_2 ):
 341
 342     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 343     ADD_L     ( EDI, EAX )              /* next vertex                       */
 344
 345     PFMUL     ( MM0, MM4 )              /*                 | x0*m00          */
 346     PFADD     ( MM2, MM4 )              /* m31             | x0*m00+m30      */
 347
 348     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 349     ADD_L     ( CONST(16), EDX )        /* next r                            */
 350
 351     DEC_L     ( ESI )                   /* decrement vertex counter          */
 352     JNZ       ( LLBL( G3TP2NRR_2 ) )    /* cnt > 0 ? -> process next vertex  */
 353
 354 LLBL( G3TP2NRR_3 ):
 355
 356     FEMMS
 357     POP_L     ( EDI )
 358     POP_L     ( ESI )
 359     RET
 360
 361
 362
 363
 364 ALIGNTEXT16
 365 GLOBL GLNAME( _mesa_3dnow_transform_points1_3d )
 366 GLNAME( _mesa_3dnow_transform_points1_3d ):
 367
 368     PUSH_L    ( ESI )
 369
 370     MOV_L     ( ARG_DEST, ECX )
 371     MOV_L     ( ARG_MATRIX, ESI )
 372     MOV_L     ( ARG_SOURCE, EAX )
 373     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 374     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 375     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 376     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 377
 378     PUSH_L    ( EDI )
 379
 380     MOV_L     ( REGOFF(4, ECX), EDX )
 381     MOV_L     ( ESI, ECX )
 382     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 383     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 384     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 385
 386     TEST_L    ( ESI, ESI )
 387     JZ        ( LLBL( G3TP3R_3 ) )
 388
 389     MOVQ      ( REGIND(ECX), MM0 )      /* m01             | m00             */
 390     MOVD      ( REGOFF(8, ECX), MM1 )   /*                 | m02             */
 391
 392     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 393     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 394
 395 ALIGNTEXT16
 396 LLBL( G3TP3R_2 ):
 397
 398     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 399     PUNPCKLDQ ( MM4, MM4 )              /* x0              | x0              */
 400
 401     MOVQ      ( MM4, MM5 )              /*                 | x0              */
 402     PFMUL     ( MM0, MM4 )              /* x0*m01          | x0*m00          */
 403
 404     PFMUL     ( MM1, MM5 )              /*                 | x0*m02          */
 405     PFADD     ( MM2, MM4 )              /* x0*m01+m31      | x0*m00+m30      */
 406
 407     PFADD     ( MM3, MM5 )              /*                 | x0*m02+m32      */
 408     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 409
 410     MOVD      ( MM5, REGOFF(8, EDX) )   /* write r2                          */
 411     ADD_L     ( EDI, EAX )              /* next vertex                       */
 412
 413     ADD_L     ( CONST(16), EDX )        /* next r                            */
 414     DEC_L     ( ESI )                   /* decrement vertex counter          */
 415
 416     JNZ       ( LLBL( G3TP3R_2 ) )      /* cnt > 0 ? -> process next vertex  */
 417
 418 LLBL( G3TP3R_3 ):
 419
 420     FEMMS
 421     POP_L     ( EDI )
 422     POP_L     ( ESI )
 423     RET