src/mesa/x86/3dnow_xform2.S

   1 /* $Id: 3dnow_xform2.S,v 1.2 2004/04/26 10:10:25 alanh Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #ifdef USE_3DNOW_ASM
  28 #include "matypes.h"
  29 #include "xform_args.h"
  30
  31     SEG_TEXT
  32
  33 #define FRAME_OFFSET    4
  34
  35
  36 ALIGNTEXT16
  37 GLOBL GLNAME( _mesa_3dnow_transform_points2_general )
  38 GLNAME( _mesa_3dnow_transform_points2_general ):
  39
  40     PUSH_L    ( ESI )
  41
  42     MOV_L     ( ARG_DEST, ECX )
  43     MOV_L     ( ARG_MATRIX, ESI )
  44     MOV_L     ( ARG_SOURCE, EAX )
  45     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
  46     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
  47     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
  48     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
  49
  50     PUSH_L    ( EDI )
  51
  52     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
  53     MOV_L     ( ESI, ECX )
  54     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
  55     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
  56     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
  57
  58     TEST_L    ( ESI, ESI )
  59     JZ        ( LLBL( G3TPGR_3 ) )
  60
  61     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
  62     PUNPCKLDQ ( REGOFF(16, ECX), MM0 )  /* m10             | m00             */
  63
  64     MOVD      ( REGOFF(4, ECX), MM1 )   /*                 | m01             */
  65     PUNPCKLDQ ( REGOFF(20, ECX), MM1 )  /* m11             | m01             */
  66
  67     MOVD      ( REGOFF(8, ECX), MM2 )   /*                 | m02             */
  68     PUNPCKLDQ ( REGOFF(24, ECX), MM2 )  /* m12             | m02             */
  69
  70     MOVD      ( REGOFF(12, ECX), MM3 )  /*                 | m03             */
  71     PUNPCKLDQ ( REGOFF(28, ECX), MM3 )  /* m13             | m03             */
  72
  73     MOVQ      ( REGOFF(48, ECX), MM4 )  /* m31             | m30             */
  74     MOVQ      ( REGOFF(56, ECX), MM5 )  /* m33             | m32             */
  75
  76 ALIGNTEXT16
  77 LLBL( G3TPGR_2 ):
  78
  79     MOVQ      ( REGIND(EAX), MM6 )      /* x1              | x0              */
  80     MOVQ      ( MM6, MM7 )              /* x1              | x0              */
  81
  82     PFMUL     ( MM0, MM6 )              /* x1*m10          | x0*m00          */
  83     PFMUL     ( MM1, MM7 )              /* x1*m11          | x0*m01          */
  84
  85     PFACC     ( MM7, MM6 )              /* x0*m01+x1*m11   | x0*x00+x1*m10   */
  86     PFADD     ( MM4, MM6 )              /* x0*...*m11+m31  | x0*...*m10+m30  */
  87
  88     MOVQ      ( MM6, REGIND(EDX) )      /* write r1, r0                      */
  89     MOVQ      ( REGIND(EAX), MM6 )      /* x1              | x0              */
  90
  91     MOVQ      ( MM6, MM7 )              /* x1              | x0              */
  92     PFMUL     ( MM2, MM6 )              /* x1*m12          | x0*m02          */
  93
  94     PFMUL     ( MM3, MM7 )              /* x1*m13          | x0*m03          */
  95     ADD_L     ( EDI, EAX )              /* next vertex                       */
  96
  97     PFACC     ( MM7, MM6 )              /* x0*m03+x1*m13   | x0*x02+x1*m12   */
  98     PFADD     ( MM5, MM6 )              /* x0*...*m13+m33  | x0*...*m12+m32  */
  99
 100     MOVQ      ( MM6, REGOFF(8, EDX) )   /* write r3, r2                      */
 101     ADD_L     ( CONST(16), EDX )        /* next r                            */
 102
 103     DEC_L     ( ESI )                   /* decrement vertex counter          */
 104     JNZ       ( LLBL( G3TPGR_2 ) )      /* cnt > 0 ? -> process next vertex  */
 105
 106 LLBL( G3TPGR_3 ):
 107
 108     FEMMS
 109     POP_L     ( EDI )
 110     POP_L     ( ESI )
 111     RET
 112
 113
 114
 115
 116 ALIGNTEXT16
 117 GLOBL GLNAME( _mesa_3dnow_transform_points2_perspective )
 118 GLNAME( _mesa_3dnow_transform_points2_perspective ):
 119
 120     PUSH_L    ( ESI )
 121
 122     MOV_L     ( ARG_DEST, ECX )
 123     MOV_L     ( ARG_MATRIX, ESI )
 124     MOV_L     ( ARG_SOURCE, EAX )
 125     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 126     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 127     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 128     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 129
 130     PUSH_L    ( EDI )
 131
 132     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 133     MOV_L     ( ESI, ECX )
 134     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 135     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 136     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 137
 138     TEST_L    ( ESI, ESI )
 139     JZ        ( LLBL( G3TPPR_3 ) )
 140
 141     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 142     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 143
 144     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 145
 146 ALIGNTEXT16
 147 LLBL( G3TPPR_2 ):
 148
 149     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 150     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 151
 152     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 153     MOVQ      ( MM3, REGOFF(8, EDX) )   /* write r2  (=m32), r3 (=0)         */
 154
 155     ADD_L     ( EDI, EAX )              /* next vertex                       */
 156     ADD_L     ( CONST(16), EDX )        /* next r                            */
 157
 158     DEC_L     ( ESI )                   /* decrement vertex counter          */
 159     JNZ       ( LLBL( G3TPPR_2 ) )      /* cnt > 0 ? -> process next vertex  */
 160
 161 LLBL( G3TPPR_3 ):
 162
 163     FEMMS
 164     POP_L     ( EDI )
 165     POP_L     ( ESI )
 166     RET
 167
 168
 169
 170
 171 ALIGNTEXT16
 172 GLOBL GLNAME( _mesa_3dnow_transform_points2_3d )
 173 GLNAME( _mesa_3dnow_transform_points2_3d ):
 174
 175     PUSH_L    ( ESI )
 176
 177     MOV_L     ( ARG_DEST, ECX )
 178     MOV_L     ( ARG_MATRIX, ESI )
 179     MOV_L     ( ARG_SOURCE, EAX )
 180     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 181     OR_B      ( CONST(VEC_SIZE_3 ), REGOFF(V4F_FLAGS, ECX) )
 182     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 183     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 184
 185     PUSH_L    ( EDI )
 186
 187     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 188     MOV_L     ( ESI, ECX )
 189     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 190     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 191     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 192
 193     TEST_L    ( ESI, ESI )
 194     JZ        ( LLBL( G3TP3R_3 ) )
 195
 196     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 197     PUNPCKLDQ ( REGOFF(16, ECX), MM0 )  /* m10             | m00             */
 198
 199     MOVD      ( REGOFF(4, ECX), MM1 )   /*                 | m01             */
 200     PUNPCKLDQ ( REGOFF(20, ECX), MM1 )  /* m11             | m01             */
 201
 202     MOVD      ( REGOFF(8, ECX), MM2 )   /*                 | m02             */
 203     PUNPCKLDQ ( REGOFF(24, ECX), MM2 )  /* m12             | m02             */
 204
 205     MOVQ      ( REGOFF(48, ECX), MM4 )  /* m31             | m30             */
 206     MOVD      ( REGOFF(56, ECX), MM5 )  /*                 | m32             */
 207
 208 ALIGNTEXT16
 209 LLBL( G3TP3R_2 ):
 210
 211     MOVQ      ( REGIND(EAX), MM6 )      /* x1              | x0              */
 212     MOVQ      ( MM6, MM7 )              /* x1              | x0              */
 213
 214     PFMUL     ( MM0, MM6 )              /* x1*m10          | x0*m00          */
 215     PFMUL     ( MM1, MM7 )              /* x1*m11          | x0*m01          */
 216
 217     PFACC     ( MM7, MM6 )              /* x0*m01+x1*m11   | x0*x00+x1*m10   */
 218     PFADD     ( MM4, MM6 )              /* x0*...*m11+m31  | x0*...*m10+m30  */
 219
 220     MOVQ      ( MM6, REGIND(EDX) )      /* write r1, r0                      */
 221     MOVQ      ( REGIND(EAX), MM6 )      /* x1              | x0              */
 222
 223     MOVQ      ( MM6, MM7 )              /* x1              | x0              */
 224     PFMUL     ( MM2, MM6 )              /* x1*m12          | x0*m02          */
 225
 226     PFACC     ( MM7, MM6 )              /* ***trash***     | x0*x02+x1*m12   */
 227     PFADD     ( MM5, MM6 )              /* ***trash***     | x0*...*m12+m32  */
 228
 229     MOVD      ( MM6, REGOFF(8, EDX) )   /* write r2                          */
 230     ADD_L     ( EDI, EAX )              /* next vertex                       */
 231
 232     ADD_L     ( CONST(16), EDX )        /* next r                            */
 233     DEC_L     ( ESI )                   /* decrement vertex counter          */
 234
 235     JNZ       ( LLBL( G3TP3R_2 ) )      /* cnt > 0 ? -> process next vertex  */
 236
 237 LLBL( G3TP3R_3 ):
 238
 239     FEMMS
 240     POP_L     ( EDI )
 241     POP_L     ( ESI )
 242     RET
 243
 244
 245
 246
 247 ALIGNTEXT16
 248 GLOBL GLNAME( _mesa_3dnow_transform_points2_3d_no_rot )
 249 GLNAME( _mesa_3dnow_transform_points2_3d_no_rot ):
 250
 251     PUSH_L    ( ESI )
 252
 253     MOV_L     ( ARG_DEST, ECX )
 254     MOV_L     ( ARG_MATRIX, ESI )
 255     MOV_L     ( ARG_SOURCE, EAX )
 256     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 257     OR_B      ( CONST(VEC_SIZE_3 ), REGOFF(V4F_FLAGS, ECX) )
 258     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 259     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 260
 261     PUSH_L    ( EDI )
 262
 263     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 264     MOV_L     ( ESI, ECX )
 265     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 266     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 267     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 268
 269     TEST_L    ( ESI, ESI )
 270     JZ        ( LLBL( G3TP3NRR_3 ) )
 271
 272     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 273     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 274
 275     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 276     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 277
 278 ALIGNTEXT16
 279 LLBL( G3TP3NRR_2 ):
 280
 281     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 282     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 283
 284     PFADD     ( MM2, MM4 )              /* x1*m11+m31      | x0*m00+m30      */
 285     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 286
 287     MOVD      ( MM3, REGOFF(8, EDX) )   /* write r2                          */
 288     ADD_L     ( EDI, EAX )              /* next vertex                       */
 289
 290     ADD_L     ( CONST(16), EDX )        /* next r                            */
 291     DEC_L     ( ESI )                   /* decrement vertex counter          */
 292
 293     JNZ       ( LLBL( G3TP3NRR_2 ) )    /* cnt > 0 ? -> process next vertex  */
 294
 295 LLBL( G3TP3NRR_3 ):
 296
 297     FEMMS
 298     POP_L     ( EDI )
 299     POP_L     ( ESI )
 300     RET
 301
 302
 303
 304
 305 ALIGNTEXT16
 306 GLOBL GLNAME( _mesa_3dnow_transform_points2_2d )
 307 GLNAME( _mesa_3dnow_transform_points2_2d ):
 308
 309     PUSH_L    ( ESI )
 310
 311     MOV_L     ( ARG_DEST, ECX )
 312     MOV_L     ( ARG_MATRIX, ESI )
 313     MOV_L     ( ARG_SOURCE, EAX )
 314     MOV_L     ( CONST(2), REGOFF(V4F_SIZE, ECX) )
 315     OR_B      ( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, ECX) )
 316     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 317     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 318
 319     PUSH_L    ( EDI )
 320
 321     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 322     MOV_L     ( ESI, ECX )
 323     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 324     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 325     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 326
 327     TEST_L    ( ESI, ESI )
 328     JZ        ( LLBL( G3TP2R_3 ) )
 329
 330     MOVQ      ( REGIND(ECX), MM0 )      /* m01             | m00             */
 331     MOVQ      ( REGOFF(16, ECX), MM1 )  /* m11             | m10             */
 332
 333     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 334
 335 ALIGNTEXT16
 336 LLBL( G3TP2R_2 ):
 337
 338     MOVD      ( REGIND(EAX), MM4 )      /*                 | x0              */
 339     MOVD      ( REGOFF(4, EAX), MM5 )   /*                 | x1              */
 340
 341     PUNPCKLDQ ( MM4, MM4 )              /* x0              | x0              */
 342     ADD_L     ( EDI, EAX )              /* next vertex                       */
 343
 344     PFMUL     ( MM0, MM4 )              /* x0*m01          | x0*m00          */
 345     PUNPCKLDQ ( MM5, MM5 )              /* x1              | x1              */
 346
 347     PFMUL     ( MM1, MM5 )              /* x1*m11          | x1*m10          */
 348     PFADD     ( MM2, MM4 )              /* x...x1*m11+31   | x0*..*m10+m30   */
 349
 350     PFADD     ( MM5, MM4 )              /* x0*m01+x1*m11   | x0*m00+x1*m10   */
 351     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 352
 353     ADD_L     ( CONST(16), EDX )        /* next r                            */
 354     DEC_L     ( ESI )                   /* decrement vertex counter          */
 355
 356     JNZ       ( LLBL( G3TP2R_2 ) )      /* cnt > 0 ? -> process next vertex  */
 357
 358 LLBL( G3TP2R_3 ):
 359
 360     FEMMS
 361     POP_L     ( EDI )
 362     POP_L     ( ESI )
 363     RET
 364
 365
 366
 367
 368 ALIGNTEXT16
 369 GLOBL GLNAME( _mesa_3dnow_transform_points2_2d_no_rot )
 370 GLNAME( _mesa_3dnow_transform_points2_2d_no_rot ):
 371
 372     PUSH_L    ( ESI )
 373
 374     MOV_L     ( ARG_DEST, ECX )
 375     MOV_L     ( ARG_MATRIX, ESI )
 376     MOV_L     ( ARG_SOURCE, EAX )
 377     MOV_L     ( CONST(2), REGOFF(V4F_SIZE, ECX) )
 378     OR_B      ( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, ECX) )
 379     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 380     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 381
 382     PUSH_L    ( EDI )
 383
 384     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 385     MOV_L     ( ESI, ECX )
 386     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 387     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 388     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 389
 390     TEST_L    ( ESI, ESI )
 391     JZ        ( LLBL( G3TP2NRR_3 ) )
 392
 393     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 394     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 395
 396     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 397
 398 ALIGNTEXT16
 399 LLBL( G3TP2NRR_2 ):
 400
 401     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 402     ADD_L     ( EDI, EAX )              /* next vertex                       */
 403
 404     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 405     PFADD     ( MM2, MM4 )              /* m31             | x0*m00+m30      */
 406
 407     MOVQ      ( MM4, REGIND(EDX) )      /* write r1, r0                      */
 408     ADD_L     ( CONST(16), EDX )        /* next r                            */
 409
 410     DEC_L     ( ESI )                   /* decrement vertex counter          */
 411     JNZ       ( LLBL( G3TP2NRR_2 ) )    /* cnt > 0 ? -> process next vertex  */
 412
 413 LLBL( G3TP2NRR_3 ):
 414
 415     FEMMS
 416     POP_L     ( EDI )
 417     POP_L     ( ESI )
 418     RET
 419
 420
 421
 422
 423 ALIGNTEXT16
 424 GLOBL GLNAME( _mesa_3dnow_transform_points2_identity )
 425 GLNAME( _mesa_3dnow_transform_points2_identity ):
 426
 427     PUSH_L    ( ESI )
 428
 429     MOV_L     ( ARG_DEST, ECX )
 430     MOV_L     ( ARG_MATRIX, ESI )
 431     MOV_L     ( ARG_SOURCE, EAX )
 432     MOV_L     ( CONST(2), REGOFF(V4F_SIZE, ECX) )
 433     OR_B      ( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, ECX) )
 434     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 435     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 436
 437     PUSH_L    ( EDI )
 438
 439     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 440     MOV_L     ( ESI, ECX )
 441     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 442     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 443     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 444
 445     TEST_L    ( ESI, ESI )
 446     JZ        ( LLBL( G3TPIR_3 ) )
 447
 448 ALIGNTEXT16
 449 LLBL( G3TPIR_3 ):
 450
 451     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
 452     ADD_L     ( EDI, EAX )              /* next vertex                       */
 453
 454     MOVQ      ( MM0, REGIND(EDX) )      /* r1              | r0              */
 455     ADD_L     ( CONST(16), EDX )        /* next r                            */
 456
 457     DEC_L     ( ESI )                   /* decrement vertex counter          */
 458     JNZ       ( LLBL( G3TPIR_3 ) )      /* cnt > 0 ? -> process next vertex  */
 459
 460 LLBL( G3TPIR_4 ):
 461
 462     FEMMS
 463     POP_L     ( EDI )
 464     POP_L     ( ESI )
 465     RET
 466 #endif