src/mesa/x86/sse_xform2.S

   1
   2 /*
   3  * Mesa 3-D graphics library
   4  * Version:  3.5
   5  *
   6  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   7  *
   8  * Permission is hereby granted, free of charge, to any person obtaining a
   9  * copy of this software and associated documentation files (the "Software"),
  10  * to deal in the Software without restriction, including without limitation
  11  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  12  * and/or sell copies of the Software, and to permit persons to whom the
  13  * Software is furnished to do so, subject to the following conditions:
  14  *
  15  * The above copyright notice and this permission notice shall be included
  16  * in all copies or substantial portions of the Software.
  17  *
  18  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  19  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  20  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  21  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  22  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  23  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  24  */
  25
  26 /** TODO:
  27   * - insert PREFETCH instructions to avoid cache-misses !
  28   * - some more optimizations are possible...
  29   * - for 40-50% more performance in the SSE-functions, the
  30   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  31   */
  32
  33 #ifdef USE_SSE_ASM
  34 #include "matypes.h"
  35 #include "xform_args.h"
  36
  37    SEG_TEXT
  38
  39 #define S(i)    REGOFF(i * 4, ESI)
  40 #define D(i)    REGOFF(i * 4, EDI)
  41 #define M(i)    REGOFF(i * 4, EDX)
  42
  43
  44 ALIGNTEXT4
  45 GLOBL GLNAME(_mesa_sse_transform_points2_general)
  46 HIDDEN (_mesa_sse_transform_points2_general)
  47 GLNAME( _mesa_sse_transform_points2_general ):
  48
  49 #define FRAME_OFFSET 8
  50     PUSH_L    ( ESI )
  51     PUSH_L    ( EDI )
  52
  53     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
  54     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
  55
  56     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
  57     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
  58
  59     TEST_L( ECX, ECX )
  60     JZ( LLBL(K_GTP2GR_finish) )                 /* count was zero; go to finish */
  61
  62     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
  63     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
  64
  65     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
  66     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
  67
  68     SHL_L( CONST(4), ECX )                      /* count *= 16 */
  69     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
  70
  71     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
  72     ADD_L( EDI, ECX )                           /* count += dest ptr */
  73
  74 ALIGNTEXT32
  75     MOVAPS( M(0), XMM0 )                        /* m3  | m2  | m1  | m0 */
  76     MOVAPS( M(4), XMM1 )                        /* m7  | m6  | m5  | m4 */
  77     MOVAPS( M(12), XMM2 )                       /* m15 | m14 | m13 | m12 */
  78
  79 ALIGNTEXT32
  80 LLBL(K_GTP2GR_top):
  81     MOVSS( S(0), XMM3 )                         /* ox */
  82     SHUFPS( CONST(0x0), XMM3, XMM3 )            /* ox | ox | ox | ox */
  83     MULPS( XMM0, XMM3 )                         /* ox*m3 | ox*m2 | ox*m1 | ox*m0 */
  84     MOVSS( S(1), XMM4 )                         /* oy */
  85     SHUFPS( CONST(0x0), XMM4, XMM4 )            /* oy | oy | oy | oy */
  86     MULPS( XMM1, XMM4 )                         /* oy*m7 | oy*m6 | oy*m5 | oy*m4 */
  87
  88     ADDPS( XMM4, XMM3 )
  89     ADDPS( XMM2, XMM3 )
  90     MOVAPS( XMM3, D(0) )
  91
  92 LLBL(K_GTP2GR_skip):
  93     ADD_L     ( CONST(16), EDI )
  94     ADD_L     ( EAX, ESI )
  95     CMP_L     ( ECX, EDI )
  96     JNE       ( LLBL(K_GTP2GR_top) )
  97
  98 LLBL(K_GTP2GR_finish):
  99     POP_L     ( EDI )
 100     POP_L     ( ESI )
 101     RET
 102 #undef FRAME_OFFSET
 103
 104
 105 ALIGNTEXT4
 106 GLOBL GLNAME(_mesa_sse_transform_points2_identity)
 107 HIDDEN(_mesa_sse_transform_points2_identity)
 108 GLNAME( _mesa_sse_transform_points2_identity ):
 109
 110 #define FRAME_OFFSET 8
 111     PUSH_L    ( ESI )
 112     PUSH_L    ( EDI )
 113
 114     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI ) /* ptr to source GLvector4f */
 115     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 116
 117     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 118
 119     TEST_L( ECX, ECX)
 120     JZ( LLBL(K_GTP2IR_finish) )                 /* count was zero; go to finish */
 121
 122     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 123     OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 124
 125     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 126     MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 127
 128     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 129     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 130
 131     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 132     ADD_L( EDI, ECX )                           /* count += dest ptr */
 133
 134     CMP_L( ESI, EDI )
 135     JE( LLBL(K_GTP2IR_finish) )
 136
 137
 138 ALIGNTEXT32
 139 LLBL(K_GTP2IR_top):
 140     MOV_L     ( S(0), EDX )
 141     MOV_L     ( EDX, D(0) )
 142     MOV_L     ( S(1), EDX )
 143     MOV_L     ( EDX, D(1) )
 144
 145 LLBL(K_GTP2IR_skip):
 146     ADD_L     ( CONST(16), EDI )
 147     ADD_L     ( EAX, ESI )
 148     CMP_L     ( ECX, EDI )
 149     JNE       ( LLBL(K_GTP2IR_top) )
 150
 151 LLBL(K_GTP2IR_finish):
 152     POP_L     ( EDI )
 153     POP_L     ( ESI )
 154     RET
 155 #undef FRAME_OFFSET
 156
 157
 158 ALIGNTEXT4
 159 GLOBL GLNAME(_mesa_sse_transform_points2_3d_no_rot)
 160 HIDDEN(_mesa_sse_transform_points2_3d_no_rot)
 161 GLNAME(_mesa_sse_transform_points2_3d_no_rot):
 162
 163 #define FRAME_OFFSET 8
 164     PUSH_L( ESI )
 165     PUSH_L( EDI )
 166
 167     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 168     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 169
 170     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 171     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 172
 173     TEST_L( ECX, ECX)
 174     JZ( LLBL(K_GTP23DNRR_finish) )              /* count was zero; go to finish */
 175
 176     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 177     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 178
 179     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 180     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 181
 182     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 183     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 184
 185     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 186     ADD_L( EDI, ECX )                           /* count += dest ptr */
 187
 188
 189 ALIGNTEXT32
 190     MOVSS    ( M(0), XMM1 )                     /* - | - |  -  | m0  */
 191     MOVSS    ( M(5), XMM2 )                     /* - | - |  -  | m5  */
 192     UNPCKLPS ( XMM2, XMM1 )                     /* - | - | m5  | m0  */
 193     MOVLPS   ( M(12), XMM2 )                    /* - | - | m13 | m12 */
 194     MOVSS    ( M(14), XMM3 )                    /* - | - |  -  | m14 */
 195
 196 ALIGNTEXT32
 197 LLBL(K_GTP23DNRR_top):
 198     MOVLPS   ( S(0), XMM0 )                     /* - | - |  oy   | ox */
 199     MULPS    ( XMM1, XMM0 )                     /* - | - | oy*m5 | ox*m0 */
 200     ADDPS    ( XMM2, XMM0 )                     /* - | - | +m13  | +m12 */
 201     MOVLPS   ( XMM0, D(0) )                     /* -> D(1) | -> D(0) */
 202
 203     MOVSS    ( XMM3, D(2) )                     /* -> D(2) */
 204
 205 LLBL(K_GTP23DNRR_skip):
 206     ADD_L    ( CONST(16), EDI )
 207     ADD_L    ( EAX, ESI )
 208     CMP_L    ( ECX, EDI )
 209     JNE      ( LLBL(K_GTP23DNRR_top) )
 210
 211 LLBL(K_GTP23DNRR_finish):
 212     POP_L    ( EDI )
 213     POP_L    ( ESI )
 214     RET
 215 #undef FRAME_OFFSET
 216
 217
 218 ALIGNTEXT4
 219 GLOBL GLNAME(_mesa_sse_transform_points2_perspective)
 220 HIDDEN(_mesa_sse_transform_points2_perspective)
 221 GLNAME(_mesa_sse_transform_points2_perspective):
 222
 223 #define FRAME_OFFSET 8
 224     PUSH_L   ( ESI )
 225     PUSH_L   ( EDI )
 226
 227     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 228     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 229
 230     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 231     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 232
 233     TEST_L( ECX, ECX)
 234     JZ( LLBL(K_GTP23PR_finish) )                /* count was zero; go to finish */
 235
 236     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 237     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 238
 239     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 240     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 241
 242     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 243     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 244
 245     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 246     ADD_L( EDI, ECX )                           /* count += dest ptr */
 247
 248 ALIGNTEXT32
 249     MOVSS    ( M(0), XMM1 )                     /* -  | -  |  -  | m0  */
 250     MOVSS    ( M(5), XMM2 )                     /* -  | -  |  -  | m5  */
 251     UNPCKLPS ( XMM2, XMM1 )                     /* -  | -  | m5  | m0  */
 252     MOVSS    ( M(14), XMM3 )                    /* m14 */
 253     XORPS    ( XMM0, XMM0 )                     /* 0 | 0 | 0 | 0 */
 254
 255 ALIGNTEXT32
 256 LLBL(K_GTP23PR_top):
 257     MOVLPS( S(0), XMM4 )                        /* oy | ox */
 258     MULPS( XMM1, XMM4 )                         /* oy*m5 | ox*m0 */
 259     MOVLPS( XMM4, D(0) )                        /* ->D(1) | ->D(0) */
 260     MOVSS( XMM3, D(2) )                         /* ->D(2) */
 261     MOVSS( XMM0, D(3) )                         /* ->D(3) */
 262
 263 LLBL(K_GTP23PR_skip):
 264     ADD_L( CONST(16), EDI )
 265     ADD_L( EAX, ESI )
 266     CMP_L( ECX, EDI )
 267     JNE( LLBL(K_GTP23PR_top) )
 268
 269 LLBL(K_GTP23PR_finish):
 270     POP_L    ( EDI )
 271     POP_L    ( ESI )
 272     RET
 273 #undef FRAME_OFFSET
 274
 275
 276
 277 ALIGNTEXT4
 278 GLOBL GLNAME(_mesa_sse_transform_points2_2d)
 279 HIDDEN(_mesa_sse_transform_points2_2d)
 280 GLNAME(_mesa_sse_transform_points2_2d):
 281
 282 #define FRAME_OFFSET 8
 283     PUSH_L( ESI )
 284     PUSH_L( EDI )
 285
 286     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 287     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 288
 289     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 290     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 291
 292     TEST_L( ECX, ECX)
 293     JZ( LLBL(K_GTP23P2DR_finish) )              /* count was zero; go to finish */
 294
 295     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 296     OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 297
 298     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 299     MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 300
 301     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 302     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 303
 304     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 305     ADD_L( EDI, ECX )                           /* count += dest ptr */
 306
 307 ALIGNTEXT32
 308     MOVLPS( M(0), XMM0 )                        /* m1  | m0 */
 309     MOVLPS( M(4), XMM1 )                        /* m5  | m4 */
 310     MOVLPS( M(12), XMM2 )                       /* m13 | m12 */
 311
 312 ALIGNTEXT32
 313 LLBL(K_GTP23P2DR_top):
 314     MOVSS( S(0), XMM3 )                         /* ox */
 315     SHUFPS( CONST(0x0), XMM3, XMM3 )            /* ox | ox */
 316     MULPS( XMM0, XMM3 )                         /* ox*m1 | ox*m0 */
 317
 318     MOVSS( S(1), XMM4 )                         /* oy */
 319     SHUFPS( CONST(0x0), XMM4, XMM4 )            /* oy | oy */
 320     MULPS( XMM1, XMM4 )                         /* oy*m5 | oy*m4 */
 321
 322     ADDPS( XMM4, XMM3 )
 323     ADDPS( XMM2, XMM3 )
 324     MOVLPS( XMM3, D(0) )                        /* ->D(1) | ->D(0) */
 325
 326 LLBL(K_GTP23P2DR_skip):
 327     ADD_L    ( CONST(16), EDI )
 328     ADD_L    ( EAX, ESI )
 329     CMP_L    ( ECX, EDI )
 330     JNE      ( LLBL(K_GTP23P2DR_top) )
 331
 332 LLBL(K_GTP23P2DR_finish):
 333     POP_L    ( EDI )
 334     POP_L    ( ESI )
 335     RET
 336 #undef FRAME_OFFSET
 337
 338
 339
 340 ALIGNTEXT4
 341 GLOBL GLNAME(_mesa_sse_transform_points2_2d_no_rot)
 342 HIDDEN(_mesa_sse_transform_points2_2d_no_rot)
 343 GLNAME(_mesa_sse_transform_points2_2d_no_rot):
 344
 345 #define FRAME_OFFSET 8
 346         PUSH_L( ESI )
 347         PUSH_L( EDI )
 348
 349         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 350         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 351
 352         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 353         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 354
 355         TEST_L( ECX, ECX)
 356         JZ( LLBL(K_GTP23P2DNRR_finish) )        /* count was zero; go to finish */
 357
 358         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 359         OR_L( CONST(VEC_SIZE_2), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 360
 361         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 362         MOV_L( CONST(2), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 363
 364         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 365         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 366
 367         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 368         ADD_L( EDI, ECX )                       /* count += dest ptr */
 369
 370 ALIGNTEXT32
 371         MOVSS    ( M(0), XMM1 )                 /* m0 */
 372         MOVSS    ( M(5), XMM2 )                 /* m5 */
 373         UNPCKLPS ( XMM2, XMM1 )                 /* m5 | m0 */
 374         MOVLPS   ( M(12), XMM2 )                /* m13 | m12 */
 375
 376 ALIGNTEXT32
 377 LLBL(K_GTP23P2DNRR_top):
 378         MOVLPS( S(0), XMM0 )                    /* oy | ox */
 379         MULPS( XMM1, XMM0 )                     /* oy*m5 | ox*m0 */
 380         ADDPS( XMM2, XMM0 )                     /* +m13 | +m12 */
 381         MOVLPS( XMM0, D(0) )                    /* ->D(1) | ->D(0) */
 382
 383 LLBL(K_GTP23P2DNRR_skip):
 384         ADD_L( CONST(16), EDI )
 385         ADD_L( EAX, ESI )
 386         CMP_L( ECX, EDI )
 387         JNE( LLBL(K_GTP23P2DNRR_top) )
 388
 389 LLBL(K_GTP23P2DNRR_finish):
 390         POP_L( EDI )
 391         POP_L( ESI )
 392         RET
 393 #undef FRAME_OFFSET
 394
 395
 396
 397 ALIGNTEXT4
 398 GLOBL GLNAME(_mesa_sse_transform_points2_3d)
 399 HIDDEN(_mesa_sse_transform_points2_3d)
 400 GLNAME(_mesa_sse_transform_points2_3d):
 401
 402 #define FRAME_OFFSET 8
 403         PUSH_L( ESI )
 404         PUSH_L( EDI )
 405
 406         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 407         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 408
 409         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 410         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 411
 412         TEST_L( ECX, ECX)
 413         JZ( LLBL(K_GTP23P3DR_finish) )  /* count was zero; go to finish */
 414
 415         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 416         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 417
 418         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 419         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 420
 421         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 422         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 423
 424         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 425         ADD_L( EDI, ECX )                       /* count += dest ptr */
 426
 427 ALIGNTEXT32
 428         MOVAPS( M(0), XMM0 )                    /* m2  | m1  | m0 */
 429         MOVAPS( M(4), XMM1 )                    /* m6  | m5  | m4 */
 430         MOVAPS( M(12), XMM2 )                   /* m14 | m13 | m12 */
 431
 432 ALIGNTEXT32
 433 LLBL(K_GTP23P3DR_top):
 434         MOVSS( S(0), XMM3 )                     /* ox */
 435         SHUFPS( CONST(0x0), XMM3, XMM3 )        /* ox | ox | ox */
 436         MULPS( XMM0, XMM3 )                     /* ox*m2 | ox*m1 | ox*m0 */
 437
 438         MOVSS( S(1), XMM4 )                     /* oy */
 439         SHUFPS( CONST(0x0), XMM4, XMM4 )        /* oy | oy | oy */
 440         MULPS( XMM1, XMM4 )                     /* oy*m6 | oy*m5 | oy*m4 */
 441
 442         ADDPS( XMM4, XMM3 )
 443         ADDPS( XMM2, XMM3 )
 444
 445         MOVLPS( XMM3, D(0) )                    /* ->D(1) | ->D(0) */
 446         UNPCKHPS( XMM3, XMM3 )
 447         MOVSS( XMM3, D(2) )                     /* ->D(2) */
 448
 449 LLBL(K_GTP23P3DR_skip):
 450         ADD_L( CONST(16), EDI )
 451         ADD_L( EAX, ESI )
 452         CMP_L( ECX, EDI )
 453         JNE( LLBL(K_GTP23P3DR_top) )
 454
 455 LLBL(K_GTP23P3DR_finish):
 456         POP_L( EDI )
 457         POP_L( ESI )
 458         RET
 459 #undef FRAME_OFFSET
 460 #endif
 461
 462 #if defined (__ELF__) && defined (__linux__)
 463         .section .note.GNU-stack,"",%progbits
 464 #endif