src/mesa/x86/3dnow_xform3.S

   1 /* $Id: 3dnow_xform3.S,v 1.3 2004/04/26 10:10:25 alanh Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #ifdef USE_3DNOW_ASM
  28 #include "matypes.h"
  29 #include "xform_args.h"
  30
  31     SEG_TEXT
  32
  33 #define FRAME_OFFSET    4
  34
  35
  36 ALIGNTEXT16
  37 GLOBL GLNAME( _mesa_3dnow_transform_points3_general )
  38 GLNAME( _mesa_3dnow_transform_points3_general ):
  39
  40     PUSH_L    ( ESI )
  41
  42     MOV_L     ( ARG_DEST, ECX )
  43     MOV_L     ( ARG_MATRIX, ESI )
  44     MOV_L     ( ARG_SOURCE, EAX )
  45     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
  46     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
  47     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
  48     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
  49
  50     PUSH_L    ( EDI )
  51
  52     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
  53     MOV_L     ( ESI, ECX )
  54     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
  55     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
  56     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
  57
  58     TEST_L    ( ESI, ESI )
  59     JZ        ( LLBL( G3TPGR_2 ) )
  60
  61     PREFETCHW ( REGIND(EDX) )
  62
  63 ALIGNTEXT16
  64 LLBL( G3TPGR_1 ):
  65
  66     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
  67
  68     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
  69     MOVD      ( REGOFF(8, EAX), MM2 )   /*                 | x2              */
  70
  71     ADD_L     ( EDI, EAX )              /* next vertex                       */
  72     PREFETCH  ( REGIND(EAX) )
  73
  74     MOVQ      ( MM0, MM1 )              /* x1              | x0              */
  75     PUNPCKLDQ ( MM2, MM2 )              /* x2              | x2              */
  76
  77     PUNPCKLDQ ( MM0, MM0 )              /* x0              | x0              */
  78     MOVQ      ( MM2, MM5 )              /* x2              | x2              */
  79
  80     PUNPCKHDQ ( MM1, MM1 )              /* x1              | x1              */
  81     PFMUL     ( REGOFF(32, ECX), MM2 )  /* x2*m9           | x2*m8           */
  82
  83     MOVQ      ( MM0, MM3 )              /* x0              | x0              */
  84     PFMUL     ( REGOFF(40, ECX), MM5 )  /* x2*m11          | x2*m10          */
  85
  86     MOVQ      ( MM1, MM4 )              /* x1              | x1              */
  87     PFMUL     ( REGIND(ECX), MM0 )      /* x0*m1           | x0*m0           */
  88
  89     PFADD     ( REGOFF(48, ECX), MM2 )  /* x2*m9+m13       | x2*m8+m12       */
  90     PFMUL     ( REGOFF(16, ECX), MM1 )  /* x1*m5           | x1*m4           */
  91
  92     PFADD     ( REGOFF(56, ECX), MM5 )  /* x2*m11+m15      | x2*m10+m14      */
  93     PFADD     ( MM0, MM1 )              /* x0*m1+x1*m5     | x0*m0+x1*m4     */
  94
  95     PFMUL     ( REGOFF(8, ECX), MM3 )   /* x0*m3           | x0*m2           */
  96     PFADD     ( MM1, MM2 )              /* r1              | r0              */
  97
  98     PFMUL     ( REGOFF(24, ECX), MM4 )  /* x1*m7           | x1*m6           */
  99     ADD_L     ( CONST(16), EDX )        /* next output vertex                */
 100
 101     PFADD     ( MM3, MM4 )              /* x0*m3+x1*m7     | x0*m2+x1*m6     */
 102     MOVQ      ( MM2, REGOFF(-16, EDX) ) /* write r0, r1                      */
 103
 104     PFADD     ( MM4, MM5 )              /* r3              | r2              */
 105     MOVQ      ( MM5, REGOFF(-8, EDX) )  /* write r2, r3                      */
 106
 107     DEC_L     ( ESI )                   /* decrement vertex counter          */
 108     JNZ       ( LLBL( G3TPGR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 109
 110 LLBL( G3TPGR_2 ):
 111
 112     FEMMS
 113     POP_L     ( EDI )
 114     POP_L     ( ESI )
 115     RET
 116
 117
 118
 119
 120 ALIGNTEXT16
 121 GLOBL GLNAME( _mesa_3dnow_transform_points3_perspective )
 122 GLNAME( _mesa_3dnow_transform_points3_perspective ):
 123
 124     PUSH_L    ( ESI )
 125
 126     MOV_L     ( ARG_DEST, ECX )
 127     MOV_L     ( ARG_MATRIX, ESI )
 128     MOV_L     ( ARG_SOURCE, EAX )
 129     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 130     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 131     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 132     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 133
 134     PUSH_L    ( EDI )
 135
 136     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 137     MOV_L     ( ESI, ECX )
 138     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 139     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 140     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 141
 142     TEST_L    ( ESI, ESI )
 143     JZ        ( LLBL( G3TPPR_2 ) )
 144
 145     PREFETCH  ( REGIND(EAX) )
 146     PREFETCHW ( REGIND(EDX) )
 147
 148     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 149     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 150
 151     MOVQ      ( REGOFF(32, ECX), MM1 )  /* m21             | m20             */
 152     MOVD      ( REGOFF(40, ECX), MM2 )  /*                 | m22             */
 153
 154     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 155
 156 ALIGNTEXT16
 157 LLBL( G3TPPR_1 ):
 158
 159     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 160
 161     MOVD      ( REGOFF(8, EAX), MM5 )   /*                 | x2              */
 162     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 163
 164     ADD_L     ( EDI, EAX )              /* next vertex                       */
 165     PREFETCH  ( REGIND(EAX) )
 166
 167     PXOR      ( MM7, MM7 )              /* 0               | 0               */
 168     MOVQ      ( MM5, MM6 )              /*                 | x2              */
 169
 170     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 171     PFSUB     ( MM5, MM7 )              /*                 | -x2             */
 172
 173     PFMUL     ( MM2, MM6 )              /*                 | x2*m22          */
 174     PUNPCKLDQ ( MM5, MM5 )              /* x2              | x2              */
 175
 176     ADD_L     ( CONST(16), EDX )        /* next r                            */
 177     PFMUL     ( MM1, MM5 )              /* x2*m21          | x2*m20          */
 178
 179     PFADD     ( MM3, MM6 )              /*                 | x2*m22+m32      */
 180     PFADD     ( MM4, MM5 )              /* x1*m11+x2*m21   | x0*m00+x2*m20   */
 181
 182     MOVQ      ( MM5, REGOFF(-16, EDX) ) /* write r0, r1                      */
 183     MOVD      ( MM6, REGOFF(-8, EDX) )  /* write r2                          */
 184
 185     MOVD      ( MM7, REGOFF(-4, EDX) )  /* write r3                          */
 186
 187     DEC_L     ( ESI )                   /* decrement vertex counter          */
 188     JNZ       ( LLBL( G3TPPR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 189
 190 LLBL( G3TPPR_2 ):
 191
 192     FEMMS
 193     POP_L     ( EDI )
 194     POP_L     ( ESI )
 195     RET
 196
 197
 198
 199
 200 ALIGNTEXT16
 201 GLOBL GLNAME( _mesa_3dnow_transform_points3_3d )
 202 GLNAME( _mesa_3dnow_transform_points3_3d ):
 203
 204     PUSH_L    ( ESI )
 205
 206     MOV_L     ( ARG_DEST, ECX )
 207     MOV_L     ( ARG_MATRIX, ESI )
 208     MOV_L     ( ARG_SOURCE, EAX )
 209     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 210     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 211     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 212     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 213
 214     PUSH_L    ( EDI )
 215
 216     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 217     MOV_L     ( ESI, ECX )
 218     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 219     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 220     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 221
 222     TEST_L    ( ESI, ESI )
 223     JZ        ( LLBL( G3TP3R_2 ) )
 224
 225     PREFETCH  ( REGIND(EAX) )
 226     PREFETCH  ( REGIND(EDX) )
 227
 228     MOVD      ( REGOFF(8, ECX), MM7 )   /*                 | m2              */
 229     PUNPCKLDQ ( REGOFF(24, ECX), MM7 )  /* m6              | m2              */
 230
 231
 232 ALIGNTEXT16
 233 LLBL( G3TP3R_1 ):
 234
 235     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 236
 237     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
 238     MOVD      ( REGOFF(8, EAX), MM1 )   /*                 | x2              */
 239
 240     ADD_L     ( EDI, EAX )              /* next vertex                       */
 241     PREFETCH  ( REGIND(EAX) )
 242
 243     MOVQ      ( MM0, MM2 )              /* x1              | x0              */
 244     ADD_L     ( CONST(16), EDX )        /* next r                            */
 245
 246     PUNPCKLDQ ( MM2, MM2 )              /* x0              | x0              */
 247     MOVQ      ( MM0, MM3 )              /* x1              | x0              */
 248
 249     PFMUL     ( REGIND(ECX), MM2 )      /* x0*m1           | x0*m0           */
 250     PUNPCKHDQ ( MM3, MM3 )              /* x1              | x1              */
 251
 252     MOVQ      ( MM1, MM4 )              /*                 | x2              */
 253     PFMUL     ( REGOFF(16, ECX), MM3 )  /* x1*m5           | x1*m4           */
 254
 255     PUNPCKLDQ ( MM4, MM4 )              /* x2              | x2              */
 256     PFADD     ( MM2, MM3 )              /* x0*m1+x1*m5     | x0*m0+x1*m4     */
 257
 258     PFMUL     ( REGOFF(32, ECX), MM4 )  /* x2*m9           | x2*m8           */
 259     PFADD     ( REGOFF(48, ECX), MM3 )  /* x0*m1+...+m11   | x0*m0+x1*m4+m12 */
 260
 261     PFMUL     ( MM7, MM0 )              /* x1*m6           | x0*m2           */
 262     PFADD     ( MM4, MM3 )              /* r1              | r0              */
 263
 264     PFMUL     ( REGOFF(40, ECX), MM1 )  /*                 | x2*m10          */
 265     PUNPCKLDQ ( REGOFF(56, ECX), MM1 )  /* m14             | x2*m10          */
 266
 267     PFACC     ( MM0, MM1 )
 268
 269     MOVQ      ( MM3, REGOFF(-16, EDX) ) /* write r0, r1                      */
 270     PFACC     ( MM1, MM1 )              /*                 | r2              */
 271
 272     MOVD      ( MM1, REGOFF(-8, EDX) )  /* write r2                          */
 273
 274     DEC_L     ( ESI )                   /* decrement vertex counter          */
 275     JNZ       ( LLBL( G3TP3R_1 ) )      /* cnt > 0 ? -> process next vertex  */
 276
 277 LLBL( G3TP3R_2 ):
 278
 279     FEMMS
 280     POP_L     ( EDI )
 281     POP_L     ( ESI )
 282     RET
 283
 284
 285
 286
 287 ALIGNTEXT16
 288 GLOBL GLNAME( _mesa_3dnow_transform_points3_3d_no_rot )
 289 GLNAME( _mesa_3dnow_transform_points3_3d_no_rot ):
 290
 291     PUSH_L    ( ESI )
 292
 293     MOV_L     ( ARG_DEST, ECX )
 294     MOV_L     ( ARG_MATRIX, ESI )
 295     MOV_L     ( ARG_SOURCE, EAX )
 296     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 297     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 298     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 299     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 300
 301     PUSH_L    ( EDI )
 302
 303     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 304     MOV_L     ( ESI, ECX )
 305     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 306     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 307     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 308
 309     TEST_L    ( ESI, ESI )
 310     JZ        ( LLBL( G3TP3NRR_2 ) )
 311
 312     PREFETCH  ( REGIND(EAX) )
 313     PREFETCHW ( REGIND(EDX) )
 314
 315     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 316     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 317
 318     MOVD      ( REGOFF(40, ECX), MM2 )  /*                 | m22             */
 319     PUNPCKLDQ ( MM2, MM2 )              /* m22             | m22             */
 320
 321     MOVQ      ( REGOFF(48, ECX), MM1 )  /* m31             | m30             */
 322     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 323
 324     PUNPCKLDQ ( MM3, MM3 )              /* m32             | m32             */
 325
 326
 327 ALIGNTEXT16
 328 LLBL( G3TP3NRR_1 ):
 329
 330     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 331
 332     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 333     MOVD      ( REGOFF(8, EAX), MM5 )   /*                 | x2              */
 334
 335     ADD_L     ( EDI, EAX )              /* next vertex                       */
 336     PREFETCHW ( REGIND(EAX) )
 337
 338     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 339
 340     PFADD     ( MM1, MM4 )              /* x1*m11+m31      | x0*m00+m30      */
 341     PFMUL     ( MM2, MM5 )              /*                 | x2*m22          */
 342
 343     PFADD     ( MM3, MM5 )              /*                 | x2*m22+m32      */
 344     MOVQ      ( MM4, REGIND(EDX) )      /* write r0, r1                      */
 345
 346     ADD_L     ( CONST(16), EDX )        /* next r                            */
 347     DEC_L     ( ESI )                   /* decrement vertex counter          */
 348
 349     MOVD      ( MM5, REGOFF(-8, EDX) )  /* write r2                          */
 350     JNZ       ( LLBL( G3TP3NRR_1 ) )    /* cnt > 0 ? -> process next vertex  */
 351
 352 LLBL( G3TP3NRR_2 ):
 353
 354     FEMMS
 355     POP_L     ( EDI )
 356     POP_L     ( ESI )
 357     RET
 358
 359
 360
 361
 362 ALIGNTEXT16
 363 GLOBL GLNAME( _mesa_3dnow_transform_points3_2d )
 364 GLNAME( _mesa_3dnow_transform_points3_2d ):
 365
 366     PUSH_L    ( ESI )
 367
 368     MOV_L     ( ARG_DEST, ECX )
 369     MOV_L     ( ARG_MATRIX, ESI )
 370     MOV_L     ( ARG_SOURCE, EAX )
 371     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 372     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 373     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 374     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 375
 376     PUSH_L    ( EDI )
 377
 378     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 379     MOV_L     ( ESI, ECX )
 380     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 381     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 382     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 383
 384     TEST_L    ( ESI, ESI )
 385     JZ        ( LLBL( G3TP2R_3) )
 386
 387     PREFETCH  ( REGIND(EAX) )
 388     PREFETCHW ( REGIND(EDX) )
 389
 390     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 391     PUNPCKLDQ ( REGOFF(16, ECX), MM0 )  /* m10             | m00             */
 392
 393     MOVD      ( REGOFF(4, ECX), MM1 )   /*                 | m01             */
 394     PUNPCKLDQ ( REGOFF(20, ECX), MM1 )  /* m11             | m01             */
 395
 396     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 397
 398 ALIGNTEXT16
 399 LLBL( G3TP2R_2 ):
 400
 401     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 402
 403     MOVQ      ( REGIND(EAX), MM3 )      /* x1              | x0              */
 404     MOVD      ( REGOFF(8, EAX), MM5 )   /*                 | x2              */
 405
 406     ADD_L     ( EDI, EAX )              /* next vertex                       */
 407     PREFETCH  ( REGIND(EAX) )
 408
 409     MOVQ      ( MM3, MM4 )              /* x1              | x0              */
 410     PFMUL     ( MM0, MM3 )              /* x1*m10          | x0*m00          */
 411
 412     ADD_L     ( CONST(16), EDX )        /* next r                            */
 413     PFMUL     ( MM1, MM4 )              /* x1*m11          | x0*m01          */
 414
 415     PFACC     ( MM4, MM3 )              /* x0*m00+x1*m10   | x0*m01+x1*m11   */
 416     MOVD      ( MM5, REGOFF(-8, EDX) )  /* write r2 (=x2)                    */
 417
 418     PFADD     ( MM2, MM3 )              /* x0*...*m10+m30  | x0*...*m11+m31  */
 419     MOVQ      ( MM3, REGOFF(-16, EDX) ) /* write r0, r1                      */
 420
 421     DEC_L     ( ESI )                   /* decrement vertex counter          */
 422     JNZ       ( LLBL( G3TP2R_2 ) )      /* cnt > 0 ? -> process next vertex  */
 423
 424 LLBL( G3TP2R_3 ):
 425
 426     FEMMS
 427     POP_L     ( EDI )
 428     POP_L     ( ESI )
 429     RET
 430
 431
 432
 433
 434 ALIGNTEXT16
 435 GLOBL GLNAME( _mesa_3dnow_transform_points3_2d_no_rot )
 436 GLNAME( _mesa_3dnow_transform_points3_2d_no_rot ):
 437
 438     PUSH_L    ( ESI )
 439
 440     MOV_L     ( ARG_DEST, ECX )
 441     MOV_L     ( ARG_MATRIX, ESI )
 442     MOV_L     ( ARG_SOURCE, EAX )
 443     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 444     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 445     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 446     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 447
 448     PUSH_L    ( EDI )
 449
 450     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 451     MOV_L     ( ESI, ECX )
 452     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 453     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 454     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 455
 456     TEST_L    ( ESI, ESI )
 457     JZ        ( LLBL( G3TP2NRR_2 ) )
 458
 459     PREFETCH  ( REGIND(EAX) )
 460     PREFETCHW ( REGIND(EDX) )
 461
 462     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 463     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 464
 465     MOVQ      ( REGOFF(48, ECX), MM1 )  /* m31             | m30             */
 466
 467
 468 ALIGNTEXT16
 469 LLBL( G3TP2NRR_1 ):
 470
 471     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 472
 473     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 474     MOVD      ( REGOFF(8, EAX), MM5 )   /*                 | x2              */
 475
 476     ADD_L     ( EDI, EAX )              /* next vertex                       */
 477     PREFETCH  ( REGIND(EAX) )
 478
 479     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 480     ADD_L     ( CONST(16), EDX )        /* next r                            */
 481
 482     PFADD     ( MM1, MM4 )              /* x1*m11+m31      | x0*m00+m30      */
 483
 484     MOVQ      ( MM4, REGOFF(-16, EDX) ) /* write r0, r1                      */
 485     MOVD      ( MM5, REGOFF(-8, EDX) )  /* write r2 (=x2)                    */
 486
 487     DEC_L     ( ESI )                   /* decrement vertex counter          */
 488     JNZ       ( LLBL( G3TP2NRR_1 ) )    /* cnt > 0 ? -> process next vertex  */
 489
 490 LLBL( G3TP2NRR_2 ):
 491
 492     FEMMS
 493     POP_L     ( EDI )
 494     POP_L     ( ESI )
 495     RET
 496
 497
 498
 499
 500 ALIGNTEXT16
 501 GLOBL GLNAME( _mesa_3dnow_transform_points3_identity )
 502 GLNAME( _mesa_3dnow_transform_points3_identity ):
 503
 504     PUSH_L    ( ESI )
 505
 506     MOV_L     ( ARG_DEST, ECX )
 507     MOV_L     ( ARG_MATRIX, ESI )
 508     MOV_L     ( ARG_SOURCE, EAX )
 509     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 510     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 511     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 512     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 513
 514     PUSH_L    ( EDI )
 515
 516     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 517     MOV_L     ( ESI, ECX )
 518     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 519     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 520     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 521
 522     TEST_L    ( ESI, ESI )
 523     JZ        ( LLBL( G3TPIR_2 ) )
 524
 525     PREFETCHW ( REGIND(EDX) )
 526
 527 ALIGNTEXT16
 528 LLBL( G3TPIR_1 ):
 529
 530     PREFETCHW ( REGOFF(32, EDX) )
 531
 532     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
 533     MOVD      ( REGOFF(8, EAX), MM1 )   /*                 | x2              */
 534
 535     ADD_L     ( EDI, EAX )              /* next vertex                       */
 536     ADD_L     ( CONST(16), EDX )        /* next r                            */
 537
 538     DEC_L     ( ESI )                   /* decrement vertex counter          */
 539     MOVQ      ( MM0, REGOFF(-16, EDX) ) /* r1              | r0              */
 540
 541     MOVD      ( MM1, REGOFF(-8, EDX) )  /*                 | r2              */
 542     JNZ       ( LLBL( G3TPIR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 543
 544 LLBL( G3TPIR_2 ):
 545
 546     FEMMS
 547     POP_L     ( EDI )
 548     POP_L     ( ESI )
 549     RET
 550 #endif