src/mesa/x86/3dnow_xform4.S

   1 /* $Id: 3dnow_xform4.S,v 1.1 2001/03/29 06:46:16 gareth Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #include "matypes.h"
  28 #include "xform_args.h"
  29
  30     SEG_TEXT
  31
  32 #define FRAME_OFFSET    4
  33
  34
  35 ALIGNTEXT16
  36 GLOBL GLNAME( _mesa_3dnow_transform_points4_general )
  37 GLNAME( _mesa_3dnow_transform_points4_general ):
  38
  39     PUSH_L    ( ESI )
  40
  41     MOV_L     ( ARG_DEST, ECX )
  42     MOV_L     ( ARG_MATRIX, ESI )
  43     MOV_L     ( ARG_SOURCE, EAX )
  44     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
  45     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
  46     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
  47     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
  48
  49     PUSH_L    ( EDI )
  50
  51     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
  52     MOV_L     ( ESI, ECX )
  53     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
  54     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
  55     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
  56
  57     TEST_L    ( ESI, ESI )
  58     JZ        ( LLBL( G3TPGR_2 ) )
  59
  60     PREFETCHW ( REGIND(EDX) )
  61
  62     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
  63     MOVQ      ( REGOFF(8, EAX), MM4 )   /* x3              | x2              */
  64
  65     ADD_L     ( EDI, EAX )              /* next vertex                       */
  66
  67 ALIGNTEXT16
  68 LLBL( G3TPGR_1 ):
  69
  70     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
  71     PREFETCH  ( REGIND(EAX) )
  72
  73     MOVQ      ( MM0, MM2 )              /* x1              | x0              */
  74     MOVQ      ( MM4, MM6 )              /* x3              | x2              */
  75
  76     PUNPCKLDQ ( MM0, MM0 )              /* x0              | x0              */
  77     PUNPCKHDQ ( MM2, MM2 )              /* x1              | x1              */
  78
  79     MOVQ      ( MM0, MM1 )              /* x0              | x0              */
  80     ADD_L     ( CONST(16), EDX )        /* next r                            */
  81
  82     PFMUL     ( REGIND(ECX), MM0 )      /* x0*m1           | x0*m0           */
  83     MOVQ      ( MM2, MM3 )              /* x1              | x1              */
  84
  85     PFMUL     ( REGOFF(8, ECX), MM1 )   /* x0*m3           | x0*m2           */
  86     PUNPCKLDQ ( MM4, MM4 )              /* x2              | x2              */
  87
  88     PFMUL     ( REGOFF(16, ECX), MM2 )  /* x1*m5           | x1*m4           */
  89     MOVQ      ( MM4, MM5 )              /* x2              | x2              */
  90
  91     PFMUL     ( REGOFF(24, ECX), MM3 )  /* x1*m7           | x1*m6           */
  92     PUNPCKHDQ ( MM6, MM6 )              /* x3              | x3              */
  93
  94     PFMUL     ( REGOFF(32, ECX), MM4 )  /* x2*m9           | x2*m8           */
  95     MOVQ      ( MM6, MM7 )              /* x3              | x3              */
  96
  97     PFMUL     ( REGOFF(40, ECX), MM5 )  /* x2*m11          | x2*m10          */
  98     PFADD     ( MM0, MM2 )
  99
 100     PFMUL     ( REGOFF(48, ECX), MM6 )  /* x3*m13          | x3*m12          */
 101     PFADD     ( MM1, MM3 )
 102
 103     PFMUL     ( REGOFF(56, ECX), MM7 )  /* x3*m15          | x3*m14          */
 104     PFADD     ( MM4, MM6 )
 105
 106     PFADD     ( MM5, MM7 )
 107     PFADD     ( MM2, MM6 )
 108
 109     PFADD     ( MM3, MM7 )
 110     MOVQ      ( MM6, REGOFF(-16, EDX) )
 111
 112     MOVQ      ( MM7, REGOFF(-8, EDX) )
 113     MOVQ      ( REGIND(EAX), MM0 )      /* x1            | x0                */
 114
 115     MOVQ      ( REGOFF(8, EAX), MM4 )   /* x3            | x2                */
 116     ADD_L     ( EDI, EAX )              /* next vertex                       */
 117
 118     DEC_L     ( ESI )                   /* decrement vertex counter          */
 119     JNZ       ( LLBL( G3TPGR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 120
 121 LLBL( G3TPGR_2 ):
 122
 123     FEMMS
 124     POP_L     ( EDI )
 125     POP_L     ( ESI )
 126     RET
 127
 128
 129
 130
 131 ALIGNTEXT16
 132 GLOBL GLNAME( _mesa_3dnow_transform_points4_perspective )
 133 GLNAME( _mesa_3dnow_transform_points4_perspective ):
 134
 135     PUSH_L    ( ESI )
 136
 137     MOV_L     ( ARG_DEST, ECX )
 138     MOV_L     ( ARG_MATRIX, ESI )
 139     MOV_L     ( ARG_SOURCE, EAX )
 140     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 141     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 142     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 143     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 144
 145     PUSH_L    ( EDI )
 146
 147     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 148     MOV_L     ( ESI, ECX )
 149     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 150     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 151     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 152
 153     TEST_L    ( ESI, ESI )
 154     JZ        ( LLBL( G3TPPR_2 ) )
 155
 156     PREFETCH  ( REGIND(EAX) )
 157     PREFETCHW ( REGIND(EDX) )
 158
 159     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 160     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 161
 162     MOVD      ( REGOFF(40, ECX), MM1 )  /*                 | m22             */
 163     PUNPCKLDQ ( REGOFF(56, ECX), MM1 )  /* m32             | m22             */
 164
 165     MOVQ      ( REGOFF(32, ECX), MM2 )  /* m21             | m20             */
 166     PXOR      ( MM7, MM7 )              /* 0               | 0               */
 167
 168     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 169     MOVQ      ( REGOFF(8, EAX), MM5 )   /* x3              | x2              */
 170     MOVD      ( REGOFF(8, EAX), MM3 )   /*                 | x2              */
 171
 172     ADD_L     ( EDI, EAX )              /* next vertex                       */
 173
 174 ALIGNTEXT16
 175 LLBL( G3TPPR_1 ):
 176
 177     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 178     PREFETCH  ( REGOFF(32, EAX) )       /* hopefully stride is zero          */
 179
 180     MOVQ      ( MM5, MM6 )              /* x3              | x2              */
 181     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 182
 183     PUNPCKLDQ ( MM5, MM5 )              /* x2              | x2              */
 184     ADD_L     ( CONST(16), EDX )        /* next r                            */
 185
 186     PFMUL     ( MM2, MM5 )              /* x2*m21          | x2*m20          */
 187     PFSUBR    ( MM7, MM3 )              /*                 | -x2             */
 188
 189     PFMUL     ( MM1, MM6 )              /* x3*m32          | x2*m22          */
 190     PFADD     ( MM4, MM5 )              /* x1*m11+x2*m21   | x0*m00+x2*m20   */
 191
 192     PFACC     ( MM3, MM6 )              /* -x2             | x2*m22+x3*m32   */
 193     MOVQ      ( MM5, REGOFF(-16, EDX) ) /* write r0, r1                      */
 194
 195     MOVQ      ( MM6, REGOFF(-8, EDX) )  /* write r2, r3                      */
 196     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 197
 198     MOVQ      ( REGOFF(8, EAX), MM5 )   /* x3              | x2              */
 199     MOVD      ( REGOFF(8, EAX), MM3 )   /*                 | x2              */
 200
 201     ADD_L     ( EDI, EAX )              /* next vertex                       */
 202     DEC_L     ( ESI )                   /* decrement vertex counter          */
 203
 204     JNZ       ( LLBL( G3TPPR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 205
 206 LLBL( G3TPPR_2 ):
 207
 208     FEMMS
 209     POP_L     ( EDI )
 210     POP_L     ( ESI )
 211     RET
 212
 213
 214
 215
 216 ALIGNTEXT16
 217 GLOBL GLNAME( _mesa_3dnow_transform_points4_3d )
 218 GLNAME( _mesa_3dnow_transform_points4_3d ):
 219
 220     PUSH_L    ( ESI )
 221
 222     MOV_L     ( ARG_DEST, ECX )
 223     MOV_L     ( ARG_MATRIX, ESI )
 224     MOV_L     ( ARG_SOURCE, EAX )
 225     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 226     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 227     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 228     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 229
 230     PUSH_L    ( EDI )
 231
 232     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 233     MOV_L     ( ESI, ECX )
 234     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 235     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 236     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 237
 238     TEST_L    ( ESI, ESI )
 239     JZ        ( LLBL( G3TP3R_2 ) )
 240
 241     MOVD      ( REGOFF(8, ECX), MM6 )   /*                 | m2              */
 242     PUNPCKLDQ ( REGOFF(24, ECX), MM6 )  /* m6              | m2              */
 243
 244     MOVD      ( REGOFF(40, ECX), MM7 )  /*                 | m10             */
 245     PUNPCKLDQ ( REGOFF(56, ECX), MM7 )  /* m14             | m10             */
 246
 247     MOVQ      ( REGIND(EAX), MM2 )      /* x1              | x0              */
 248     MOVQ      ( REGOFF(8, EAX), MM3 )   /* x3              | x2              */
 249
 250 ALIGNTEXT16
 251 LLBL( G3TP3R_1 ):
 252
 253     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 254     PREFETCH  ( REGOFF(32, EAX) )       /* hopefully array is tightly packed */
 255
 256     MOVQ      ( MM2, MM0 )              /* x1              | x0              */
 257     MOVQ      ( MM3, MM4 )              /* x3              | x2              */
 258
 259     MOVQ      ( MM0, MM1 )              /* x1              | x0              */
 260     MOVQ      ( MM4, MM5 )              /* x3              | x2              */
 261
 262     PUNPCKLDQ ( MM0, MM0 )              /* x0              | x0              */
 263     PUNPCKHDQ ( MM1, MM1 )              /* x1              | x1              */
 264
 265     PFMUL     ( REGIND(ECX), MM0 )      /* x0*m1           | x0*m0           */
 266     PUNPCKLDQ ( MM3, MM3 )              /* x2              | x2              */
 267
 268     PFMUL     ( REGOFF(16, ECX), MM1 )  /* x1*m5           | x1*m4           */
 269     PUNPCKHDQ ( MM4, MM4 )              /* x3              | x3              */
 270
 271     PFMUL     ( MM6, MM2 )              /* x1*m6           | x0*m2           */
 272     PFADD     ( MM0, MM1 )              /* x0*m1+x1*m5     | x0*m0+x1*m4     */
 273
 274     PFMUL     ( REGOFF(32, ECX), MM3 )  /* x2*m9           | x2*m8           */
 275     ADD_L     ( CONST(16), EDX )        /* next r                            */
 276
 277     PFMUL     ( REGOFF(48, ECX), MM4 )  /* x3*m13          | x3*m12          */
 278     PFADD     ( MM1, MM3 )              /* x0*m1+..+x2*m9  | x0*m0+...+x2*m8 */
 279
 280     PFMUL     ( MM7, MM5 )              /* x3*m14          | x2*m10          */
 281     PFADD     ( MM3, MM4 )              /* r1              | r0              */
 282
 283     PFACC     ( MM2, MM5 )              /* x0*m2+x1*m6     | x2*m10+x3*m14   */
 284     MOVD      ( REGOFF(12, EAX), MM0 )  /*                 | x3              */
 285
 286     ADD_L     ( EDI, EAX )              /* next vertex                       */
 287     PFACC     ( MM0, MM5 )              /* r3              | r2              */
 288
 289     MOVQ      ( MM4, REGOFF(-16, EDX) ) /* write r0, r1                      */
 290     MOVQ      ( MM5, REGOFF(-8, EDX) )  /* write r2, r3                      */
 291
 292     MOVQ      ( REGIND(EAX), MM2 )      /* x1              | x0              */
 293     MOVQ      ( REGOFF(8, EAX), MM3 )   /* x3              | x2              */
 294
 295     DEC_L     ( ESI )                   /* decrement vertex counter          */
 296     JNZ       ( LLBL( G3TP3R_1 ) )      /* cnt > 0 ? -> process next vertex  */
 297
 298 LLBL( G3TP3R_2 ):
 299
 300     FEMMS
 301     POP_L     ( EDI )
 302     POP_L     ( ESI )
 303     RET
 304
 305
 306
 307
 308 ALIGNTEXT16
 309 GLOBL GLNAME( _mesa_3dnow_transform_points4_3d_no_rot )
 310 GLNAME( _mesa_3dnow_transform_points4_3d_no_rot ):
 311
 312     PUSH_L    ( ESI )
 313     MOV_L     ( ARG_DEST, ECX )
 314     MOV_L     ( ARG_MATRIX, ESI )
 315     MOV_L     ( ARG_SOURCE, EAX )
 316     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 317     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 318     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 319     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 320
 321     PUSH_L    ( EDI )
 322
 323     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 324     MOV_L     ( ESI, ECX )
 325     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 326     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 327     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 328
 329     TEST_L    ( ESI, ESI )
 330     JZ        ( LLBL( G3TP3NRR_2 ) )
 331
 332     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 333     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 334
 335     MOVD      ( REGOFF(40, ECX), MM2 )  /*                 | m22             */
 336     PUNPCKLDQ ( REGOFF(56, ECX), MM2 )  /* m32             | m22             */
 337
 338     MOVQ      ( REGOFF(48, ECX), MM1 )  /* m31             | m30             */
 339
 340     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 341     MOVQ      ( REGOFF(8, EAX), MM5 )   /* x3              | x2              */
 342     MOVD      ( REGOFF(12, EAX), MM7 )  /*                 | x3              */
 343
 344     ADD_L     ( EDI, EAX )              /* next vertex                       */
 345
 346 ALIGNTEXT16
 347 LLBL( G3TP3NRR_1 ):
 348
 349     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 350     PREFETCH  ( REGOFF(32, EAX) )       /* hopefully stride is zero          */
 351
 352     MOVQ      ( MM5, MM6 )              /* x3              | x2              */
 353     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 354
 355     PUNPCKHDQ ( MM6, MM6 )              /* x3              | x3              */
 356     PFMUL     ( MM2, MM5 )              /* x3*m32          | x2*m22          */
 357
 358     PFMUL     ( MM1, MM6 )              /* x3*m31          | x3*m30          */
 359     PFACC     ( MM7, MM5 )              /* x3              | x2*m22+x3*m32   */
 360
 361     PFADD     ( MM6, MM4 )              /* x1*m11+x3*m31   | x0*m00+x3*m30   */
 362     ADD_L     ( CONST(16), EDX )        /* next r                            */
 363
 364     MOVQ      ( MM4, REGOFF(-16, EDX) ) /* write r0, r1                      */
 365     MOVQ      ( MM5, REGOFF(-8, EDX) )  /* write r2, r3                      */
 366
 367     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 368     MOVQ      ( REGOFF(8, EAX), MM5 )   /* x3              | x2              */
 369
 370     MOVD      ( REGOFF(12, EAX), MM7 )  /*                 | x3              */
 371     ADD_L     ( EDI, EAX )              /* next vertex                       */
 372
 373     DEC_L     ( ESI )                   /* decrement vertex counter          */
 374     JNZ       ( LLBL( G3TP3NRR_1 ) )    /* cnt > 0 ? -> process next vertex  */
 375
 376 LLBL( G3TP3NRR_2 ):
 377
 378     FEMMS
 379     POP_L     ( EDI )
 380     POP_L     ( ESI )
 381     RET
 382
 383
 384
 385
 386 ALIGNTEXT16
 387 GLOBL GLNAME( _mesa_3dnow_transform_points4_2d )
 388 GLNAME( _mesa_3dnow_transform_points4_2d ):
 389
 390     PUSH_L    ( ESI )
 391
 392     MOV_L     ( ARG_DEST, ECX )
 393     MOV_L     ( ARG_MATRIX, ESI )
 394     MOV_L     ( ARG_SOURCE, EAX )
 395     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 396     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 397     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 398     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 399
 400     PUSH_L    ( EDI )
 401
 402     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 403     MOV_L     ( ESI, ECX )
 404     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 405     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 406     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 407
 408     TEST_L    ( ESI, ESI )
 409     JZ        ( LLBL( G3TP2R_2 ) )
 410
 411     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 412     PUNPCKLDQ ( REGOFF(16, ECX), MM0 )  /* m10             | m00             */
 413
 414     MOVD      ( REGOFF(4, ECX), MM1 )   /*                 | m01             */
 415     PUNPCKLDQ ( REGOFF(20, ECX), MM1 )  /* m11             | m01             */
 416
 417     MOVQ      ( REGOFF(48, ECX), MM2 )  /* m31             | m30             */
 418
 419     MOVQ      ( REGIND(EAX), MM3 )      /* x1              | x0              */
 420     MOVQ      ( REGOFF(8, EAX), MM5 )   /* x3              | x2              */
 421
 422     ADD_L     ( EDI, EAX )              /* next vertex                       */
 423
 424 ALIGNTEXT16
 425 LLBL( G3TP2R_1 ):
 426
 427     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 428     PREFETCH  ( REGIND(EAX) )
 429
 430     MOVQ      ( MM3, MM4 )              /* x1              | x0              */
 431     MOVQ      ( MM5, MM6 )              /* x3              | x2              */
 432
 433     PFMUL     ( MM1, MM4 )              /* x1*m11          | x0*m01          */
 434     PUNPCKHDQ ( MM6, MM6 )              /* x3              | x3              */
 435
 436     PFMUL     ( MM0, MM3 )              /* x1*m10          | x0*m00          */
 437     ADD_L     ( CONST(16), EDX )        /* next r                            */
 438
 439     PFACC     ( MM4, MM3 )              /* x0*m01+x1*m11   | x0*m00+x1*m10   */
 440     PFMUL     ( MM2, MM6 )              /* x3*m31          | x3*m30          */
 441
 442     PFADD     ( MM6, MM3 )              /* r1              | r0              */
 443     MOVQ      ( MM5, REGOFF(-8, EDX) )  /* write r2, r3                      */
 444
 445     MOVQ      ( MM3, REGOFF(-16, EDX) ) /* write r0, r1                      */
 446     MOVQ      ( REGIND(EAX), MM3 )      /* x1              | x0              */
 447
 448     MOVQ      ( REGOFF(8, EAX), MM5 )   /* x3              | x2              */
 449     ADD_L     ( EDI, EAX )              /* next vertex                       */
 450
 451     DEC_L     ( ESI )                   /* decrement vertex counter          */
 452     JNZ       ( LLBL( G3TP2R_1 ) )      /* cnt > 0 ? -> process next vertex  */
 453
 454 LLBL( G3TP2R_2 ):
 455
 456     FEMMS
 457     POP_L     ( EDI )
 458     POP_L     ( ESI )
 459     RET
 460
 461
 462
 463
 464 ALIGNTEXT16
 465 GLOBL GLNAME( _mesa_3dnow_transform_points4_2d_no_rot )
 466 GLNAME( _mesa_3dnow_transform_points4_2d_no_rot ):
 467
 468     PUSH_L    ( ESI )
 469
 470     MOV_L     ( ARG_DEST, ECX )
 471     MOV_L     ( ARG_MATRIX, ESI )
 472     MOV_L     ( ARG_SOURCE, EAX )
 473     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 474     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 475     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 476     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 477
 478     PUSH_L    ( EDI )
 479
 480     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 481     MOV_L     ( ESI, ECX )
 482     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 483     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 484     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 485
 486     TEST_L    ( ESI, ESI )
 487     JZ        ( LLBL( G3TP2NRR_3 ) )
 488
 489     MOVD      ( REGIND(ECX), MM0 )      /*                 | m00             */
 490     PUNPCKLDQ ( REGOFF(20, ECX), MM0 )  /* m11             | m00             */
 491
 492     MOVQ      ( REGOFF(48, ECX), MM1 )  /* m31             | m30             */
 493
 494     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 495     MOVQ      ( REGOFF(8, EAX), MM5 )   /* x3              | x2              */
 496
 497     ADD_L     ( EDI, EAX )              /* next vertex                       */
 498
 499 ALIGNTEXT16
 500 LLBL( G3TP2NRR_2 ):
 501
 502     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 503     PREFETCH  ( REGIND(EAX) )
 504
 505     PFMUL     ( MM0, MM4 )              /* x1*m11          | x0*m00          */
 506     MOVQ      ( MM5, MM6 )              /* x3              | x2              */
 507
 508     ADD_L     ( CONST(16), EDX )        /* next r                            */
 509     PUNPCKHDQ ( MM6, MM6 )              /* x3              | x3              */
 510
 511     PFMUL     ( MM1, MM6 )              /* x3*m31          | x3*m30          */
 512     PFADD     ( MM4, MM6 )              /* x1*m11+x3*m31   | x0*m00+x3*m30   */
 513
 514     MOVQ      ( MM6, REGOFF(-16, EDX) ) /* write r0, r1                      */
 515     MOVQ      ( MM5, REGOFF(-8, EDX) )  /* write r2, r3                      */
 516
 517     MOVQ      ( REGIND(EAX), MM4 )      /* x1              | x0              */
 518     MOVQ      ( REGOFF(8, EAX), MM5 )   /* x3              | x2              */
 519
 520     ADD_L     ( EDI, EAX )              /* next vertex                       */
 521     DEC_L     ( ESI )                   /* decrement vertex counter          */
 522
 523     JNZ       ( LLBL( G3TP2NRR_2 ) )    /* cnt > 0 ? -> process next vertex  */
 524
 525 LLBL( G3TP2NRR_3 ):
 526
 527     FEMMS
 528     POP_L     ( EDI )
 529     POP_L     ( ESI )
 530     RET
 531
 532
 533
 534
 535 ALIGNTEXT16
 536 GLOBL GLNAME( _mesa_3dnow_transform_points4_identity )
 537 GLNAME( _mesa_3dnow_transform_points4_identity ):
 538
 539     PUSH_L    ( ESI )
 540
 541     MOV_L     ( ARG_DEST, ECX )
 542     MOV_L     ( ARG_MATRIX, ESI )
 543     MOV_L     ( ARG_SOURCE, EAX )
 544     MOV_L     ( CONST(4), REGOFF(V4F_SIZE, ECX) )
 545     OR_B      ( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, ECX) )
 546     MOV_L     ( REGOFF(V4F_COUNT, EAX), EDX )
 547     MOV_L     ( EDX, REGOFF(V4F_COUNT, ECX) )
 548
 549     PUSH_L    ( EDI )
 550
 551     MOV_L     ( REGOFF(V4F_START, ECX), EDX )
 552     MOV_L     ( ESI, ECX )
 553     MOV_L     ( REGOFF(V4F_COUNT, EAX), ESI )
 554     MOV_L     ( REGOFF(V4F_STRIDE, EAX), EDI )
 555     MOV_L     ( REGOFF(V4F_START, EAX), EAX )
 556
 557     TEST_L    ( ESI, ESI )
 558     JZ        ( LLBL( G3TPIR_2 ) )
 559
 560     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
 561     MOVQ      ( REGOFF(8, EAX), MM1 )   /* x3              | x2              */
 562
 563     ADD_L     ( EDI, EAX )              /* next vertex                       */
 564
 565 ALIGNTEXT16
 566 LLBL( G3TPIR_1 ):
 567
 568     PREFETCHW ( REGOFF(32, EDX) )       /* prefetch 2 vertices ahead         */
 569     PREFETCH  ( REGIND(EAX) )
 570
 571     ADD_L     ( CONST(16), EDX )        /* next r                            */
 572     MOVQ      ( MM0, REGOFF(-16, EDX) ) /* r1              | r0              */
 573
 574     MOVQ      ( MM1, REGOFF(-8, EDX) )  /* r3              | r2              */
 575     MOVQ      ( REGIND(EAX), MM0 )      /* x1              | x0              */
 576
 577     MOVQ      ( REGOFF(8, EAX), MM1 )   /* x3              | x2              */
 578     ADD_L     ( EDI, EAX )              /* next vertex                       */
 579
 580     DEC_L     ( ESI )                   /* decrement vertex counter          */
 581     JNZ       ( LLBL( G3TPIR_1 ) )      /* cnt > 0 ? -> process next vertex  */
 582
 583 LLBL( G3TPIR_2 ):
 584
 585     FEMMS
 586     POP_L     ( EDI )
 587     POP_L     ( ESI )
 588     RET