techlibs/xilinx/cells_map.v

   1 /*
   2  *  yosys -- Yosys Open SYnthesis Suite
   3  *
   4  *  Copyright (C) 2012  Clifford Wolf <clifford@clifford.at>
   5  *
   6  *  Permission to use, copy, modify, and/or distribute this software for any
   7  *  purpose with or without fee is hereby granted, provided that the above
   8  *  copyright notice and this permission notice appear in all copies.
   9  *
  10  *  THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  11  *  WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  12  *  MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  13  *  ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  14  *  WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  15  *  ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  16  *  OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  17  *
  18  */
  19
  20 module \$__SHREG_ (input C, input D, input E, output Q);
  21   parameter DEPTH = 0;
  22   parameter [DEPTH-1:0] INIT = 0;
  23   parameter CLKPOL = 1;
  24   parameter ENPOL = 2;
  25
  26   \$__XILINX_SHREG_ #(.DEPTH(DEPTH), .INIT(INIT), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) _TECHMAP_REPLACE_ (.C(C), .D(D), .L(DEPTH-1), .E(E), .Q(Q));
  27 endmodule
  28
  29 module \$__XILINX_SHREG_ (input C, input D, input [31:0] L, input E, output Q, output SO);
  30   parameter DEPTH = 0;
  31   parameter [DEPTH-1:0] INIT = 0;
  32   parameter CLKPOL = 1;
  33   parameter ENPOL = 2;
  34
  35   // shregmap's INIT parameter shifts out LSB first;
  36   // however Xilinx expects MSB first
  37   function [DEPTH-1:0] brev;
  38     input [DEPTH-1:0] din;
  39     integer i;
  40     begin
  41       for (i = 0; i < DEPTH; i=i+1)
  42         brev[i] = din[DEPTH-1-i];
  43     end
  44   endfunction
  45   localparam [DEPTH-1:0] INIT_R = brev(INIT);
  46
  47   parameter _TECHMAP_CONSTMSK_L_ = 0;
  48   parameter _TECHMAP_CONSTVAL_L_ = 0;
  49
  50   wire CE;
  51   generate
  52     if (ENPOL == 0)
  53       assign CE = ~E;
  54     else if (ENPOL == 1)
  55       assign CE = E;
  56     else
  57       assign CE = 1'b1;
  58     if (DEPTH == 1) begin
  59       if (CLKPOL)
  60           FDRE #(.INIT(INIT_R)) _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .CE(CE), .R(1'b0));
  61       else
  62           FDRE_1 #(.INIT(INIT_R)) _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .CE(CE), .R(1'b0));
  63     end else
  64     if (DEPTH <= 16) begin
  65       SRL16E #(.INIT(INIT_R), .IS_CLK_INVERTED(~CLKPOL[0])) _TECHMAP_REPLACE_ (.A0(L[0]), .A1(L[1]), .A2(L[2]), .A3(L[3]), .CE(CE), .CLK(C), .D(D), .Q(Q));
  66     end else
  67     if (DEPTH > 17 && DEPTH <= 32) begin
  68       SRLC32E #(.INIT(INIT_R), .IS_CLK_INVERTED(~CLKPOL[0])) _TECHMAP_REPLACE_ (.A(L[4:0]), .CE(CE), .CLK(C), .D(D), .Q(Q));
  69     end else
  70     if (DEPTH > 33 && DEPTH <= 64) begin
  71       wire T0, T1, T2;
  72       SRLC32E #(.INIT(INIT_R[32-1:0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D(D), .Q(T0), .Q31(T1));
  73       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-32), .INIT(INIT[DEPTH-32-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T1), .L(L), .E(E), .Q(T2));
  74       if (&_TECHMAP_CONSTMSK_L_)
  75         assign Q = T2;
  76       else
  77         MUXF7 fpga_mux_0 (.O(Q), .I0(T0), .I1(T2), .S(L[5]));
  78     end else
  79     if (DEPTH > 65 && DEPTH <= 96) begin
  80       wire T0, T1, T2, T3, T4, T5, T6;
  81       SRLC32E #(.INIT(INIT_R[32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
  82       SRLC32E #(.INIT(INIT_R[64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
  83       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-64), .INIT(INIT[DEPTH-64-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_2 (.C(C), .D(T3), .L(L[4:0]), .E(E), .Q(T4));
  84       if (&_TECHMAP_CONSTMSK_L_)
  85         assign Q = T4;
  86       else begin
  87         MUXF7 fpga_mux_0 (.O(T5), .I0(T0), .I1(T2), .S(L[5]));
  88         MUXF7 fpga_mux_1 (.O(T6), .I0(T4), .I1(1'b0 /* unused */), .S(L[5]));
  89         MUXF8 fpga_mux_2 (.O(Q), .I0(T5), .I1(T6), .S(L[6]));
  90       end
  91     end else
  92     if (DEPTH > 97 && DEPTH < 128) begin
  93       wire T0, T1, T2, T3, T4, T5, T6, T7, T8;
  94       SRLC32E #(.INIT(INIT_R[32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
  95       SRLC32E #(.INIT(INIT_R[64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
  96       SRLC32E #(.INIT(INIT_R[96-1:64]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_2 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T3), .Q(T4), .Q31(T5));
  97       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-96), .INIT(INIT[DEPTH-96-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_3 (.C(C), .D(T5), .L(L[4:0]), .E(E), .Q(T6));
  98       if (&_TECHMAP_CONSTMSK_L_)
  99         assign Q = T6;
 100       else begin
 101         MUXF7 fpga_mux_0 (.O(T7), .I0(T0), .I1(T2), .S(L[5]));
 102         MUXF7 fpga_mux_1 (.O(T8), .I0(T4), .I1(T6), .S(L[5]));
 103         MUXF8 fpga_mux_2 (.O(Q), .I0(T7), .I1(T8), .S(L[6]));
 104       end
 105     end
 106     else if (DEPTH == 128) begin
 107       wire T0, T1, T2, T3, T4, T5, T6;
 108       SRLC32E #(.INIT(INIT_R[ 32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
 109       SRLC32E #(.INIT(INIT_R[ 64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
 110       SRLC32E #(.INIT(INIT_R[ 96-1:64]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_2 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T3), .Q(T4), .Q31(T5));
 111       SRLC32E #(.INIT(INIT_R[128-1:96]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_3 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T5), .Q(T6), .Q31(SO));
 112       if (&_TECHMAP_CONSTMSK_L_)
 113         assign Q = T6;
 114       else begin
 115         wire T7, T8;
 116         MUXF7 fpga_mux_0 (.O(T7), .I0(T0), .I1(T2), .S(L[5]));
 117         MUXF7 fpga_mux_1 (.O(T8), .I0(T4), .I1(T6), .S(L[5]));
 118         MUXF8 fpga_mux_2 (.O(Q), .I0(T7), .I1(T8), .S(L[6]));
 119       end
 120     end
 121     else if (DEPTH <= 129 && ~&_TECHMAP_CONSTMSK_L_) begin
 122       // Handle cases where fixed-length depth is
 123       // just 1 over a convenient value
 124       \$__XILINX_SHREG_ #(.DEPTH(DEPTH+1), .INIT({INIT,1'b0}), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) _TECHMAP_REPLACE_ (.C(C), .D(D), .L(L), .E(E), .Q(Q));
 125     end
 126     else begin
 127       localparam lower_clog2 = $clog2((DEPTH+1)/2);
 128       localparam lower_depth = 2 ** lower_clog2;
 129       wire T0, T1, T2, T3;
 130       if (&_TECHMAP_CONSTMSK_L_) begin
 131         \$__XILINX_SHREG_ #(.DEPTH(lower_depth), .INIT(INIT[DEPTH-1:DEPTH-lower_depth]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_0 (.C(C), .D(D), .L(lower_depth-1), .E(E), .Q(T0));
 132         \$__XILINX_SHREG_ #(.DEPTH(DEPTH-lower_depth), .INIT(INIT[DEPTH-lower_depth-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T0), .L(DEPTH-lower_depth-1), .E(E), .Q(Q), .SO(T3));
 133       end
 134       else begin
 135         \$__XILINX_SHREG_ #(.DEPTH(lower_depth), .INIT(INIT[DEPTH-1:DEPTH-lower_depth]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_0 (.C(C), .D(D), .L(L[lower_clog2-1:0]), .E(E), .Q(T0), .SO(T1));
 136         \$__XILINX_SHREG_ #(.DEPTH(DEPTH-lower_depth), .INIT(INIT[DEPTH-lower_depth-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T1), .L(L[lower_clog2-1:0]), .E(E), .Q(T2), .SO(T3));
 137         assign Q = L[lower_clog2] ? T2 : T0;
 138       end
 139       if (DEPTH == 2 * lower_depth)
 140           assign SO = T3;
 141     end
 142   endgenerate
 143 endmodule
 144
 145 `ifndef NO_MUXFN
 146 module \$shiftx (A, B, Y);
 147   parameter A_SIGNED = 0;
 148   parameter B_SIGNED = 0;
 149   parameter A_WIDTH = 1;
 150   parameter B_WIDTH = 1;
 151   parameter Y_WIDTH = 1;
 152
 153   input [A_WIDTH-1:0] A;
 154   input [B_WIDTH-1:0] B;
 155   output [Y_WIDTH-1:0] Y;
 156
 157   parameter [B_WIDTH-1:0] _TECHMAP_CONSTMSK_B_ = 0;
 158   parameter [B_WIDTH-1:0] _TECHMAP_CONSTVAL_B_ = 0;
 159
 160   generate
 161     genvar i, j;
 162     if (B_SIGNED) begin
 163       if (_TECHMAP_CONSTMSK_B_[B_WIDTH-1] && _TECHMAP_CONSTVAL_B_[B_WIDTH-1] == 1'b0)
 164         // Optimisation to remove B_SIGNED if sign bit of B is constant-0
 165         \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(0), .A_WIDTH(A_WIDTH), .B_WIDTH(B_WIDTH-1'd1), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(A), .B(B[B_WIDTH-2:0]), .Y(Y));
 166       else
 167         wire _TECHMAP_FAIL_ = 1;
 168     end
 169     else if (Y_WIDTH > 1) begin
 170       for (i = 0; i < Y_WIDTH; i++)
 171         \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(A_WIDTH-Y_WIDTH+1), .B_WIDTH(B_WIDTH), .Y_WIDTH(1'd1)) bitblast (.A(A[A_WIDTH-Y_WIDTH+i:i]), .B(B), .Y(Y[i]));
 172     end
 173     // If the LSB of B is constant zero (and Y_WIDTH is 1) then
 174     //   we can optimise by removing every other entry from A
 175     //   and popping the constant zero from B
 176     else if (_TECHMAP_CONSTMSK_B_[0] && !_TECHMAP_CONSTVAL_B_[0]) begin
 177       wire [(A_WIDTH+1)/2-1:0] A_i;
 178       for (i = 0; i < (A_WIDTH+1)/2; i++)
 179         assign A_i[i] = A[i*2];
 180       \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH((A_WIDTH+1'd1)/2'd2), .B_WIDTH(B_WIDTH-1'd1), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(A_i), .B(B[B_WIDTH-1:1]), .Y(Y));
 181     end
 182     else if (B_WIDTH < 3) begin
 183       wire _TECHMAP_FAIL_ = 1;
 184     end
 185     else if (B_WIDTH == 3) begin
 186       localparam a_width0 = 2 ** 2;
 187       localparam a_widthN = A_WIDTH - a_width0;
 188       wire T0, T1;
 189       \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_width0), .B_WIDTH(2),                .Y_WIDTH(Y_WIDTH)) fpga_shiftx      (.A(A[a_width0-1:0]),       .B(B[2-1:0]),                .Y(T0));
 190       \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_widthN), .B_WIDTH($clog2(a_widthN)), .Y_WIDTH(Y_WIDTH)) fpga_shiftx_last (.A(A[A_WIDTH-1:a_width0]), .B(B[$clog2(a_widthN)-1:0]), .Y(T1));
 191       MUXF7 fpga_mux (.I0(T0), .I1(T1), .S(B[B_WIDTH-1]), .O(Y));
 192     end
 193     else if (B_WIDTH == 4) begin
 194       localparam a_width0 = 2 ** 2;
 195       localparam num_mux8 = A_WIDTH / a_width0;
 196       localparam a_widthN = A_WIDTH - num_mux8*a_width0;
 197       wire [4-1:0] T;
 198       wire T0, T1;
 199       for (i = 0; i < 4; i++)
 200         if (i < num_mux8)
 201           \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_width0), .B_WIDTH(2),                .Y_WIDTH(Y_WIDTH)) fpga_shiftx      (.A(A[i*a_width0+:a_width0]), .B(B[2-1:0]),                .Y(T[i]));
 202         else if (i == num_mux8 && a_widthN > 0)
 203           \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_widthN), .B_WIDTH($clog2(a_widthN)), .Y_WIDTH(Y_WIDTH)) fpga_shiftx_last (.A(A[A_WIDTH-1:i*a_width0]), .B(B[$clog2(a_widthN)-1:0]), .Y(T[i]));
 204         else
 205           assign T[i] = 1'bx;
 206       MUXF7 fpga_mux_0 (.I0(T[0]), .I1(T[1]), .S(B[2]), .O(T0));
 207       MUXF7 fpga_mux_1 (.I0(T[2]), .I1(T[3]), .S(B[2]), .O(T1));
 208       MUXF8 fpga_mux_2 (.I0(T0),   .I1(T1),   .S(B[3]), .O(Y));
 209     end
 210     else begin
 211       localparam a_width0 = 2 ** 4;
 212       localparam num_mux16 = A_WIDTH / a_width0;
 213       localparam a_widthN = A_WIDTH - num_mux16*a_width0;
 214       wire [(2**(B_WIDTH-4))-1:0] T;
 215       for (i = 0; i < 2 ** (B_WIDTH-4); i++)
 216         if (i < num_mux16)
 217           \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_width0), .B_WIDTH(4),                .Y_WIDTH(Y_WIDTH)) fpga_shiftx      (.A(A[i*a_width0+:a_width0]), .B(B[4-1:0]),                .Y(T[i]));
 218         else if (i == num_mux16 && a_widthN > 0) begin
 219           \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(a_widthN), .B_WIDTH($clog2(a_widthN)), .Y_WIDTH(Y_WIDTH)) fpga_shiftx_last (.A(A[A_WIDTH-1:i*a_width0]), .B(B[$clog2(a_widthN)-1:0]), .Y(T[i]));
 220         end
 221         else
 222           assign T[i] = 1'bx;
 223       \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(2**(B_WIDTH-4)), .B_WIDTH(B_WIDTH-4), .Y_WIDTH(Y_WIDTH)) fpga_shiftx (.A(T), .B(B[B_WIDTH-1:4]), .Y(Y));
 224     end
 225   endgenerate
 226 endmodule
 227 `endif // NO_MUXFN