techlibs/efinix/arith_map.v

   1 /*
   2  *  yosys -- Yosys Open SYnthesis Suite
   3  *
   4  *  Copyright (C) 2018  Miodrag Milanovic <miodrag@symbioticeda.com>
   5  *  Copyright (C) 2012  Clifford Wolf <clifford@clifford.at>
   6  *
   7  *  Permission to use, copy, modify, and/or distribute this software for any
   8  *  purpose with or without fee is hereby granted, provided that the above
   9  *  copyright notice and this permission notice appear in all copies.
  10  *
  11  *  THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  12  *  WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  13  *  MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  14  *  ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  15  *  WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  16  *  ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  17  *  OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  18  *
  19  */
  20
  21 (* techmap_celltype = "$alu" *)
  22 module _80_efinix_alu (A, B, CI, BI, X, Y, CO);
  23         parameter A_SIGNED = 0;
  24         parameter B_SIGNED = 0;
  25         parameter A_WIDTH  = 1;
  26         parameter B_WIDTH  = 1;
  27         parameter Y_WIDTH  = 1;
  28
  29         input [A_WIDTH-1:0] A;
  30         input [B_WIDTH-1:0] B;
  31         output [Y_WIDTH-1:0] X, Y;
  32
  33         input CI, BI;
  34         output CO;
  35
  36         wire _TECHMAP_FAIL_ = Y_WIDTH <= 2;
  37
  38         wire [Y_WIDTH-1:0] A_buf, B_buf;
  39         \$pos #(.A_SIGNED(A_SIGNED), .A_WIDTH(A_WIDTH), .Y_WIDTH(Y_WIDTH)) A_conv (.A(A), .Y(A_buf));
  40         \$pos #(.A_SIGNED(B_SIGNED), .A_WIDTH(B_WIDTH), .Y_WIDTH(Y_WIDTH)) B_conv (.A(B), .Y(B_buf));
  41
  42         wire [Y_WIDTH-1:0] AA = A_buf;
  43         wire [Y_WIDTH-1:0] BB = BI ? ~B_buf : B_buf;
  44         wire [Y_WIDTH+1:0] COx;
  45         wire [Y_WIDTH+2:0] C = {COx, CI};
  46
  47    EFX_ADD #(.I0_POLARITY(1'b1),.I1_POLARITY(1'b1))
  48    adder_cin  (
  49         .I0(C[0]),
  50         .I1(1'b1),
  51         .CI(1'b0),
  52         .CO(COx[0])
  53         );
  54
  55         genvar i;
  56         generate for (i = 0; i < Y_WIDTH; i = i + 1) begin: slice
  57       EFX_ADD #(.I0_POLARITY(1'b1),.I1_POLARITY(1'b1))
  58       adder_i (
  59             .I0(AA[i]),
  60             .I1(BB[i]),
  61             .CI(C[i+1]),
  62             .O(Y[i]),
  63             .CO(COx[i+1])
  64         );
  65           end: slice
  66         endgenerate
  67
  68    EFX_ADD #(.I0_POLARITY(1'b1),.I1_POLARITY(1'b1))
  69    adder_cout  (
  70       .I0(1'b0),
  71       .I1(1'b0),
  72       .CI(C[Y_WIDTH+1]),
  73       .O(COx[Y_WIDTH+1])
  74    );
  75    assign CO = COx[Y_WIDTH+1];
  76         /* End implementation */
  77         assign X = AA ^ BB;
  78 endmodule