src/mesa/x86/sse_xform3.S

   1
   2 /*
   3  * Mesa 3-D graphics library
   4  * Version:  3.5
   5  *
   6  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   7  *
   8  * Permission is hereby granted, free of charge, to any person obtaining a
   9  * copy of this software and associated documentation files (the "Software"),
  10  * to deal in the Software without restriction, including without limitation
  11  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  12  * and/or sell copies of the Software, and to permit persons to whom the
  13  * Software is furnished to do so, subject to the following conditions:
  14  *
  15  * The above copyright notice and this permission notice shall be included
  16  * in all copies or substantial portions of the Software.
  17  *
  18  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  19  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  20  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  21  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  22  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  23  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  24  */
  25
  26 /** TODO:
  27   * - insert PREFETCH instructions to avoid cache-misses !
  28   * - some more optimizations are possible...
  29   * - for 40-50% more performance in the SSE-functions, the
  30   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  31   */
  32
  33 #ifdef USE_SSE_ASM
  34 #include "matypes.h"
  35 #include "xform_args.h"
  36
  37    SEG_TEXT
  38
  39 #define S(i)    REGOFF(i * 4, ESI)
  40 #define D(i)    REGOFF(i * 4, EDI)
  41 #define M(i)    REGOFF(i * 4, EDX)
  42
  43
  44 ALIGNTEXT4
  45 GLOBL GLNAME(_mesa_sse_transform_points3_general)
  46 HIDDEN(_mesa_sse_transform_points3_general)
  47 GLNAME( _mesa_sse_transform_points3_general ):
  48
  49 #define FRAME_OFFSET 8
  50     PUSH_L    ( ESI )
  51     PUSH_L    ( EDI )
  52
  53     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
  54     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
  55
  56     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
  57     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
  58
  59     CMP_L     ( CONST(0), ECX )                 /* count == 0 ? */
  60     JE        ( LLBL(K_GTPGR_finish) )          /* yes -> nothing to do. */
  61
  62     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
  63     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
  64
  65     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
  66     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
  67
  68     SHL_L( CONST(4), ECX )                      /* count *= 16 */
  69     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
  70
  71     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
  72     ADD_L( EDI, ECX )                           /* count += dest ptr */
  73
  74
  75 ALIGNTEXT32
  76     MOVAPS    ( REGOFF(0, EDX), XMM0 )  /* m0  | m1  | m2  | m3 */
  77     MOVAPS    ( REGOFF(16, EDX), XMM1 ) /* m4  | m5  | m6  | m7 */
  78     MOVAPS    ( REGOFF(32, EDX), XMM2 ) /* m8  | m9  | m10 | m11 */
  79     MOVAPS    ( REGOFF(48, EDX), XMM3 ) /* m12 | m13 | m14 | m15 */
  80
  81
  82 ALIGNTEXT32
  83 LLBL(K_GTPGR_top):
  84     MOVSS     ( REGOFF(0, ESI), XMM4 )          /*    |    |    | ox */
  85     SHUFPS    ( CONST(0x0), XMM4, XMM4 )        /* ox | ox | ox | ox */
  86     MOVSS     ( REGOFF(4, ESI), XMM5 )          /*    |    |    | oy */
  87     SHUFPS    ( CONST(0x0), XMM5, XMM5 )        /* oy | oy | oy | oy */
  88     MOVSS     ( REGOFF(8, ESI), XMM6 )          /*    |    |    | oz */
  89     SHUFPS    ( CONST(0x0), XMM6, XMM6 )        /* oz | oz | oz | oz */
  90
  91     MULPS     ( XMM0, XMM4 )            /* m3*ox  | m2*ox  | m1*ox | m0*ox */
  92     MULPS     ( XMM1, XMM5 )            /* m7*oy  | m6*oy  | m5*oy | m4*oy */
  93     MULPS     ( XMM2, XMM6 )            /* m11*oz | m10*oz | m9*oz | m8*oz */
  94
  95     ADDPS     ( XMM5, XMM4 )
  96     ADDPS     ( XMM6, XMM4 )
  97     ADDPS     ( XMM3, XMM4 )
  98
  99     MOVAPS    ( XMM4, REGOFF(0, EDI) )
 100
 101 LLBL(K_GTPGR_skip):
 102     ADD_L     ( CONST(16), EDI )
 103     ADD_L     ( EAX, ESI )
 104     CMP_L     ( ECX, EDI )
 105     JNE       ( LLBL(K_GTPGR_top) )
 106
 107 LLBL(K_GTPGR_finish):
 108     POP_L     ( EDI )
 109     POP_L     ( ESI )
 110     RET
 111 #undef FRAME_OFFSET
 112
 113
 114 ALIGNTEXT4
 115 GLOBL GLNAME(_mesa_sse_transform_points3_identity)
 116 HIDDEN(_mesa_sse_transform_points3_identity)
 117 GLNAME( _mesa_sse_transform_points3_identity ):
 118
 119 #define FRAME_OFFSET 8
 120     PUSH_L    ( ESI )
 121     PUSH_L    ( EDI )
 122
 123     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 124     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 125
 126     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 127
 128     TEST_L( ECX, ECX)
 129     JZ( LLBL(K_GTPIR_finish) )                  /* count was zero; go to finish */
 130
 131     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 132     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 133
 134     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 135     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 136
 137     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 138     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 139
 140     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 141     ADD_L( EDI, ECX )                           /* count += dest ptr */
 142
 143     CMP_L( ESI, EDI )
 144     JE( LLBL(K_GTPIR_finish) )
 145
 146
 147 ALIGNTEXT32
 148 LLBL(K_GTPIR_top):
 149     MOVLPS    ( S(0), XMM0 )
 150     MOVLPS    ( XMM0, D(0) )
 151     MOVSS     ( S(2), XMM0 )
 152     MOVSS     ( XMM0, D(2) )
 153
 154 LLBL(K_GTPIR_skip):
 155     ADD_L     ( CONST(16), EDI )
 156     ADD_L     ( EAX, ESI )
 157     CMP_L     ( ECX, EDI )
 158     JNE       ( LLBL(K_GTPIR_top) )
 159
 160 LLBL(K_GTPIR_finish):
 161     POP_L     ( EDI )
 162     POP_L     ( ESI )
 163     RET
 164 #undef FRAME_OFFSET
 165
 166
 167
 168
 169 ALIGNTEXT4
 170 GLOBL GLNAME(_mesa_sse_transform_points3_3d_no_rot)
 171 HIDDEN(_mesa_sse_transform_points3_3d_no_rot)
 172 GLNAME(_mesa_sse_transform_points3_3d_no_rot):
 173
 174 #define FRAME_OFFSET 8
 175     PUSH_L( ESI )
 176     PUSH_L( EDI )
 177
 178     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 179     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 180
 181
 182     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 183     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 184
 185     TEST_L( ECX, ECX)
 186     JZ( LLBL(K_GTP3DNRR_finish) )               /* count was zero; go to finish */
 187
 188     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 189     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 190
 191     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 192     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 193
 194     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 195     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 196
 197     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 198     ADD_L( EDI, ECX )                           /* count += dest ptr */
 199
 200
 201 ALIGNTEXT32
 202     MOVSS    ( M(0), XMM1 )                     /* - | - |  -  | m0  */
 203     MOVSS    ( M(5), XMM2 )                     /* - | - |  -  | m5  */
 204     UNPCKLPS ( XMM2, XMM1 )                     /* - | - | m5  | m0  */
 205     MOVLPS   ( M(12), XMM2 )                    /* - | - | m13 | m12 */
 206     MOVSS    ( M(10), XMM3 )                    /* - | - |  -  | m10 */
 207     MOVSS    ( M(14), XMM4 )                    /* - | - |  -  | m14 */
 208
 209 ALIGNTEXT32
 210 LLBL(K_GTP3DNRR_top):
 211
 212     MOVLPS   ( S(0), XMM0 )                     /* - | - |  s1   | s0 */
 213     MULPS    ( XMM1, XMM0 )                     /* - | - | s1*m5 | s0*m0 */
 214     ADDPS    ( XMM2, XMM0 )                     /* - | - | +m13  | +m12 */
 215     MOVLPS   ( XMM0, D(0) )                     /* -> D(1) | -> D(0) */
 216
 217     MOVSS    ( S(2), XMM0 )                     /* sz */
 218     MULSS    ( XMM3, XMM0 )                     /* sz*m10 */
 219     ADDSS    ( XMM4, XMM0 )                     /* +m14 */
 220     MOVSS    ( XMM0, D(2) )                     /* -> D(2) */
 221
 222 LLBL(K_GTP3DNRR_skip):
 223     ADD_L    ( CONST(16), EDI )
 224     ADD_L    ( EAX, ESI )
 225     CMP_L    ( ECX, EDI )
 226     JNE      ( LLBL(K_GTP3DNRR_top) )
 227
 228 LLBL(K_GTP3DNRR_finish):
 229     POP_L    ( EDI )
 230     POP_L    ( ESI )
 231     RET
 232 #undef FRAME_OFFSET
 233
 234
 235
 236 ALIGNTEXT4
 237 GLOBL GLNAME(_mesa_sse_transform_points3_perspective)
 238 HIDDEN(_mesa_sse_transform_points3_perspective)
 239 GLNAME(_mesa_sse_transform_points3_perspective):
 240
 241 #define FRAME_OFFSET 8
 242     PUSH_L   ( ESI )
 243     PUSH_L   ( EDI )
 244
 245     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 246     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 247
 248     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 249     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 250
 251     TEST_L( ECX, ECX)
 252     JZ( LLBL(K_GTP3PR_finish) )                 /* count was zero; go to finish */
 253
 254     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 255     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 256
 257     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 258     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 259
 260     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 261     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 262
 263     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 264     ADD_L( EDI, ECX )                           /* count += dest ptr */
 265
 266 ALIGNTEXT32
 267     MOVSS    ( M(0), XMM1 )                     /* -  | -  |  -  | m0  */
 268     MOVSS    ( M(5), XMM2 )                     /* -  | -  |  -  | m5  */
 269     UNPCKLPS ( XMM2, XMM1 )                     /* -  | -  | m5  | m0  */
 270     MOVLPS   ( M(8), XMM2 )                     /* -  | -  | m9  | m8  */
 271     MOVSS    ( M(10), XMM3 )                    /* m10 */
 272     MOVSS    ( M(14), XMM4 )                    /* m14 */
 273     XORPS    ( XMM6, XMM6 )                     /* 0 */
 274
 275 ALIGNTEXT32
 276 LLBL(K_GTP3PR_top):
 277     MOVLPS   ( S(0), XMM0 )                     /* oy | ox */
 278     MULPS    ( XMM1, XMM0 )                     /* oy*m5 | ox*m0 */
 279     MOVSS    ( S(2), XMM5 )                     /* oz */
 280     SHUFPS   ( CONST(0x0), XMM5, XMM5 )         /* oz | oz */
 281     MULPS    ( XMM2, XMM5 )                     /* oz*m9 | oz*m8 */
 282     ADDPS    ( XMM5, XMM0 )                     /* +oy*m5 | +ox*m0 */
 283     MOVLPS   ( XMM0, D(0) )                     /* ->D(1) | ->D(0) */
 284
 285     MOVSS    ( S(2), XMM0 )                     /* oz */
 286     MULSS    ( XMM3, XMM0 )                     /* oz*m10 */
 287     ADDSS    ( XMM4, XMM0 )                     /* +m14 */
 288     MOVSS    ( XMM0, D(2) )                     /* ->D(2) */
 289
 290     MOVSS    ( S(2), XMM0 )                     /* oz */
 291     MOVSS    ( XMM6, XMM5 )                     /* 0 */
 292     SUBPS    ( XMM0, XMM5 )                     /* -oz */
 293     MOVSS    ( XMM5, D(3) )                     /* ->D(3) */
 294
 295 LLBL(K_GTP3PR_skip):
 296     ADD_L( CONST(16), EDI )
 297     ADD_L( EAX, ESI )
 298     CMP_L( ECX, EDI )
 299     JNE( LLBL(K_GTP3PR_top) )
 300
 301 LLBL(K_GTP3PR_finish):
 302     POP_L    ( EDI )
 303     POP_L    ( ESI )
 304     RET
 305 #undef FRAME_OFFSET
 306
 307
 308
 309 ALIGNTEXT4
 310 GLOBL GLNAME(_mesa_sse_transform_points3_2d)
 311 HIDDEN(_mesa_sse_transform_points3_2d)
 312 GLNAME(_mesa_sse_transform_points3_2d):
 313
 314 #define FRAME_OFFSET 8
 315     PUSH_L( ESI )
 316     PUSH_L( EDI )
 317
 318     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 319     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 320
 321     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 322     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 323
 324     TEST_L( ECX, ECX)
 325     JZ( LLBL(K_GTP3P2DR_finish) )               /* count was zero; go to finish */
 326
 327     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 328     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 329
 330     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 331     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 332
 333     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 334     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 335
 336     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 337     ADD_L( EDI, ECX )                           /* count += dest ptr */
 338
 339 ALIGNTEXT32
 340     MOVLPS( M(0), XMM0 )                        /* m1  | m0 */
 341     MOVLPS( M(4), XMM1 )                        /* m5  | m4 */
 342     MOVLPS( M(12), XMM2 )                       /* m13 | m12 */
 343
 344 ALIGNTEXT32
 345 LLBL(K_GTP3P2DR_top):
 346     MOVSS    ( S(0), XMM3 )                     /* ox */
 347     SHUFPS   ( CONST(0x0), XMM3, XMM3 )         /* ox | ox */
 348     MULPS    ( XMM0, XMM3 )                     /* ox*m1 | ox*m0 */
 349     MOVSS    ( S(1), XMM4 )                     /* oy */
 350     SHUFPS   ( CONST(0x0), XMM4, XMM4 )         /* oy | oy */
 351     MULPS    ( XMM1, XMM4 )                     /* oy*m5 | oy*m4 */
 352
 353     ADDPS    ( XMM4, XMM3 )
 354     ADDPS    ( XMM2, XMM3 )
 355     MOVLPS   ( XMM3, D(0) )
 356
 357     MOVSS    ( S(2), XMM3 )
 358     MOVSS    ( XMM3, D(2) )
 359
 360 LLBL(K_GTP3P2DR_skip):
 361     ADD_L    ( CONST(16), EDI )
 362     ADD_L    ( EAX, ESI )
 363     CMP_L    ( ECX, EDI )
 364     JNE      ( LLBL(K_GTP3P2DR_top) )
 365
 366 LLBL(K_GTP3P2DR_finish):
 367     POP_L    ( EDI )
 368     POP_L    ( ESI )
 369     RET
 370 #undef FRAME_OFFSET
 371
 372
 373
 374 ALIGNTEXT4
 375 GLOBL GLNAME(_mesa_sse_transform_points3_2d_no_rot)
 376 HIDDEN(_mesa_sse_transform_points3_2d_no_rot)
 377 GLNAME(_mesa_sse_transform_points3_2d_no_rot):
 378
 379 #define FRAME_OFFSET 8
 380         PUSH_L( ESI )
 381         PUSH_L( EDI )
 382
 383         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 384         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 385
 386         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 387         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 388
 389         TEST_L( ECX, ECX)
 390         JZ( LLBL(K_GTP3P2DNRR_finish) )         /* count was zero; go to finish */
 391
 392         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 393         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 394
 395         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 396         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 397
 398         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 399         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 400
 401         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 402         ADD_L( EDI, ECX )                       /* count += dest ptr */
 403
 404 ALIGNTEXT32
 405         MOVSS    ( M(0), XMM1 )                 /* m0 */
 406         MOVSS    ( M(5), XMM2 )                 /* m5 */
 407         UNPCKLPS ( XMM2, XMM1 )                 /* m5 | m0 */
 408         MOVLPS   ( M(12), XMM2 )                /* m13 | m12 */
 409
 410 ALIGNTEXT32
 411 LLBL(K_GTP3P2DNRR_top):
 412         MOVLPS( S(0), XMM0 )                    /* oy | ox */
 413         MULPS( XMM1, XMM0 )                     /* oy*m5 | ox*m0 */
 414         ADDPS( XMM2, XMM0 )                     /* +m13 | +m12 */
 415         MOVLPS( XMM0, D(0) )                    /* ->D(1) | ->D(0) */
 416
 417         MOVSS( S(2), XMM0 )
 418         MOVSS( XMM0, D(2) )
 419
 420 LLBL(K_GTP3P2DNRR_skip):
 421         ADD_L( CONST(16), EDI )
 422         ADD_L( EAX, ESI )
 423         CMP_L( ECX, EDI )
 424         JNE( LLBL(K_GTP3P2DNRR_top) )
 425
 426 LLBL(K_GTP3P2DNRR_finish):
 427         POP_L( EDI )
 428         POP_L( ESI )
 429         RET
 430 #undef FRAME_OFFSET
 431
 432
 433
 434
 435 ALIGNTEXT4
 436 GLOBL GLNAME(_mesa_sse_transform_points3_3d)
 437 HIDDEN(_mesa_sse_transform_points3_3d)
 438 GLNAME(_mesa_sse_transform_points3_3d):
 439
 440 #define FRAME_OFFSET 8
 441         PUSH_L( ESI )
 442         PUSH_L( EDI )
 443
 444         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 445         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 446
 447
 448         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 449         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 450
 451         TEST_L( ECX, ECX)
 452         JZ( LLBL(K_GTP3P3DR_finish) )   /* count was zero; go to finish */
 453
 454         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 455         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 456
 457         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 458         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 459
 460         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 461         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 462
 463         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 464         ADD_L( EDI, ECX )                       /* count += dest ptr */
 465
 466
 467 ALIGNTEXT32
 468         MOVAPS( M(0), XMM0 )                    /* m2  | m1  | m0 */
 469         MOVAPS( M(4), XMM1 )                    /* m6  | m5  | m4 */
 470         MOVAPS( M(8), XMM2 )                    /* m10 | m9  | m8 */
 471         MOVAPS( M(12), XMM3 )                   /* m14 | m13 | m12 */
 472
 473 ALIGNTEXT32
 474 LLBL(K_GTP3P3DR_top):
 475         MOVSS( S(0), XMM4 )
 476         SHUFPS( CONST(0x0), XMM4, XMM4 )        /* ox | ox | ox */
 477         MULPS( XMM0, XMM4 )                     /* ox*m2 | ox*m1 | ox*m0 */
 478
 479         MOVSS( S(1), XMM5 )
 480         SHUFPS( CONST(0x0), XMM5, XMM5 )        /* oy | oy | oy */
 481         MULPS( XMM1, XMM5 )                     /* oy*m6 | oy*m5 | oy*m4 */
 482
 483         MOVSS( S(2), XMM6 )
 484         SHUFPS( CONST(0x0), XMM6, XMM6 )        /* oz | oz | oz */
 485         MULPS( XMM2, XMM6 )                     /* oz*m10 | oz*m9 | oz*m8 */
 486
 487         ADDPS( XMM5, XMM4 )                     /* + | + | + */
 488         ADDPS( XMM6, XMM4 )                     /* + | + | + */
 489         ADDPS( XMM3, XMM4 )                     /* + | + | + */
 490
 491         MOVLPS( XMM4, D(0) )                    /* => D(1) | => D(0) */
 492         UNPCKHPS( XMM4, XMM4 )
 493         MOVSS( XMM4, D(2) )
 494
 495 LLBL(K_GTP3P3DR_skip):
 496         ADD_L( CONST(16), EDI )
 497         ADD_L( EAX, ESI )
 498         CMP_L( ECX, EDI )
 499         JNE( LLBL(K_GTP3P3DR_top) )
 500
 501 LLBL(K_GTP3P3DR_finish):
 502         POP_L( EDI )
 503         POP_L( ESI )
 504         RET
 505 #undef FRAME_OFFSET
 506 #endif
 507
 508 #if defined (__ELF__) && defined (__linux__)
 509         .section .note.GNU-stack,"",%progbits
 510 #endif