src/mesa/x86/sse_xform4.S

   1
   2 /*
   3  * Mesa 3-D graphics library
   4  * Version:  3.5
   5  *
   6  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   7  *
   8  * Permission is hereby granted, free of charge, to any person obtaining a
   9  * copy of this software and associated documentation files (the "Software"),
  10  * to deal in the Software without restriction, including without limitation
  11  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  12  * and/or sell copies of the Software, and to permit persons to whom the
  13  * Software is furnished to do so, subject to the following conditions:
  14  *
  15  * The above copyright notice and this permission notice shall be included
  16  * in all copies or substantial portions of the Software.
  17  *
  18  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  19  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  20  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  21  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  22  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  23  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  24  */
  25
  26 #ifdef USE_SSE_ASM
  27 #include "matypes.h"
  28 #include "xform_args.h"
  29
  30         SEG_TEXT
  31
  32 #define FRAME_OFFSET    8
  33
  34 #define SRC(i)          REGOFF(i * 4, ESI)
  35 #define DST(i)          REGOFF(i * 4, EDI)
  36 #define MAT(i)          REGOFF(i * 4, EDX)
  37
  38 #define SELECT(r0, r1, r2, r3)  CONST( r0 * 64 + r1 * 16 + r2 * 4 + r3 )
  39
  40
  41 ALIGNTEXT16
  42 GLOBL GLNAME( _mesa_sse_transform_points4_general )
  43 HIDDEN(_mesa_sse_transform_points4_general)
  44 GLNAME( _mesa_sse_transform_points4_general ):
  45
  46         PUSH_L( ESI )
  47         PUSH_L( EDI )
  48
  49         MOV_L( ARG_SOURCE, ESI )
  50         MOV_L( ARG_DEST, EDI )
  51
  52         MOV_L( ARG_MATRIX, EDX )
  53         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )
  54
  55         TEST_L( ECX, ECX )                      /* verify non-zero count */
  56         JE( LLBL( sse_general_done ) )
  57
  58         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
  59         OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) ) /* set dest flags */
  60
  61         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
  62         MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )/* set dest size */
  63
  64         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
  65         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
  66
  67         PREFETCHT0( REGIND(ESI) )
  68
  69         MOVAPS( MAT(0), XMM4 )                  /* m3  | m2  | m1  | m0  */
  70         MOVAPS( MAT(4), XMM5 )                  /* m7  | m6  | m5  | m4  */
  71         MOVAPS( MAT(8), XMM6 )                  /* m11 | m10 | m9  | m8  */
  72         MOVAPS( MAT(12), XMM7 )                 /* m15 | m14 | m13 | m12 */
  73
  74 ALIGNTEXT16
  75 LLBL( sse_general_loop ):
  76
  77         MOVSS( SRC(0), XMM0 )                   /* ox */
  78         SHUFPS( CONST(0x0), XMM0, XMM0 )        /* ox | ox | ox | ox */
  79         MULPS( XMM4, XMM0 )                     /* ox*m3 | ox*m2 | ox*m1 | ox*m0 */
  80
  81         MOVSS( SRC(1), XMM1 )                   /* oy */
  82         SHUFPS( CONST(0x0), XMM1, XMM1 )        /* oy | oy | oy | oy */
  83         MULPS( XMM5, XMM1 )                     /* oy*m7 | oy*m6 | oy*m5 | oy*m4 */
  84
  85         MOVSS( SRC(2), XMM2 )                   /* oz */
  86         SHUFPS( CONST(0x0), XMM2, XMM2 )        /* oz | oz | oz | oz */
  87         MULPS( XMM6, XMM2 )                     /* oz*m11 | oz*m10 | oz*m9 | oz*m8 */
  88
  89         MOVSS( SRC(3), XMM3 )                   /* ow */
  90         SHUFPS( CONST(0x0), XMM3, XMM3 )        /* ow | ow | ow | ow */
  91         MULPS( XMM7, XMM3 )                     /* ow*m15 | ow*m14 | ow*m13 | ow*m12 */
  92
  93         ADDPS( XMM1, XMM0 )                     /* ox*m3+oy*m7 | ... */
  94         ADDPS( XMM2, XMM0 )                     /* ox*m3+oy*m7+oz*m11 | ... */
  95         ADDPS( XMM3, XMM0 )                     /* ox*m3+oy*m7+oz*m11+ow*m15 | ... */
  96         MOVAPS( XMM0, DST(0) )                  /* ->D(3) | ->D(2) | ->D(1) | ->D(0) */
  97
  98         ADD_L( CONST(16), EDI )
  99         ADD_L( EAX, ESI )
 100
 101         DEC_L( ECX )
 102         JNZ( LLBL( sse_general_loop ) )
 103
 104 LLBL( sse_general_done ):
 105
 106         POP_L( EDI )
 107         POP_L( ESI )
 108         RET
 109
 110
 111
 112
 113 ALIGNTEXT4
 114 GLOBL GLNAME( _mesa_sse_transform_points4_3d )
 115 HIDDEN(_mesa_sse_transform_points4_3d)
 116 GLNAME( _mesa_sse_transform_points4_3d ):
 117
 118         PUSH_L( ESI )
 119         PUSH_L( EDI )
 120
 121         MOV_L( ARG_SOURCE, ESI )                /* ptr to source GLvector4f */
 122         MOV_L( ARG_DEST, EDI )                  /* ptr to dest GLvector4f */
 123
 124         MOV_L( ARG_MATRIX, EDX )                /* ptr to matrix */
 125         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )    /* source count */
 126
 127         TEST_L( ECX, ECX)
 128         JZ( LLBL(K_GTP43P3DR_finish) )          /* count was zero; go to finish */
 129
 130         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 131         OR_L( CONST(VEC_SIZE_3), REGOFF(V4F_FLAGS, EDI) ) /* set dest flags */
 132
 133         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 134         MOV_L( CONST(3), REGOFF(V4F_SIZE, EDI) )/* set dest size */
 135
 136         SHL_L( CONST(4), ECX )                  /* count *= 16 */
 137         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 138
 139         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 140         ADD_L( EDI, ECX )                       /* count += dest ptr */
 141
 142         MOVAPS( MAT(0), XMM0 )                  /* m3  | m2  | m1  |  m0 */
 143         MOVAPS( MAT(4), XMM1 )                  /* m7  | m6  | m5  |  m4 */
 144         MOVAPS( MAT(8), XMM2 )                  /* m11 | m10 | m9  |  m8 */
 145         MOVAPS( MAT(12), XMM3 )                 /* m15 | m14 | m13 | m12 */
 146
 147 ALIGNTEXT32
 148 LLBL( K_GTP43P3DR_top ):
 149         MOVSS( SRC(0), XMM4 )                   /* ox */
 150         SHUFPS( CONST(0x0), XMM4, XMM4 )        /* ox | ox | ox | ox */
 151         MULPS( XMM0, XMM4 )                     /* ox*m3 | ox*m2 | ox*m1 | ox*m0 */
 152
 153         MOVSS( SRC(1), XMM5 )                   /* oy */
 154         SHUFPS( CONST(0x0), XMM5, XMM5 )        /* oy | oy | oy | oy */
 155         MULPS( XMM1, XMM5 )                     /* oy*m7 | oy*m6 | oy*m5 | oy*m4 */
 156
 157         MOVSS( SRC(2), XMM6 )                   /* oz */
 158         SHUFPS( CONST(0x0), XMM6, XMM6 )        /* oz | oz | oz | oz */
 159         MULPS( XMM2, XMM6 )                     /* oz*m11 | oz*m10 | oz*m9 | oz*m8 */
 160
 161         MOVSS( SRC(3), XMM7 )                   /* ow */
 162         SHUFPS( CONST(0x0), XMM7, XMM7 )        /* ow | ow | ow | ow */
 163         MULPS( XMM3, XMM7 )                     /* ow*m15 | ow*m14 | ow*m13 | ow*m12 */
 164
 165         ADDPS( XMM5, XMM4 )                     /* ox*m3+oy*m7 | ... */
 166         ADDPS( XMM6, XMM4 )                     /* ox*m3+oy*m7+oz*m11 | ... */
 167         ADDPS( XMM7, XMM4 )                     /* ox*m3+oy*m7+oz*m11+ow*m15 | ... */
 168         MOVAPS( XMM4, DST(0) )                  /* ->D(3) | ->D(2) | ->D(1) | ->D(0) */
 169
 170         MOVSS( SRC(3), XMM4 )                   /* ow */
 171         MOVSS( XMM4, DST(3) )                   /* ->D(3) */
 172
 173 LLBL( K_GTP43P3DR_skip ):
 174         ADD_L( CONST(16), EDI )
 175         ADD_L( EAX, ESI )
 176         CMP_L( ECX, EDI )
 177         JNE( LLBL(K_GTP43P3DR_top) )
 178
 179 LLBL( K_GTP43P3DR_finish ):
 180         POP_L( EDI )
 181         POP_L( ESI )
 182         RET
 183
 184
 185 ALIGNTEXT16
 186 GLOBL GLNAME( _mesa_sse_transform_points4_identity )
 187 HIDDEN(_mesa_sse_transform_points4_identity)
 188 GLNAME( _mesa_sse_transform_points4_identity ):
 189
 190         PUSH_L( ESI )
 191         PUSH_L( EDI )
 192
 193         MOV_L( ARG_SOURCE, ESI )
 194         MOV_L( ARG_DEST, EDI )
 195
 196         MOV_L( ARG_MATRIX, EDX )
 197         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )
 198
 199         TEST_L( ECX, ECX )                      /* verify non-zero count */
 200         JE( LLBL( sse_identity_done ) )
 201
 202         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )   /* stride */
 203         OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) ) /* set dest flags */
 204
 205         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )    /* set dest count */
 206         MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )/* set dest size */
 207
 208         MOV_L( REGOFF(V4F_START, ESI), ESI )    /* ptr to first source vertex */
 209         MOV_L( REGOFF(V4F_START, EDI), EDI )    /* ptr to first dest vertex */
 210
 211 ALIGNTEXT16
 212 LLBL( sse_identity_loop ):
 213
 214         PREFETCHNTA( REGOFF(32, ESI) )
 215
 216         MOVAPS( REGIND(ESI), XMM0 )
 217         ADD_L( EAX, ESI )
 218
 219         MOVAPS( XMM0, REGIND(EDI) )
 220         ADD_L( CONST(16), EDI )
 221
 222         DEC_L( ECX )
 223         JNZ( LLBL( sse_identity_loop ) )
 224
 225 LLBL( sse_identity_done ):
 226
 227         POP_L( EDI )
 228         POP_L( ESI )
 229         RET
 230 #endif
 231
 232 #if defined (__ELF__) && defined (__linux__)
 233         .section .note.GNU-stack,"",%progbits
 234 #endif