src/mesa/x86/3dnow_xform1.S

   1 /* $Id: 3dnow_xform1.S,v 1.2 2004/04/26 10:10:25 alanh Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #ifdef USE_3DNOW_ASM
  28 #include "matypes.h"
  29 #include "xform_args.h"
  30
  31     SEG_TEXT
  32
  33 #define FRAME_OFFSET    4
  34
  35
  36 ALIGNTEXT16
  37 GLOBL GLNAME( _mesa_3dnow_transform_points1_general )
  38 GLNAME( _mesa_3dnow_transform_points1_general ):
  39
  40     PUSH_L    ( ESI )
  41
  42     MOV_L     ( ARG_DEST, ECX )
  43     MOV_L     ( ARG_MATRIX, ESI )
  44     MOV_L     ( ARG_SOURCE, EAX )
  45     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
  46     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
  47     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
  48     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
  49
  50     PUSH_L    ( EDI )
  51
  52     MOV_L     ( REGOFF(4, ECX), EDX )
  53     MOV_L     ( ESI, ECX )
  54     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
  55     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
  56     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
  57
  58     TEST_L    ( ESI, ESI )
  59     JZ        ( LLBL( G3TPGR_3 ) )
  60
  61     MOVQ      ( REGIND(ECX), MM0 )      /* m01             | m00             */
  62     MOVQ      ( REGOFF(8, ECX), MM1 )   /* m03             | m02             */
  63
  64     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
  65     MOVQ      ( REGOFF(56, ECX), MM3 )  /* m33             | m32             */
  66
  67 ALIGNTEXT16
  68 LLBL( G3TPGR_2 ):
  69
  70     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
  71     PUNPCKLDQ ( MM4, MM4 )              /* x0              | x0              */
  72
  73     MOVQ      ( MM4, MM5 )              /* x0              | x0              */
  74     PFMUL     ( MM0, MM4 )              /* x0*m01          | x0*m00          */
  75
  76     PFMUL     ( MM1, MM5 )              /* x0*m03          | x0*m02          */
  77     PFADD     ( MM2, MM4 )              /* x0*m01+m31      | x0*m00+m30      */
  78
  79     PFADD     ( MM3, MM5 )              /* x0*m03+m33      | x0*m02+m32      */
  80     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
  81
  82     MOVQ      ( MM5, REGOFF(8, EDX) )   /* write r3, r2                      */
  83     ADD_L     ( EDI, EAX )              /* next vertex                       */
  84
  85     ADD_L     ( CONST(16), EDX )        /* next r                            */
  86     DEC_L     ( ESI )                   /* decrement vertex counter          */
  87
  88     JNZ       ( LLBL( G3TPGR_2 ) )      /* cnt > 0 ? -> process next vertex  */
  89
  90 LLBL( G3TPGR_3 ):
  91
  92     FEMMS
  93     POP_L     ( EDI )
  94     POP_L     ( ESI )
  95     RET
  96
  97
  98
  99
 100 ALIGNTEXT16
 101 GLOBL GLNAME( _mesa_3dnow_transform_points1_identity )
 102 GLNAME( _mesa_3dnow_transform_points1_identity ):
 103
 104     PUSH_L    ( ESI )
 105
 106     MOV_L     ( ARG_DEST, ECX )
 107     MOV_L     ( ARG_MATRIX, ESI )
 108     MOV_L     ( ARG_SOURCE, EAX )
 109     MOV_L     ( CONST(1), REGOFF(V4F_SIZE, ECX) )
 110     OR_B      ( CONST(VEC_SIZE_1), REGOFF(V4F_FLAGS, ECX) )
 111     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 112     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 113
 114     PUSH_L    ( EDI )
 115
 116     MOV_L     ( REGOFF(4, ECX), EDX )
 117     MOV_L     ( ESI, ECX )
 118     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 119     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 120     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 121
 122     TEST_L    ( ESI, ESI )
 123     JZ        ( LLBL( G3TPIR_4) )
 124
 125 ALIGNTEXT16
 126 LLBL( G3TPIR_3 ):
 127
 128     MOVD      ( REGIND(EAX), MM0 )      /*                 | x0              */
 129     ADD_L     ( EDI, EAX )              /* next vertex                       */
 130
 131     MOVD      ( MM0, REGIND(EDX) )      /*                 | r0              */
 132     ADD_L     ( CONST(16), EDX )        /* next r                            */
 133
 134     DEC_L     ( ESI )                   /* decrement vertex counter          */
 135     JNZ       ( LLBL( G3TPIR_3 ) )      /* cnt > 0 ? -> process next vertex  */
 136
 137 LLBL( G3TPIR_4 ):
 138
 139     FEMMS
 140     POP_L     ( EDI )
 141     POP_L     ( ESI )
 142     RET
 143
 144
 145
 146
 147 ALIGNTEXT16
 148 GLOBL GLNAME( _mesa_3dnow_transform_points1_3d_no_rot )
 149 GLNAME( _mesa_3dnow_transform_points1_3d_no_rot ):
 150
 151     PUSH_L    ( ESI )
 152
 153     MOV_L     ( ARG_DEST, ECX )
 154     MOV_L     ( ARG_MATRIX, ESI )
 155     MOV_L     ( ARG_SOURCE, EAX )
 156     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 157     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 158     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 159     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 160
 161     PUSH_L    ( EDI )
 162
 163     MOV_L     ( REGOFF(4, ECX), EDX )
 164     MOV_L     ( ESI, ECX )
 165     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 166     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 167     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 168
 169     TEST_L    ( ESI, ESI )
 170     JZ        ( LLBL( G3TP3NRR_3 ) )
 171
 172     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 173     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 174
 175     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 176
 177 ALIGNTEXT16
 178 LLBL( G3TP3NRR_2 ):
 179
 180     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 181     PFMUL     ( MM0, MM4 )              /*                 | x0*m00          */
 182
 183     PFADD     ( MM2, MM4 )              /* m31             | x0*m00+m30      */
 184     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 185
 186     MOVD      ( MM3, REGOFF(8, EDX) )   /* write r2                          */
 187     ADD_L     ( EDI, EAX )              /* next vertex                       */
 188
 189     ADD_L     ( CONST(16), EDX )        /* next r                            */
 190     DEC_L     ( ESI )                   /* decrement vertex counter          */
 191
 192     JNZ       ( LLBL( G3TP3NRR_2 ) )    /* cnt > 0 ? -> process next vertex  */
 193
 194 LLBL( G3TP3NRR_3 ):
 195
 196     FEMMS
 197     POP_L     ( EDI )
 198     POP_L     ( ESI )
 199     RET
 200
 201
 202
 203
 204 ALIGNTEXT16
 205 GLOBL GLNAME( _mesa_3dnow_transform_points1_perspective )
 206 GLNAME( _mesa_3dnow_transform_points1_perspective ):
 207
 208     PUSH_L    ( ESI )
 209
 210     MOV_L     ( ARG_DEST, ECX )
 211     MOV_L     ( ARG_MATRIX, ESI )
 212     MOV_L     ( ARG_SOURCE, EAX )
 213     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 214     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 215     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 216     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 217
 218     PUSH_L    ( EDI )
 219
 220     MOV_L     ( REGOFF(4, ECX), EDX )
 221     MOV_L     ( ESI, ECX )
 222     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 223     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 224     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 225
 226     TEST_L    ( ESI, ESI )
 227     JZ        ( LLBL( G3TPPR_3 ) )
 228
 229     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 230     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 231
 232 ALIGNTEXT16
 233 LLBL( G3TPPR_2 ):
 234
 235     MOVD      ( REGIND(EAX), MM4 )      /* 0               | x0              */
 236     PFMUL     ( MM0, MM4 )              /* 0               | x0*m00          */
 237
 238     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 239     MOVQ      ( MM3, REGOFF(8, EDX) )   /* write r2  (=m32), r3 (=0)         */
 240
 241     ADD_L     ( EDI, EAX )              /* next vertex                       */
 242     ADD_L     ( CONST(16), EDX )        /* next r                            */
 243
 244     DEC_L     ( ESI )                   /* decrement vertex counter          */
 245     JNZ       ( LLBL( G3TPPR_2 ) )      /* cnt > 0 ? -> process next vertex  */
 246
 247 LLBL( G3TPPR_3 ):
 248
 249     FEMMS
 250     POP_L     ( EDI )
 251     POP_L     ( ESI )
 252     RET
 253
 254
 255
 256
 257 ALIGNTEXT16
 258 GLOBL GLNAME( _mesa_3dnow_transform_points1_2d )
 259 GLNAME( _mesa_3dnow_transform_points1_2d ):
 260
 261     PUSH_L    ( ESI )
 262
 263     MOV_L     ( ARG_DEST, ECX )
 264     MOV_L     ( ARG_MATRIX, ESI )
 265     MOV_L     ( ARG_SOURCE, EAX )
 266     MOV_L     ( CONST(2), REGOFF(V4F_SIZE, ECX) )
 267     OR_B      ( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, ECX) )
 268     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 269     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 270
 271     PUSH_L    ( EDI )
 272
 273     MOV_L     ( REGOFF(4, ECX), EDX )
 274     MOV_L     ( ESI, ECX )
 275     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 276     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 277     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 278
 279     TEST_L    ( ESI, ESI )
 280     JZ        ( LLBL( G3TP2R_3 ) )
 281
 282     MOVQ      ( REGIND(ECX), MM0 )      /* m01             | m00             */
 283     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 284
 285 ALIGNTEXT16
 286 LLBL( G3TP2R_2 ):
 287
 288     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 289     PUNPCKLDQ ( MM4, MM4 )              /* x0              | x0              */
 290
 291     PFMUL     ( MM0, MM4 )              /* x0*m01          | x0*m00          */
 292     PFADD     ( MM2, MM4 )              /* x0*m01+m31      | x0*m00+m30      */
 293
 294     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 295     ADD_L     ( EDI, EAX )              /* next vertex                       */
 296
 297     ADD_L     ( CONST(16), EDX )        /* next r                            */
 298     DEC_L     ( ESI )                   /* decrement vertex counter          */
 299
 300     JNZ       ( LLBL( G3TP2R_2 ) )      /* cnt > 0 ? -> process next vertex  */
 301
 302 LLBL( G3TP2R_3 ):
 303
 304     FEMMS
 305     POP_L     ( EDI )
 306     POP_L     ( ESI )
 307     RET
 308
 309
 310
 311
 312 ALIGNTEXT16
 313 GLOBL GLNAME( _mesa_3dnow_transform_points1_2d_no_rot )
 314 GLNAME( _mesa_3dnow_transform_points1_2d_no_rot ):
 315
 316     PUSH_L    ( ESI )
 317
 318     MOV_L     ( ARG_DEST, ECX )
 319     MOV_L     ( ARG_MATRIX, ESI )
 320     MOV_L     ( ARG_SOURCE, EAX )
 321     MOV_L     ( CONST(2), REGOFF(V4F_SIZE, ECX) )
 322     OR_B      ( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, ECX) )
 323     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 324     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 325
 326     PUSH_L    ( EDI )
 327
 328     MOV_L     ( REGOFF(4, ECX), EDX )
 329     MOV_L     ( ESI, ECX )
 330     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 331     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 332     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 333
 334     TEST_L    ( ESI, ESI )
 335     JZ        ( LLBL( G3TP2NRR_3 ) )
 336
 337     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 338     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 339
 340 ALIGNTEXT16
 341 LLBL( G3TP2NRR_2 ):
 342
 343     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 344     ADD_L     ( EDI, EAX )              /* next vertex                       */
 345
 346     PFMUL     ( MM0, MM4 )              /*                 | x0*m00          */
 347     PFADD     ( MM2, MM4 )              /* m31             | x0*m00+m30      */
 348
 349     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 350     ADD_L     ( CONST(16), EDX )        /* next r                            */
 351
 352     DEC_L     ( ESI )                   /* decrement vertex counter          */
 353     JNZ       ( LLBL( G3TP2NRR_2 ) )    /* cnt > 0 ? -> process next vertex  */
 354
 355 LLBL( G3TP2NRR_3 ):
 356
 357     FEMMS
 358     POP_L     ( EDI )
 359     POP_L     ( ESI )
 360     RET
 361
 362
 363
 364
 365 ALIGNTEXT16
 366 GLOBL GLNAME( _mesa_3dnow_transform_points1_3d )
 367 GLNAME( _mesa_3dnow_transform_points1_3d ):
 368
 369     PUSH_L    ( ESI )
 370
 371     MOV_L     ( ARG_DEST, ECX )
 372     MOV_L     ( ARG_MATRIX, ESI )
 373     MOV_L     ( ARG_SOURCE, EAX )
 374     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 375     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 376     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 377     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 378
 379     PUSH_L    ( EDI )
 380
 381     MOV_L     ( REGOFF(4, ECX), EDX )
 382     MOV_L     ( ESI, ECX )
 383     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 384     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 385     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 386
 387     TEST_L    ( ESI, ESI )
 388     JZ        ( LLBL( G3TP3R_3 ) )
 389
 390     MOVQ      ( REGIND(ECX), MM0 )      /* m01             | m00             */
 391     MOVD      ( REGOFF(8, ECX), MM1 )   /*                 | m02             */
 392
 393     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 394     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 395
 396 ALIGNTEXT16
 397 LLBL( G3TP3R_2 ):
 398
 399     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 400     PUNPCKLDQ ( MM4, MM4 )              /* x0              | x0              */
 401
 402     MOVQ      ( MM4, MM5 )              /*                 | x0              */
 403     PFMUL     ( MM0, MM4 )              /* x0*m01          | x0*m00          */
 404
 405     PFMUL     ( MM1, MM5 )              /*                 | x0*m02          */
 406     PFADD     ( MM2, MM4 )              /* x0*m01+m31      | x0*m00+m30      */
 407
 408     PFADD     ( MM3, MM5 )              /*                 | x0*m02+m32      */
 409     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 410
 411     MOVD      ( MM5, REGOFF(8, EDX) )   /* write r2                          */
 412     ADD_L     ( EDI, EAX )              /* next vertex                       */
 413
 414     ADD_L     ( CONST(16), EDX )        /* next r                            */
 415     DEC_L     ( ESI )                   /* decrement vertex counter          */
 416
 417     JNZ       ( LLBL( G3TP3R_2 ) )      /* cnt > 0 ? -> process next vertex  */
 418
 419 LLBL( G3TP3R_3 ):
 420
 421     FEMMS
 422     POP_L     ( EDI )
 423     POP_L     ( ESI )
 424     RET
 425
 426 #endif