projects / yosys.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
mul2dsp.v slice names
[yosys.git] / techlibs / common / mul2dsp.v
1 /*
2 * yosys -- Yosys Open SYnthesis Suite
3 *
4 * Copyright (C) 2012 Clifford Wolf <clifford@clifford.at>
5 * 2019 Eddie Hung <eddie@fpgeh.com>
6 * 2019 David Shah <dave@ds0.me>
7 *
8 * Permission to use, copy, modify, and/or distribute this software for any
9 * purpose with or without fee is hereby granted, provided that the above
10 * copyright notice and this permission notice appear in all copies.
11 *
12 * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
13 * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
14 * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
15 * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
16 * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
17 * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
18 * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
19 *
20 * ---
21 *
22 * Tech-mapping rules for decomposing arbitrarily-sized $mul cells
23 * into an equivalent collection of smaller `DSP_NAME cells (with the
24 * same interface as $mul) no larger than `DSP_[AB]_MAXWIDTH, attached
25 * to $shl and $add cells.
26 *
27 */
28
29 `ifndef DSP_A_MAXWIDTH
30 $fatal(1, "Macro DSP_A_MAXWIDTH must be defined");
31 `endif
32 `ifndef DSP_B_MAXWIDTH
33 $fatal(1, "Macro DSP_B_MAXWIDTH must be defined");
34 `endif
35 `ifndef DSP_B_MAXWIDTH
36 $fatal(1, "Macro DSP_B_MAXWIDTH must be defined");
37 `endif
38 `ifndef DSP_A_MAXWIDTH_PARTIAL
39 `define DSP_A_MAXWIDTH_PARTIAL `DSP_A_MAXWIDTH
40 `endif
41 `ifndef DSP_B_MAXWIDTH_PARTIAL
42 `define DSP_B_MAXWIDTH_PARTIAL `DSP_B_MAXWIDTH
43 `endif
44
45 `ifndef DSP_NAME
46 $fatal(1, "Macro DSP_NAME must be defined");
47 `endif
48
49 `define MAX(a,b) (a > b ? a : b)
50 `define MIN(a,b) (a < b ? a : b)
51
52 (* techmap_celltype = "$mul $__mul" *)
53 module _80_mul (A, B, Y);
54 parameter A_SIGNED = 0;
55 parameter B_SIGNED = 0;
56 parameter A_WIDTH = 1;
57 parameter B_WIDTH = 1;
58 parameter Y_WIDTH = 1;
59
60 input [A_WIDTH-1:0] A;
61 input [B_WIDTH-1:0] B;
62 output [Y_WIDTH-1:0] Y;
63
64 parameter _TECHMAP_CELLTYPE_ = "";
65
66 generate
67 if (0) begin end
68 `ifdef DSP_A_MINWIDTH
69 else if (A_WIDTH < `DSP_A_MINWIDTH)
70 wire _TECHMAP_FAIL_ = 1;
71 `endif
72 `ifdef DSP_B_MINWIDTH
73 else if (B_WIDTH < `DSP_B_MINWIDTH)
74 wire _TECHMAP_FAIL_ = 1;
75 `endif
76 `ifdef DSP_Y_MINWIDTH
77 else if (Y_WIDTH < `DSP_Y_MINWIDTH)
78 wire _TECHMAP_FAIL_ = 1;
79 `endif
80 `ifdef DSP_SIGNEDONLY
81 else if (_TECHMAP_CELLTYPE_ == "$mul" && !A_SIGNED && !B_SIGNED)
82 \$mul #(
83 .A_SIGNED(1),
84 .B_SIGNED(1),
85 .A_WIDTH(A_WIDTH + 1),
86 .B_WIDTH(B_WIDTH + 1),
87 .Y_WIDTH(Y_WIDTH)
88 ) _TECHMAP_REPLACE_ (
89 .A({1'b0, A}),
90 .B({1'b0, B}),
91 .Y(Y)
92 );
93 `endif
94 else if (_TECHMAP_CELLTYPE_ == "$mul" && A_WIDTH < B_WIDTH)
95 \$mul #(
96 .A_SIGNED(B_SIGNED),
97 .B_SIGNED(A_SIGNED),
98 .A_WIDTH(B_WIDTH),
99 .B_WIDTH(A_WIDTH),
100 .Y_WIDTH(Y_WIDTH)
101 ) _TECHMAP_REPLACE_ (
102 .A(B),
103 .B(A),
104 .Y(Y)
105 );
106 else begin
107 wire [1023:0] _TECHMAP_DO_ = "proc; clean";
108
109 `ifdef DSP_SIGNEDONLY
110 localparam sign_headroom = 1;
111 `else
112 localparam sign_headroom = 0;
113 `endif
114
115 genvar i;
116 if (A_WIDTH > `DSP_A_MAXWIDTH) begin
117 localparam n = (A_WIDTH-`DSP_A_MAXWIDTH+`DSP_A_MAXWIDTH_PARTIAL-sign_headroom-1) / (`DSP_A_MAXWIDTH_PARTIAL-sign_headroom);
118 localparam partial_Y_WIDTH = `MIN(Y_WIDTH, B_WIDTH+`DSP_A_MAXWIDTH_PARTIAL);
119 localparam last_A_WIDTH = A_WIDTH-n*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom);
120 localparam last_Y_WIDTH = B_WIDTH+last_A_WIDTH;
121 if (A_SIGNED && B_SIGNED) begin
122 wire signed [partial_Y_WIDTH-1:0] partial [n-1:0];
123 wire signed [last_Y_WIDTH-1:0] last_partial;
124 wire signed [Y_WIDTH-1:0] partial_sum [n:0];
125 end
126 else begin
127 wire [partial_Y_WIDTH-1:0] partial [n-1:0];
128 wire [last_Y_WIDTH-1:0] last_partial;
129 wire [Y_WIDTH-1:0] partial_sum [n:0];
130 end
131
132 for (i = 0; i < n; i=i+1) begin:sliceA
133 \$__mul #(
134 .A_SIGNED(sign_headroom),
135 .B_SIGNED(B_SIGNED),
136 .A_WIDTH(`DSP_A_MAXWIDTH_PARTIAL),
137 .B_WIDTH(B_WIDTH),
138 .Y_WIDTH(partial_Y_WIDTH)
139 ) mul (
140 .A({{sign_headroom{1'b0}}, A[i*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom) +: `DSP_A_MAXWIDTH_PARTIAL-sign_headroom]}),
141 .B(B),
142 .Y(partial[i])
143 );
144 // TODO: Currently a 'cascade' approach to summing the partial
145 // products is taken here, but a more efficient 'binary
146 // reduction' approach also exists...
147 if (i == 0)
148 assign partial_sum[i] = partial[i];
149 else begin
150 // Rewrite the following statement explicitly in order
151 // to save on a call to 'opt_expr -fine' which would
152 // optimise away the '<<' op and trim size of adder
153 //assign partial_sum[i] = (partial[i] << i*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)) + partial_sum[i-1];
154 if (A_SIGNED && B_SIGNED)
155 assign partial_sum[i][Y_WIDTH-1:i*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)] = partial[i] + $signed(partial_sum[i-1][Y_WIDTH-1:i*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)]);
156 else
157 assign partial_sum[i][Y_WIDTH-1:i*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)] = partial[i] + partial_sum[i-1][Y_WIDTH-1:i*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)];
158 assign partial_sum[i][i*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)-1:0] = partial_sum[i-1][i*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)-1:0];
159 end
160 end
161
162 \$__mul #(
163 .A_SIGNED(A_SIGNED),
164 .B_SIGNED(B_SIGNED),
165 .A_WIDTH(last_A_WIDTH),
166 .B_WIDTH(B_WIDTH),
167 .Y_WIDTH(last_Y_WIDTH)
168 ) sliceA.last (
169 .A(A[A_WIDTH-1 -: last_A_WIDTH]),
170 .B(B),
171 .Y(last_partial)
172 );
173 //assign partial_sum[n] = (last_partial << n*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)) + partial_sum[n-1];
174 if (A_SIGNED && B_SIGNED)
175 assign partial_sum[n][Y_WIDTH-1:n*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)] = last_partial + $signed(partial_sum[n-1][Y_WIDTH-1:n*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)]);
176 else
177 assign partial_sum[n][Y_WIDTH-1:n*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)] = last_partial + partial_sum[n-1][Y_WIDTH-1:n*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)];
178 assign partial_sum[n][n*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)-1:0] = partial_sum[n-1][n*(`DSP_A_MAXWIDTH_PARTIAL-sign_headroom)-1:0];
179 assign Y = partial_sum[n];
180 end
181 else if (B_WIDTH > `DSP_B_MAXWIDTH) begin
182 localparam n = (B_WIDTH-`DSP_B_MAXWIDTH+`DSP_B_MAXWIDTH_PARTIAL-sign_headroom-1) / (`DSP_B_MAXWIDTH_PARTIAL-sign_headroom);
183 localparam partial_Y_WIDTH = `MIN(Y_WIDTH, A_WIDTH+`DSP_B_MAXWIDTH_PARTIAL);
184 localparam last_B_WIDTH = B_WIDTH-n*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom);
185 localparam last_Y_WIDTH = A_WIDTH+last_B_WIDTH;
186 if (A_SIGNED && B_SIGNED) begin
187 wire signed [partial_Y_WIDTH-1:0] partial [n-1:0];
188 wire signed [last_Y_WIDTH-1:0] last_partial;
189 wire signed [Y_WIDTH-1:0] partial_sum [n:0];
190 end
191 else begin
192 wire [partial_Y_WIDTH-1:0] partial [n-1:0];
193 wire [last_Y_WIDTH-1:0] last_partial;
194 wire [Y_WIDTH-1:0] partial_sum [n:0];
195 end
196
197 for (i = 0; i < n; i=i+1) begin:sliceB
198 \$__mul #(
199 .A_SIGNED(A_SIGNED),
200 .B_SIGNED(sign_headroom),
201 .A_WIDTH(A_WIDTH),
202 .B_WIDTH(`DSP_B_MAXWIDTH_PARTIAL),
203 .Y_WIDTH(partial_Y_WIDTH)
204 ) mul (
205 .A(A),
206 .B({{sign_headroom{1'b0}}, B[i*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom) +: `DSP_B_MAXWIDTH_PARTIAL-sign_headroom]}),
207 .Y(partial[i])
208 );
209 // TODO: Currently a 'cascade' approach to summing the partial
210 // products is taken here, but a more efficient 'binary
211 // reduction' approach also exists...
212 if (i == 0)
213 assign partial_sum[i] = partial[i];
214 else begin
215 // Rewrite the following statement explicitly in order
216 // to save on a call to 'opt_expr -fine' which would
217 // optimise away the '<<' op and trim size of adder
218 //assign partial_sum[i] = (partial[i] << i*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)) + partial_sum[i-1];
219 if (A_SIGNED && B_SIGNED)
220 assign partial_sum[i][Y_WIDTH-1:i*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)] = partial[i] + $signed(partial_sum[i-1][Y_WIDTH-1:i*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)]);
221 else
222 assign partial_sum[i][Y_WIDTH-1:i*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)] = partial[i] + partial_sum[i-1][Y_WIDTH-1:i*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)];
223 assign partial_sum[i][i*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)-1:0] = partial_sum[i-1][i*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)-1:0];
224 end
225 end
226
227 \$__mul #(
228 .A_SIGNED(A_SIGNED),
229 .B_SIGNED(B_SIGNED),
230 .A_WIDTH(A_WIDTH),
231 .B_WIDTH(last_B_WIDTH),
232 .Y_WIDTH(last_Y_WIDTH)
233 ) mul_sliceB_last (
234 .A(A),
235 .B(B[B_WIDTH-1 -: last_B_WIDTH]),
236 .Y(last_partial)
237 );
238 //assign partial_sum[n] = (last_partial << n*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)) + partial_sum[n-1];
239 if (A_SIGNED && B_SIGNED)
240 assign partial_sum[n][Y_WIDTH-1:n*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)] = last_partial + $signed(partial_sum[n-1][Y_WIDTH-1:n*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)]);
241 else
242 assign partial_sum[n][Y_WIDTH-1:n*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)] = last_partial + partial_sum[n-1][Y_WIDTH-1:n*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)];
243 assign partial_sum[n][n*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)-1:0] = partial_sum[n-1][n*(`DSP_B_MAXWIDTH_PARTIAL-sign_headroom)-1:0];
244 assign Y = partial_sum[n];
245 end
246 else begin
247 if (A_SIGNED)
248 wire signed [`DSP_A_MAXWIDTH-1:0] Aext = $signed(A);
249 else
250 wire [`DSP_A_MAXWIDTH-1:0] Aext = A;
251 if (B_SIGNED)
252 wire signed [`DSP_B_MAXWIDTH-1:0] Bext = $signed(B);
253 else
254 wire [`DSP_B_MAXWIDTH-1:0] Bext = B;
255
256 `DSP_NAME #(
257 .A_SIGNED(A_SIGNED),
258 .B_SIGNED(B_SIGNED),
259 .A_WIDTH(`DSP_A_MAXWIDTH),
260 .B_WIDTH(`DSP_B_MAXWIDTH),
261 .Y_WIDTH(`MIN(Y_WIDTH,`DSP_A_MAXWIDTH+`DSP_B_MAXWIDTH)),
262 ) _TECHMAP_REPLACE_ (
263 .A(Aext),
264 .B(Bext),
265 .Y(Y)
266 );
267 end
268 end
269 endgenerate
270 endmodule
271
272 (* techmap_celltype = "$mul $__mul" *)
273 module _90_soft_mul (A, B, Y);
274 parameter A_SIGNED = 0;
275 parameter B_SIGNED = 0;
276 parameter A_WIDTH = 1;
277 parameter B_WIDTH = 1;
278 parameter Y_WIDTH = 1;
279
280 input [A_WIDTH-1:0] A;
281 input [B_WIDTH-1:0] B;
282 output [Y_WIDTH-1:0] Y;
283
284 // Indirection necessary since mapping
285 // back to $mul will cause recursion
286 generate
287 if (A_SIGNED && !B_SIGNED)
288 \$__soft_mul #(
289 .A_SIGNED(A_SIGNED),
290 .B_SIGNED(1),
291 .A_WIDTH(A_WIDTH),
292 .B_WIDTH(B_WIDTH+1),
293 .Y_WIDTH(Y_WIDTH)
294 ) _TECHMAP_REPLACE_ (
295 .A(A),
296 .B({1'b0,B}),
297 .Y(Y)
298 );
299 else if (!A_SIGNED && B_SIGNED)
300 \$__soft_mul #(
301 .A_SIGNED(1),
302 .B_SIGNED(B_SIGNED),
303 .A_WIDTH(A_WIDTH+1),
304 .B_WIDTH(B_WIDTH),
305 .Y_WIDTH(Y_WIDTH)
306 ) _TECHMAP_REPLACE_ (
307 .A({1'b0,A}),
308 .B(B),
309 .Y(Y)
310 );
311 else
312 \$__soft_mul #(
313 .A_SIGNED(A_SIGNED),
314 .B_SIGNED(B_SIGNED),
315 .A_WIDTH(A_WIDTH),
316 .B_WIDTH(B_WIDTH),
317 .Y_WIDTH(Y_WIDTH)
318 ) _TECHMAP_REPLACE_ (
319 .A(A),
320 .B(B),
321 .Y(Y)
322 );
323 endgenerate
324 endmodule