src/mesa/x86/sse_xform3.S

   1 /* $Id: sse_xform3.S,v 1.2 2004/04/26 10:10:25 alanh Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 /** TODO:
  28   * - insert PREFETCH instructions to avoid cache-misses !
  29   * - some more optimizations are possible...
  30   * - for 40-50% more performance in the SSE-functions, the
  31   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  32   */
  33
  34 #ifdef USE_SSE_ASM
  35 #include "matypes.h"
  36 #include "xform_args.h"
  37
  38    SEG_TEXT
  39
  40 #define S(i)    REGOFF(i * 4, ESI)
  41 #define D(i)    REGOFF(i * 4, EDI)
  42 #define M(i)    REGOFF(i * 4, EDX)
  43
  44
  45 ALIGNTEXT4
  46 GLOBL GLNAME(_mesa_sse_transform_points3_general)
  47 GLNAME( _mesa_sse_transform_points3_general ):
  48
  49 #define FRAME_OFFSET 8
  50     PUSH_L    ( ESI )
  51     PUSH_L    ( EDI )
  52
  53     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
  54     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
  55
  56     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
  57     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
  58
  59     CMP_L     ( CONST(0), ECX )                 /* count == 0 ? */
  60     JE        ( LLBL(K_GTPGR_finish) )          /* yes -> nothing to do. */
  61
  62     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
  63     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
  64
  65     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
  66     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
  67
  68     SHL_L( CONST(4), ECX )                      /* count *= 16 */
  69     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
  70
  71     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
  72     ADD_L( EDI, ECX )                           /* count += dest ptr */
  73
  74
  75 ALIGNTEXT32
  76     MOVAPS    ( REGOFF(0, EDX), XMM0 )  /* m0  | m1  | m2  | m3 */
  77     MOVAPS    ( REGOFF(16, EDX), XMM1 ) /* m4  | m5  | m6  | m7 */
  78     MOVAPS    ( REGOFF(32, EDX), XMM2 ) /* m8  | m9  | m10 | m11 */
  79     MOVAPS    ( REGOFF(48, EDX), XMM3 ) /* m12 | m13 | m14 | m15 */
  80
  81
  82 ALIGNTEXT32
  83 LLBL(K_GTPGR_top):
  84     MOVSS     ( REGOFF(0, ESI), XMM4 )          /*    |    |    | ox */
  85     SHUFPS    ( CONST(0x0), XMM4, XMM4 )        /* ox | ox | ox | ox */
  86     MOVSS     ( REGOFF(4, ESI), XMM5 )          /*    |    |    | oy */
  87     SHUFPS    ( CONST(0x0), XMM5, XMM5 )        /* oy | oy | oy | oy */
  88     MOVSS     ( REGOFF(8, ESI), XMM6 )          /*    |    |    | oz */
  89     SHUFPS    ( CONST(0x0), XMM6, XMM6 )        /* oz | oz | oz | oz */
  90
  91     MULPS     ( XMM0, XMM4 )            /* m3*ox  | m2*ox  | m1*ox | m0*ox */
  92     MULPS     ( XMM1, XMM5 )            /* m7*oy  | m6*oy  | m5*oy | m4*oy */
  93     MULPS     ( XMM2, XMM6 )            /* m11*oz | m10*oz | m9*oz | m8*oz */
  94
  95     ADDPS     ( XMM5, XMM4 )
  96     ADDPS     ( XMM6, XMM4 )
  97     ADDPS     ( XMM3, XMM4 )
  98
  99     MOVAPS    ( XMM4, REGOFF(0, EDI) )
 100
 101 LLBL(K_GTPGR_skip):
 102     ADD_L     ( CONST(16), EDI )
 103     ADD_L     ( EAX, ESI )
 104     CMP_L     ( ECX, EDI )
 105     JNE       ( LLBL(K_GTPGR_top) )
 106
 107 LLBL(K_GTPGR_finish):
 108     POP_L     ( EDI )
 109     POP_L     ( ESI )
 110     RET
 111 #undef FRAME_OFFSET
 112
 113
 114 ALIGNTEXT4
 115 GLOBL GLNAME(_mesa_sse_transform_points3_identity)
 116 GLNAME( _mesa_sse_transform_points3_identity ):
 117
 118 #define FRAME_OFFSET 8
 119     PUSH_L    ( ESI )
 120     PUSH_L    ( EDI )
 121
 122     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 123     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 124
 125     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 126
 127     TEST_L( ECX, ECX)
 128     JZ( LLBL(K_GTPIR_finish) )                  /* count was zero; go to finish */
 129
 130     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 131     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 132
 133     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 134     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 135
 136     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 137     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 138
 139     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 140     ADD_L( EDI, ECX )                           /* count += dest ptr */
 141
 142     CMP_L( ESI, EDI )
 143     JE( LLBL(K_GTPIR_finish) )
 144
 145
 146 ALIGNTEXT32
 147 LLBL(K_GTPIR_top):
 148     MOVLPS    ( S(0), XMM0 )
 149     MOVLPS    ( XMM0, D(0) )
 150     MOVSS     ( S(2), XMM0 )
 151     MOVSS     ( XMM0, D(2) )
 152
 153 LLBL(K_GTPIR_skip):
 154     ADD_L     ( CONST(16), EDI )
 155     ADD_L     ( EAX, ESI )
 156     CMP_L     ( ECX, EDI )
 157     JNE       ( LLBL(K_GTPIR_top) )
 158
 159 LLBL(K_GTPIR_finish):
 160     POP_L     ( EDI )
 161     POP_L     ( ESI )
 162     RET
 163 #undef FRAME_OFFSET
 164
 165
 166
 167
 168 ALIGNTEXT4
 169 GLOBL GLNAME(_mesa_sse_transform_points3_3d_no_rot)
 170 GLNAME(_mesa_sse_transform_points3_3d_no_rot):
 171
 172 #define FRAME_OFFSET 8
 173     PUSH_L( ESI )
 174     PUSH_L( EDI )
 175
 176     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 177     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 178
 179
 180     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 181     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 182
 183     TEST_L( ECX, ECX)
 184     JZ( LLBL(K_GTP3DNRR_finish) )               /* count was zero; go to finish */
 185
 186     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 187     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 188
 189     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 190     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 191
 192     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 193     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 194
 195     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 196     ADD_L( EDI, ECX )                           /* count += dest ptr */
 197
 198
 199 ALIGNTEXT32
 200     MOVSS    ( M(0), XMM1 )                     /* - | - |  -  | m0  */
 201     MOVSS    ( M(5), XMM2 )                     /* - | - |  -  | m5  */
 202     UNPCKLPS ( XMM2, XMM1 )                     /* - | - | m5  | m0  */
 203     MOVLPS   ( M(12), XMM2 )                    /* - | - | m13 | m12 */
 204     MOVSS    ( M(10), XMM3 )                    /* - | - |  -  | m10 */
 205     MOVSS    ( M(14), XMM4 )                    /* - | - |  -  | m14 */
 206
 207 ALIGNTEXT32
 208 LLBL(K_GTP3DNRR_top):
 209
 210     MOVLPS   ( S(0), XMM0 )                     /* - | - |  s1   | s0 */
 211     MULPS    ( XMM1, XMM0 )                     /* - | - | s1*m5 | s0*m0 */
 212     ADDPS    ( XMM2, XMM0 )                     /* - | - | +m13  | +m12 */
 213     MOVLPS   ( XMM0, D(0) )                     /* -> D(1) | -> D(0) */
 214
 215     MOVSS    ( S(2), XMM0 )                     /* sz */
 216     MULSS    ( XMM3, XMM0 )                     /* sz*m10 */
 217     ADDSS    ( XMM4, XMM0 )                     /* +m14 */
 218     MOVSS    ( XMM0, D(2) )                     /* -> D(2) */
 219
 220 LLBL(K_GTP3DNRR_skip):
 221     ADD_L    ( CONST(16), EDI )
 222     ADD_L    ( EAX, ESI )
 223     CMP_L    ( ECX, EDI )
 224     JNE      ( LLBL(K_GTP3DNRR_top) )
 225
 226 LLBL(K_GTP3DNRR_finish):
 227     POP_L    ( EDI )
 228     POP_L    ( ESI )
 229     RET
 230 #undef FRAME_OFFSET
 231
 232
 233
 234 ALIGNTEXT4
 235 GLOBL GLNAME(_mesa_sse_transform_points3_perspective)
 236 GLNAME(_mesa_sse_transform_points3_perspective):
 237
 238 #define FRAME_OFFSET 8
 239     PUSH_L   ( ESI )
 240     PUSH_L   ( EDI )
 241
 242     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 243     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 244
 245     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 246     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 247
 248     TEST_L( ECX, ECX)
 249     JZ( LLBL(K_GTP3PR_finish) )                 /* count was zero; go to finish */
 250
 251     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 252     OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 253
 254     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 255     MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 256
 257     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 258     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 259
 260     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 261     ADD_L( EDI, ECX )                           /* count += dest ptr */
 262
 263 ALIGNTEXT32
 264     MOVSS    ( M(0), XMM1 )                     /* -  | -  |  -  | m0  */
 265     MOVSS    ( M(5), XMM2 )                     /* -  | -  |  -  | m5  */
 266     UNPCKLPS ( XMM2, XMM1 )                     /* -  | -  | m5  | m0  */
 267     MOVLPS   ( M(8), XMM2 )                     /* -  | -  | m9  | m8  */
 268     MOVSS    ( M(10), XMM3 )                    /* m10 */
 269     MOVSS    ( M(14), XMM4 )                    /* m14 */
 270     XORPS    ( XMM6, XMM6 )                     /* 0 */
 271
 272 ALIGNTEXT32
 273 LLBL(K_GTP3PR_top):
 274     MOVLPS   ( S(0), XMM0 )                     /* oy | ox */
 275     MULPS    ( XMM1, XMM0 )                     /* oy*m5 | ox*m0 */
 276     MOVSS    ( S(2), XMM5 )                     /* oz */
 277     SHUFPS   ( CONST(0x0), XMM5, XMM5 )         /* oz | oz */
 278     MULPS    ( XMM2, XMM5 )                     /* oz*m9 | oz*m8 */
 279     ADDPS    ( XMM5, XMM0 )                     /* +oy*m5 | +ox*m0 */
 280     MOVLPS   ( XMM0, D(0) )                     /* ->D(1) | ->D(0) */
 281
 282     MOVSS    ( S(2), XMM0 )                     /* oz */
 283     MULSS    ( XMM3, XMM0 )                     /* oz*m10 */
 284     ADDSS    ( XMM4, XMM0 )                     /* +m14 */
 285     MOVSS    ( XMM0, D(2) )                     /* ->D(2) */
 286
 287     MOVSS    ( S(2), XMM0 )                     /* oz */
 288     MOVSS    ( XMM6, XMM5 )                     /* 0 */
 289     SUBPS    ( XMM0, XMM5 )                     /* -oz */
 290     MOVSS    ( XMM5, D(3) )                     /* ->D(3) */
 291
 292 LLBL(K_GTP3PR_skip):
 293     ADD_L( CONST(16), EDI )
 294     ADD_L( EAX, ESI )
 295     CMP_L( ECX, EDI )
 296     JNE( LLBL(K_GTP3PR_top) )
 297
 298 LLBL(K_GTP3PR_finish):
 299     POP_L    ( EDI )
 300     POP_L    ( ESI )
 301     RET
 302 #undef FRAME_OFFSET
 303
 304
 305
 306 ALIGNTEXT4
 307 GLOBL GLNAME(_mesa_sse_transform_points3_2d)
 308 GLNAME(_mesa_sse_transform_points3_2d):
 309
 310 #define FRAME_OFFSET 8
 311     PUSH_L( ESI )
 312     PUSH_L( EDI )
 313
 314     MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )  /* ptr to source GLvector4f */
 315     MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )    /* ptr to dest GLvector4f */
 316
 317     MOV_L( ARG_MATRIX, EDX )                    /* ptr to matrix */
 318     MOV_L( REGOFF(V4F_COUNT, ESI), ECX )        /* source count */
 319
 320     TEST_L( ECX, ECX)
 321     JZ( LLBL(K_GTP3P2DR_finish) )               /* count was zero; go to finish */
 322
 323     MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )       /* stride */
 324     OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )   /* set dest flags */
 325
 326     MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )        /* set dest count */
 327     MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )    /* set dest size */
 328
 329     SHL_L( CONST(4), ECX )                      /* count *= 16 */
 330     MOV_L( REGOFF(V4F_START, ESI), ESI )        /* ptr to first source vertex */
 331
 332     MOV_L( REGOFF(V4F_START, EDI), EDI )        /* ptr to first dest vertex */
 333     ADD_L( EDI, ECX )                           /* count += dest ptr */
 334
 335 ALIGNTEXT32
 336     MOVLPS( M(0), XMM0 )                        /* m1  | m0 */
 337     MOVLPS( M(4), XMM1 )                        /* m5  | m4 */
 338     MOVLPS( M(12), XMM2 )                       /* m13 | m12 */
 339
 340 ALIGNTEXT32
 341 LLBL(K_GTP3P2DR_top):
 342     MOVSS    ( S(0), XMM3 )                     /* ox */
 343     SHUFPS   ( CONST(0x0), XMM3, XMM3 )         /* ox | ox */
 344     MULPS    ( XMM0, XMM3 )                     /* ox*m1 | ox*m0 */
 345     MOVSS    ( S(1), XMM4 )                     /* oy */
 346     SHUFPS   ( CONST(0x0), XMM4, XMM4 )         /* oy | oy */
 347     MULPS    ( XMM1, XMM4 )                     /* oy*m5 | oy*m4 */
 348
 349     ADDPS    ( XMM4, XMM3 )
 350     ADDPS    ( XMM2, XMM3 )
 351     MOVLPS   ( XMM3, D(0) )
 352
 353     MOVSS    ( S(2), XMM3 )
 354     MOVSS    ( XMM3, D(2) )
 355
 356 LLBL(K_GTP3P2DR_skip):
 357     ADD_L    ( CONST(16), EDI )
 358     ADD_L    ( EAX, ESI )
 359     CMP_L    ( ECX, EDI )
 360     JNE      ( LLBL(K_GTP3P2DR_top) )
 361
 362 LLBL(K_GTP3P2DR_finish):
 363     POP_L    ( EDI )
 364     POP_L    ( ESI )
 365     RET
 366 #undef FRAME_OFFSET
 367
 368
 369
 370 ALIGNTEXT4
 371 GLOBL GLNAME(_mesa_sse_transform_points3_2d_no_rot)
 372 GLNAME(_mesa_sse_transform_points3_2d_no_rot):
 373
 374 #define FRAME_OFFSET 8
 375         PUSH_L( ESI )
 376         PUSH_L( EDI )
 377
 378         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 379         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 380
 381         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 382         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 383
 384         TEST_L( ECX, ECX)
 385         JZ( LLBL(K_GTP3P2DNRR_finish) )         /* count was zero; go to finish */
 386
 387         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 388         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 389
 390         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 391         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 392
 393         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 394         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 395
 396         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 397         ADD_L( EDI, ECX )                       /* count += dest ptr */
 398
 399 ALIGNTEXT32
 400         MOVSS    ( M(0), XMM1 )                 /* m0 */
 401         MOVSS    ( M(5), XMM2 )                 /* m5 */
 402         UNPCKLPS ( XMM2, XMM1 )                 /* m5 | m0 */
 403         MOVLPS   ( M(12), XMM2 )                /* m13 | m12 */
 404
 405 ALIGNTEXT32
 406 LLBL(K_GTP3P2DNRR_top):
 407         MOVLPS( S(0), XMM0 )                    /* oy | ox */
 408         MULPS( XMM1, XMM0 )                     /* oy*m5 | ox*m0 */
 409         ADDPS( XMM2, XMM0 )                     /* +m13 | +m12 */
 410         MOVLPS( XMM0, D(0) )                    /* ->D(1) | ->D(0) */
 411
 412         MOVSS( S(2), XMM0 )
 413         MOVSS( XMM0, D(2) )
 414
 415 LLBL(K_GTP3P2DNRR_skip):
 416         ADD_L( CONST(16), EDI )
 417         ADD_L( EAX, ESI )
 418         CMP_L( ECX, EDI )
 419         JNE( LLBL(K_GTP3P2DNRR_top) )
 420
 421 LLBL(K_GTP3P2DNRR_finish):
 422         POP_L( EDI )
 423         POP_L( ESI )
 424         RET
 425 #undef FRAME_OFFSET
 426
 427
 428
 429
 430 ALIGNTEXT4
 431 GLOBL GLNAME(_mesa_sse_transform_points3_3d)
 432 GLNAME(_mesa_sse_transform_points3_3d):
 433
 434 #define FRAME_OFFSET 8
 435         PUSH_L( ESI )
 436         PUSH_L( EDI )
 437
 438         MOV_L( REGOFF(OFFSET_SOURCE+8, ESP), ESI )      /* ptr to source GLvector4f */
 439         MOV_L( REGOFF(OFFSET_DEST+8, ESP), EDI )        /* ptr to dest GLvector4f */
 440
 441
 442         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 443         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 444
 445         TEST_L( ECX, ECX)
 446         JZ( LLBL(K_GTP3P3DR_finish) )   /* count was zero; go to finish */
 447
 448         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 449         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) )       /* set dest flags */
 450
 451         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 452         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )        /* set dest size */
 453
 454         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 455         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 456
 457         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 458         ADD_L( EDI, ECX )                       /* count += dest ptr */
 459
 460
 461 ALIGNTEXT32
 462         MOVAPS( M(0), XMM0 )                    /* m2  | m1  | m0 */
 463         MOVAPS( M(4), XMM1 )                    /* m6  | m5  | m4 */
 464         MOVAPS( M(8), XMM2 )                    /* m10 | m9  | m8 */
 465         MOVAPS( M(12), XMM3 )                   /* m14 | m13 | m12 */
 466
 467 ALIGNTEXT32
 468 LLBL(K_GTP3P3DR_top):
 469         MOVSS( S(0), XMM4 )
 470         SHUFPS( CONST(0x0), XMM4, XMM4 )        /* ox | ox | ox */
 471         MULPS( XMM0, XMM4 )                     /* ox*m2 | ox*m1 | ox*m0 */
 472
 473         MOVSS( S(1), XMM5 )
 474         SHUFPS( CONST(0x0), XMM5, XMM5 )        /* oy | oy | oy */
 475         MULPS( XMM1, XMM5 )                     /* oy*m6 | oy*m5 | oy*m4 */
 476
 477         MOVSS( S(2), XMM6 )
 478         SHUFPS( CONST(0x0), XMM6, XMM6 )        /* oz | oz | oz */
 479         MULPS( XMM2, XMM6 )                     /* oz*m10 | oz*m9 | oz*m8 */
 480
 481         ADDPS( XMM5, XMM4 )                     /* + | + | + */
 482         ADDPS( XMM6, XMM4 )                     /* + | + | + */
 483         ADDPS( XMM3, XMM4 )                     /* + | + | + */
 484
 485         MOVLPS( XMM4, D(0) )                    /* => D(1) | => D(0) */
 486         UNPCKHPS( XMM4, XMM4 )
 487         MOVSS( XMM4, D(2) )
 488
 489 LLBL(K_GTP3P3DR_skip):
 490         ADD_L( CONST(16), EDI )
 491         ADD_L( EAX, ESI )
 492         CMP_L( ECX, EDI )
 493         JNE( LLBL(K_GTP3P3DR_top) )
 494
 495 LLBL(K_GTP3P3DR_finish):
 496         POP_L( EDI )
 497         POP_L( ESI )
 498         RET
 499 #undef FRAME_OFFSET
 500 #endif