src/mesa/x86/sse_normal.S

   1 /* $Id: sse_normal.S,v 1.4 2004/04/26 10:10:25 alanh Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 /** TODO:
  28   * - insert PREFETCH instructions to avoid cache-misses !
  29   * - some more optimizations are possible...
  30   * - for 40-50% more performance in the SSE-functions, the
  31   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  32   */
  33
  34 #ifdef USE_SSE_ASM
  35 #include "matypes.h"
  36 #include "norm_args.h"
  37
  38    SEG_TEXT
  39
  40 #define M(i)    REGOFF(i * 4, EDX)
  41 #define S(i)    REGOFF(i * 4, ESI)
  42 #define D(i)    REGOFF(i * 4, EDI)
  43 #define STRIDE  REGOFF(12, ESI)
  44
  45
  46 ALIGNTEXT16
  47 GLOBL GLNAME(_mesa_sse_transform_rescale_normals_no_rot)
  48 GLNAME(_mesa_sse_transform_rescale_normals_no_rot):
  49
  50 #define FRAME_OFFSET 8
  51         PUSH_L  ( ESI )
  52         PUSH_L  ( EDI )
  53
  54         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
  55         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
  56
  57         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
  58         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
  59
  60         MOV_L   ( REGOFF(V4F_COUNT, ESI), ECX )         /* source count */
  61
  62         TEST_L  ( ECX, ECX )
  63         JZ( LLBL(K_G3TRNNRR_finish) )                   /* count was zero; go to finish */
  64
  65         MOV_L   ( STRIDE, EAX )                         /* stride */
  66         MOV_L   ( ECX, REGOFF(V4F_COUNT, EDI) )         /* set dest-count */
  67
  68         IMUL_L( CONST(16), ECX )                        /* count *= 16 */
  69         MOV_L( REGOFF(V4F_START, ESI), ESI )            /* ptr to first source vertex */
  70
  71         MOV_L( REGOFF(V4F_START, EDI), EDI )            /* ptr to first dest vertex */
  72         ADD_L( EDI, ECX )                               /* count += dest ptr */
  73
  74 ALIGNTEXT32
  75         MOVSS   ( M(0), XMM1 )                          /* m0 */
  76         MOVSS   ( M(5), XMM2 )                          /* m5 */
  77         UNPCKLPS( XMM2, XMM1 )                          /* m5 | m0 */
  78         MOVSS   ( ARG_SCALE, XMM0 )                     /* scale */
  79         SHUFPS  ( CONST(0x0), XMM0, XMM0 )              /* scale | scale */
  80         MULPS   ( XMM0, XMM1 )                          /* m5*scale | m0*scale */
  81         MULSS   ( M(10), XMM0 )                         /* m10*scale */
  82
  83 ALIGNTEXT32
  84 LLBL(K_G3TRNNRR_top):
  85         MOVLPS  ( S(0), XMM2 )                          /* uy | ux */
  86         MULPS   ( XMM1, XMM2 )                          /* uy*m5*scale | ux*m0*scale */
  87         MOVLPS  ( XMM2, D(0) )                          /* ->D(1) | D(0) */
  88
  89         MOVSS   ( S(2), XMM2 )                          /* uz */
  90         MULSS   ( XMM0, XMM2 )                          /* uz*m10*scale */
  91         MOVSS   ( XMM2, D(2) )                          /* ->D(2) */
  92
  93 LLBL(K_G3TRNNRR_skip):
  94         ADD_L   ( CONST(16), EDI )
  95         ADD_L   ( EAX, ESI )
  96         CMP_L   ( ECX, EDI )
  97         JNE     ( LLBL(K_G3TRNNRR_top) )
  98
  99 LLBL(K_G3TRNNRR_finish):
 100         POP_L   ( EDI )
 101         POP_L   ( ESI )
 102         RET
 103 #undef FRAME_OFFSET
 104
 105
 106
 107 ALIGNTEXT16
 108 GLOBL GLNAME(_mesa_sse_transform_rescale_normals)
 109 GLNAME(_mesa_sse_transform_rescale_normals):
 110
 111 #define FRAME_OFFSET 8
 112         PUSH_L  ( ESI )
 113         PUSH_L  ( EDI )
 114
 115         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
 116         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
 117
 118         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
 119         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
 120
 121         MOV_L   ( REGOFF(V4F_COUNT, ESI), ECX )         /* source count */
 122
 123         TEST_L  ( ECX, ECX )
 124         JZ( LLBL(K_G3TRNR_finish) )                     /* count was zero; go to finish */
 125
 126         MOV_L   ( STRIDE, EAX )                         /* stride */
 127         MOV_L   ( ECX, REGOFF(V4F_COUNT, EDI) )         /* set dest-count */
 128
 129         IMUL_L( CONST(16), ECX )                        /* count *= 16 */
 130         MOV_L( REGOFF(V4F_START, ESI), ESI )            /* ptr to first source vertex */
 131
 132         MOV_L( REGOFF(V4F_START, EDI), EDI )            /* ptr to first dest vertex */
 133         ADD_L( EDI, ECX )                               /* count += dest ptr */
 134
 135 ALIGNTEXT32
 136         MOVSS   ( M(0), XMM0 )                          /* m0 */
 137         MOVSS   ( M(4), XMM1 )                          /* m4 */
 138         UNPCKLPS( XMM1, XMM0 )                          /* m4 | m0 */
 139
 140         MOVSS   ( ARG_SCALE, XMM4 )                     /* scale */
 141         SHUFPS  ( CONST(0x0), XMM4, XMM4 )              /* scale | scale */
 142
 143         MULPS   ( XMM4, XMM0 )                          /* m4*scale | m0*scale */
 144         MOVSS   ( M(1), XMM1 )                          /* m1 */
 145         MOVSS   ( M(5), XMM2 )                          /* m5 */
 146         UNPCKLPS( XMM2, XMM1 )                          /* m5 | m1 */
 147         MULPS   ( XMM4, XMM1 )                          /* m5*scale | m1*scale */
 148         MOVSS   ( M(2), XMM2 )                          /* m2 */
 149         MOVSS   ( M(6), XMM3 )                          /* m6 */
 150         UNPCKLPS( XMM3, XMM2 )                          /* m6 | m2 */
 151         MULPS   ( XMM4, XMM2 )                          /* m6*scale | m2*scale */
 152
 153         MOVSS   ( M(8), XMM6 )                          /* m8 */
 154         MULSS   ( ARG_SCALE, XMM6 )                     /* m8*scale */
 155         MOVSS   ( M(9), XMM7 )                          /* m9 */
 156         MULSS   ( ARG_SCALE, XMM7 )                     /* m9*scale */
 157
 158 ALIGNTEXT32
 159 LLBL(K_G3TRNR_top):
 160         MOVSS   ( S(0), XMM3 )                          /* ux */
 161         SHUFPS  ( CONST(0x0), XMM3, XMM3 )              /* ux | ux */
 162         MULPS   ( XMM0, XMM3 )                          /* ux*m4 | ux*m0 */
 163         MOVSS   ( S(1), XMM4 )                          /* uy */
 164         SHUFPS  ( CONST(0x0), XMM4, XMM4 )              /* uy | uy */
 165         MULPS   ( XMM1, XMM4 )                          /* uy*m5 | uy*m1 */
 166         MOVSS   ( S(2), XMM5 )                          /* uz */
 167         SHUFPS  ( CONST(0x0), XMM5, XMM5 )              /* uz | uz */
 168         MULPS   ( XMM2, XMM5 )                          /* uz*m6 | uz*m2 */
 169
 170         ADDPS   ( XMM4, XMM3 )
 171         ADDPS   ( XMM5, XMM3 )
 172         MOVLPS  ( XMM3, D(0) )
 173
 174         MOVSS   ( M(10), XMM3 )                         /* m10 */
 175         MULSS   ( ARG_SCALE, XMM3 )                     /* m10*scale */
 176         MULSS   ( S(2), XMM3 )                          /* m10*scale*uz */
 177         MOVSS   ( S(1), XMM4 )                          /* uy */
 178         MULSS   ( XMM7, XMM4 )                          /* uy*m9*scale */
 179         MOVSS   ( S(0), XMM5 )                          /* ux */
 180         MULSS   ( XMM6, XMM5 )                          /* ux*m8*scale */
 181
 182         ADDSS   ( XMM4, XMM3 )
 183         ADDSS   ( XMM5, XMM3 )
 184         MOVSS   ( XMM3, D(2) )
 185
 186 LLBL(K_G3TRNR_skip):
 187         ADD_L   ( CONST(16), EDI )
 188         ADD_L   ( EAX, ESI )
 189         CMP_L   ( ECX, EDI )
 190         JNE     ( LLBL(K_G3TRNR_top) )
 191
 192 LLBL(K_G3TRNR_finish):
 193         POP_L   ( EDI )
 194         POP_L   ( ESI )
 195         RET
 196 #undef FRAME_OFFSET
 197
 198
 199 ALIGNTEXT16
 200 GLOBL GLNAME(_mesa_sse_transform_normals_no_rot)
 201 GLNAME(_mesa_sse_transform_normals_no_rot):
 202
 203 #define FRAME_OFFSET 8
 204         PUSH_L  ( ESI )
 205         PUSH_L  ( EDI )
 206
 207         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
 208         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
 209
 210         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
 211         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
 212
 213         MOV_L   ( REGOFF(V4F_COUNT, ESI), ECX )         /* source count */
 214
 215         TEST_L  ( ECX, ECX )
 216         JZ( LLBL(K_G3TNNRR_finish) )                    /* count was zero; go to finish */
 217
 218         MOV_L   ( STRIDE, EAX )                         /* stride */
 219         MOV_L   ( ECX, REGOFF(V4F_COUNT, EDI) )         /* set dest-count */
 220
 221         IMUL_L( CONST(16), ECX )                        /* count *= 16 */
 222         MOV_L( REGOFF(V4F_START, ESI), ESI )            /* ptr to first source vertex */
 223
 224         MOV_L( REGOFF(V4F_START, EDI), EDI )            /* ptr to first dest vertex */
 225         ADD_L( EDI, ECX )                               /* count += dest ptr */
 226
 227 ALIGNTEXT32
 228         MOVSS( M(0), XMM0 )                             /* m0 */
 229         MOVSS( M(5), XMM1 )                             /* m5 */
 230         UNPCKLPS( XMM1, XMM0 )                          /* m5 | m0 */
 231         MOVSS( M(10), XMM1 )                            /* m10 */
 232
 233 ALIGNTEXT32
 234 LLBL(K_G3TNNRR_top):
 235         MOVLPS( S(0), XMM2 )                            /* uy | ux */
 236         MULPS( XMM0, XMM2 )                             /* uy*m5 | ux*m0 */
 237         MOVLPS( XMM2, D(0) )
 238
 239         MOVSS( S(2), XMM2 )                             /* uz */
 240         MULSS( XMM1, XMM2 )                             /* uz*m10 */
 241         MOVSS( XMM2, D(2) )
 242
 243 LLBL(K_G3TNNRR_skip):
 244         ADD_L   ( CONST(16), EDI )
 245         ADD_L   ( EAX, ESI )
 246         CMP_L   ( ECX, EDI )
 247         JNE     ( LLBL(K_G3TNNRR_top) )
 248
 249 LLBL(K_G3TNNRR_finish):
 250         POP_L   ( EDI )
 251         POP_L   ( ESI )
 252         RET
 253 #undef FRAME_OFFSET
 254 #endif