src/mesa/x86/sse_xform2.S

   1
   2 /*
   3  * Mesa 3-D graphics library
   4  * Version:  3.5
   5  *
   6  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   7  *
   8  * Permission is hereby granted, free of charge, to any person obtaining a
   9  * copy of this software and associated documentation files (the "Software"),
  10  * to deal in the Software without restriction, including without limitation
  11  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  12  * and/or sell copies of the Software, and to permit persons to whom the
  13  * Software is furnished to do so, subject to the following conditions:
  14  *
  15  * The above copyright notice and this permission notice shall be included
  16  * in all copies or substantial portions of the Software.
  17  *
  18  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  19  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  20  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  21  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  22  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  23  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  24  */
  25
  26 /** TODO:
  27   * - insert PREFETCH instructions to avoid cache-misses !
  28   * - some more optimizations are possible...
  29   * - for 40-50% more performance in the SSE-functions, the
  30   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  31   */
  32
  33 #ifdef USE_SSE_ASM
  34 #include "assyntax.h"
  35 #include "matypes.h"
  36 #include "xform_args.h"
  37
  38    SEG_TEXT
  39
  40 #define S(i)    REGOFF(i * 4, ESI)
  41 #define D(i)    REGOFF(i * 4, EDI)
  42 #define M(i)    REGOFF(i * 4, EDX)
  43
  44
  45 ALIGNTEXT4
  46 GLOBL GLNAME(_mesa_sse_transform_points2_general)
  47 HIDDEN (_mesa_sse_transform_points2_general)
  48 GLNAME( _mesa_sse_transform_points2_general ):
  49
  50 #define FRAME_OFFSET 8
  51     PUSH_L    ( ESI )
  52     PUSH_L    ( EDI )
  53
  54     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
  55     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
  56
  57     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
  58     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
  59
  60     TEST_L( ECX, ECX )
  61     JZ( LLBL(K_GTP2GR_finish) )                 /* count was zero; go to finish */
  62
  63     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
  64     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
  65
  66     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
  67     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
  68
  69     SHL_L( CONST(4), ECX )                      /* count *= 16 */
  70     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
  71
  72     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
  73     ADD_L( EDI, ECX )                           /* count += dest ptr */
  74
  75 ALIGNTEXT32
  76     MOVAPS( M(0), XMM0 )                        /* m3  | m2  | m1  | m0 */
  77     MOVAPS( M(4), XMM1 )                        /* m7  | m6  | m5  | m4 */
  78     MOVAPS( M(12), XMM2 )                       /* m15 | m14 | m13 | m12 */
  79
  80 ALIGNTEXT32
  81 LLBL(K_GTP2GR_top):
  82     MOVSS( S(0), XMM3 )                         /* ox */
  83     SHUFPS( CONST(0x0), XMM3, XMM3 )            /* ox | ox | ox | ox */
  84     MULPS( XMM0, XMM3 )                         /* ox*m3 | ox*m2 | ox*m1 | ox*m0 */
  85     MOVSS( S(1), XMM4 )                         /* oy */
  86     SHUFPS( CONST(0x0), XMM4, XMM4 )            /* oy | oy | oy | oy */
  87     MULPS( XMM1, XMM4 )                         /* oy*m7 | oy*m6 | oy*m5 | oy*m4 */
  88
  89     ADDPS( XMM4, XMM3 )
  90     ADDPS( XMM2, XMM3 )
  91     MOVAPS( XMM3, D(0) )
  92
  93 LLBL(K_GTP2GR_skip):
  94     ADD_L     ( CONST(16), EDI )
  95     ADD_L     ( EAX, ESI )
  96     CMP_L     ( ECX, EDI )
  97     JNE       ( LLBL(K_GTP2GR_top) )
  98
  99 LLBL(K_GTP2GR_finish):
 100     POP_L     ( EDI )
 101     POP_L     ( ESI )
 102     RET
 103 #undef FRAME_OFFSET
 104
 105
 106 ALIGNTEXT4
 107 GLOBL GLNAME(_mesa_sse_transform_points2_identity)
 108 HIDDEN(_mesa_sse_transform_points2_identity)
 109 GLNAME( _mesa_sse_transform_points2_identity ):
 110
 111 #define FRAME_OFFSET 8
 112     PUSH_L    ( ESI )
 113     PUSH_L    ( EDI )
 114
 115     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI ) /* ptr to source GLvector4f */
 116     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 117
 118     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 119
 120     TEST_L( ECX, ECX)
 121     JZ( LLBL(K_GTP2IR_finish) )                 /* count was zero; go to finish */
 122
 123     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 124     OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 125
 126     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 127     MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 128
 129     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 130     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 131
 132     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 133     ADD_L( EDI, ECX )                           /* count += dest ptr */
 134
 135     CMP_L( ESI, EDI )
 136     JE( LLBL(K_GTP2IR_finish) )
 137
 138
 139 ALIGNTEXT32
 140 LLBL(K_GTP2IR_top):
 141     MOV_L     ( S(0), EDX )
 142     MOV_L     ( EDX, D(0) )
 143     MOV_L     ( S(1), EDX )
 144     MOV_L     ( EDX, D(1) )
 145
 146 LLBL(K_GTP2IR_skip):
 147     ADD_L     ( CONST(16), EDI )
 148     ADD_L     ( EAX, ESI )
 149     CMP_L     ( ECX, EDI )
 150     JNE       ( LLBL(K_GTP2IR_top) )
 151
 152 LLBL(K_GTP2IR_finish):
 153     POP_L     ( EDI )
 154     POP_L     ( ESI )
 155     RET
 156 #undef FRAME_OFFSET
 157
 158
 159 ALIGNTEXT4
 160 GLOBL GLNAME(_mesa_sse_transform_points2_3d_no_rot)
 161 HIDDEN(_mesa_sse_transform_points2_3d_no_rot)
 162 GLNAME(_mesa_sse_transform_points2_3d_no_rot):
 163
 164 #define FRAME_OFFSET 8
 165     PUSH_L( ESI )
 166     PUSH_L( EDI )
 167
 168     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 169     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 170
 171     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 172     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 173
 174     TEST_L( ECX, ECX)
 175     JZ( LLBL(K_GTP23DNRR_finish) )              /* count was zero; go to finish */
 176
 177     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 178     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 179
 180     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 181     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 182
 183     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 184     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 185
 186     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 187     ADD_L( EDI, ECX )                           /* count += dest ptr */
 188
 189
 190 ALIGNTEXT32
 191     MOVSS    ( M(0), XMM1 )                     /* - | - |  -  | m0  */
 192     MOVSS    ( M(5), XMM2 )                     /* - | - |  -  | m5  */
 193     UNPCKLPS ( XMM2, XMM1 )                     /* - | - | m5  | m0  */
 194     MOVLPS   ( M(12), XMM2 )                    /* - | - | m13 | m12 */
 195     MOVSS    ( M(14), XMM3 )                    /* - | - |  -  | m14 */
 196
 197 ALIGNTEXT32
 198 LLBL(K_GTP23DNRR_top):
 199     MOVLPS   ( S(0), XMM0 )                     /* - | - |  oy   | ox */
 200     MULPS    ( XMM1, XMM0 )                     /* - | - | oy*m5 | ox*m0 */
 201     ADDPS    ( XMM2, XMM0 )                     /* - | - | +m13  | +m12 */
 202     MOVLPS   ( XMM0, D(0) )                     /* -> D(1) | -> D(0) */
 203
 204     MOVSS    ( XMM3, D(2) )                     /* -> D(2) */
 205
 206 LLBL(K_GTP23DNRR_skip):
 207     ADD_L    ( CONST(16), EDI )
 208     ADD_L    ( EAX, ESI )
 209     CMP_L    ( ECX, EDI )
 210     JNE      ( LLBL(K_GTP23DNRR_top) )
 211
 212 LLBL(K_GTP23DNRR_finish):
 213     POP_L    ( EDI )
 214     POP_L    ( ESI )
 215     RET
 216 #undef FRAME_OFFSET
 217
 218
 219 ALIGNTEXT4
 220 GLOBL GLNAME(_mesa_sse_transform_points2_perspective)
 221 HIDDEN(_mesa_sse_transform_points2_perspective)
 222 GLNAME(_mesa_sse_transform_points2_perspective):
 223
 224 #define FRAME_OFFSET 8
 225     PUSH_L   ( ESI )
 226     PUSH_L   ( EDI )
 227
 228     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 229     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 230
 231     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 232     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 233
 234     TEST_L( ECX, ECX)
 235     JZ( LLBL(K_GTP23PR_finish) )                /* count was zero; go to finish */
 236
 237     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 238     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 239
 240     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 241     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 242
 243     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 244     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 245
 246     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 247     ADD_L( EDI, ECX )                           /* count += dest ptr */
 248
 249 ALIGNTEXT32
 250     MOVSS    ( M(0), XMM1 )                     /* -  | -  |  -  | m0  */
 251     MOVSS    ( M(5), XMM2 )                     /* -  | -  |  -  | m5  */
 252     UNPCKLPS ( XMM2, XMM1 )                     /* -  | -  | m5  | m0  */
 253     MOVSS    ( M(14), XMM3 )                    /* m14 */
 254     XORPS    ( XMM0, XMM0 )                     /* 0 | 0 | 0 | 0 */
 255
 256 ALIGNTEXT32
 257 LLBL(K_GTP23PR_top):
 258     MOVLPS( S(0), XMM4 )                        /* oy | ox */
 259     MULPS( XMM1, XMM4 )                         /* oy*m5 | ox*m0 */
 260     MOVLPS( XMM4, D(0) )                        /* ->D(1) | ->D(0) */
 261     MOVSS( XMM3, D(2) )                         /* ->D(2) */
 262     MOVSS( XMM0, D(3) )                         /* ->D(3) */
 263
 264 LLBL(K_GTP23PR_skip):
 265     ADD_L( CONST(16), EDI )
 266     ADD_L( EAX, ESI )
 267     CMP_L( ECX, EDI )
 268     JNE( LLBL(K_GTP23PR_top) )
 269
 270 LLBL(K_GTP23PR_finish):
 271     POP_L    ( EDI )
 272     POP_L    ( ESI )
 273     RET
 274 #undef FRAME_OFFSET
 275
 276
 277
 278 ALIGNTEXT4
 279 GLOBL GLNAME(_mesa_sse_transform_points2_2d)
 280 HIDDEN(_mesa_sse_transform_points2_2d)
 281 GLNAME(_mesa_sse_transform_points2_2d):
 282
 283 #define FRAME_OFFSET 8
 284     PUSH_L( ESI )
 285     PUSH_L( EDI )
 286
 287     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 288     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 289
 290     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 291     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 292
 293     TEST_L( ECX, ECX)
 294     JZ( LLBL(K_GTP23P2DR_finish) )              /* count was zero; go to finish */
 295
 296     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 297     OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 298
 299     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 300     MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 301
 302     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 303     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 304
 305     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 306     ADD_L( EDI, ECX )                           /* count += dest ptr */
 307
 308 ALIGNTEXT32
 309     MOVLPS( M(0), XMM0 )                        /* m1  | m0 */
 310     MOVLPS( M(4), XMM1 )                        /* m5  | m4 */
 311     MOVLPS( M(12), XMM2 )                       /* m13 | m12 */
 312
 313 ALIGNTEXT32
 314 LLBL(K_GTP23P2DR_top):
 315     MOVSS( S(0), XMM3 )                         /* ox */
 316     SHUFPS( CONST(0x0), XMM3, XMM3 )            /* ox | ox */
 317     MULPS( XMM0, XMM3 )                         /* ox*m1 | ox*m0 */
 318
 319     MOVSS( S(1), XMM4 )                         /* oy */
 320     SHUFPS( CONST(0x0), XMM4, XMM4 )            /* oy | oy */
 321     MULPS( XMM1, XMM4 )                         /* oy*m5 | oy*m4 */
 322
 323     ADDPS( XMM4, XMM3 )
 324     ADDPS( XMM2, XMM3 )
 325     MOVLPS( XMM3, D(0) )                        /* ->D(1) | ->D(0) */
 326
 327 LLBL(K_GTP23P2DR_skip):
 328     ADD_L    ( CONST(16), EDI )
 329     ADD_L    ( EAX, ESI )
 330     CMP_L    ( ECX, EDI )
 331     JNE      ( LLBL(K_GTP23P2DR_top) )
 332
 333 LLBL(K_GTP23P2DR_finish):
 334     POP_L    ( EDI )
 335     POP_L    ( ESI )
 336     RET
 337 #undef FRAME_OFFSET
 338
 339
 340
 341 ALIGNTEXT4
 342 GLOBL GLNAME(_mesa_sse_transform_points2_2d_no_rot)
 343 HIDDEN(_mesa_sse_transform_points2_2d_no_rot)
 344 GLNAME(_mesa_sse_transform_points2_2d_no_rot):
 345
 346 #define FRAME_OFFSET 8
 347         PUSH_L( ESI )
 348         PUSH_L( EDI )
 349
 350         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 351         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 352
 353         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 354         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 355
 356         TEST_L( ECX, ECX)
 357         JZ( LLBL(K_GTP23P2DNRR_finish) )        /* count was zero; go to finish */
 358
 359         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 360         OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 361
 362         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 363         MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 364
 365         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 366         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 367
 368         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 369         ADD_L( EDI, ECX )                       /* count += dest ptr */
 370
 371 ALIGNTEXT32
 372         MOVSS    ( M(0), XMM1 )                 /* m0 */
 373         MOVSS    ( M(5), XMM2 )                 /* m5 */
 374         UNPCKLPS ( XMM2, XMM1 )                 /* m5 | m0 */
 375         MOVLPS   ( M(12), XMM2 )                /* m13 | m12 */
 376
 377 ALIGNTEXT32
 378 LLBL(K_GTP23P2DNRR_top):
 379         MOVLPS( S(0), XMM0 )                    /* oy | ox */
 380         MULPS( XMM1, XMM0 )                     /* oy*m5 | ox*m0 */
 381         ADDPS( XMM2, XMM0 )                     /* +m13 | +m12 */
 382         MOVLPS( XMM0, D(0) )                    /* ->D(1) | ->D(0) */
 383
 384 LLBL(K_GTP23P2DNRR_skip):
 385         ADD_L( CONST(16), EDI )
 386         ADD_L( EAX, ESI )
 387         CMP_L( ECX, EDI )
 388         JNE( LLBL(K_GTP23P2DNRR_top) )
 389
 390 LLBL(K_GTP23P2DNRR_finish):
 391         POP_L( EDI )
 392         POP_L( ESI )
 393         RET
 394 #undef FRAME_OFFSET
 395
 396
 397
 398 ALIGNTEXT4
 399 GLOBL GLNAME(_mesa_sse_transform_points2_3d)
 400 HIDDEN(_mesa_sse_transform_points2_3d)
 401 GLNAME(_mesa_sse_transform_points2_3d):
 402
 403 #define FRAME_OFFSET 8
 404         PUSH_L( ESI )
 405         PUSH_L( EDI )
 406
 407         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 408         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 409
 410         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 411         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 412
 413         TEST_L( ECX, ECX)
 414         JZ( LLBL(K_GTP23P3DR_finish) )  /* count was zero; go to finish */
 415
 416         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 417         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 418
 419         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 420         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 421
 422         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 423         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 424
 425         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 426         ADD_L( EDI, ECX )                       /* count += dest ptr */
 427
 428 ALIGNTEXT32
 429         MOVAPS( M(0), XMM0 )                    /* m2  | m1  | m0 */
 430         MOVAPS( M(4), XMM1 )                    /* m6  | m5  | m4 */
 431         MOVAPS( M(12), XMM2 )                   /* m14 | m13 | m12 */
 432
 433 ALIGNTEXT32
 434 LLBL(K_GTP23P3DR_top):
 435         MOVSS( S(0), XMM3 )                     /* ox */
 436         SHUFPS( CONST(0x0), XMM3, XMM3 )        /* ox | ox | ox */
 437         MULPS( XMM0, XMM3 )                     /* ox*m2 | ox*m1 | ox*m0 */
 438
 439         MOVSS( S(1), XMM4 )                     /* oy */
 440         SHUFPS( CONST(0x0), XMM4, XMM4 )        /* oy | oy | oy */
 441         MULPS( XMM1, XMM4 )                     /* oy*m6 | oy*m5 | oy*m4 */
 442
 443         ADDPS( XMM4, XMM3 )
 444         ADDPS( XMM2, XMM3 )
 445
 446         MOVLPS( XMM3, D(0) )                    /* ->D(1) | ->D(0) */
 447         UNPCKHPS( XMM3, XMM3 )
 448         MOVSS( XMM3, D(2) )                     /* ->D(2) */
 449
 450 LLBL(K_GTP23P3DR_skip):
 451         ADD_L( CONST(16), EDI )
 452         ADD_L( EAX, ESI )
 453         CMP_L( ECX, EDI )
 454         JNE( LLBL(K_GTP23P3DR_top) )
 455
 456 LLBL(K_GTP23P3DR_finish):
 457         POP_L( EDI )
 458         POP_L( ESI )
 459         RET
 460 #undef FRAME_OFFSET
 461 #endif
 462
 463 #if defined (__ELF__) && defined (__linux__)
 464         .section .note.GNU-stack,"",%progbits
 465 #endif