techlibs/xilinx/cells_map.v

   1 /*
   2  *  yosys -- Yosys Open SYnthesis Suite
   3  *
   4  *  Copyright (C) 2012  Clifford Wolf <clifford@clifford.at>
   5  *                2019  Eddie Hung    <eddie@fpgeh.com>
   6  *
   7  *  Permission to use, copy, modify, and/or distribute this software for any
   8  *  purpose with or without fee is hereby granted, provided that the above
   9  *  copyright notice and this permission notice appear in all copies.
  10  *
  11  *  THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  12  *  WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  13  *  MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  14  *  ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  15  *  WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  16  *  ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  17  *  OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  18  *
  19  */
  20
  21 // Convert negative-polarity reset to positive-polarity
  22 (* techmap_celltype = "$_DFF_NN0_" *)
  23 module _90_dff_nn0_to_np0 (input D, C, R, output Q); \$_DFF_NP0_  _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .R(~R)); endmodule
  24 (* techmap_celltype = "$_DFF_PN0_" *)
  25 module _90_dff_pn0_to_pp0 (input D, C, R, output Q); \$_DFF_PP0_  _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .R(~R)); endmodule
  26 (* techmap_celltype = "$_DFF_NN1_" *)
  27 module _90_dff_nn1_to_np1 (input D, C, R, output Q); \$_DFF_NP1   _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .R(~R)); endmodule
  28 (* techmap_celltype = "$_DFF_PN1_" *)
  29 module _90_dff_pn1_to_pp1 (input D, C, R, output Q); \$_DFF_PP1   _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .R(~R)); endmodule
  30
  31 module \$__SHREG_ (input C, input D, input E, output Q);
  32   parameter DEPTH = 0;
  33   parameter [DEPTH-1:0] INIT = 0;
  34   parameter CLKPOL = 1;
  35   parameter ENPOL = 2;
  36
  37   \$__XILINX_SHREG_ #(.DEPTH(DEPTH), .INIT(INIT), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) _TECHMAP_REPLACE_ (.C(C), .D(D), .L(DEPTH-1), .E(E), .Q(Q));
  38 endmodule
  39
  40 module \$__XILINX_SHREG_ (input C, input D, input [31:0] L, input E, output Q, output SO);
  41   parameter DEPTH = 0;
  42   parameter [DEPTH-1:0] INIT = 0;
  43   parameter CLKPOL = 1;
  44   parameter ENPOL = 2;
  45
  46   // shregmap's INIT parameter shifts out LSB first;
  47   // however Xilinx expects MSB first
  48   function [DEPTH-1:0] brev;
  49     input [DEPTH-1:0] din;
  50     integer i;
  51     begin
  52       for (i = 0; i < DEPTH; i=i+1)
  53         brev[i] = din[DEPTH-1-i];
  54     end
  55   endfunction
  56   localparam [DEPTH-1:0] INIT_R = brev(INIT);
  57
  58   parameter _TECHMAP_CONSTMSK_L_ = 0;
  59   parameter _TECHMAP_CONSTVAL_L_ = 0;
  60
  61   wire CE;
  62   generate
  63     if (ENPOL == 0)
  64       assign CE = ~E;
  65     else if (ENPOL == 1)
  66       assign CE = E;
  67     else
  68       assign CE = 1'b1;
  69     if (DEPTH == 1) begin
  70       if (CLKPOL)
  71           FDRE #(.INIT(INIT_R)) _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .CE(CE), .R(1'b0));
  72       else
  73           FDRE_1 #(.INIT(INIT_R)) _TECHMAP_REPLACE_ (.D(D), .Q(Q), .C(C), .CE(CE), .R(1'b0));
  74     end else
  75     if (DEPTH <= 16) begin
  76       SRL16E #(.INIT(INIT_R), .IS_CLK_INVERTED(~CLKPOL[0])) _TECHMAP_REPLACE_ (.A0(L[0]), .A1(L[1]), .A2(L[2]), .A3(L[3]), .CE(CE), .CLK(C), .D(D), .Q(Q));
  77     end else
  78     if (DEPTH > 17 && DEPTH <= 32) begin
  79       SRLC32E #(.INIT(INIT_R), .IS_CLK_INVERTED(~CLKPOL[0])) _TECHMAP_REPLACE_ (.A(L[4:0]), .CE(CE), .CLK(C), .D(D), .Q(Q));
  80     end else
  81     if (DEPTH > 33 && DEPTH <= 64) begin
  82       wire T0, T1, T2;
  83       SRLC32E #(.INIT(INIT_R[32-1:0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D(D), .Q(T0), .Q31(T1));
  84       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-32), .INIT(INIT[DEPTH-32-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T1), .L(L), .E(E), .Q(T2));
  85       if (&_TECHMAP_CONSTMSK_L_)
  86         assign Q = T2;
  87       else
  88         MUXF7 fpga_mux_0 (.O(Q), .I0(T0), .I1(T2), .S(L[5]));
  89     end else
  90     if (DEPTH > 65 && DEPTH <= 96) begin
  91       wire T0, T1, T2, T3, T4, T5, T6;
  92       SRLC32E #(.INIT(INIT_R[32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
  93       SRLC32E #(.INIT(INIT_R[64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
  94       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-64), .INIT(INIT[DEPTH-64-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_2 (.C(C), .D(T3), .L(L[4:0]), .E(E), .Q(T4));
  95       if (&_TECHMAP_CONSTMSK_L_)
  96         assign Q = T4;
  97       else
  98         \$__XILINX_MUXF78 fpga_hard_mux (.I0(T0), .I1(T2), .I2(T4), .I3(1'bx), .S0(L[5]), .S1(L[6]), .O(Q));
  99     end else
 100     if (DEPTH > 97 && DEPTH < 128) begin
 101       wire T0, T1, T2, T3, T4, T5, T6, T7, T8;
 102       SRLC32E #(.INIT(INIT_R[32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
 103       SRLC32E #(.INIT(INIT_R[64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
 104       SRLC32E #(.INIT(INIT_R[96-1:64]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_2 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T3), .Q(T4), .Q31(T5));
 105       \$__XILINX_SHREG_ #(.DEPTH(DEPTH-96), .INIT(INIT[DEPTH-96-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_3 (.C(C), .D(T5), .L(L[4:0]), .E(E), .Q(T6));
 106       if (&_TECHMAP_CONSTMSK_L_)
 107         assign Q = T6;
 108       else
 109         \$__XILINX_MUXF78 fpga_hard_mux (.I0(T0), .I1(T2), .I2(T4), .I3(T6), .S0(L[5]), .S1(L[6]), .O(Q));
 110     end
 111     else if (DEPTH == 128) begin
 112       wire T0, T1, T2, T3, T4, T5, T6;
 113       SRLC32E #(.INIT(INIT_R[ 32-1: 0]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_0 (.A(L[4:0]), .CE(CE), .CLK(C), .D( D), .Q(T0), .Q31(T1));
 114       SRLC32E #(.INIT(INIT_R[ 64-1:32]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_1 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T1), .Q(T2), .Q31(T3));
 115       SRLC32E #(.INIT(INIT_R[ 96-1:64]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_2 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T3), .Q(T4), .Q31(T5));
 116       SRLC32E #(.INIT(INIT_R[128-1:96]), .IS_CLK_INVERTED(~CLKPOL[0])) fpga_srl_3 (.A(L[4:0]), .CE(CE), .CLK(C), .D(T5), .Q(T6), .Q31(SO));
 117       if (&_TECHMAP_CONSTMSK_L_)
 118         assign Q = T6;
 119       else
 120         \$__XILINX_MUXF78 fpga_hard_mux (.I0(T0), .I1(T2), .I2(T4), .I3(T6), .S0(L[5]), .S1(L[6]), .O(Q));
 121     end
 122     else if (DEPTH <= 129 && ~&_TECHMAP_CONSTMSK_L_) begin
 123       // Handle cases where fixed-length depth is
 124       // just 1 over a convenient value
 125       \$__XILINX_SHREG_ #(.DEPTH(DEPTH+1), .INIT({INIT,1'b0}), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) _TECHMAP_REPLACE_ (.C(C), .D(D), .L(L), .E(E), .Q(Q));
 126     end
 127     else begin
 128       localparam lower_clog2 = $clog2((DEPTH+1)/2);
 129       localparam lower_depth = 2 ** lower_clog2;
 130       wire T0, T1, T2, T3;
 131       if (&_TECHMAP_CONSTMSK_L_) begin
 132         \$__XILINX_SHREG_ #(.DEPTH(lower_depth), .INIT(INIT[DEPTH-1:DEPTH-lower_depth]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_0 (.C(C), .D(D), .L(lower_depth-1), .E(E), .Q(T0));
 133         \$__XILINX_SHREG_ #(.DEPTH(DEPTH-lower_depth), .INIT(INIT[DEPTH-lower_depth-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T0), .L(DEPTH-lower_depth-1), .E(E), .Q(Q), .SO(T3));
 134       end
 135       else begin
 136         \$__XILINX_SHREG_ #(.DEPTH(lower_depth), .INIT(INIT[DEPTH-1:DEPTH-lower_depth]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_0 (.C(C), .D(D), .L(L[lower_clog2-1:0]), .E(E), .Q(T0), .SO(T1));
 137         \$__XILINX_SHREG_ #(.DEPTH(DEPTH-lower_depth), .INIT(INIT[DEPTH-lower_depth-1:0]), .CLKPOL(CLKPOL), .ENPOL(ENPOL)) fpga_srl_1 (.C(C), .D(T1), .L(L[lower_clog2-1:0]), .E(E), .Q(T2), .SO(T3));
 138         assign Q = L[lower_clog2] ? T2 : T0;
 139       end
 140       if (DEPTH == 2 * lower_depth)
 141           assign SO = T3;
 142     end
 143   endgenerate
 144 endmodule
 145
 146 `ifdef MIN_MUX_INPUTS
 147 module \$__XILINX_SHIFTX (A, B, Y);
 148   parameter A_SIGNED = 0;
 149   parameter B_SIGNED = 0;
 150   parameter A_WIDTH = 1;
 151   parameter B_WIDTH = 1;
 152   parameter Y_WIDTH = 1;
 153
 154   input [A_WIDTH-1:0] A;
 155   input [B_WIDTH-1:0] B;
 156   output [Y_WIDTH-1:0] Y;
 157
 158   parameter [A_WIDTH-1:0] _TECHMAP_CONSTMSK_A_ = 0;
 159   parameter [A_WIDTH-1:0] _TECHMAP_CONSTVAL_A_ = 0;
 160   parameter [B_WIDTH-1:0] _TECHMAP_CONSTMSK_B_ = 0;
 161   parameter [B_WIDTH-1:0] _TECHMAP_CONSTVAL_B_ = 0;
 162
 163   function integer A_WIDTH_trimmed;
 164     input integer start;
 165   begin
 166     A_WIDTH_trimmed = start;
 167     while (A_WIDTH_trimmed > 0 && _TECHMAP_CONSTMSK_A_[A_WIDTH_trimmed-1] && _TECHMAP_CONSTVAL_A_[A_WIDTH_trimmed-1] === 1'bx)
 168       A_WIDTH_trimmed = A_WIDTH_trimmed - 1;
 169   end
 170   endfunction
 171
 172   generate
 173     genvar i, j;
 174     // Bit-blast
 175     if (Y_WIDTH > 1) begin
 176       for (i = 0; i < Y_WIDTH; i++)
 177         \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(A_WIDTH-Y_WIDTH+1), .B_WIDTH(B_WIDTH), .Y_WIDTH(1'd1)) bitblast (.A(A[A_WIDTH-Y_WIDTH+i:i]), .B(B), .Y(Y[i]));
 178     end
 179     // If the LSB of B is constant zero (and Y_WIDTH is 1) then
 180     //   we can optimise by removing every other entry from A
 181     //   and popping the constant zero from B
 182     else if (_TECHMAP_CONSTMSK_B_[0] && !_TECHMAP_CONSTVAL_B_[0]) begin
 183       wire [(A_WIDTH+1)/2-1:0] A_i;
 184       for (i = 0; i < (A_WIDTH+1)/2; i++)
 185         assign A_i[i] = A[i*2];
 186       \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH((A_WIDTH+1'd1)/2'd2), .B_WIDTH(B_WIDTH-1'd1), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(A_i), .B(B[B_WIDTH-1:1]), .Y(Y));
 187     end
 188     // Trim off any leading 1'bx -es in A
 189     else if (_TECHMAP_CONSTMSK_A_[A_WIDTH-1] && _TECHMAP_CONSTVAL_A_[A_WIDTH-1] === 1'bx) begin
 190       localparam A_WIDTH_new = A_WIDTH_trimmed(A_WIDTH-1);
 191       \$__XILINX_SHIFTX  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(A_WIDTH_new), .B_WIDTH(B_WIDTH), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(A[A_WIDTH_new-1:0]), .B(B), .Y(Y));
 192     end
 193     else if (A_WIDTH < `MIN_MUX_INPUTS) begin
 194       wire _TECHMAP_FAIL_ = 1;
 195     end
 196     else if (A_WIDTH == 2) begin
 197       MUXF7 fpga_hard_mux (.I0(A[0]), .I1(A[1]), .S(B[0]), .O(Y));
 198     end
 199     else if (A_WIDTH <= 4) begin
 200       // Rather than extend with 1'bx which gets flattened to 1'b0
 201       // causing the "don't care" status to get lost, extend with MSB
 202       // so that we can recognise again later when mapping MUXF78
 203       wire [4-1:0] Ax;
 204       if (A_WIDTH == 4)
 205         assign Ax = A;
 206       else
 207         assign Ax = {A[1-:4-A_WIDTH], A};
 208       \$__XILINX_MUXF78 fpga_hard_mux (.I0(Ax[0]), .I1(Ax[2]), .I2(Ax[1]), .I3(Ax[3]), .S0(B[1]), .S1(B[0]), .O(Y));
 209     end
 210     else if (A_WIDTH <= 8) begin
 211       // Rather than extend with 1'bx which gets flattened to 1'b0
 212       // causing the "don't care" status to get lost, extend with MSB
 213       // so that we can recognise again later when mapping MUXF78
 214       wire [8-1:0] Ax;
 215       if (A_WIDTH == 8)
 216         assign Ax = A;
 217       else
 218         assign Ax = {A[3-:8-A_WIDTH], A};
 219       wire T0 = B[2] ? Ax[4] : Ax[0];
 220       wire T1 = B[2] ? Ax[5] : Ax[1];
 221       wire T2 = B[2] ? Ax[6] : Ax[2];
 222       wire T3 = B[2] ? Ax[7] : Ax[3];
 223       \$__XILINX_MUXF78 fpga_hard_mux (.I0(T0), .I1(T2), .I2(T1), .I3(T3), .S0(B[1]), .S1(B[0]), .O(Y));
 224     end
 225     else if (A_WIDTH <= 16) begin
 226       // Rather than extend with 1'bx which gets flattened to 1'b0
 227       // causing the "don't care" status to get lost, extend with MSB
 228       // so that we can recognise again later when mapping MUXF78
 229       wire [16-1:0] Ax;
 230       if (A_WIDTH == 16)
 231         assign Ax = A;
 232       else
 233         assign Ax = {A[7-:8-A_WIDTH], A};
 234       wire T0 = B[2] ? B[3] ? Ax[12] : Ax[4]
 235                      : B[3] ? Ax[ 8] : Ax[0];
 236       wire T1 = B[2] ? B[3] ? Ax[13] : Ax[5]
 237                      : B[3] ? Ax[ 9] : Ax[1];
 238       wire T2 = B[2] ? B[3] ? Ax[14] : Ax[6]
 239                      : B[3] ? Ax[10] : Ax[2];
 240       wire T3 = B[2] ? B[3] ? Ax[15] : Ax[7]
 241                      : B[3] ? Ax[11] : Ax[3];
 242       \$__XILINX_MUXF78 fpga_hard_mux (.I0(T0), .I1(T2), .I2(T1), .I3(T3), .S0(B[1]), .S1(B[0]), .O(Y));
 243     end
 244     else begin
 245       localparam num_mux16 = (A_WIDTH+15) / 16;
 246       localparam clog2_num_mux16 = $clog2(num_mux16);
 247       wire [num_mux16-1:0] T;
 248       wire [num_mux16*16-1:0] Ax = {{(num_mux16*16-A_WIDTH){1'bx}}, A};
 249       for (i = 0; i < num_mux16; i++)
 250         \$__XILINX_SHIFTX  #(
 251           .A_SIGNED(A_SIGNED),
 252           .B_SIGNED(B_SIGNED),
 253           .A_WIDTH(16),
 254           .B_WIDTH(4),
 255           .Y_WIDTH(Y_WIDTH)
 256         ) fpga_mux (
 257           .A(Ax[i*16+:16]),
 258           .B(B[3:0]),
 259           .Y(T[i])
 260         );
 261       \$__XILINX_SHIFTX  #(
 262           .A_SIGNED(A_SIGNED),
 263           .B_SIGNED(B_SIGNED),
 264           .A_WIDTH(num_mux16),
 265           .B_WIDTH(clog2_num_mux16),
 266           .Y_WIDTH(Y_WIDTH)
 267       ) _TECHMAP_REPLACE_ (
 268           .A(T),
 269           .B(B[B_WIDTH-1-:clog2_num_mux16]),
 270           .Y(Y));
 271     end
 272   endgenerate
 273 endmodule
 274
 275 (* techmap_celltype = "$__XILINX_SHIFTX" *)
 276 module _90__XILINX_SHIFTX (A, B, Y);
 277   parameter A_SIGNED = 0;
 278   parameter B_SIGNED = 0;
 279   parameter A_WIDTH = 1;
 280   parameter B_WIDTH = 1;
 281   parameter Y_WIDTH = 1;
 282
 283   input [A_WIDTH-1:0] A;
 284   input [B_WIDTH-1:0] B;
 285   output [Y_WIDTH-1:0] Y;
 286
 287   \$shiftx  #(.A_SIGNED(A_SIGNED), .B_SIGNED(B_SIGNED), .A_WIDTH(A_WIDTH), .B_WIDTH(B_WIDTH), .Y_WIDTH(Y_WIDTH)) _TECHMAP_REPLACE_ (.A(A), .B(B), .Y(Y));
 288 endmodule
 289
 290 module \$_MUX_ (A, B, S, Y);
 291   input A, B, S;
 292   output Y;
 293   generate
 294     if (`MIN_MUX_INPUTS == 2)
 295       \$__XILINX_SHIFTX  #(.A_SIGNED(0), .B_SIGNED(0), .A_WIDTH(2), .B_WIDTH(1), .Y_WIDTH(1)) _TECHMAP_REPLACE_ (.A({B,A}), .B(S), .Y(Y));
 296     else
 297       wire _TECHMAP_FAIL_ = 1;
 298   endgenerate
 299 endmodule
 300
 301 module \$_MUX4_ (A, B, C, D, S, T, Y);
 302   input A, B, C, D, S, T;
 303   output Y;
 304   \$__XILINX_SHIFTX  #(.A_SIGNED(0), .B_SIGNED(0), .A_WIDTH(4), .B_WIDTH(2), .Y_WIDTH(1)) _TECHMAP_REPLACE_ (.A({D,C,B,A}), .B({T,S}), .Y(Y));
 305 endmodule
 306
 307 module \$_MUX8_ (A, B, C, D, E, F, G, H, S, T, U, Y);
 308   input A, B, C, D, E, F, G, H, S, T, U;
 309   output Y;
 310   \$__XILINX_SHIFTX  #(.A_SIGNED(0), .B_SIGNED(0), .A_WIDTH(8), .B_WIDTH(3), .Y_WIDTH(1)) _TECHMAP_REPLACE_ (.A({H,G,F,E,D,C,B,A}), .B({U,T,S}), .Y(Y));
 311 endmodule
 312
 313 module \$_MUX16_ (A, B, C, D, E, F, G, H, I, J, K, L, M, N, O, P, S, T, U, V, Y);
 314   input A, B, C, D, E, F, G, H, I, J, K, L, M, N, O, P, S, T, U, V;
 315   output Y;
 316   \$__XILINX_SHIFTX  #(.A_SIGNED(0), .B_SIGNED(0), .A_WIDTH(16), .B_WIDTH(4), .Y_WIDTH(1)) _TECHMAP_REPLACE_ (.A({P,O,N,M,L,K,J,I,H,G,F,E,D,C,B,A}), .B({V,U,T,S}), .Y(Y));
 317 endmodule
 318 `endif
 319
 320 `ifndef _ABC
 321 module \$__XILINX_MUXF78 (O, I0, I1, I2, I3, S0, S1);
 322   output O;
 323   input I0, I1, I2, I3, S0, S1;
 324   wire T0, T1;
 325   parameter _TECHMAP_BITS_CONNMAP_ = 0;
 326   parameter [_TECHMAP_BITS_CONNMAP_-1:0] _TECHMAP_CONNMAP_I0_ = 0;
 327   parameter [_TECHMAP_BITS_CONNMAP_-1:0] _TECHMAP_CONNMAP_I1_ = 0;
 328   parameter [_TECHMAP_BITS_CONNMAP_-1:0] _TECHMAP_CONNMAP_I2_ = 0;
 329   parameter [_TECHMAP_BITS_CONNMAP_-1:0] _TECHMAP_CONNMAP_I3_ = 0;
 330   parameter _TECHMAP_CONSTMSK_S0_ = 0;
 331   parameter _TECHMAP_CONSTVAL_S0_ = 0;
 332   parameter _TECHMAP_CONSTMSK_S1_ = 0;
 333   parameter _TECHMAP_CONSTVAL_S1_ = 0;
 334   if (_TECHMAP_CONSTMSK_S0_ && _TECHMAP_CONSTVAL_S0_ === 1'b1)
 335     assign T0 = I1;
 336   else if (_TECHMAP_CONSTMSK_S0_ || _TECHMAP_CONNMAP_I0_ === _TECHMAP_CONNMAP_I1_)
 337     assign T0 = I0;
 338   else
 339     MUXF7 mux7a (.I0(I0), .I1(I1), .S(S0), .O(T0));
 340   if (_TECHMAP_CONSTMSK_S0_ && _TECHMAP_CONSTVAL_S0_ === 1'b1)
 341     assign T1 = I3;
 342   else if (_TECHMAP_CONSTMSK_S0_ || _TECHMAP_CONNMAP_I2_ === _TECHMAP_CONNMAP_I3_)
 343     assign T1 = I2;
 344   else
 345     MUXF7 mux7b (.I0(I2), .I1(I3), .S(S0), .O(T1));
 346   if (_TECHMAP_CONSTMSK_S1_ && _TECHMAP_CONSTVAL_S1_ === 1'b1)
 347     assign O = T1;
 348   else if (_TECHMAP_CONSTMSK_S1_ || (_TECHMAP_CONNMAP_I0_ === _TECHMAP_CONNMAP_I1_ && _TECHMAP_CONNMAP_I1_ === _TECHMAP_CONNMAP_I2_ && _TECHMAP_CONNMAP_I2_ === _TECHMAP_CONNMAP_I3_))
 349     assign O = T0;
 350   else
 351     MUXF8 mux8 (.I0(T0), .I1(T1), .S(S1), .O(O));
 352 endmodule
 353 `endif