src/mesa/x86/3dnow_xform3.S

   1 /* $Id: 3dnow_xform3.S,v 1.2 2001/10/22 01:21:16 brianp Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #include "matypes.h"
  28 #include "xform_args.h"
  29
  30     SEG_TEXT
  31
  32 #define FRAME_OFFSET    4
  33
  34
  35 ALIGNTEXT16
  36 GLOBL GLNAME( _mesa_3dnow_transform_points3_general )
  37 GLNAME( _mesa_3dnow_transform_points3_general ):
  38
  39     PUSH_L    ( ESI )
  40
  41     MOV_L     ( ARG_DEST, ECX )
  42     MOV_L     ( ARG_MATRIX, ESI )
  43     MOV_L     ( ARG_SOURCE, EAX )
  44     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
  45     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
  46     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
  47     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
  48
  49     PUSH_L    ( EDI )
  50
  51     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
  52     MOV_L     ( ESI, ECX )
  53     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
  54     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
  55     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
  56
  57     TEST_L    ( ESI, ESI )
  58     JZ        ( LLBL( G3TPGR_2 ) )
  59
  60     PREFETCHW ( REGIND(EDX) )
  61
  62 ALIGNTEXT16
  63 LLBL( G3TPGR_1 ):
  64
  65     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
  66
  67     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
  68     MOVD      ( REGOFF(8, EAX), MM2 )   /*                 | x2              */
  69
  70     ADD_L     ( EDI, EAX )              /* next vertex                       */
  71     PREFETCH  ( REGIND(EAX) )
  72
  73     MOVQ      ( MM0, MM1 )              /* x1              | x0              */
  74     PUNPCKLDQ ( MM2, MM2 )              /* x2              | x2              */
  75
  76     PUNPCKLDQ ( MM0, MM0 )              /* x0              | x0              */
  77     MOVQ      ( MM2, MM5 )              /* x2              | x2              */
  78
  79     PUNPCKHDQ ( MM1, MM1 )              /* x1              | x1              */
  80     PFMUL     ( REGOFF(32, ECX), MM2 )  /* x2*m9           | x2*m8           */
  81
  82     MOVQ      ( MM0, MM3 )              /* x0              | x0              */
  83     PFMUL     ( REGOFF(40, ECX), MM5 )  /* x2*m11          | x2*m10          */
  84
  85     MOVQ      ( MM1, MM4 )              /* x1              | x1              */
  86     PFMUL     ( REGIND(ECX), MM0 )      /* x0*m1           | x0*m0           */
  87
  88     PFADD     ( REGOFF(48, ECX), MM2 )  /* x2*m9+m13       | x2*m8+m12       */
  89     PFMUL     ( REGOFF(16, ECX), MM1 )  /* x1*m5           | x1*m4           */
  90
  91     PFADD     ( REGOFF(56, ECX), MM5 )  /* x2*m11+m15      | x2*m10+m14      */
  92     PFADD     ( MM0, MM1 )              /* x0*m1+x1*m5     | x0*m0+x1*m4     */
  93
  94     PFMUL     ( REGOFF(8, ECX), MM3 )   /* x0*m3           | x0*m2           */
  95     PFADD     ( MM1, MM2 )              /* r1              | r0              */
  96
  97     PFMUL     ( REGOFF(24, ECX), MM4 )  /* x1*m7           | x1*m6           */
  98     ADD_L     ( CONST(16), EDX )        /* next output vertex                */
  99
 100     PFADD     ( MM3, MM4 )              /* x0*m3+x1*m7     | x0*m2+x1*m6     */
 101     MOVQ      ( MM2, REGOFF(-16, EDX) ) /* write r0, r1                      */
 102
 103     PFADD     ( MM4, MM5 )              /* r3              | r2              */
 104     MOVQ      ( MM5, REGOFF(-8, EDX) )  /* write r2, r3                      */
 105
 106     DEC_L     ( ESI )                   /* decrement vertex counter          */
 107     JNZ       ( LLBL( G3TPGR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 108
 109 LLBL( G3TPGR_2 ):
 110
 111     FEMMS
 112     POP_L     ( EDI )
 113     POP_L     ( ESI )
 114     RET
 115
 116
 117
 118
 119 ALIGNTEXT16
 120 GLOBL GLNAME( _mesa_3dnow_transform_points3_perspective )
 121 GLNAME( _mesa_3dnow_transform_points3_perspective ):
 122
 123     PUSH_L    ( ESI )
 124
 125     MOV_L     ( ARG_DEST, ECX )
 126     MOV_L     ( ARG_MATRIX, ESI )
 127     MOV_L     ( ARG_SOURCE, EAX )
 128     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 129     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 130     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 131     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 132
 133     PUSH_L    ( EDI )
 134
 135     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 136     MOV_L     ( ESI, ECX )
 137     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 138     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 139     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 140
 141     TEST_L    ( ESI, ESI )
 142     JZ        ( LLBL( G3TPPR_2 ) )
 143
 144     PREFETCH  ( REGIND(EAX) )
 145     PREFETCHW ( REGIND(EDX) )
 146
 147     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 148     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 149
 150     MOVQ      ( REGOFF(32, ECX), MM1 )  /* m21             | m20             */
 151     MOVD      ( REGOFF(40, ECX), MM2 )  /*                 | m22             */
 152
 153     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 154
 155 ALIGNTEXT16
 156 LLBL( G3TPPR_1 ):
 157
 158     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 159
 160     MOVD      ( REGOFF(8, EAX), MM5 )   /*                 | x2              */
 161     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 162
 163     ADD_L     ( EDI, EAX )              /* next vertex                       */
 164     PREFETCH  ( REGIND(EAX) )
 165
 166     PXOR      ( MM7, MM7 )              /* 0               | 0               */
 167     MOVQ      ( MM5, MM6 )              /*                 | x2              */
 168
 169     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 170     PFSUB     ( MM5, MM7 )              /*                 | -x2             */
 171
 172     PFMUL     ( MM2, MM6 )              /*                 | x2*m22          */
 173     PUNPCKLDQ ( MM5, MM5 )              /* x2              | x2              */
 174
 175     ADD_L     ( CONST(16), EDX )        /* next r                            */
 176     PFMUL     ( MM1, MM5 )              /* x2*m21          | x2*m20          */
 177
 178     PFADD     ( MM3, MM6 )              /*                 | x2*m22+m32      */
 179     PFADD     ( MM4, MM5 )              /* x1*m11+x2*m21   | x0*m00+x2*m20   */
 180
 181     MOVQ      ( MM5, REGOFF(-16, EDX) ) /* write r0, r1                      */
 182     MOVD      ( MM6, REGOFF(-8, EDX) )  /* write r2                          */
 183
 184     MOVD      ( MM7, REGOFF(-4, EDX) )  /* write r3                          */
 185
 186     DEC_L     ( ESI )                   /* decrement vertex counter          */
 187     JNZ       ( LLBL( G3TPPR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 188
 189 LLBL( G3TPPR_2 ):
 190
 191     FEMMS
 192     POP_L     ( EDI )
 193     POP_L     ( ESI )
 194     RET
 195
 196
 197
 198
 199 ALIGNTEXT16
 200 GLOBL GLNAME( _mesa_3dnow_transform_points3_3d )
 201 GLNAME( _mesa_3dnow_transform_points3_3d ):
 202
 203     PUSH_L    ( ESI )
 204
 205     MOV_L     ( ARG_DEST, ECX )
 206     MOV_L     ( ARG_MATRIX, ESI )
 207     MOV_L     ( ARG_SOURCE, EAX )
 208     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 209     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 210     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 211     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 212
 213     PUSH_L    ( EDI )
 214
 215     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 216     MOV_L     ( ESI, ECX )
 217     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 218     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 219     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 220
 221     TEST_L    ( ESI, ESI )
 222     JZ        ( LLBL( G3TP3R_2 ) )
 223
 224     PREFETCH  ( REGIND(EAX) )
 225     PREFETCH  ( REGIND(EDX) )
 226
 227     MOVD      ( REGOFF(8, ECX), MM7 )   /*                 | m2              */
 228     PUNPCKLDQ ( REGOFF(24, ECX), MM7 )  /* m6              | m2              */
 229
 230
 231 ALIGNTEXT16
 232 LLBL( G3TP3R_1 ):
 233
 234     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 235
 236     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
 237     MOVD      ( REGOFF(8, EAX), MM1 )   /*                 | x2              */
 238
 239     ADD_L     ( EDI, EAX )              /* next vertex                       */
 240     PREFETCH  ( REGIND(EAX) )
 241
 242     MOVQ      ( MM0, MM2 )              /* x1              | x0              */
 243     ADD_L     ( CONST(16), EDX )        /* next r                            */
 244
 245     PUNPCKLDQ ( MM2, MM2 )              /* x0              | x0              */
 246     MOVQ      ( MM0, MM3 )              /* x1              | x0              */
 247
 248     PFMUL     ( REGIND(ECX), MM2 )      /* x0*m1           | x0*m0           */
 249     PUNPCKHDQ ( MM3, MM3 )              /* x1              | x1              */
 250
 251     MOVQ      ( MM1, MM4 )              /*                 | x2              */
 252     PFMUL     ( REGOFF(16, ECX), MM3 )  /* x1*m5           | x1*m4           */
 253
 254     PUNPCKLDQ ( MM4, MM4 )              /* x2              | x2              */
 255     PFADD     ( MM2, MM3 )              /* x0*m1+x1*m5     | x0*m0+x1*m4     */
 256
 257     PFMUL     ( REGOFF(32, ECX), MM4 )  /* x2*m9           | x2*m8           */
 258     PFADD     ( REGOFF(48, ECX), MM3 )  /* x0*m1+...+m11   | x0*m0+x1*m4+m12 */
 259
 260     PFMUL     ( MM7, MM0 )              /* x1*m6           | x0*m2           */
 261     PFADD     ( MM4, MM3 )              /* r1              | r0              */
 262
 263     PFMUL     ( REGOFF(40, ECX), MM1 )  /*                 | x2*m10          */
 264     PUNPCKLDQ ( REGOFF(56, ECX), MM1 )  /* m14             | x2*m10          */
 265
 266     PFACC     ( MM0, MM1 )
 267
 268     MOVQ      ( MM3, REGOFF(-16, EDX) ) /* write r0, r1                      */
 269     PFACC     ( MM1, MM1 )              /*                 | r2              */
 270
 271     MOVD      ( MM1, REGOFF(-8, EDX) )  /* write r2                          */
 272
 273     DEC_L     ( ESI )                   /* decrement vertex counter          */
 274     JNZ       ( LLBL( G3TP3R_1 ) )      /* cnt > 0 ? -> process next vertex  */
 275
 276 LLBL( G3TP3R_2 ):
 277
 278     FEMMS
 279     POP_L     ( EDI )
 280     POP_L     ( ESI )
 281     RET
 282
 283
 284
 285
 286 ALIGNTEXT16
 287 GLOBL GLNAME( _mesa_3dnow_transform_points3_3d_no_rot )
 288 GLNAME( _mesa_3dnow_transform_points3_3d_no_rot ):
 289
 290     PUSH_L    ( ESI )
 291
 292     MOV_L     ( ARG_DEST, ECX )
 293     MOV_L     ( ARG_MATRIX, ESI )
 294     MOV_L     ( ARG_SOURCE, EAX )
 295     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 296     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 297     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 298     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 299
 300     PUSH_L    ( EDI )
 301
 302     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 303     MOV_L     ( ESI, ECX )
 304     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 305     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 306     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 307
 308     TEST_L    ( ESI, ESI )
 309     JZ        ( LLBL( G3TP3NRR_2 ) )
 310
 311     PREFETCH  ( REGIND(EAX) )
 312     PREFETCHW ( REGIND(EDX) )
 313
 314     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 315     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 316
 317     MOVD      ( REGOFF(40, ECX), MM2 )  /*                 | m22             */
 318     PUNPCKLDQ ( MM2, MM2 )              /* m22             | m22             */
 319
 320     MOVQ      ( REGOFF(48, ECX), MM1 )  /* m31             | m30             */
 321     MOVD      ( REGOFF(56, ECX), MM3 )  /*                 | m32             */
 322
 323     PUNPCKLDQ ( MM3, MM3 )              /* m32             | m32             */
 324
 325
 326 ALIGNTEXT16
 327 LLBL( G3TP3NRR_1 ):
 328
 329     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 330
 331     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 332     MOVD      ( REGOFF(8, EAX), MM5 )   /*                 | x2              */
 333
 334     ADD_L     ( EDI, EAX )              /* next vertex                       */
 335     PREFETCHW ( REGIND(EAX) )
 336
 337     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 338
 339     PFADD     ( MM1, MM4 )              /* x1*m11+m31      | x0*m00+m30      */
 340     PFMUL     ( MM2, MM5 )              /*                 | x2*m22          */
 341
 342     PFADD     ( MM3, MM5 )              /*                 | x2*m22+m32      */
 343     MOVQ      ( MM4, REGIND(EDX) )      /* write r0, r1                      */
 344
 345     ADD_L     ( CONST(16), EDX )        /* next r                            */
 346     DEC_L     ( ESI )                   /* decrement vertex counter          */
 347
 348     MOVD      ( MM5, REGOFF(-8, EDX) )  /* write r2                          */
 349     JNZ       ( LLBL( G3TP3NRR_1 ) )    /* cnt > 0 ? -> process next vertex  */
 350
 351 LLBL( G3TP3NRR_2 ):
 352
 353     FEMMS
 354     POP_L     ( EDI )
 355     POP_L     ( ESI )
 356     RET
 357
 358
 359
 360
 361 ALIGNTEXT16
 362 GLOBL GLNAME( _mesa_3dnow_transform_points3_2d )
 363 GLNAME( _mesa_3dnow_transform_points3_2d ):
 364
 365     PUSH_L    ( ESI )
 366
 367     MOV_L     ( ARG_DEST, ECX )
 368     MOV_L     ( ARG_MATRIX, ESI )
 369     MOV_L     ( ARG_SOURCE, EAX )
 370     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 371     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 372     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 373     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 374
 375     PUSH_L    ( EDI )
 376
 377     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 378     MOV_L     ( ESI, ECX )
 379     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 380     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 381     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 382
 383     TEST_L    ( ESI, ESI )
 384     JZ        ( LLBL( G3TP2R_3) )
 385
 386     PREFETCH  ( REGIND(EAX) )
 387     PREFETCHW ( REGIND(EDX) )
 388
 389     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 390     PUNPCKLDQ ( REGOFF(16, ECX), MM0 )  /* m10             | m00             */
 391
 392     MOVD      ( REGOFF(4, ECX), MM1 )   /*                 | m01             */
 393     PUNPCKLDQ ( REGOFF(20, ECX), MM1 )  /* m11             | m01             */
 394
 395     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 396
 397 ALIGNTEXT16
 398 LLBL( G3TP2R_2 ):
 399
 400     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 401
 402     MOVQ      ( REGIND(EAX), MM3 )      /* x1              | x0              */
 403     MOVD      ( REGOFF(8, EAX), MM5 )   /*                 | x2              */
 404
 405     ADD_L     ( EDI, EAX )              /* next vertex                       */
 406     PREFETCH  ( REGIND(EAX) )
 407
 408     MOVQ      ( MM3, MM4 )              /* x1              | x0              */
 409     PFMUL     ( MM0, MM3 )              /* x1*m10          | x0*m00          */
 410
 411     ADD_L     ( CONST(16), EDX )        /* next r                            */
 412     PFMUL     ( MM1, MM4 )              /* x1*m11          | x0*m01          */
 413
 414     PFACC     ( MM4, MM3 )              /* x0*m00+x1*m10   | x0*m01+x1*m11   */
 415     MOVD      ( MM5, REGOFF(-8, EDX) )  /* write r2 (=x2)                    */
 416
 417     PFADD     ( MM2, MM3 )              /* x0*...*m10+m30  | x0*...*m11+m31  */
 418     MOVQ      ( MM3, REGOFF(-16, EDX) ) /* write r0, r1                      */
 419
 420     DEC_L     ( ESI )                   /* decrement vertex counter          */
 421     JNZ       ( LLBL( G3TP2R_2 ) )      /* cnt > 0 ? -> process next vertex  */
 422
 423 LLBL( G3TP2R_3 ):
 424
 425     FEMMS
 426     POP_L     ( EDI )
 427     POP_L     ( ESI )
 428     RET
 429
 430
 431
 432
 433 ALIGNTEXT16
 434 GLOBL GLNAME( _mesa_3dnow_transform_points3_2d_no_rot )
 435 GLNAME( _mesa_3dnow_transform_points3_2d_no_rot ):
 436
 437     PUSH_L    ( ESI )
 438
 439     MOV_L     ( ARG_DEST, ECX )
 440     MOV_L     ( ARG_MATRIX, ESI )
 441     MOV_L     ( ARG_SOURCE, EAX )
 442     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 443     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 444     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 445     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 446
 447     PUSH_L    ( EDI )
 448
 449     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 450     MOV_L     ( ESI, ECX )
 451     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 452     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 453     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 454
 455     TEST_L    ( ESI, ESI )
 456     JZ        ( LLBL( G3TP2NRR_2 ) )
 457
 458     PREFETCH  ( REGIND(EAX) )
 459     PREFETCHW ( REGIND(EDX) )
 460
 461     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 462     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 463
 464     MOVQ      ( REGOFF(48, ECX), MM1 )  /* m31             | m30             */
 465
 466
 467 ALIGNTEXT16
 468 LLBL( G3TP2NRR_1 ):
 469
 470     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 471
 472     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 473     MOVD      ( REGOFF(8, EAX), MM5 )   /*                 | x2              */
 474
 475     ADD_L     ( EDI, EAX )              /* next vertex                       */
 476     PREFETCH  ( REGIND(EAX) )
 477
 478     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 479     ADD_L     ( CONST(16), EDX )        /* next r                            */
 480
 481     PFADD     ( MM1, MM4 )              /* x1*m11+m31      | x0*m00+m30      */
 482
 483     MOVQ      ( MM4, REGOFF(-16, EDX) ) /* write r0, r1                      */
 484     MOVD      ( MM5, REGOFF(-8, EDX) )  /* write r2 (=x2)                    */
 485
 486     DEC_L     ( ESI )                   /* decrement vertex counter          */
 487     JNZ       ( LLBL( G3TP2NRR_1 ) )    /* cnt > 0 ? -> process next vertex  */
 488
 489 LLBL( G3TP2NRR_2 ):
 490
 491     FEMMS
 492     POP_L     ( EDI )
 493     POP_L     ( ESI )
 494     RET
 495
 496
 497
 498
 499 ALIGNTEXT16
 500 GLOBL GLNAME( _mesa_3dnow_transform_points3_identity )
 501 GLNAME( _mesa_3dnow_transform_points3_identity ):
 502
 503     PUSH_L    ( ESI )
 504
 505     MOV_L     ( ARG_DEST, ECX )
 506     MOV_L     ( ARG_MATRIX, ESI )
 507     MOV_L     ( ARG_SOURCE, EAX )
 508     MOV_L     ( CONST(3), REGOFF(V4F_SIZE, ECX) )
 509     OR_B      ( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, ECX) )
 510     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 511     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 512
 513     PUSH_L    ( EDI )
 514
 515     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 516     MOV_L     ( ESI, ECX )
 517     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 518     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 519     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 520
 521     TEST_L    ( ESI, ESI )
 522     JZ        ( LLBL( G3TPIR_2 ) )
 523
 524     PREFETCHW ( REGIND(EDX) )
 525
 526 ALIGNTEXT16
 527 LLBL( G3TPIR_1 ):
 528
 529     PREFETCHW ( REGOFF(32, EDX) )
 530
 531     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
 532     MOVD      ( REGOFF(8, EAX), MM1 )   /*                 | x2              */
 533
 534     ADD_L     ( EDI, EAX )              /* next vertex                       */
 535     ADD_L     ( CONST(16), EDX )        /* next r                            */
 536
 537     DEC_L     ( ESI )                   /* decrement vertex counter          */
 538     MOVQ      ( MM0, REGOFF(-16, EDX) ) /* r1              | r0              */
 539
 540     MOVD      ( MM1, REGOFF(-8, EDX) )  /*                 | r2              */
 541     JNZ       ( LLBL( G3TPIR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 542
 543 LLBL( G3TPIR_2 ):
 544
 545     FEMMS
 546     POP_L     ( EDI )
 547     POP_L     ( ESI )
 548     RET