src/mesa/x86/x86_cliptest.S

   1 /* $Id: x86_cliptest.S,v 1.7 2001/05/13 18:55:15 gareth Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #include "matypes.h"
  28 #include "clip_args.h"
  29
  30 #define FP_ONE          1065353216
  31 #define FP_ZERO         0
  32
  33 #define SRC(i)          REGOFF(i * 4, ESI)
  34 #define DST(i)          REGOFF(i * 4, EDI)
  35 #define MAT(i)          REGOFF(i * 4, EDX)
  36
  37
  38 /*
  39  * Table for clip test.
  40  *
  41  *      bit6 = SRC(3) < 0
  42  *      bit5 = SRC(2) < 0
  43  *      bit4 = abs(S(2)) > abs(S(3))
  44  *      bit3 = SRC(1) < 0
  45  *      bit2 = abs(S(1)) > abs(S(3))
  46  *      bit1 = SRC(0) < 0
  47  *      bit0 = abs(S(0)) > abs(S(3))
  48  */
  49
  50         SEG_DATA
  51
  52 clip_table:
  53         D_BYTE 0, 1, 0, 2, 4, 5, 4, 6
  54         D_BYTE 0, 1, 0, 2, 8, 9, 8, 10
  55         D_BYTE 32, 33, 32, 34, 36, 37, 36, 38
  56         D_BYTE 32, 33, 32, 34, 40, 41, 40, 42
  57         D_BYTE 0, 1, 0, 2, 4, 5, 4, 6
  58         D_BYTE 0, 1, 0, 2, 8, 9, 8, 10
  59         D_BYTE 16, 17, 16, 18, 20, 21, 20, 22
  60         D_BYTE 16, 17, 16, 18, 24, 25, 24, 26
  61         D_BYTE 63, 61, 63, 62, 55, 53, 55, 54
  62         D_BYTE 63, 61, 63, 62, 59, 57, 59, 58
  63         D_BYTE 47, 45, 47, 46, 39, 37, 39, 38
  64         D_BYTE 47, 45, 47, 46, 43, 41, 43, 42
  65         D_BYTE 63, 61, 63, 62, 55, 53, 55, 54
  66         D_BYTE 63, 61, 63, 62, 59, 57, 59, 58
  67         D_BYTE 31, 29, 31, 30, 23, 21, 23, 22
  68         D_BYTE 31, 29, 31, 30, 27, 25, 27, 26
  69
  70
  71         SEG_TEXT
  72
  73 /*
  74  * _mesa_x86_cliptest_points4
  75  *
  76  *   AL:  ormask
  77  *   AH:  andmask
  78  *   EBX: temp0
  79  *   ECX: temp1
  80  *   EDX: clipmask[]
  81  *   ESI: clip[]
  82  *   EDI: proj[]
  83  *   EBP: temp2
  84  */
  85
  86 #if defined(__ELF__) && defined(__PIC__) && !defined(ELFPIC)
  87 #define ELFPIC
  88 #endif
  89
  90 ALIGNTEXT16
  91 GLOBL GLNAME( _mesa_x86_cliptest_points4 )
  92 GLNAME( _mesa_x86_cliptest_points4 ):
  93
  94 #ifdef ELFPIC
  95 #define FRAME_OFFSET 20
  96 #else
  97 #define FRAME_OFFSET 16
  98 #endif
  99         PUSH_L( ESI )
 100         PUSH_L( EDI )
 101         PUSH_L( EBP )
 102         PUSH_L( EBX )
 103
 104 #ifdef ELFPIC
 105         /* store pointer to clip_table on stack */
 106         CALL( LLBL( ctp4_get_eip ) )
 107         ADD_L( CONST(_GLOBAL_OFFSET_TABLE_), EBX )
 108         MOV_L( REGOFF(clip_table@GOT, EBX), EBX )
 109         PUSH_L( EBX )
 110         JMP( LLBL( ctp4_clip_table_ready ) )
 111
 112 LLBL( ctp4_get_eip ):
 113         /* store eip in ebx */
 114         MOV_L( REGIND(ESP), EBX )
 115         RET
 116
 117 LLBL( ctp4_clip_table_ready ):
 118 #endif
 119
 120         MOV_L( ARG_SOURCE, ESI )
 121         MOV_L( ARG_DEST, EDI )
 122
 123         MOV_L( ARG_CLIP, EDX )
 124         MOV_L( ARG_OR, EBX )
 125
 126         MOV_L( ARG_AND, EBP )
 127         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )
 128
 129         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )
 130         MOV_L( REGOFF(V4F_START, ESI), ESI )
 131
 132         OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )
 133         MOV_L( EAX, ARG_SOURCE )        /* put stride in ARG_SOURCE */
 134
 135         MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )
 136         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )
 137
 138         MOV_L( REGOFF(V4F_START, EDI), EDI )
 139         ADD_L( EDX, ECX )
 140
 141         MOV_L( ECX, ARG_CLIP )          /* put clipmask + count in ARG_CLIP */
 142         CMP_L( ECX, EDX )
 143
 144         MOV_B( REGIND(EBX), AL )
 145         MOV_B( REGIND(EBP), AH )
 146
 147         JZ( LLBL( ctp4_finish ) )
 148
 149 ALIGNTEXT16
 150 LLBL( ctp4_top ):
 151
 152         MOV_L( SRC(3), ECX )
 153         FLD1                            /* F3 */
 154
 155         TEST_L( ECX, ECX )              /* GH: If src[3] is zero, abort */
 156         JZ( LLBL( ctp4_noproj ) )
 157
 158         FDIV_S( SRC(3) )
 159
 160         MOV_L( SRC(3), EBP )
 161         MOV_L( SRC(2), EBX )
 162
 163         XOR_L( ECX, ECX )
 164         ADD_L( EBP, EBP )       /* ebp = abs(S(3))*2 ; carry = sign of S(3) */
 165
 166         ADC_L( ECX, ECX )
 167         ADD_L( EBX, EBX )       /* ebx = abs(S(2))*2 ; carry = sign of S(2) */
 168
 169         ADC_L( ECX, ECX )
 170         CMP_L( EBX, EBP )       /* carry = abs(S(2))*2 > abs(S(3))*2 */
 171
 172         ADC_L( ECX, ECX )
 173         MOV_L( SRC(1), EBX )
 174
 175         ADD_L( EBX, EBX )       /* ebx = abs(S(1))*2 ; carry = sign of S(1) */
 176
 177         ADC_L( ECX, ECX )
 178         CMP_L( EBX, EBP )       /* carry = abs(S(1))*2 > abs(S(3))*2 */
 179
 180         ADC_L( ECX, ECX )
 181         MOV_L( SRC(0), EBX )
 182
 183         ADD_L( EBX, EBX )       /* ebx = abs(S(0))*2 ; carry = sign of S(0) */
 184
 185         ADC_L( ECX, ECX )
 186         CMP_L( EBX, EBP )       /* carry = abs(S(0))*2 > abs(S(3))*2 */
 187
 188         ADC_L( ECX, ECX )
 189
 190 #ifdef ELFPIC
 191         MOV_L( REGIND(ESP), EBP )       /* clip_table */
 192
 193         MOV_B( REGBI(EBP, ECX), CL )
 194 #else
 195         MOV_B( REGOFF(clip_table,ECX), CL )
 196 #endif
 197
 198         OR_B( CL, AL )
 199         AND_B( CL, AH )
 200
 201         TEST_B( CL, CL )
 202         MOV_B( CL, REGIND(EDX) )
 203
 204         JZ( LLBL( ctp4_proj ) )
 205
 206 LLBL( ctp4_noproj ):
 207
 208         FLDZ                            /* F0 F3 */
 209
 210         FST_S( DST(0) )                 /* F0 F3 */
 211         FST_S( DST(1) )                 /* F0 F3 */
 212         FSTP_S( DST(2) )                /* F3 */
 213         FSTP_S( DST(3) )                /* */
 214
 215         JMP( LLBL( ctp4_next ) )
 216
 217 LLBL( ctp4_proj ):
 218
 219         FLD_S( SRC(0) )                 /* F0 F3 */
 220         FMUL2( ST(1), ST(0) )
 221
 222         FLD_S( SRC(1) )                 /* F1 F0 F3 */
 223         FMUL2( ST(2), ST(0) )
 224
 225         FLD_S( SRC(2) )                 /* F2 F1 F0 F3 */
 226         FMUL2( ST(3), ST(0) )
 227
 228         FXCH( ST(2) )                   /* F0 F1 F2 F3 */
 229         FSTP_S( DST(0) )                /* F1 F2 F3 */
 230         FSTP_S( DST(1) )                /* F2 F3 */
 231         FSTP_S( DST(2) )                /* F3 */
 232         FSTP_S( DST(3) )                /* */
 233
 234 LLBL( ctp4_next ):
 235
 236         INC_L( EDX )
 237         ADD_L( CONST(16), EDI )
 238
 239         ADD_L( ARG_SOURCE, ESI )
 240         CMP_L( EDX, ARG_CLIP )
 241
 242         JNZ( LLBL( ctp4_top ) )
 243
 244         MOV_L( ARG_OR, ECX )
 245         MOV_L( ARG_AND, EDX )
 246
 247         MOV_B( AL, REGIND(ECX) )
 248         MOV_B( AH, REGIND(EDX) )
 249
 250 LLBL( ctp4_finish ):
 251
 252         MOV_L( ARG_DEST, EAX )
 253 #ifdef ELFPIC
 254         POP_L( ESI )                    /* discard ptr to clip_table */
 255 #endif
 256         POP_L( EBX )
 257         POP_L( EBP )
 258         POP_L( EDI )
 259         POP_L( ESI )
 260
 261         RET
 262
 263
 264
 265
 266
 267
 268
 269 ALIGNTEXT16
 270 GLOBL GLNAME( _mesa_x86_cliptest_points4_np )
 271 GLNAME( _mesa_x86_cliptest_points4_np ):
 272
 273 #ifdef ELFPIC
 274 #define FRAME_OFFSET 20
 275 #else
 276 #define FRAME_OFFSET 16
 277 #endif
 278         PUSH_L( ESI )
 279         PUSH_L( EDI )
 280         PUSH_L( EBP )
 281         PUSH_L( EBX )
 282
 283 #ifdef ELFPIC
 284         /* store pointer to clip_table on stack */
 285         CALL( LLBL( ctp4_np_get_eip ) )
 286         ADD_L( CONST(_GLOBAL_OFFSET_TABLE_), EBX )
 287         MOV_L( REGOFF(clip_table@GOT, EBX), EBX )
 288         PUSH_L( EBX )
 289         JMP( LLBL( ctp4_np_clip_table_ready ) )
 290
 291 LLBL( ctp4_np_get_eip ):
 292         /* store eip in ebx */
 293         MOV_L( REGIND(ESP), EBX )
 294         RET
 295
 296 LLBL( ctp4_np_clip_table_ready ):
 297 #endif
 298
 299         MOV_L( ARG_SOURCE, ESI )
 300         /* slot */
 301
 302         MOV_L( ARG_CLIP, EDX )
 303         MOV_L( ARG_OR, EBX )
 304
 305         MOV_L( ARG_AND, EBP )
 306         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )
 307
 308         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )
 309         MOV_L( REGOFF(V4F_START, ESI), ESI )
 310
 311         MOV_L( EAX, ARG_DEST )          /* put stride in ARG_DEST */
 312         ADD_L( EDX, ECX )
 313
 314         MOV_L( ECX, EDI )               /* put clipmask + count in EDI */
 315         CMP_L( ECX, EDX )
 316
 317         MOV_B( REGIND(EBX), AL )
 318         MOV_B( REGIND(EBP), AH )
 319
 320         JZ( LLBL( ctp4_np_finish ) )
 321
 322 ALIGNTEXT16
 323 LLBL( ctp4_np_top ):
 324
 325         MOV_L( SRC(3), EBP )
 326         MOV_L( SRC(2), EBX )
 327
 328         XOR_L( ECX, ECX )
 329         ADD_L( EBP, EBP )       /* ebp = abs(S(3))*2 ; carry = sign of S(3) */
 330
 331         ADC_L( ECX, ECX )
 332         ADD_L( EBX, EBX )       /* ebx = abs(S(2))*2 ; carry = sign of S(2) */
 333
 334         ADC_L( ECX, ECX )
 335         CMP_L( EBX, EBP )       /* carry = abs(S(2))*2 > abs(S(3))*2 */
 336
 337         ADC_L( ECX, ECX )
 338         MOV_L( SRC(1), EBX )
 339
 340         ADD_L( EBX, EBX )       /* ebx = abs(S(1))*2 ; carry = sign of S(1) */
 341
 342         ADC_L( ECX, ECX )
 343         CMP_L( EBX, EBP )       /* carry = abs(S(1))*2 > abs(S(3))*2 */
 344
 345         ADC_L( ECX, ECX )
 346         MOV_L( SRC(0), EBX )
 347
 348         ADD_L( EBX, EBX )       /* ebx = abs(S(0))*2 ; carry = sign of S(0) */
 349
 350         ADC_L( ECX, ECX )
 351         CMP_L( EBX, EBP )       /* carry = abs(S(0))*2 > abs(S(3))*2 */
 352
 353         ADC_L( ECX, ECX )
 354
 355 #ifdef ELFPIC
 356         MOV_L( REGIND(ESP), EBP )       /* clip_table */
 357
 358         MOV_B( REGBI(EBP, ECX), CL )
 359 #else
 360         MOV_B( REGOFF(clip_table,ECX), CL )
 361 #endif
 362
 363         OR_B( CL, AL )
 364         AND_B( CL, AH )
 365
 366         TEST_B( CL, CL )
 367         MOV_B( CL, REGIND(EDX) )
 368
 369         INC_L( EDX )
 370         /* slot */
 371
 372         ADD_L( ARG_DEST, ESI )
 373         CMP_L( EDX, EDI )
 374
 375         JNZ( LLBL( ctp4_np_top ) )
 376
 377         MOV_L( ARG_OR, ECX )
 378         MOV_L( ARG_AND, EDX )
 379
 380         MOV_B( AL, REGIND(ECX) )
 381         MOV_B( AH, REGIND(EDX) )
 382
 383 LLBL( ctp4_np_finish ):
 384
 385         MOV_L( ARG_SOURCE, EAX )
 386 #ifdef ELFPIC
 387         POP_L( ESI )                    /* discard ptr to clip_table */
 388 #endif
 389         POP_L( EBX )
 390         POP_L( EBP )
 391         POP_L( EDI )
 392         POP_L( ESI )
 393
 394         RET