src/mesa/x86/sse_xform2.S

   1 /* $Id: sse_xform2.S,v 1.2 2004/04/26 10:10:25 alanh Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 /** TODO:
  28   * - insert PREFETCH instructions to avoid cache-misses !
  29   * - some more optimizations are possible...
  30   * - for 40-50% more performance in the SSE-functions, the
  31   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  32   */
  33
  34 #ifdef USE_SSE_ASM
  35 #include "matypes.h"
  36 #include "xform_args.h"
  37
  38    SEG_TEXT
  39
  40 #define S(i)    REGOFF(i * 4, ESI)
  41 #define D(i)    REGOFF(i * 4, EDI)
  42 #define M(i)    REGOFF(i * 4, EDX)
  43
  44
  45 ALIGNTEXT4
  46 GLOBL GLNAME(_mesa_sse_transform_points2_general)
  47 GLNAME( _mesa_sse_transform_points2_general ):
  48
  49 #define FRAME_OFFSET 8
  50     PUSH_L    ( ESI )
  51     PUSH_L    ( EDI )
  52
  53     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
  54     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
  55
  56     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
  57     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
  58
  59     TEST_L( ECX, ECX )
  60     JZ( LLBL(K_GTP2GR_finish) )                 /* count was zero; go to finish */
  61
  62     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
  63     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
  64
  65     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
  66     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
  67
  68     SHL_L( CONST(4), ECX )                      /* count *= 16 */
  69     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
  70
  71     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
  72     ADD_L( EDI, ECX )                           /* count += dest ptr */
  73
  74 ALIGNTEXT32
  75     MOVAPS( M(0), XMM0 )                        /* m3  | m2  | m1  | m0 */
  76     MOVAPS( M(4), XMM1 )                        /* m7  | m6  | m5  | m4 */
  77     MOVAPS( M(12), XMM2 )                       /* m15 | m14 | m13 | m12 */
  78
  79 ALIGNTEXT32
  80 LLBL(K_GTP2GR_top):
  81     MOVSS( S(0), XMM3 )                         /* ox */
  82     SHUFPS( CONST(0x0), XMM3, XMM3 )            /* ox | ox | ox | ox */
  83     MULPS( XMM0, XMM3 )                         /* ox*m3 | ox*m2 | ox*m1 | ox*m0 */
  84     MOVSS( S(1), XMM4 )                         /* oy */
  85     SHUFPS( CONST(0x0), XMM4, XMM4 )            /* oy | oy | oy | oy */
  86     MULPS( XMM1, XMM4 )                         /* oy*m7 | oy*m6 | oy*m5 | oy*m4 */
  87
  88     ADDPS( XMM4, XMM3 )
  89     ADDPS( XMM2, XMM3 )
  90     MOVAPS( XMM3, D(0) )
  91
  92 LLBL(K_GTP2GR_skip):
  93     ADD_L     ( CONST(16), EDI )
  94     ADD_L     ( EAX, ESI )
  95     CMP_L     ( ECX, EDI )
  96     JNE       ( LLBL(K_GTP2GR_top) )
  97
  98 LLBL(K_GTP2GR_finish):
  99     POP_L     ( EDI )
 100     POP_L     ( ESI )
 101     RET
 102 #undef FRAME_OFFSET
 103
 104
 105 ALIGNTEXT4
 106 GLOBL GLNAME(_mesa_sse_transform_points2_identity)
 107 GLNAME( _mesa_sse_transform_points2_identity ):
 108
 109 #define FRAME_OFFSET 8
 110     PUSH_L    ( ESI )
 111     PUSH_L    ( EDI )
 112
 113     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI ) /* ptr to source GLvector4f */
 114     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 115
 116     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 117
 118     TEST_L( ECX, ECX)
 119     JZ( LLBL(K_GTP2IR_finish) )                 /* count was zero; go to finish */
 120
 121     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 122     OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 123
 124     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 125     MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 126
 127     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 128     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 129
 130     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 131     ADD_L( EDI, ECX )                           /* count += dest ptr */
 132
 133     CMP_L( ESI, EDI )
 134     JE( LLBL(K_GTP2IR_finish) )
 135
 136
 137 ALIGNTEXT32
 138 LLBL(K_GTP2IR_top):
 139     MOV_L     ( S(0), EDX )
 140     MOV_L     ( EDX, D(0) )
 141     MOV_L     ( S(1), EDX )
 142     MOV_L     ( EDX, D(1) )
 143
 144 LLBL(K_GTP2IR_skip):
 145     ADD_L     ( CONST(16), EDI )
 146     ADD_L     ( EAX, ESI )
 147     CMP_L     ( ECX, EDI )
 148     JNE       ( LLBL(K_GTP2IR_top) )
 149
 150 LLBL(K_GTP2IR_finish):
 151     POP_L     ( EDI )
 152     POP_L     ( ESI )
 153     RET
 154 #undef FRAME_OFFSET
 155
 156
 157 ALIGNTEXT4
 158 GLOBL GLNAME(_mesa_sse_transform_points2_3d_no_rot)
 159 GLNAME(_mesa_sse_transform_points2_3d_no_rot):
 160
 161 #define FRAME_OFFSET 8
 162     PUSH_L( ESI )
 163     PUSH_L( EDI )
 164
 165     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 166     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 167
 168     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 169     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 170
 171     TEST_L( ECX, ECX)
 172     JZ( LLBL(K_GTP23DNRR_finish) )              /* count was zero; go to finish */
 173
 174     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 175     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 176
 177     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 178     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 179
 180     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 181     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 182
 183     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 184     ADD_L( EDI, ECX )                           /* count += dest ptr */
 185
 186
 187 ALIGNTEXT32
 188     MOVSS    ( M(0), XMM1 )                     /* - | - |  -  | m0  */
 189     MOVSS    ( M(5), XMM2 )                     /* - | - |  -  | m5  */
 190     UNPCKLPS ( XMM2, XMM1 )                     /* - | - | m5  | m0  */
 191     MOVLPS   ( M(12), XMM2 )                    /* - | - | m13 | m12 */
 192     MOVSS    ( M(14), XMM3 )                    /* - | - |  -  | m14 */
 193
 194 ALIGNTEXT32
 195 LLBL(K_GTP23DNRR_top):
 196     MOVLPS   ( S(0), XMM0 )                     /* - | - |  oy   | ox */
 197     MULPS    ( XMM1, XMM0 )                     /* - | - | oy*m5 | ox*m0 */
 198     ADDPS    ( XMM2, XMM0 )                     /* - | - | +m13  | +m12 */
 199     MOVLPS   ( XMM0, D(0) )                     /* -> D(1) | -> D(0) */
 200
 201     MOVSS    ( XMM3, D(2) )                     /* -> D(2) */
 202
 203 LLBL(K_GTP23DNRR_skip):
 204     ADD_L    ( CONST(16), EDI )
 205     ADD_L    ( EAX, ESI )
 206     CMP_L    ( ECX, EDI )
 207     JNE      ( LLBL(K_GTP23DNRR_top) )
 208
 209 LLBL(K_GTP23DNRR_finish):
 210     POP_L    ( EDI )
 211     POP_L    ( ESI )
 212     RET
 213 #undef FRAME_OFFSET
 214
 215
 216 ALIGNTEXT4
 217 GLOBL GLNAME(_mesa_sse_transform_points2_perspective)
 218 GLNAME(_mesa_sse_transform_points2_perspective):
 219
 220 #define FRAME_OFFSET 8
 221     PUSH_L   ( ESI )
 222     PUSH_L   ( EDI )
 223
 224     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 225     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 226
 227     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 228     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 229
 230     TEST_L( ECX, ECX)
 231     JZ( LLBL(K_GTP23PR_finish) )                /* count was zero; go to finish */
 232
 233     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 234     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 235
 236     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 237     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 238
 239     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 240     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 241
 242     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 243     ADD_L( EDI, ECX )                           /* count += dest ptr */
 244
 245 ALIGNTEXT32
 246     MOVSS    ( M(0), XMM1 )                     /* -  | -  |  -  | m0  */
 247     MOVSS    ( M(5), XMM2 )                     /* -  | -  |  -  | m5  */
 248     UNPCKLPS ( XMM2, XMM1 )                     /* -  | -  | m5  | m0  */
 249     MOVSS    ( M(14), XMM3 )                    /* m14 */
 250     XORPS    ( XMM0, XMM0 )                     /* 0 | 0 | 0 | 0 */
 251
 252 ALIGNTEXT32
 253 LLBL(K_GTP23PR_top):
 254     MOVLPS( S(0), XMM4 )                        /* oy | ox */
 255     MULPS( XMM1, XMM4 )                         /* oy*m5 | ox*m0 */
 256     MOVLPS( XMM4, D(0) )                        /* ->D(1) | ->D(0) */
 257     MOVSS( XMM3, D(2) )                         /* ->D(2) */
 258     MOVSS( XMM0, D(3) )                         /* ->D(3) */
 259
 260 LLBL(K_GTP23PR_skip):
 261     ADD_L( CONST(16), EDI )
 262     ADD_L( EAX, ESI )
 263     CMP_L( ECX, EDI )
 264     JNE( LLBL(K_GTP23PR_top) )
 265
 266 LLBL(K_GTP23PR_finish):
 267     POP_L    ( EDI )
 268     POP_L    ( ESI )
 269     RET
 270 #undef FRAME_OFFSET
 271
 272
 273
 274 ALIGNTEXT4
 275 GLOBL GLNAME(_mesa_sse_transform_points2_2d)
 276 GLNAME(_mesa_sse_transform_points2_2d):
 277
 278 #define FRAME_OFFSET 8
 279     PUSH_L( ESI )
 280     PUSH_L( EDI )
 281
 282     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 283     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 284
 285     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 286     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 287
 288     TEST_L( ECX, ECX)
 289     JZ( LLBL(K_GTP23P2DR_finish) )              /* count was zero; go to finish */
 290
 291     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 292     OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 293
 294     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 295     MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 296
 297     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 298     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 299
 300     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 301     ADD_L( EDI, ECX )                           /* count += dest ptr */
 302
 303 ALIGNTEXT32
 304     MOVLPS( M(0), XMM0 )                        /* m1  | m0 */
 305     MOVLPS( M(4), XMM1 )                        /* m5  | m4 */
 306     MOVLPS( M(12), XMM2 )                       /* m13 | m12 */
 307
 308 ALIGNTEXT32
 309 LLBL(K_GTP23P2DR_top):
 310     MOVSS( S(0), XMM3 )                         /* ox */
 311     SHUFPS( CONST(0x0), XMM3, XMM3 )            /* ox | ox */
 312     MULPS( XMM0, XMM3 )                         /* ox*m1 | ox*m0 */
 313
 314     MOVSS( S(1), XMM4 )                         /* oy */
 315     SHUFPS( CONST(0x0), XMM4, XMM4 )            /* oy | oy */
 316     MULPS( XMM1, XMM4 )                         /* oy*m5 | oy*m4 */
 317
 318     ADDPS( XMM4, XMM3 )
 319     ADDPS( XMM2, XMM3 )
 320     MOVLPS( XMM3, D(0) )                        /* ->D(1) | ->D(0) */
 321
 322 LLBL(K_GTP23P2DR_skip):
 323     ADD_L    ( CONST(16), EDI )
 324     ADD_L    ( EAX, ESI )
 325     CMP_L    ( ECX, EDI )
 326     JNE      ( LLBL(K_GTP23P2DR_top) )
 327
 328 LLBL(K_GTP23P2DR_finish):
 329     POP_L    ( EDI )
 330     POP_L    ( ESI )
 331     RET
 332 #undef FRAME_OFFSET
 333
 334
 335
 336 ALIGNTEXT4
 337 GLOBL GLNAME(_mesa_sse_transform_points2_2d_no_rot)
 338 GLNAME(_mesa_sse_transform_points2_2d_no_rot):
 339
 340 #define FRAME_OFFSET 8
 341         PUSH_L( ESI )
 342         PUSH_L( EDI )
 343
 344         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 345         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 346
 347         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 348         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 349
 350         TEST_L( ECX, ECX)
 351         JZ( LLBL(K_GTP23P2DNRR_finish) )        /* count was zero; go to finish */
 352
 353         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 354         OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 355
 356         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 357         MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 358
 359         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 360         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 361
 362         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 363         ADD_L( EDI, ECX )                       /* count += dest ptr */
 364
 365 ALIGNTEXT32
 366         MOVSS    ( M(0), XMM1 )                 /* m0 */
 367         MOVSS    ( M(5), XMM2 )                 /* m5 */
 368         UNPCKLPS ( XMM2, XMM1 )                 /* m5 | m0 */
 369         MOVLPS   ( M(12), XMM2 )                /* m13 | m12 */
 370
 371 ALIGNTEXT32
 372 LLBL(K_GTP23P2DNRR_top):
 373         MOVLPS( S(0), XMM0 )                    /* oy | ox */
 374         MULPS( XMM1, XMM0 )                     /* oy*m5 | ox*m0 */
 375         ADDPS( XMM2, XMM0 )                     /* +m13 | +m12 */
 376         MOVLPS( XMM0, D(0) )                    /* ->D(1) | ->D(0) */
 377
 378 LLBL(K_GTP23P2DNRR_skip):
 379         ADD_L( CONST(16), EDI )
 380         ADD_L( EAX, ESI )
 381         CMP_L( ECX, EDI )
 382         JNE( LLBL(K_GTP23P2DNRR_top) )
 383
 384 LLBL(K_GTP23P2DNRR_finish):
 385         POP_L( EDI )
 386         POP_L( ESI )
 387         RET
 388 #undef FRAME_OFFSET
 389
 390
 391
 392 ALIGNTEXT4
 393 GLOBL GLNAME(_mesa_sse_transform_points2_3d)
 394 GLNAME(_mesa_sse_transform_points2_3d):
 395
 396 #define FRAME_OFFSET 8
 397         PUSH_L( ESI )
 398         PUSH_L( EDI )
 399
 400         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 401         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 402
 403         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 404         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 405
 406         TEST_L( ECX, ECX)
 407         JZ( LLBL(K_GTP23P3DR_finish) )  /* count was zero; go to finish */
 408
 409         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 410         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 411
 412         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 413         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 414
 415         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 416         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 417
 418         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 419         ADD_L( EDI, ECX )                       /* count += dest ptr */
 420
 421 ALIGNTEXT32
 422         MOVAPS( M(0), XMM0 )                    /* m2  | m1  | m0 */
 423         MOVAPS( M(4), XMM1 )                    /* m6  | m5  | m4 */
 424         MOVAPS( M(12), XMM2 )                   /* m14 | m13 | m12 */
 425
 426 ALIGNTEXT32
 427 LLBL(K_GTP23P3DR_top):
 428         MOVSS( S(0), XMM3 )                     /* ox */
 429         SHUFPS( CONST(0x0), XMM3, XMM3 )        /* ox | ox | ox */
 430         MULPS( XMM0, XMM3 )                     /* ox*m2 | ox*m1 | ox*m0 */
 431
 432         MOVSS( S(1), XMM4 )                     /* oy */
 433         SHUFPS( CONST(0x0), XMM4, XMM4 )        /* oy | oy | oy */
 434         MULPS( XMM1, XMM4 )                     /* oy*m6 | oy*m5 | oy*m4 */
 435
 436         ADDPS( XMM4, XMM3 )
 437         ADDPS( XMM2, XMM3 )
 438
 439         MOVLPS( XMM3, D(0) )                    /* ->D(1) | ->D(0) */
 440         UNPCKHPS( XMM3, XMM3 )
 441         MOVSS( XMM3, D(2) )                     /* ->D(2) */
 442
 443 LLBL(K_GTP23P3DR_skip):
 444         ADD_L( CONST(16), EDI )
 445         ADD_L( EAX, ESI )
 446         CMP_L( ECX, EDI )
 447         JNE( LLBL(K_GTP23P3DR_top) )
 448
 449 LLBL(K_GTP23P3DR_finish):
 450         POP_L( EDI )
 451         POP_L( ESI )
 452         RET
 453 #undef FRAME_OFFSET
 454 #endif