techlibs/xilinx/cells_map.v

   1 /*
   2  *  yosys -- Yosys Open SYnthesis Suite
   3  *
   4  *  Copyright (C) 2012  Clifford Wolf <clifford@clifford.at>
   5  *                2019  Eddie Hung    <eddie@fpgeh.com>
   6  *
   7  *  Permission to use, copy, modify, and/or distribute this software for any
   8  *  purpose with or without fee is hereby granted, provided that the above
   9  *  copyright notice and this permission notice appear in all copies.
  10  *
  11  *  THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  12  *  WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  13  *  MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  14  *  ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  15  *  WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  16  *  ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  17  *  OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  18  *
  19  */
  20
  21 module \$__SHREG_ (input C, input D, input E, output Q);
  22   parameter DEPTH = 0;
  23   parameter [DEPTH-1:0] INIT = 0;
  24   parameter CLKPOL = 1;
  25   parameter ENPOL = 2;
  26
  27   \$__XILINX_SHREG_ #(.DEPTH(DEPTH), .INIT(INIT), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) _TECHMAP_REPLACE_ (.C(C), .D(D), .L(DEPTH-1), .E(E), .Q(Q));
  28 endmodule
  29
  30 module \$__XILINX_SHREG_ (input C, input D, input [31:0] L, input E, output Q, output SO);
  31   parameter DEPTH = 0;
  32   parameter [DEPTH-1:0] INIT = 0;
  33   parameter CLKPOL = 1;
  34   parameter ENPOL = 2;
  35
  36   // shregmap's INIT parameter shifts out LSB first;
  37   // however Xilinx expects MSB first
  38   function [DEPTH-1:0] brev;
  39     input [DEPTH-1:0] din;
  40     integer i;
  41     begin
  42       for (i = 0; i < DEPTH; i=i+1)
  43         brev[i] = din[DEPTH-1-i];
  44     end
  45   endfunction
  46   localparam [DEPTH-1:0] INIT_R = brev(INIT);
  47
  48   parameter _TECHMAP_CONSTMSK_L_ = 0;
  49   parameter _TECHMAP_CONSTVAL_L_ = 0;
  50
  51   wire CE;
  52   generate
  53     if (ENPOL == 0)
  54       assign CE = ~E;
  55     else if (ENPOL == 1)
  56       assign CE = E;
  57     else
  58       assign CE = 1'b1;
  59     if (DEPTH == 1) begin
  60       if (CLKPOL)
  61           FDRE #(.INIT(INIT_R)) _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .CE(CE), .R(1'b0));
  62       else
  63           FDRE_1 #(.INIT(INIT_R)) _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .CE(CE), .R(1'b0));
  64     end else
  65     if (DEPTH <= 16) begin
  66       SRL16E #(.INIT(INIT_R), .IS_CLK_INVERTED(~CLKPOL[0])) _TECHMAP_REPLACE_ (.A0(L[0]), .A1(L[1]), .A2(L[2]), .A3(L[3]), .CE(CE), .CLK(C), .D(D), .Q(Q));
  67     end else
  68     if (DEPTH > 17 && DEPTH <= 32) begin
  69       SRLC32E #(.INIT(INIT_R), .IS_CLK_INVERTED(~CLKPOL[0])) _TECHMAP_REPLACE_ (.A(L[4:0]), .CE(CE), .CLK(C), .D(D), .Q(Q));
  70     end else
  71     if (DEPTH > 33 && DEPTH <= 64) begin
  72       wire T0, T1, T2;
  73       SRLC32E #(.INIT(INIT_R[32-1:0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D(D), .Q(T0), .Q31(T1));
  74       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-32), .INIT(INIT[DEPTH-32-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T1), .L(L), .E(E), .Q(T2));
  75       if (&_TECHMAP_CONSTMSK_L_)
  76         assign Q = T2;
  77       else
  78         MUXF7 fpga_mux_0 (.O(Q), .I0(T0), .I1(T2), .S(L[5]));
  79     end else
  80     if (DEPTH > 65 && DEPTH <= 96) begin
  81       wire T0, T1, T2, T3, T4, T5, T6;
  82       SRLC32E #(.INIT(INIT_R[32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
  83       SRLC32E #(.INIT(INIT_R[64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
  84       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-64), .INIT(INIT[DEPTH-64-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_2 (.C(C), .D(T3), .L(L[4:0]), .E(E), .Q(T4));
  85       if (&_TECHMAP_CONSTMSK_L_)
  86         assign Q = T4;
  87       else begin
  88         MUXF7 fpga_mux_0 (.O(T5), .I0(T0), .I1(T2), .S(L[5]));
  89         MUXF7 fpga_mux_1 (.O(T6), .I0(T4), .I1(1'b0 /* unused */), .S(L[5]));
  90         MUXF8 fpga_mux_2 (.O(Q), .I0(T5), .I1(T6), .S(L[6]));
  91       end
  92     end else
  93     if (DEPTH > 97 && DEPTH < 128) begin
  94       wire T0, T1, T2, T3, T4, T5, T6, T7, T8;
  95       SRLC32E #(.INIT(INIT_R[32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
  96       SRLC32E #(.INIT(INIT_R[64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
  97       SRLC32E #(.INIT(INIT_R[96-1:64]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_2 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T3), .Q(T4), .Q31(T5));
  98       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-96), .INIT(INIT[DEPTH-96-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_3 (.C(C), .D(T5), .L(L[4:0]), .E(E), .Q(T6));
  99       if (&_TECHMAP_CONSTMSK_L_)
 100         assign Q = T6;
 101       else begin
 102         MUXF7 fpga_mux_0 (.O(T7), .I0(T0), .I1(T2), .S(L[5]));
 103         MUXF7 fpga_mux_1 (.O(T8), .I0(T4), .I1(T6), .S(L[5]));
 104         MUXF8 fpga_mux_2 (.O(Q), .I0(T7), .I1(T8), .S(L[6]));
 105       end
 106     end
 107     else if (DEPTH == 128) begin
 108       wire T0, T1, T2, T3, T4, T5, T6;
 109       SRLC32E #(.INIT(INIT_R[ 32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
 110       SRLC32E #(.INIT(INIT_R[ 64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
 111       SRLC32E #(.INIT(INIT_R[ 96-1:64]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_2 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T3), .Q(T4), .Q31(T5));
 112       SRLC32E #(.INIT(INIT_R[128-1:96]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_3 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T5), .Q(T6), .Q31(SO));
 113       if (&_TECHMAP_CONSTMSK_L_)
 114         assign Q = T6;
 115       else begin
 116         wire T7, T8;
 117         MUXF7 fpga_mux_0 (.O(T7), .I0(T0), .I1(T2), .S(L[5]));
 118         MUXF7 fpga_mux_1 (.O(T8), .I0(T4), .I1(T6), .S(L[5]));
 119         MUXF8 fpga_mux_2 (.O(Q), .I0(T7), .I1(T8), .S(L[6]));
 120       end
 121     end
 122     else if (DEPTH <= 129 && ~&_TECHMAP_CONSTMSK_L_) begin
 123       // Handle cases where fixed-length depth is
 124       // just 1 over a convenient value
 125       \$__XILINX_SHREG_ #(.DEPTH(DEPTH+1), .INIT({INIT,1'b0}), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) _TECHMAP_REPLACE_ (.C(C), .D(D), .L(L), .E(E), .Q(Q));
 126     end
 127     else begin
 128       localparam lower_clog2 = $clog2((DEPTH+1)/2);
 129       localparam lower_depth = 2 ** lower_clog2;
 130       wire T0, T1, T2, T3;
 131       if (&_TECHMAP_CONSTMSK_L_) begin
 132         \$__XILINX_SHREG_ #(.DEPTH(lower_depth), .INIT(INIT[DEPTH-1:DEPTH-lower_depth]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_0 (.C(C), .D(D), .L(lower_depth-1), .E(E), .Q(T0));
 133         \$__XILINX_SHREG_ #(.DEPTH(DEPTH-lower_depth), .INIT(INIT[DEPTH-lower_depth-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T0), .L(DEPTH-lower_depth-1), .E(E), .Q(Q), .SO(T3));
 134       end
 135       else begin
 136         \$__XILINX_SHREG_ #(.DEPTH(lower_depth), .INIT(INIT[DEPTH-1:DEPTH-lower_depth]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_0 (.C(C), .D(D), .L(L[lower_clog2-1:0]), .E(E), .Q(T0), .SO(T1));
 137         \$__XILINX_SHREG_ #(.DEPTH(DEPTH-lower_depth), .INIT(INIT[DEPTH-lower_depth-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T1), .L(L[lower_clog2-1:0]), .E(E), .Q(T2), .SO(T3));
 138         assign Q = L[lower_clog2] ? T2 : T0;
 139       end
 140       if (DEPTH == 2 * lower_depth)
 141           assign SO = T3;
 142     end
 143   endgenerate
 144 endmodule
 145
 146 module \$__XILINX_SHIFTX (A, B, Y);
 147   parameter A_SIGNED = 0;
 148   parameter B_SIGNED = 0;
 149   parameter A_WIDTH = 1;
 150   parameter B_WIDTH = 1;
 151   parameter Y_WIDTH = 1;
 152
 153   input [A_WIDTH-1:0] A;
 154   input [B_WIDTH-1:0] B;
 155   output [Y_WIDTH-1:0] Y;
 156
 157   parameter [A_WIDTH-1:0] _TECHMAP_CONSTMSK_A_ = 0;
 158   parameter [A_WIDTH-1:0] _TECHMAP_CONSTVAL_A_ = 0;
 159   parameter [B_WIDTH-1:0] _TECHMAP_CONSTMSK_B_ = 0;
 160   parameter [B_WIDTH-1:0] _TECHMAP_CONSTVAL_B_ = 0;
 161
 162   function integer compute_num_leading_X_in_A;
 163     integer i, c;
 164   begin
 165     compute_num_leading_X_in_A = 0;
 166     c = 1;
 167     for (i = A_WIDTH-1; i >= 0; i=i-1) begin
 168       if (!_TECHMAP_CONSTMSK_A_[i] || _TECHMAP_CONSTVAL_A_[i] !== 1'bx)
 169         c = 0;
 170       compute_num_leading_X_in_A = compute_num_leading_X_in_A + c;
 171     end
 172   end
 173   endfunction
 174   localparam num_leading_X_in_A = compute_num_leading_X_in_A();
 175
 176   generate
 177     genvar i, j;
 178     // Bit-blast
 179     if (Y_WIDTH > 1) begin
 180       for (i = 0; i < Y_WIDTH; i++)
 181         \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(A_WIDTH-Y_WIDTH+1), .B_WIDTH(B_WIDTH), .Y_WIDTH(1'd1)) bitblast (.A(A[A_WIDTH-Y_WIDTH+i:i]), .B(B), .Y(Y[i]));
 182     end
 183     // If the LSB of B is constant zero (and Y_WIDTH is 1) then
 184     //   we can optimise by removing every other entry from A
 185     //   and popping the constant zero from B
 186     else if (_TECHMAP_CONSTMSK_B_[0] && !_TECHMAP_CONSTVAL_B_[0]) begin
 187       wire [(A_WIDTH+1)/2-1:0] A_i;
 188       for (i = 0; i < (A_WIDTH+1)/2; i++)
 189         assign A_i[i] = A[i*2];
 190       \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH((A_WIDTH+1'd1)/2'd2), .B_WIDTH(B_WIDTH-1'd1), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(A_i), .B(B[B_WIDTH-1:1]), .Y(Y));
 191     end
 192     // Trim off any leading 1'bx -es in A, and resize B accordingly
 193     else if (num_leading_X_in_A > 0) begin
 194       localparam A_WIDTH_new = A_WIDTH - num_leading_X_in_A;
 195       localparam B_WIDTH_new = $clog2(A_WIDTH_new);
 196       \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(A_WIDTH_new), .B_WIDTH(B_WIDTH_new), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(A[A_WIDTH_new-1:0]), .B(B[B_WIDTH_new-1:0]), .Y(Y));
 197     end
 198     else if (B_WIDTH < 3 || A_WIDTH <= 4) begin
 199       \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(A_WIDTH), .B_WIDTH(B_WIDTH), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(A), .B(B), .Y(Y));
 200     end
 201     else if (B_WIDTH == 3) begin
 202       localparam a_width0 = 2 ** 2;
 203       localparam a_widthN = A_WIDTH - a_width0;
 204       wire T0, T1;
 205       \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_width0), .B_WIDTH(2),                .Y_WIDTH(Y_WIDTH)) fpga_soft_mux      (.A(A[a_width0-1:0]),       .B(B[2-1:0]),                .Y(T0));
 206       if (a_widthN > 1)
 207         \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_widthN), .B_WIDTH($clog2(a_widthN)), .Y_WIDTH(Y_WIDTH)) fpga_soft_mux_last (.A(A[A_WIDTH-1:a_width0]), .B(B[$clog2(a_widthN)-1:0]), .Y(T1));
 208       else
 209         assign T1 = A[A_WIDTH-1];
 210       MUXF7 fpga_hard_mux (.I0(T0), .I1(T1), .S(B[B_WIDTH-1]), .O(Y));
 211     end
 212     else if (B_WIDTH == 4) begin
 213       localparam a_width0 = 2 ** 2;
 214       localparam num_mux8 = A_WIDTH / a_width0;
 215       localparam a_widthN = A_WIDTH - num_mux8*a_width0;
 216       wire [4-1:0] T;
 217       wire T0, T1;
 218       for (i = 0; i < 4; i++)
 219         if (i < num_mux8)
 220           \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_width0), .B_WIDTH(2),                .Y_WIDTH(Y_WIDTH)) fpga_soft_mux      (.A(A[i*a_width0+:a_width0]), .B(B[2-1:0]),                .Y(T[i]));
 221         else if (i == num_mux8 && a_widthN > 0) begin
 222           if (a_widthN > 1)
 223             \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_widthN), .B_WIDTH($clog2(a_widthN)), .Y_WIDTH(Y_WIDTH)) fpga_soft_mux_last (.A(A[A_WIDTH-1:i*a_width0]), .B(B[$clog2(a_widthN)-1:0]), .Y(T[i]));
 224           else
 225             assign T[i] = A[A_WIDTH-1];
 226         end
 227         else
 228           assign T[i] = 1'bx;
 229       MUXF7 fpga_hard_mux_0 (.I0(T[0]), .I1(T[1]), .S(B[2]), .O(T0));
 230       MUXF7 fpga_hard_mux_1 (.I0(T[2]), .I1(T[3]), .S(B[2]), .O(T1));
 231       MUXF8 fpga_hard_mux_2 (.I0(T0),   .I1(T1),   .S(B[3]), .O(Y));
 232     end
 233     else begin
 234       localparam a_width0 = 2 ** 4;
 235       localparam num_mux16 = A_WIDTH / a_width0;
 236       localparam a_widthN = A_WIDTH - num_mux16*a_width0;
 237       wire [(2**(B_WIDTH-4))-1:0] T;
 238       for (i = 0; i < 2 ** (B_WIDTH-4); i++)
 239         if (i < num_mux16)
 240           \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_width0), .B_WIDTH(4),                .Y_WIDTH(Y_WIDTH)) fpga_soft_mux      (.A(A[i*a_width0+:a_width0]), .B(B[4-1:0]),                .Y(T[i]));
 241         else if (i == num_mux16 && a_widthN > 0) begin
 242           if (a_widthN > 1)
 243             \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_widthN), .B_WIDTH($clog2(a_widthN)), .Y_WIDTH(Y_WIDTH)) fpga_soft_mux_last (.A(A[A_WIDTH-1:i*a_width0]), .B(B[$clog2(a_widthN)-1:0]), .Y(T[i]));
 244           else
 245             assign T[i] = A[A_WIDTH-1];
 246         end
 247         else
 248           assign T[i] = 1'bx;
 249       \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(2**(B_WIDTH-4)), .B_WIDTH(B_WIDTH-4), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(T), .B(B[B_WIDTH-1:4]), .Y(Y));
 250     end
 251   endgenerate
 252 endmodule
 253
 254 module \$_MUX8_ (A, B, C, D, E, F, G, H, S, T, U, Y);
 255 input A, B, C, D, E, F, G, H, S, T, U;
 256 output Y;
 257   \$__XILINX_SHIFTX  #(.A_SIGNED(0), .B_SIGNED(0), .A_WIDTH(8), .B_WIDTH(3), .Y_WIDTH(1)) _TECHMAP_REPLACE_ (.A({H,G,F,E,D,C,B,A}), .B({U,T,S}), .Y(Y));
 258 endmodule
 259
 260 module \$_MUX16_ (A, B, C, D, E, F, G, H, I, J, K, L, M, N, O, P, S, T, U, V, Y);
 261 input A, B, C, D, E, F, G, H, I, J, K, L, M, N, O, P, S, T, U, V;
 262 output Y;
 263   \$__XILINX_SHIFTX  #(.A_SIGNED(0), .B_SIGNED(0), .A_WIDTH(16), .B_WIDTH(4), .Y_WIDTH(1)) _TECHMAP_REPLACE_ (.A({P,O,N,M,L,K,J,I,H,G,F,E,D,C,B,A}), .B({V,U,T,S}), .Y(Y));
 264 endmodule