src/mesa/x86/sse_xform1.S

   1 /* $Id: sse_xform1.S,v 1.1 2001/03/29 06:46:27 gareth Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 /** TODO:
  28   * - insert PREFETCH instructions to avoid cache-misses !
  29   * - some more optimizations are possible...
  30   * - for 40-50% more performance in the SSE-functions, the
  31   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  32   */
  33
  34 #include "matypes.h"
  35 #include "xform_args.h"
  36
  37    SEG_TEXT
  38
  39 #define S(i)    REGOFF(i * 4, ESI)
  40 #define D(i)    REGOFF(i * 4, EDI)
  41 #define M(i)    REGOFF(i * 4, EDX)
  42
  43
  44 ALIGNTEXT4
  45 GLOBL GLNAME(_mesa_sse_transform_points1_general)
  46 GLNAME( _mesa_sse_transform_points1_general ):
  47
  48 #define FRAME_OFFSET 8
  49     PUSH_L    ( ESI )
  50     PUSH_L    ( EDI )
  51
  52     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
  53     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
  54
  55     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
  56     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
  57
  58     CMP_L( CONST(0), ECX )                      /* count == 0 ? */
  59     JE( LLBL(K_GTP1GR_finish) )                 /* yes -> nothing to do. */
  60
  61     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
  62     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
  63
  64     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
  65     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
  66
  67     SHL_L( CONST(4), ECX )                      /* count *= 16 */
  68     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
  69
  70     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
  71     ADD_L( EDI, ECX )                           /* count += dest ptr */
  72
  73
  74 ALIGNTEXT32
  75     MOVAPS( M(0), XMM0 )                        /* m3  | m2  | m1  | m0  */
  76     MOVAPS( M(12), XMM1 )                       /* m15 | m14 | m13 | m12 */
  77
  78 ALIGNTEXT32
  79 LLBL(K_GTP1GR_top):
  80     MOVSS( S(0), XMM2 )                         /* ox */
  81     SHUFPS( CONST(0x0), XMM2, XMM2 )            /* ox | ox | ox | ox */
  82     MULPS( XMM0, XMM2 )                         /* ox*m3 | ox*m2 | ox*m1 | ox*m0 */
  83     ADDPS( XMM1, XMM2 )                         /* + | + | + | + */
  84     MOVUPS( XMM2, D(0) )
  85
  86 LLBL(K_GTP1GR_skip):
  87     ADD_L     ( CONST(16), EDI )
  88     ADD_L     ( EAX, ESI )
  89     CMP_L     ( ECX, EDI )
  90     JNE       ( LLBL(K_GTP1GR_top) )
  91
  92 LLBL(K_GTP1GR_finish):
  93     POP_L     ( EDI )
  94     POP_L     ( ESI )
  95     RET
  96 #undef FRAME_OFFSET
  97
  98
  99
 100 ALIGNTEXT4
 101 GLOBL GLNAME(_mesa_sse_transform_points1_identity)
 102 GLNAME( _mesa_sse_transform_points1_identity ):
 103
 104 #define FRAME_OFFSET 8
 105     PUSH_L    ( ESI )
 106     PUSH_L    ( EDI )
 107
 108     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 109     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 110
 111     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 112
 113     TEST_L( ECX, ECX)
 114     JZ( LLBL(K_GTP1IR_finish) )                 /* count was zero; go to finish */
 115
 116     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 117     OR_L( CONST(VEC_SIZE_1), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 118
 119     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 120     MOV_L( CONST(1), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 121
 122     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 123     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 124
 125     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 126     ADD_L( EDI, ECX )                           /* count += dest ptr */
 127
 128     CMP_L( ESI, EDI )
 129     JE( LLBL(K_GTP1IR_finish) )
 130
 131
 132 ALIGNTEXT32
 133 LLBL(K_GTP1IR_top):
 134     MOV_L( S(0), EDX )
 135     MOV_L( EDX, D(0) )
 136
 137 LLBL(K_GTP1IR_skip):
 138     ADD_L     ( CONST(16), EDI )
 139     ADD_L     ( EAX, ESI )
 140     CMP_L     ( ECX, EDI )
 141     JNE       ( LLBL(K_GTP1IR_top) )
 142
 143 LLBL(K_GTP1IR_finish):
 144     POP_L     ( EDI )
 145     POP_L     ( ESI )
 146     RET
 147 #undef FRAME_OFFSET
 148
 149
 150
 151 ALIGNTEXT4
 152 GLOBL GLNAME(_mesa_sse_transform_points1_3d_no_rot)
 153 GLNAME(_mesa_sse_transform_points1_3d_no_rot):
 154
 155 #define FRAME_OFFSET 8
 156     PUSH_L( ESI )
 157     PUSH_L( EDI )
 158
 159     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 160     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 161
 162     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 163     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 164
 165     TEST_L( ECX, ECX)
 166     JZ( LLBL(K_GTP13DNRR_finish) )              /* count was zero; go to finish */
 167
 168     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 169     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 170
 171     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 172     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 173
 174     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 175     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 176
 177     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 178     ADD_L( EDI, ECX )                           /* count += dest ptr */
 179
 180
 181 ALIGNTEXT32
 182     MOVSS( M(0), XMM0 )                         /* m0 */
 183     MOVSS( M(12), XMM1 )                        /* m12 */
 184     MOVSS( M(13), XMM2 )                        /* m13 */
 185     MOVSS( M(14), XMM3 )                        /* m14 */
 186
 187 ALIGNTEXT32
 188 LLBL(K_GTP13DNRR_top):
 189     MOVSS( S(0), XMM4 )                         /* ox */
 190     MULSS( XMM0, XMM4 )                         /* ox*m0 */
 191     ADDSS( XMM1, XMM4 )                         /* ox*m0+m12 */
 192     MOVSS( XMM4, D(0) )
 193
 194     MOVSS( XMM2, D(1) )
 195     MOVSS( XMM3, D(2) )
 196
 197 LLBL(K_GTP13DNRR_skip):
 198     ADD_L    ( CONST(16), EDI )
 199     ADD_L    ( EAX, ESI )
 200     CMP_L    ( ECX, EDI )
 201     JNE      ( LLBL(K_GTP13DNRR_top) )
 202
 203 LLBL(K_GTP13DNRR_finish):
 204     POP_L    ( EDI )
 205     POP_L    ( ESI )
 206     RET
 207 #undef FRAME_OFFSET
 208
 209
 210
 211 ALIGNTEXT4
 212 GLOBL GLNAME(_mesa_sse_transform_points1_perspective)
 213 GLNAME(_mesa_sse_transform_points1_perspective):
 214
 215 #define FRAME_OFFSET 8
 216     PUSH_L   ( ESI )
 217     PUSH_L   ( EDI )
 218
 219     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 220     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 221
 222     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 223     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 224
 225     TEST_L( ECX, ECX)
 226     JZ( LLBL(K_GTP13PR_finish) )                /* count was zero; go to finish */
 227
 228     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 229     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 230
 231     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 232     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 233
 234     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 235     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 236
 237     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 238     ADD_L( EDI, ECX )                           /* count += dest ptr */
 239
 240
 241 ALIGNTEXT32
 242     XORPS( XMM0, XMM0 )                         /* 0 | 0 | 0 | 0 */
 243     MOVSS( M(0), XMM1 )                         /* m0 */
 244     MOVSS( M(14), XMM2 )                        /* m14 */
 245
 246 ALIGNTEXT32
 247 LLBL(K_GTP13PR_top):
 248     MOVSS( S(0), XMM3 )                         /* ox */
 249     MULSS( XMM1, XMM3 )                         /* ox*m0 */
 250     MOVSS( XMM3, D(0) )                         /* ox*m0->D(0) */
 251     MOVSS( XMM2, D(2) )                         /* m14->D(2) */
 252
 253     MOVSS( XMM0, D(1) )
 254     MOVSS( XMM0, D(3) )
 255
 256 LLBL(K_GTP13PR_skip):
 257     ADD_L( CONST(16), EDI )
 258     ADD_L( EAX, ESI )
 259     CMP_L( ECX, EDI )
 260     JNE( LLBL(K_GTP13PR_top) )
 261
 262 LLBL(K_GTP13PR_finish):
 263     POP_L    ( EDI )
 264     POP_L    ( ESI )
 265     RET
 266 #undef FRAME_OFFSET
 267
 268
 269 ALIGNTEXT4
 270 GLOBL GLNAME(_mesa_sse_transform_points1_2d)
 271 GLNAME(_mesa_sse_transform_points1_2d):
 272
 273 #define FRAME_OFFSET 8
 274     PUSH_L( ESI )
 275     PUSH_L( EDI )
 276
 277     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 278     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 279
 280     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 281     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 282
 283     TEST_L( ECX, ECX)
 284     JZ( LLBL(K_GTP13P2DR_finish) )              /* count was zero; go to finish */
 285
 286     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 287     OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 288
 289     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 290     MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 291
 292     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 293     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 294
 295     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 296     ADD_L( EDI, ECX )                           /* count += dest ptr */
 297
 298 ALIGNTEXT32
 299     MOVLPS( M(0), XMM0 )                        /* m1  | m0  */
 300     MOVLPS( M(12), XMM1 )                       /* m13 | m12 */
 301
 302 ALIGNTEXT32
 303 LLBL(K_GTP13P2DR_top):
 304     MOVSS( S(0), XMM2 )                         /* ox */
 305     SHUFPS( CONST(0x0), XMM2, XMM2 )            /* ox | ox | ox | ox */
 306     MULPS( XMM0, XMM2 )                         /* - | - | ox*m1 | ox*m0 */
 307     ADDPS( XMM1, XMM2 )                         /* - | - | ox*m1+m13 | ox*m0+m12 */
 308     MOVLPS( XMM2, D(0) )
 309
 310 LLBL(K_GTP13P2DR_skip):
 311     ADD_L    ( CONST(16), EDI )
 312     ADD_L    ( EAX, ESI )
 313     CMP_L    ( ECX, EDI )
 314     JNE      ( LLBL(K_GTP13P2DR_top) )
 315
 316 LLBL(K_GTP13P2DR_finish):
 317     POP_L    ( EDI )
 318     POP_L    ( ESI )
 319     RET
 320 #undef FRAME_OFFSET
 321
 322
 323 ALIGNTEXT4
 324 GLOBL GLNAME(_mesa_sse_transform_points1_2d_no_rot)
 325 GLNAME(_mesa_sse_transform_points1_2d_no_rot):
 326
 327 #define FRAME_OFFSET 8
 328         PUSH_L( ESI )
 329         PUSH_L( EDI )
 330
 331         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 332         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 333
 334         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 335         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 336
 337         TEST_L( ECX, ECX)
 338         JZ( LLBL(K_GTP13P2DNRR_finish) )        /* count was zero; go to finish */
 339
 340         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 341         OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 342
 343         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 344         MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 345
 346         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 347         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 348
 349         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 350         ADD_L( EDI, ECX )                       /* count += dest ptr */
 351
 352 ALIGNTEXT32
 353         MOVSS( M(0), XMM0 )                     /* m0 */
 354         MOVSS( M(12), XMM1 )                    /* m12 */
 355         MOVSS( M(13), XMM2 )                    /* m13 */
 356
 357 ALIGNTEXT32
 358 LLBL(K_GTP13P2DNRR_top):
 359         MOVSS( S(0), XMM3 )                     /* ox */
 360         MULSS( XMM0, XMM3 )                     /* ox*m0 */
 361         ADDSS( XMM1, XMM3 )                     /* ox*m0+m12 */
 362         MOVSS( XMM3, D(0) )
 363         MOVSS( XMM2, D(1) )
 364
 365 LLBL(K_GTP13P2DNRR_skip):
 366         ADD_L( CONST(16), EDI )
 367         ADD_L( EAX, ESI )
 368         CMP_L( ECX, EDI )
 369         JNE( LLBL(K_GTP13P2DNRR_top) )
 370
 371 LLBL(K_GTP13P2DNRR_finish):
 372         POP_L( EDI )
 373         POP_L( ESI )
 374         RET
 375 #undef FRAME_OFFSET
 376
 377
 378
 379 ALIGNTEXT4
 380 GLOBL GLNAME(_mesa_sse_transform_points1_3d)
 381 GLNAME(_mesa_sse_transform_points1_3d):
 382
 383 #define FRAME_OFFSET 8
 384         PUSH_L( ESI )
 385         PUSH_L( EDI )
 386
 387         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 388         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 389
 390         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 391         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 392
 393         TEST_L( ECX, ECX)
 394         JZ( LLBL(K_GTP13P3DR_finish) )  /* count was zero; go to finish */
 395
 396         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 397         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 398
 399         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 400         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 401
 402         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 403         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 404
 405         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 406         ADD_L( EDI, ECX )                       /* count += dest ptr */
 407
 408
 409 ALIGNTEXT32
 410         MOVAPS( M(0), XMM0 )                    /* m3  | m2  | m1  |  m0 */
 411         MOVAPS( M(12), XMM1 )                   /* m15 | m14 | m13 | m12 */
 412
 413 ALIGNTEXT32
 414 LLBL(K_GTP13P3DR_top):
 415         MOVSS( S(0), XMM2 )                     /* ox */
 416         SHUFPS( CONST(0x0), XMM2, XMM2 )        /* ox | ox | ox | ox */
 417         MULPS( XMM0, XMM2 )                     /* ox*m3 | ox*m2 | ox*m1 | ox*m0 */
 418         ADDPS( XMM1, XMM2 )                     /* +m15  | +m14  | +m13  | +m12  */
 419         MOVLPS( XMM2, D(0) )                    /*   -   |   -   | ->D(1)| ->D(0)*/
 420         UNPCKHPS( XMM2, XMM2 )                  /* ox*m3+m15 | ox*m3+m15 | ox*m2+m14 | ox*m2+m14 */
 421         MOVSS( XMM2, D(2) )
 422
 423 LLBL(K_GTP13P3DR_skip):
 424         ADD_L( CONST(16), EDI )
 425         ADD_L( EAX, ESI )
 426         CMP_L( ECX, EDI )
 427         JNE( LLBL(K_GTP13P3DR_top) )
 428
 429 LLBL(K_GTP13P3DR_finish):
 430         POP_L( EDI )
 431         POP_L( ESI )
 432         RET
 433 #undef FRAME_OFFSET