src/mesa/x86/x86_cliptest.S

   1 /* $Id: x86_cliptest.S,v 1.8 2001/05/21 16:33:41 gareth Exp $ */
   2
   3 /*
   4  * Mesa 3-D graphics library
   5  * Version:  3.5
   6  *
   7  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a
  10  * copy of this software and associated documentation files (the "Software"),
  11  * to deal in the Software without restriction, including without limitation
  12  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  13  * and/or sell copies of the Software, and to permit persons to whom the
  14  * Software is furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included
  17  * in all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  20  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  22  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  23  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  24  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25  */
  26
  27 #include "matypes.h"
  28 #include "clip_args.h"
  29
  30 #define SRC(i)          REGOFF(i * 4, ESI)
  31 #define DST(i)          REGOFF(i * 4, EDI)
  32 #define MAT(i)          REGOFF(i * 4, EDX)
  33
  34
  35 /*
  36  * Table for clip test.
  37  *
  38  *      bit6 = SRC(3) < 0
  39  *      bit5 = SRC(2) < 0
  40  *      bit4 = abs(S(2)) > abs(S(3))
  41  *      bit3 = SRC(1) < 0
  42  *      bit2 = abs(S(1)) > abs(S(3))
  43  *      bit1 = SRC(0) < 0
  44  *      bit0 = abs(S(0)) > abs(S(3))
  45  */
  46
  47         SEG_DATA
  48
  49 clip_table:
  50         D_BYTE 0x00, 0x01, 0x00, 0x02, 0x04, 0x05, 0x04, 0x06
  51         D_BYTE 0x00, 0x01, 0x00, 0x02, 0x08, 0x09, 0x08, 0x0a
  52         D_BYTE 0x20, 0x21, 0x20, 0x22, 0x24, 0x25, 0x24, 0x26
  53         D_BYTE 0x20, 0x21, 0x20, 0x22, 0x28, 0x29, 0x28, 0x2a
  54         D_BYTE 0x00, 0x01, 0x00, 0x02, 0x04, 0x05, 0x04, 0x06
  55         D_BYTE 0x00, 0x01, 0x00, 0x02, 0x08, 0x09, 0x08, 0x0a
  56         D_BYTE 0x10, 0x11, 0x10, 0x12, 0x14, 0x15, 0x14, 0x16
  57         D_BYTE 0x10, 0x11, 0x10, 0x12, 0x18, 0x19, 0x18, 0x1a
  58         D_BYTE 0x3f, 0x3d, 0x3f, 0x3e, 0x37, 0x35, 0x37, 0x36
  59         D_BYTE 0x3f, 0x3d, 0x3f, 0x3e, 0x3b, 0x39, 0x3b, 0x3a
  60         D_BYTE 0x2f, 0x2d, 0x2f, 0x2e, 0x27, 0x25, 0x27, 0x26
  61         D_BYTE 0x2f, 0x2d, 0x2f, 0x2e, 0x2b, 0x29, 0x2b, 0x2a
  62         D_BYTE 0x3f, 0x3d, 0x3f, 0x3e, 0x37, 0x35, 0x37, 0x36
  63         D_BYTE 0x3f, 0x3d, 0x3f, 0x3e, 0x3b, 0x39, 0x3b, 0x3a
  64         D_BYTE 0x1f, 0x1d, 0x1f, 0x1e, 0x17, 0x15, 0x17, 0x16
  65         D_BYTE 0x1f, 0x1d, 0x1f, 0x1e, 0x1b, 0x19, 0x1b, 0x1a
  66
  67
  68         SEG_TEXT
  69
  70 /*
  71  * _mesa_x86_cliptest_points4
  72  *
  73  *   AL:  ormask
  74  *   AH:  andmask
  75  *   EBX: temp0
  76  *   ECX: temp1
  77  *   EDX: clipmask[]
  78  *   ESI: clip[]
  79  *   EDI: proj[]
  80  *   EBP: temp2
  81  */
  82
  83 #if defined(__ELF__) && defined(__PIC__) && !defined(ELFPIC)
  84 #define ELFPIC
  85 #endif
  86
  87 ALIGNTEXT16
  88 GLOBL GLNAME( _mesa_x86_cliptest_points4 )
  89 GLNAME( _mesa_x86_cliptest_points4 ):
  90
  91 #ifdef ELFPIC
  92 #define FRAME_OFFSET 20
  93 #else
  94 #define FRAME_OFFSET 16
  95 #endif
  96         PUSH_L( ESI )
  97         PUSH_L( EDI )
  98         PUSH_L( EBP )
  99         PUSH_L( EBX )
 100
 101 #ifdef ELFPIC
 102         /* store pointer to clip_table on stack */
 103         CALL( LLBL( ctp4_get_eip ) )
 104         ADD_L( CONST(_GLOBAL_OFFSET_TABLE_), EBX )
 105         MOV_L( REGOFF(clip_table@GOT, EBX), EBX )
 106         PUSH_L( EBX )
 107         JMP( LLBL( ctp4_clip_table_ready ) )
 108
 109 LLBL( ctp4_get_eip ):
 110         /* store eip in ebx */
 111         MOV_L( REGIND(ESP), EBX )
 112         RET
 113
 114 LLBL( ctp4_clip_table_ready ):
 115 #endif
 116
 117         MOV_L( ARG_SOURCE, ESI )
 118         MOV_L( ARG_DEST, EDI )
 119
 120         MOV_L( ARG_CLIP, EDX )
 121         MOV_L( ARG_OR, EBX )
 122
 123         MOV_L( ARG_AND, EBP )
 124         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )
 125
 126         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )
 127         MOV_L( REGOFF(V4F_START, ESI), ESI )
 128
 129         OR_L( CONST(VEC_SIZE_4), REGOFF(V4F_FLAGS, EDI) )
 130         MOV_L( EAX, ARG_SOURCE )        /* put stride in ARG_SOURCE */
 131
 132         MOV_L( CONST(4), REGOFF(V4F_SIZE, EDI) )
 133         MOV_L( ECX, REGOFF(V4F_COUNT, EDI) )
 134
 135         MOV_L( REGOFF(V4F_START, EDI), EDI )
 136         ADD_L( EDX, ECX )
 137
 138         MOV_L( ECX, ARG_CLIP )          /* put clipmask + count in ARG_CLIP */
 139         CMP_L( ECX, EDX )
 140
 141         MOV_B( REGIND(EBX), AL )
 142         MOV_B( REGIND(EBP), AH )
 143
 144         JZ( LLBL( ctp4_finish ) )
 145
 146 ALIGNTEXT16
 147 LLBL( ctp4_top ):
 148
 149         FLD1                            /* F3 */
 150         FDIV_S( SRC(3) )                /* GH: don't care about div-by-zero */
 151
 152         MOV_L( SRC(3), EBP )
 153         MOV_L( SRC(2), EBX )
 154
 155         XOR_L( ECX, ECX )
 156         ADD_L( EBP, EBP )       /* ebp = abs(S(3))*2 ; carry = sign of S(3) */
 157
 158         ADC_L( ECX, ECX )
 159         ADD_L( EBX, EBX )       /* ebx = abs(S(2))*2 ; carry = sign of S(2) */
 160
 161         ADC_L( ECX, ECX )
 162         CMP_L( EBX, EBP )       /* carry = abs(S(2))*2 > abs(S(3))*2 */
 163
 164         ADC_L( ECX, ECX )
 165         MOV_L( SRC(1), EBX )
 166
 167         ADD_L( EBX, EBX )       /* ebx = abs(S(1))*2 ; carry = sign of S(1) */
 168
 169         ADC_L( ECX, ECX )
 170         CMP_L( EBX, EBP )       /* carry = abs(S(1))*2 > abs(S(3))*2 */
 171
 172         ADC_L( ECX, ECX )
 173         MOV_L( SRC(0), EBX )
 174
 175         ADD_L( EBX, EBX )       /* ebx = abs(S(0))*2 ; carry = sign of S(0) */
 176
 177         ADC_L( ECX, ECX )
 178         CMP_L( EBX, EBP )       /* carry = abs(S(0))*2 > abs(S(3))*2 */
 179
 180         ADC_L( ECX, ECX )
 181
 182 #ifdef ELFPIC
 183         MOV_L( REGIND(ESP), EBP )       /* clip_table */
 184
 185         MOV_B( REGBI(EBP, ECX), CL )
 186 #else
 187         MOV_B( REGOFF(clip_table,ECX), CL )
 188 #endif
 189
 190         OR_B( CL, AL )
 191         AND_B( CL, AH )
 192
 193         TEST_B( CL, CL )
 194         MOV_B( CL, REGIND(EDX) )
 195
 196         JZ( LLBL( ctp4_proj ) )
 197
 198 LLBL( ctp4_noproj ):
 199
 200         FSTP( ST(0) )                   /* */
 201
 202         MOV_L( CONST(0), DST(0) )
 203         MOV_L( CONST(0), DST(1) )
 204         MOV_L( CONST(0), DST(2) )
 205         MOV_L( CONST(0x3f800000), DST(3) )
 206
 207         JMP( LLBL( ctp4_next ) )
 208
 209 LLBL( ctp4_proj ):
 210
 211         FLD_S( SRC(0) )                 /* F0 F3 */
 212         FMUL2( ST(1), ST(0) )
 213
 214         FLD_S( SRC(1) )                 /* F1 F0 F3 */
 215         FMUL2( ST(2), ST(0) )
 216
 217         FLD_S( SRC(2) )                 /* F2 F1 F0 F3 */
 218         FMUL2( ST(3), ST(0) )
 219
 220         FXCH( ST(2) )                   /* F0 F1 F2 F3 */
 221         FSTP_S( DST(0) )                /* F1 F2 F3 */
 222         FSTP_S( DST(1) )                /* F2 F3 */
 223         FSTP_S( DST(2) )                /* F3 */
 224         FSTP_S( DST(3) )                /* */
 225
 226 LLBL( ctp4_next ):
 227
 228         INC_L( EDX )
 229         ADD_L( CONST(16), EDI )
 230
 231         ADD_L( ARG_SOURCE, ESI )
 232         CMP_L( EDX, ARG_CLIP )
 233
 234         JNZ( LLBL( ctp4_top ) )
 235
 236         MOV_L( ARG_OR, ECX )
 237         MOV_L( ARG_AND, EDX )
 238
 239         MOV_B( AL, REGIND(ECX) )
 240         MOV_B( AH, REGIND(EDX) )
 241
 242 LLBL( ctp4_finish ):
 243
 244         MOV_L( ARG_DEST, EAX )
 245 #ifdef ELFPIC
 246         POP_L( ESI )                    /* discard ptr to clip_table */
 247 #endif
 248         POP_L( EBX )
 249         POP_L( EBP )
 250         POP_L( EDI )
 251         POP_L( ESI )
 252
 253         RET
 254
 255
 256
 257
 258
 259
 260
 261 ALIGNTEXT16
 262 GLOBL GLNAME( _mesa_x86_cliptest_points4_np )
 263 GLNAME( _mesa_x86_cliptest_points4_np ):
 264
 265 #ifdef ELFPIC
 266 #define FRAME_OFFSET 20
 267 #else
 268 #define FRAME_OFFSET 16
 269 #endif
 270         PUSH_L( ESI )
 271         PUSH_L( EDI )
 272         PUSH_L( EBP )
 273         PUSH_L( EBX )
 274
 275 #ifdef ELFPIC
 276         /* store pointer to clip_table on stack */
 277         CALL( LLBL( ctp4_np_get_eip ) )
 278         ADD_L( CONST(_GLOBAL_OFFSET_TABLE_), EBX )
 279         MOV_L( REGOFF(clip_table@GOT, EBX), EBX )
 280         PUSH_L( EBX )
 281         JMP( LLBL( ctp4_np_clip_table_ready ) )
 282
 283 LLBL( ctp4_np_get_eip ):
 284         /* store eip in ebx */
 285         MOV_L( REGIND(ESP), EBX )
 286         RET
 287
 288 LLBL( ctp4_np_clip_table_ready ):
 289 #endif
 290
 291         MOV_L( ARG_SOURCE, ESI )
 292         /* slot */
 293
 294         MOV_L( ARG_CLIP, EDX )
 295         MOV_L( ARG_OR, EBX )
 296
 297         MOV_L( ARG_AND, EBP )
 298         MOV_L( REGOFF(V4F_STRIDE, ESI), EAX )
 299
 300         MOV_L( REGOFF(V4F_COUNT, ESI), ECX )
 301         MOV_L( REGOFF(V4F_START, ESI), ESI )
 302
 303         MOV_L( EAX, ARG_DEST )          /* put stride in ARG_DEST */
 304         ADD_L( EDX, ECX )
 305
 306         MOV_L( ECX, EDI )               /* put clipmask + count in EDI */
 307         CMP_L( ECX, EDX )
 308
 309         MOV_B( REGIND(EBX), AL )
 310         MOV_B( REGIND(EBP), AH )
 311
 312         JZ( LLBL( ctp4_np_finish ) )
 313
 314 ALIGNTEXT16
 315 LLBL( ctp4_np_top ):
 316
 317         MOV_L( SRC(3), EBP )
 318         MOV_L( SRC(2), EBX )
 319
 320         XOR_L( ECX, ECX )
 321         ADD_L( EBP, EBP )       /* ebp = abs(S(3))*2 ; carry = sign of S(3) */
 322
 323         ADC_L( ECX, ECX )
 324         ADD_L( EBX, EBX )       /* ebx = abs(S(2))*2 ; carry = sign of S(2) */
 325
 326         ADC_L( ECX, ECX )
 327         CMP_L( EBX, EBP )       /* carry = abs(S(2))*2 > abs(S(3))*2 */
 328
 329         ADC_L( ECX, ECX )
 330         MOV_L( SRC(1), EBX )
 331
 332         ADD_L( EBX, EBX )       /* ebx = abs(S(1))*2 ; carry = sign of S(1) */
 333
 334         ADC_L( ECX, ECX )
 335         CMP_L( EBX, EBP )       /* carry = abs(S(1))*2 > abs(S(3))*2 */
 336
 337         ADC_L( ECX, ECX )
 338         MOV_L( SRC(0), EBX )
 339
 340         ADD_L( EBX, EBX )       /* ebx = abs(S(0))*2 ; carry = sign of S(0) */
 341
 342         ADC_L( ECX, ECX )
 343         CMP_L( EBX, EBP )       /* carry = abs(S(0))*2 > abs(S(3))*2 */
 344
 345         ADC_L( ECX, ECX )
 346
 347 #ifdef ELFPIC
 348         MOV_L( REGIND(ESP), EBP )       /* clip_table */
 349
 350         MOV_B( REGBI(EBP, ECX), CL )
 351 #else
 352         MOV_B( REGOFF(clip_table,ECX), CL )
 353 #endif
 354
 355         OR_B( CL, AL )
 356         AND_B( CL, AH )
 357
 358         TEST_B( CL, CL )
 359         MOV_B( CL, REGIND(EDX) )
 360
 361         INC_L( EDX )
 362         /* slot */
 363
 364         ADD_L( ARG_DEST, ESI )
 365         CMP_L( EDX, EDI )
 366
 367         JNZ( LLBL( ctp4_np_top ) )
 368
 369         MOV_L( ARG_OR, ECX )
 370         MOV_L( ARG_AND, EDX )
 371
 372         MOV_B( AL, REGIND(ECX) )
 373         MOV_B( AH, REGIND(EDX) )
 374
 375 LLBL( ctp4_np_finish ):
 376
 377         MOV_L( ARG_SOURCE, EAX )
 378 #ifdef ELFPIC
 379         POP_L( ESI )                    /* discard ptr to clip_table */
 380 #endif
 381         POP_L( EBX )
 382         POP_L( EBP )
 383         POP_L( EDI )
 384         POP_L( ESI )
 385
 386         RET