src/mesa/x86/sse_normal.S

   1 /* $Id: sse_normal.S,v 1.1 2001/03/29 06:46:16 gareth Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 /** TODO:
  28   * - insert PREFETCH instructions to avoid cache-misses !
  29   * - some more optimizations are possible...
  30   * - for 40-50% more performance in the SSE-functions, the
  31   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  32   */
  33
  34 #include "matypes.h"
  35 #include "norm_args.h"
  36
  37    SEG_TEXT
  38
  39 #define M(i)    REGOFF(i * 4, EDX)
  40 #define S(i)    REGOFF(i * 4, ESI)
  41 #define D(i)    REGOFF(i * 4, EDI)
  42 #define STRIDE  REGOFF(12, ESI)
  43
  44
  45 ALIGNTEXT16
  46 GLOBL GLNAME(_mesa_sse_transform_rescale_normals_no_rot)
  47 GLNAME(_mesa_sse_transform_rescale_normals_no_rot):
  48
  49 #define FRAME_OFFSET 8
  50         PUSH_L  ( ESI )
  51         PUSH_L  ( EDI )
  52
  53         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
  54         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
  55
  56         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
  57         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
  58
  59         MOV_L   ( REGOFF(V3F_COUNT, ESI), ECX )         /* source count */
  60
  61         TEST_L  ( ECX, ECX )
  62         JZ( LLBL(K_G3TRNNRR_finish) )                   /* count was zero; go to finish */
  63
  64         MOV_L   ( STRIDE, EAX )                         /* stride */
  65         MOV_L   ( ECX, REGOFF(V3F_COUNT, EDI) )         /* set dest-count */
  66
  67         IMUL_L( CONST(12), ECX )                        /* count *= 12 */
  68         MOV_L( REGOFF(V3F_START, ESI), ESI )            /* ptr to first source vertex */
  69
  70         MOV_L( REGOFF(V3F_START, EDI), EDI )            /* ptr to first dest vertex */
  71         ADD_L( EDI, ECX )                               /* count += dest ptr */
  72
  73 ALIGNTEXT32
  74         MOVSS   ( M(0), XMM1 )                          /* m0 */
  75         MOVSS   ( M(5), XMM2 )                          /* m5 */
  76         UNPCKLPS( XMM2, XMM1 )                          /* m5 | m0 */
  77         MOVSS   ( ARG_SCALE, XMM0 )                     /* scale */
  78         SHUFPS  ( CONST(0x0), XMM0, XMM0 )              /* scale | scale */
  79         MULPS   ( XMM0, XMM1 )                          /* m5*scale | m0*scale */
  80         MULSS   ( M(10), XMM0 )                         /* m10*scale */
  81
  82 ALIGNTEXT32
  83 LLBL(K_G3TRNNRR_top):
  84         MOVLPS  ( S(0), XMM2 )                          /* uy | ux */
  85         MULPS   ( XMM1, XMM2 )                          /* uy*m5*scale | ux*m0*scale */
  86         MOVLPS  ( XMM2, D(0) )                          /* ->D(1) | D(0) */
  87
  88         MOVSS   ( S(2), XMM2 )                          /* uz */
  89         MULSS   ( XMM0, XMM2 )                          /* uz*m10*scale */
  90         MOVSS   ( XMM2, D(2) )                          /* ->D(2) */
  91
  92 LLBL(K_G3TRNNRR_skip):
  93         ADD_L   ( CONST(12), EDI )
  94         ADD_L   ( EAX, ESI )
  95         CMP_L   ( ECX, EDI )
  96         JNE     ( LLBL(K_G3TRNNRR_top) )
  97
  98 LLBL(K_G3TRNNRR_finish):
  99         POP_L   ( EDI )
 100         POP_L   ( ESI )
 101         RET
 102 #undef FRAME_OFFSET
 103
 104
 105
 106 ALIGNTEXT16
 107 GLOBL GLNAME(_mesa_sse_transform_rescale_normals)
 108 GLNAME(_mesa_sse_transform_rescale_normals):
 109
 110 #define FRAME_OFFSET 8
 111         PUSH_L  ( ESI )
 112         PUSH_L  ( EDI )
 113
 114         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
 115         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
 116
 117         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
 118         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
 119
 120         MOV_L   ( REGOFF(V3F_COUNT, ESI), ECX )         /* source count */
 121
 122         TEST_L  ( ECX, ECX )
 123         JZ( LLBL(K_G3TRNR_finish) )                     /* count was zero; go to finish */
 124
 125         MOV_L   ( STRIDE, EAX )                         /* stride */
 126         MOV_L   ( ECX, REGOFF(V3F_COUNT, EDI) )         /* set dest-count */
 127
 128         IMUL_L( CONST(12), ECX )                        /* count *= 12 */
 129         MOV_L( REGOFF(V3F_START, ESI), ESI )            /* ptr to first source vertex */
 130
 131         MOV_L( REGOFF(V3F_START, EDI), EDI )            /* ptr to first dest vertex */
 132         ADD_L( EDI, ECX )                               /* count += dest ptr */
 133
 134 ALIGNTEXT32
 135         MOVSS   ( M(0), XMM0 )                          /* m0 */
 136         MOVSS   ( M(4), XMM1 )                          /* m4 */
 137         UNPCKLPS( XMM1, XMM0 )                          /* m4 | m0 */
 138
 139         MOVSS   ( ARG_SCALE, XMM4 )                     /* scale */
 140         SHUFPS  ( CONST(0x0), XMM4, XMM4 )              /* scale | scale */
 141
 142         MULPS   ( XMM4, XMM0 )                          /* m4*scale | m0*scale */
 143         MOVSS   ( M(1), XMM1 )                          /* m1 */
 144         MOVSS   ( M(5), XMM2 )                          /* m5 */
 145         UNPCKLPS( XMM2, XMM1 )                          /* m5 | m1 */
 146         MULPS   ( XMM4, XMM1 )                          /* m5*scale | m1*scale */
 147         MOVSS   ( M(2), XMM2 )                          /* m2 */
 148         MOVSS   ( M(6), XMM3 )                          /* m6 */
 149         UNPCKLPS( XMM3, XMM2 )                          /* m6 | m2 */
 150         MULPS   ( XMM4, XMM2 )                          /* m6*scale | m2*scale */
 151
 152         MOVSS   ( M(8), XMM6 )                          /* m8 */
 153         MULSS   ( ARG_SCALE, XMM6 )                     /* m8*scale */
 154         MOVSS   ( M(9), XMM7 )                          /* m9 */
 155         MULSS   ( ARG_SCALE, XMM7 )                     /* m9*scale */
 156
 157 ALIGNTEXT32
 158 LLBL(K_G3TRNR_top):
 159         MOVSS   ( S(0), XMM3 )                          /* ux */
 160         SHUFPS  ( CONST(0x0), XMM3, XMM3 )              /* ux | ux */
 161         MULPS   ( XMM0, XMM3 )                          /* ux*m4 | ux*m0 */
 162         MOVSS   ( S(1), XMM4 )                          /* uy */
 163         SHUFPS  ( CONST(0x0), XMM4, XMM4 )              /* uy | uy */
 164         MULPS   ( XMM1, XMM4 )                          /* uy*m5 | uy*m1 */
 165         MOVSS   ( S(2), XMM5 )                          /* uz */
 166         SHUFPS  ( CONST(0x0), XMM5, XMM5 )              /* uz | uz */
 167         MULPS   ( XMM2, XMM5 )                          /* uz*m6 | uz*m2 */
 168
 169         ADDPS   ( XMM4, XMM3 )
 170         ADDPS   ( XMM5, XMM3 )
 171         MOVLPS  ( XMM3, D(0) )
 172
 173         MOVSS   ( M(10), XMM3 )                         /* m10 */
 174         MULSS   ( ARG_SCALE, XMM3 )                     /* m10*scale */
 175         MULSS   ( S(2), XMM3 )                          /* m10*scale*uz */
 176         MOVSS   ( S(1), XMM4 )                          /* uy */
 177         MULSS   ( XMM7, XMM4 )                          /* uy*m9*scale */
 178         MOVSS   ( S(0), XMM5 )                          /* ux */
 179         MULSS   ( XMM6, XMM5 )                          /* ux*m8*scale */
 180
 181         ADDSS   ( XMM4, XMM3 )
 182         ADDSS   ( XMM5, XMM3 )
 183         MOVSS   ( XMM3, D(2) )
 184
 185 LLBL(K_G3TRNR_skip):
 186         ADD_L   ( CONST(12), EDI )
 187         ADD_L   ( EAX, ESI )
 188         CMP_L   ( ECX, EDI )
 189         JNE     ( LLBL(K_G3TRNR_top) )
 190
 191 LLBL(K_G3TRNR_finish):
 192         POP_L   ( EDI )
 193         POP_L   ( ESI )
 194         RET
 195 #undef FRAME_OFFSET
 196
 197
 198 ALIGNTEXT16
 199 GLOBL GLNAME(_mesa_sse_transform_normals_no_rot)
 200 GLNAME(_mesa_sse_transform_normals_no_rot):
 201
 202 #define FRAME_OFFSET 8
 203         PUSH_L  ( ESI )
 204         PUSH_L  ( EDI )
 205
 206         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
 207         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
 208
 209         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
 210         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
 211
 212         MOV_L   ( REGOFF(V3F_COUNT, ESI), ECX )         /* source count */
 213
 214         TEST_L  ( ECX, ECX )
 215         JZ( LLBL(K_G3TNNRR_finish) )                    /* count was zero; go to finish */
 216
 217         MOV_L   ( STRIDE, EAX )                         /* stride */
 218         MOV_L   ( ECX, REGOFF(V3F_COUNT, EDI) )         /* set dest-count */
 219
 220         IMUL_L( CONST(12), ECX )                        /* count *= 12 */
 221         MOV_L( REGOFF(V3F_START, ESI), ESI )            /* ptr to first source vertex */
 222
 223         MOV_L( REGOFF(V3F_START, EDI), EDI )            /* ptr to first dest vertex */
 224         ADD_L( EDI, ECX )                               /* count += dest ptr */
 225
 226 ALIGNTEXT32
 227         MOVSS( M(0), XMM0 )                             /* m0 */
 228         MOVSS( M(5), XMM1 )                             /* m5 */
 229         UNPCKLPS( XMM1, XMM0 )                          /* m5 | m0 */
 230         MOVSS( M(10), XMM1 )                            /* m10 */
 231
 232 ALIGNTEXT32
 233 LLBL(K_G3TNNRR_top):
 234         MOVLPS( S(0), XMM2 )                            /* uy | ux */
 235         MULPS( XMM0, XMM2 )                             /* uy*m5 | ux*m0 */
 236         MOVLPS( XMM2, D(0) )
 237
 238         MOVSS( S(2), XMM2 )                             /* uz */
 239         MULSS( XMM1, XMM2 )                             /* uz*m10 */
 240         MOVSS( XMM2, D(2) )
 241
 242 LLBL(K_G3TNNRR_skip):
 243         ADD_L   ( CONST(12), EDI )
 244         ADD_L   ( EAX, ESI )
 245         CMP_L   ( ECX, EDI )
 246         JNE     ( LLBL(K_G3TNNRR_top) )
 247
 248 LLBL(K_G3TNNRR_finish):
 249         POP_L   ( EDI )
 250         POP_L   ( ESI )
 251         RET
 252 #undef FRAME_OFFSET