src/mesa/x86/x86_cliptest.S

   1 /* $Id: x86_cliptest.S,v 1.5 2001/03/03 21:11:32 brianp Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2000  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #include "assyntax.h"
  28 #include "clip_args.h"
  29
  30 #define FP_ONE          1065353216
  31 #define FP_ZERO         0
  32
  33 #define SRC(i)          REGOFF(i * 4, ESI)
  34 #define DST(i)          REGOFF(i * 4, EDI)
  35 #define MAT(i)          REGOFF(i * 4, EDX)
  36
  37
  38 /*
  39  * Table for clip test.
  40  *
  41  *      bit6 = SRC(3) < 0
  42  *      bit5 = SRC(2) < 0
  43  *      bit4 = abs(S(2)) > abs(S(3))
  44  *      bit3 = SRC(1) < 0
  45  *      bit2 = abs(S(1)) > abs(S(3))
  46  *      bit1 = SRC(0) < 0
  47  *      bit0 = abs(S(0)) > abs(S(3))
  48  */
  49
  50         SEG_DATA
  51
  52 clip_table:
  53         D_BYTE 0, 1, 0, 2, 4, 5, 4, 6
  54         D_BYTE 0, 1, 0, 2, 8, 9, 8, 10
  55         D_BYTE 32, 33, 32, 34, 36, 37, 36, 38
  56         D_BYTE 32, 33, 32, 34, 40, 41, 40, 42
  57         D_BYTE 0, 1, 0, 2, 4, 5, 4, 6
  58         D_BYTE 0, 1, 0, 2, 8, 9, 8, 10
  59         D_BYTE 16, 17, 16, 18, 20, 21, 20, 22
  60         D_BYTE 16, 17, 16, 18, 24, 25, 24, 26
  61         D_BYTE 63, 61, 63, 62, 55, 53, 55, 54
  62         D_BYTE 63, 61, 63, 62, 59, 57, 59, 58
  63         D_BYTE 47, 45, 47, 46, 39, 37, 39, 38
  64         D_BYTE 47, 45, 47, 46, 43, 41, 43, 42
  65         D_BYTE 63, 61, 63, 62, 55, 53, 55, 54
  66         D_BYTE 63, 61, 63, 62, 59, 57, 59, 58
  67         D_BYTE 31, 29, 31, 30, 23, 21, 23, 22
  68         D_BYTE 31, 29, 31, 30, 27, 25, 27, 26
  69
  70
  71         SEG_TEXT
  72
  73 /*
  74  * _mesa_x86_cliptest_points4
  75  *
  76  *   AL:  ormask
  77  *   AH:  andmask
  78  *   EBX: temp0
  79  *   ECX: temp1
  80  *   EDX: clipmask[]
  81  *   ESI: clip[]
  82  *   EDI: proj[]
  83  *   EBP: temp2
  84  */
  85
  86 #if defined(__ELF__) && defined(__PIC__) && !defined(ELFPIC)
  87 #define ELFPIC
  88 #endif
  89
  90 ALIGNTEXT16
  91 GLOBL GLNAME( _mesa_x86_cliptest_points4 )
  92 GLNAME( _mesa_x86_cliptest_points4 ):
  93
  94 #ifdef ELFPIC
  95 #define FRAME_OFFSET 20
  96 #else
  97 #define FRAME_OFFSET 16
  98 #endif
  99         PUSH_L( ESI )
 100         PUSH_L( EDI )
 101         PUSH_L( EBP )
 102         PUSH_L( EBX )
 103
 104 #ifdef ELFPIC
 105         /* store pointer to clip_table on stack */
 106         CALL( LLBL( ctp4_get_eip ) )
 107         ADD_L( CONST(_GLOBAL_OFFSET_TABLE_), EBX )
 108         MOV_L( REGOFF(clip_table@GOT, EBX), EBX )
 109         PUSH_L( EBX )
 110         JMP( LLBL( ctp4_clip_table_ready ) )
 111
 112 LLBL( ctp4_get_eip ):
 113         /* store eip in ebx */
 114         MOV_L( REGIND(ESP), EBX )
 115         RET
 116
 117 LLBL( ctp4_clip_table_ready ):
 118 #endif
 119
 120         MOV_L( ARG_SOURCE, ESI )
 121         MOV_L( ARG_DEST, EDI )
 122
 123         MOV_L( ARG_CLIP, EDX )
 124         MOV_L( ARG_OR, EBX )
 125
 126         MOV_L( ARG_AND, EBP )
 127         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )
 128
 129         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )
 130         MOV_L( REGOFF(V4F_START, ESI), ESI )
 131
 132         OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )
 133         MOV_L( EAX, ARG_SOURCE )        /* put stride in ARG_SOURCE */
 134
 135         MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )
 136         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )
 137
 138         MOV_L( REGOFF(V4F_START, EDI), EDI )
 139         ADD_L( EDX, ECX )
 140
 141         MOV_L( ECX, ARG_CLIP )          /* put clipmask + count in ARG_CLIP */
 142         CMP_L( ECX, EDX )
 143
 144         MOV_B( REGIND(EBX), AL )
 145         MOV_B( REGIND(EBP), AH )
 146
 147         JZ( LLBL( ctp4_finish ) )
 148
 149 ALIGNTEXT16
 150 LLBL( ctp4_top ):
 151
 152         FLD1                    /* F3 */
 153         FDIV_S( SRC(3) )
 154
 155         MOV_L( SRC(3), EBP )
 156         MOV_L( SRC(2), EBX )
 157
 158         XOR_L( ECX, ECX )
 159         ADD_L( EBP, EBP )       /* ebp = abs(S(3))*2 ; carry = sign of S(3) */
 160
 161         ADC_L( ECX, ECX )
 162         ADD_L( EBX, EBX )       /* ebx = abs(S(2))*2 ; carry = sign of S(2) */
 163
 164         ADC_L( ECX, ECX )
 165         CMP_L( EBX, EBP )       /* carry = abs(S(2))*2 > abs(S(3))*2 */
 166
 167         ADC_L( ECX, ECX )
 168         MOV_L( SRC(1), EBX )
 169
 170         ADD_L( EBX, EBX )       /* ebx = abs(S(1))*2 ; carry = sign of S(1) */
 171
 172         ADC_L( ECX, ECX )
 173         CMP_L( EBX, EBP )       /* carry = abs(S(1))*2 > abs(S(3))*2 */
 174
 175         ADC_L( ECX, ECX )
 176         MOV_L( SRC(0), EBX )
 177
 178         ADD_L( EBX, EBX )       /* ebx = abs(S(0))*2 ; carry = sign of S(0) */
 179
 180         ADC_L( ECX, ECX )
 181         CMP_L( EBX, EBP )       /* carry = abs(S(0))*2 > abs(S(3))*2 */
 182
 183         ADC_L( ECX, ECX )
 184
 185 #ifdef ELFPIC
 186         MOV_L( REGIND(ESP), EBP )       /* clip_table */
 187
 188         MOV_B( REGBI(EBP, ECX), CL )
 189 #else
 190         MOV_B( REGOFF(clip_table,ECX), CL )
 191 #endif
 192
 193         OR_B( CL, AL )
 194         AND_B( CL, AH )
 195
 196         TEST_B( CL, CL )
 197         MOV_B( CL, REGIND(EDX) )
 198
 199         JZ( LLBL( ctp4_proj ) )
 200
 201         FSTP( ST(0) )                   /* */
 202         JMP( LLBL( ctp4_next ) )
 203
 204 LLBL( ctp4_proj ):
 205
 206         FLD_S( SRC(0) )                 /* F0 F3 */
 207         FMUL2( ST(1), ST(0) )
 208
 209         FLD_S( SRC(1) )                 /* F1 F0 F3 */
 210         FMUL2( ST(2), ST(0) )
 211
 212         FLD_S( SRC(2) )                 /* F2 F1 F0 F3 */
 213         FMUL2( ST(3), ST(0) )
 214
 215         FXCH( ST(2) )                   /* F0 F1 F2 F3 */
 216         FSTP_S( DST(0) )                /* F1 F2 F3 */
 217         FSTP_S( DST(1) )                /* F2 F3 */
 218         FSTP_S( DST(2) )                /* F3 */
 219         FSTP_S( DST(3) )                /* */
 220
 221 LLBL( ctp4_next ):
 222
 223         INC_L( EDX )
 224         ADD_L( CONST(16), EDI )
 225
 226         ADD_L( ARG_SOURCE, ESI )
 227         CMP_L( EDX, ARG_CLIP )
 228
 229         JNZ( LLBL( ctp4_top ) )
 230
 231         MOV_L( ARG_OR, ECX )
 232         MOV_L( ARG_AND, EDX )
 233
 234         MOV_B( AL, REGIND(ECX) )
 235         MOV_B( AH, REGIND(EDX) )
 236
 237 LLBL( ctp4_finish ):
 238
 239         MOV_L( ARG_DEST, EAX )
 240 #ifdef ELFPIC
 241         POP_L( ESI )                    /* discard ptr to clip_table */
 242 #endif
 243         POP_L( EBX )
 244         POP_L( EBP )
 245         POP_L( EDI )
 246         POP_L( ESI )
 247
 248         RET
 249
 250
 251
 252
 253
 254
 255
 256 ALIGNTEXT16
 257 GLOBL GLNAME( _mesa_x86_cliptest_points4_np )
 258 GLNAME( _mesa_x86_cliptest_points4_np ):
 259
 260 #ifdef ELFPIC
 261 #define FRAME_OFFSET 20
 262 #else
 263 #define FRAME_OFFSET 16
 264 #endif
 265         PUSH_L( ESI )
 266         PUSH_L( EDI )
 267         PUSH_L( EBP )
 268         PUSH_L( EBX )
 269
 270 #ifdef ELFPIC
 271         /* store pointer to clip_table on stack */
 272         CALL( LLBL( ctp4_np_get_eip ) )
 273         ADD_L( CONST(_GLOBAL_OFFSET_TABLE_), EBX )
 274         MOV_L( REGOFF(clip_table@GOT, EBX), EBX )
 275         PUSH_L( EBX )
 276         JMP( LLBL( ctp4_np_clip_table_ready ) )
 277
 278 LLBL( ctp4_np_get_eip ):
 279         /* store eip in ebx */
 280         MOV_L( REGIND(ESP), EBX )
 281         RET
 282
 283 LLBL( ctp4_np_clip_table_ready ):
 284 #endif
 285
 286         MOV_L( ARG_SOURCE, ESI )
 287         /* slot */
 288
 289         MOV_L( ARG_CLIP, EDX )
 290         MOV_L( ARG_OR, EBX )
 291
 292         MOV_L( ARG_AND, EBP )
 293         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )
 294
 295         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )
 296         MOV_L( REGOFF(V4F_START, ESI), ESI )
 297
 298         MOV_L( EAX, ARG_DEST )          /* put stride in ARG_DEST */
 299         ADD_L( EDX, ECX )
 300
 301         MOV_L( ECX, EDI )               /* put clipmask + count in EDI */
 302         CMP_L( ECX, EDX )
 303
 304         MOV_B( REGIND(EBX), AL )
 305         MOV_B( REGIND(EBP), AH )
 306
 307         JZ( LLBL( ctp4_np_finish ) )
 308
 309 ALIGNTEXT16
 310 LLBL( ctp4_np_top ):
 311
 312         MOV_L( SRC(3), EBP )
 313         MOV_L( SRC(2), EBX )
 314
 315         XOR_L( ECX, ECX )
 316         ADD_L( EBP, EBP )       /* ebp = abs(S(3))*2 ; carry = sign of S(3) */
 317
 318         ADC_L( ECX, ECX )
 319         ADD_L( EBX, EBX )       /* ebx = abs(S(2))*2 ; carry = sign of S(2) */
 320
 321         ADC_L( ECX, ECX )
 322         CMP_L( EBX, EBP )       /* carry = abs(S(2))*2 > abs(S(3))*2 */
 323
 324         ADC_L( ECX, ECX )
 325         MOV_L( SRC(1), EBX )
 326
 327         ADD_L( EBX, EBX )       /* ebx = abs(S(1))*2 ; carry = sign of S(1) */
 328
 329         ADC_L( ECX, ECX )
 330         CMP_L( EBX, EBP )       /* carry = abs(S(1))*2 > abs(S(3))*2 */
 331
 332         ADC_L( ECX, ECX )
 333         MOV_L( SRC(0), EBX )
 334
 335         ADD_L( EBX, EBX )       /* ebx = abs(S(0))*2 ; carry = sign of S(0) */
 336
 337         ADC_L( ECX, ECX )
 338         CMP_L( EBX, EBP )       /* carry = abs(S(0))*2 > abs(S(3))*2 */
 339
 340         ADC_L( ECX, ECX )
 341
 342 #ifdef ELFPIC
 343         MOV_L( REGIND(ESP), EBP )       /* clip_table */
 344
 345         MOV_B( REGBI(EBP, ECX), CL )
 346 #else
 347         MOV_B( REGOFF(clip_table,ECX), CL )
 348 #endif
 349
 350         OR_B( CL, AL )
 351         AND_B( CL, AH )
 352
 353         TEST_B( CL, CL )
 354         MOV_B( CL, REGIND(EDX) )
 355
 356         INC_L( EDX )
 357         /* slot */
 358
 359         ADD_L( ARG_DEST, ESI )
 360         CMP_L( EDX, EDI )
 361
 362         JNZ( LLBL( ctp4_np_top ) )
 363
 364         MOV_L( ARG_OR, ECX )
 365         MOV_L( ARG_AND, EDX )
 366
 367         MOV_B( AL, REGIND(ECX) )
 368         MOV_B( AH, REGIND(EDX) )
 369
 370 LLBL( ctp4_np_finish ):
 371
 372         MOV_L( ARG_SOURCE, EAX )
 373 #ifdef ELFPIC
 374         POP_L( ESI )                    /* discard ptr to clip_table */
 375 #endif
 376         POP_L( EBX )
 377         POP_L( EBP )
 378         POP_L( EDI )
 379         POP_L( ESI )
 380
 381         RET
 382
 383
 384
 385
 386
 387
 388
 389
 390
 391
 392
 393
 394
 395
 396
 397
 398
 399
 400
 401
 402
 403
 404
 405
 406
 407
 408